ld/scripttempl/v850.sc

   1 cat << EOF
   2 OUTPUT_FORMAT("elf32-v850", "elf32-v850",
   3               "elf32-v850")
   4 OUTPUT_ARCH(v850)
   5 ENTRY(_start)
   6 SEARCH_DIR(.);
   7 /*/critters/slug/grossman/install/sun4/v850-elf/lib*/
   8 SECTIONS
   9 {
  10   /* This saves a little space in the ELF file, since the zda starts
  11      at a higher location that the ELF headers take up.  */
  12
  13   .zdata ${ZDATA_START_ADDR} : {
  14         *(.zdata)
  15         *(.zbss)
  16         *(reszdata)
  17         *(.zcommon)
  18   }
  19
  20   /* This is the read only part of the zero data area.
  21      Having it as a seperate section prevents its
  22      attributes from being inherited by the zdata
  23      section.  Specifically it prevents the zdata
  24      section from being marked READONLY.  */
  25
  26   .rozdata ${ROZDATA_START_ADDR} : {
  27         *(.rozdata)
  28         *(romzdata)
  29         *(romzbss)
  30   }
  31
  32   /* Read-only sections, merged into text segment: */
  33   . = ${TEXT_START_ADDR};
  34   .interp       : { *(.interp) }
  35   .hash         : { *(.hash) }
  36   .dynsym       : { *(.dynsym) }
  37   .dynstr       : { *(.dynstr) }
  38   .rel.text     : { *(.rel.text) }
  39   .rela.text    : { *(.rela.text) }
  40   .rel.data     : { *(.rel.data) }
  41   .rela.data    : { *(.rela.data) }
  42   .rel.rodata   : { *(.rel.rodata) }
  43   .rela.rodata  : { *(.rela.rodata) }
  44   .rel.got      : { *(.rel.got) }
  45   .rela.got     : { *(.rela.got) }
  46   .rel.ctors    : { *(.rel.ctors) }
  47   .rela.ctors   : { *(.rela.ctors) }
  48   .rel.dtors    : { *(.rel.dtors) }
  49   .rela.dtors   : { *(.rela.dtors) }
  50   .rel.init     : { *(.rel.init) }
  51   .rela.init    : { *(.rela.init) }
  52   .rel.fini     : { *(.rel.fini) }
  53   .rela.fini    : { *(.rela.fini) }
  54   .rel.bss      : { *(.rel.bss) }
  55   .rela.bss     : { *(.rela.bss) }
  56   .rel.plt      : { *(.rel.plt) }
  57   .rela.plt     : { *(.rela.plt) }
  58   .init         : { KEEP (*(.init)) } =0
  59   .plt          : { *(.plt) }
  60
  61   .text         : {
  62     *(.text)
  63     ${RELOCATING+*(.text.*)}
  64     /* .gnu.warning sections are handled specially by elf32.em.  */
  65     *(.gnu.warning)
  66     *(.gnu.linkonce.t*)
  67   } =0
  68
  69   ${RELOCATING+_etext = .;}
  70   ${RELOCATING+PROVIDE (etext = .);}
  71
  72 /* start-sanitize-v850e */
  73    /* This is special code area at the end of the normal text section.
  74       It contains a small lookup table at the start followed by the
  75       code pointed to by entries in the lookup table.  */
  76
  77   .call_table_data ${CALL_TABLE_START_ADDR} : {
  78     ${RELOCATING+PROVIDE(__ctbp = .);}
  79     *(.call_table_data)
  80   } = 0xff   /* fill gaps with 0xff */
  81   .call_table_text : {
  82     *(.call_table_text)
  83   }
  84
  85 /* end-sanitize-v850e */
  86
  87   .fini         : { KEEP (*(.fini))    } =0
  88   .rodata       : { *(.rodata) ${RELOCATING+*(.rodata.*)} *(.gnu.linkonce.r*) }
  89   .rodata1      : { *(.rodata1) }
  90
  91   .data         : {
  92     *(.data)
  93     ${RELOCATING+*(.data.*)}
  94     *(.gnu.linkonce.d*)
  95     CONSTRUCTORS
  96   }
  97   .data1        : { *(.data1) }
  98   .ctors        : {
  99     ${RELOCATING+___ctors = .;}
 100     KEEP (*(.ctors))
 101     ${RELOCATING+___ctors_end = .;}
 102   }
 103
 104   .dtors        : {
 105     ${RELOCATING+___dtors = .;}
 106     KEEP (*(.dtors))
 107     ${RELOCATING+___dtors_end = .;}
 108   }
 109
 110   .got          : { *(.got.plt) *(.got) }
 111   .dynamic      : { *(.dynamic) }
 112
 113   .tdata ${TDATA_START_ADDR} : {
 114         ${RELOCATING+PROVIDE (__ep = .);}
 115         *(.tbyte)
 116         *(.tcommon_byte)
 117         *(.tdata)
 118         *(.tbss)
 119         *(.tcommon)
 120   }
 121
 122   /* We want the small data sections together, so single-instruction offsets
 123      can access them all, and initialized data all before uninitialized, so
 124      we can shorten the on-disk segment size.  */
 125   .sdata ${SDATA_START_ADDR} : {
 126         ${RELOCATING+PROVIDE (__gp = . + 0x8000);}
 127         *(.sdata)
 128         ${RELOCATING+__sbss_start = .;}
 129         *(.sbss)
 130         *(.scommon)
 131   }
 132
 133   /* See comment about .rozdata  */
 134   .rosdata ${ROSDATA_START_ADDR} : {
 135         *(.rosdata)
 136   }
 137
 138   ${RELOCATING+_edata  = DEFINED (__sbss_start) ? __sbss_start : . ;}
 139   ${RELOCATING+PROVIDE (edata = _edata);}
 140
 141   .bss       :
 142   {
 143         ${RELOCATING+__bss_start = DEFINED (__sbss_start) ? __sbss_start : . ;}
 144         *(.dynbss)
 145         *(.bss)
 146         *(COMMON)
 147   }
 148
 149   ${RELOCATING+_end = . ;}
 150   ${RELOCATING+PROVIDE (end = .);}
 151
 152   /* Stabs debugging sections.  */
 153   .stab 0               : { *(.stab) }
 154   .stabstr 0            : { *(.stabstr) }
 155   .stab.excl 0          : { *(.stab.excl) }
 156   .stab.exclstr 0       : { *(.stab.exclstr) }
 157   .stab.index 0         : { *(.stab.index) }
 158   .stab.indexstr 0      : { *(.stab.indexstr) }
 159   .comment 0            : { *(.comment) }
 160
 161   /* DWARF debug sections.
 162      Symbols in the DWARF debugging sections are relative to the beginning
 163      of the section so we begin them at 0.  */
 164
 165   /* DWARF 1 */
 166   .debug          0     : { *(.debug) }
 167   .line           0     : { *(.line) }
 168
 169   /* GNU DWARF 1 extensions */
 170   .debug_srcinfo  0     : { *(.debug_srcinfo) }
 171   .debug_sfnames  0     : { *(.debug_sfnames) }
 172
 173   /* DWARF 1.1 and DWARF 2 */
 174   .debug_aranges  0     : { *(.debug_aranges) }
 175   .debug_pubnames 0     : { *(.debug_pubnames) }
 176
 177   /* DWARF 2 */
 178   .debug_info     0     : { *(.debug_info) }
 179   .debug_abbrev   0     : { *(.debug_abbrev) }
 180   .debug_line     0     : { *(.debug_line) }
 181   .debug_frame    0     : { *(.debug_frame) }
 182   .debug_str      0     : { *(.debug_str) }
 183   .debug_loc      0     : { *(.debug_loc) }
 184   .debug_macinfo  0     : { *(.debug_macinfo) }
 185
 186   /* SGI/MIPS DWARF 2 extensions */
 187   .debug_weaknames 0    : { *(.debug_weaknames) }
 188   .debug_funcnames 0    : { *(.debug_funcnames) }
 189   .debug_typenames 0    : { *(.debug_typenames) }
 190   .debug_varnames  0    : { *(.debug_varnames) }
 191
 192   /* User stack */
 193   .stack 0x200000       : {
 194         ${RELOCATING+__stack = .;}
 195         *(.stack)
 196   }
 197   /* These must appear regardless of  .  */
 198 }
 199 EOF