ld/scripttempl/v850.sc

   1 cat << EOF
   2 OUTPUT_FORMAT("elf32-v850", "elf32-v850",
   3               "elf32-v850")
   4 OUTPUT_ARCH(v850)
   5 ENTRY(_start)
   6 SEARCH_DIR(.);
   7 /*/critters/slug/grossman/install/sun4/v850-elf/lib*/
   8 SECTIONS
   9 {
  10   /* This saves a little space in the ELF file, since the zda starts
  11      at a higher location that the ELF headers take up.  */
  12
  13   .zdata ${ZDATA_START_ADDR} : {
  14         *(.zdata)
  15         *(.rozdata)
  16         *(.zbss)
  17         *(reszdata)
  18         *(romzdata)
  19         *(romzbss)
  20   }
  21
  22   /* Read-only sections, merged into text segment: */
  23   . = ${TEXT_START_ADDR};
  24   .interp       : { *(.interp) }
  25   .hash         : { *(.hash) }
  26   .dynsym       : { *(.dynsym) }
  27   .dynstr       : { *(.dynstr) }
  28   .rel.text     : { *(.rel.text) }
  29   .rela.text    : { *(.rela.text) }
  30   .rel.data     : { *(.rel.data) }
  31   .rela.data    : { *(.rela.data) }
  32   .rel.rodata   : { *(.rel.rodata) }
  33   .rela.rodata  : { *(.rela.rodata) }
  34   .rel.got      : { *(.rel.got) }
  35   .rela.got     : { *(.rela.got) }
  36   .rel.ctors    : { *(.rel.ctors) }
  37   .rela.ctors   : { *(.rela.ctors) }
  38   .rel.dtors    : { *(.rel.dtors) }
  39   .rela.dtors   : { *(.rela.dtors) }
  40   .rel.init     : { *(.rel.init) }
  41   .rela.init    : { *(.rela.init) }
  42   .rel.fini     : { *(.rel.fini) }
  43   .rela.fini    : { *(.rela.fini) }
  44   .rel.bss      : { *(.rel.bss) }
  45   .rela.bss     : { *(.rela.bss) }
  46   .rel.plt      : { *(.rel.plt) }
  47   .rela.plt     : { *(.rela.plt) }
  48   .init         : { *(.init) } =0
  49   .plt          : { *(.plt) }
  50
  51   .text         : {
  52     *(.text)
  53     /* .gnu.warning sections are handled specially by elf32.em.  */
  54     *(.gnu.warning)
  55     *(.gnu.linkonce.t*)
  56   } =0
  57
  58   ${RELOCATING+_etext = .;}
  59   ${RELOCATING+PROVIDE (etext = .);}
  60
  61   .fini         : { *(.fini)    } =0
  62   .rodata       : { *(.rodata) *(.gnu.linkonce.r*) }
  63   .rodata1      : { *(.rodata1) }
  64
  65   .data         : {
  66     *(.data)
  67     *(.gnu.linkonce.d*)
  68     CONSTRUCTORS
  69   }
  70   .data1        : { *(.data1) }
  71   .ctors        : {
  72     ${RELOCATING+___ctors = .;}
  73     *(.ctors)
  74     ${RELOCATING+___ctors_end = .;}
  75   }
  76
  77   .dtors        : {
  78     ${RELOCATING+___dtors = .;}
  79     *(.dtors)
  80     ${RELOCATING+___dtors_end = .;}
  81   }
  82
  83   .got          : { *(.got.plt) *(.got) }
  84   .dynamic      : { *(.dynamic) }
  85
  86   .tdata ${TDATA_START_ADDR} : {
  87         ${RELOCATING+PROVIDE (__ep = .);}
  88         *(.tdata)
  89   }
  90
  91   /* We want the small data sections together, so single-instruction offsets
  92      can access them all, and initialized data all before uninitialized, so
  93      we can shorten the on-disk segment size.  */
  94   .sdata ${SDATA_START_ADDR} : {
  95         ${RELOCATING+PROVIDE (__gp = . + 0x8000);}
  96         *(.rosdata)
  97         *(.sdata)
  98         ${RELOCATING+__sbss_start = .;}
  99         *(.sbss)
 100         *(.scommon)
 101   }
 102
 103   ${RELOCATING+_edata  = DEFINED (__sbss_start) ? __sbss_start : . ;}
 104   ${RELOCATING+PROVIDE (edata = _edata);}
 105
 106   .bss       :
 107   {
 108         ${RELOCATING+__bss_start = DEFINED (__sbss_start) ? __sbss_start : . ;}
 109         *(.dynbss)
 110         *(.bss)
 111         *(COMMON)
 112   }
 113
 114   ${RELOCATING+_end = . ;}
 115   ${RELOCATING+PROVIDE (end = .);}
 116
 117   /* Stabs debugging sections.  */
 118   .stab 0               : { *(.stab) }
 119   .stabstr 0            : { *(.stabstr) }
 120   .stab.excl 0          : { *(.stab.excl) }
 121   .stab.exclstr 0       : { *(.stab.exclstr) }
 122   .stab.index 0         : { *(.stab.index) }
 123   .stab.indexstr 0      : { *(.stab.indexstr) }
 124   .comment 0            : { *(.comment) }
 125
 126   /* DWARF debug sections.
 127      Symbols in the DWARF debugging sections are relative to the beginning
 128      of the section so we begin them at 0.  */
 129
 130   /* DWARF 1 */
 131   .debug          0     : { *(.debug) }
 132   .line           0     : { *(.line) }
 133
 134   /* GNU DWARF 1 extensions */
 135   .debug_srcinfo  0     : { *(.debug_srcinfo) }
 136   .debug_sfnames  0     : { *(.debug_sfnames) }
 137
 138   /* DWARF 1.1 and DWARF 2 */
 139   .debug_aranges  0     : { *(.debug_aranges) }
 140   .debug_pubnames 0     : { *(.debug_pubnames) }
 141
 142   /* DWARF 2 */
 143   .debug_info     0     : { *(.debug_info) }
 144   .debug_abbrev   0     : { *(.debug_abbrev) }
 145   .debug_line     0     : { *(.debug_line) }
 146   .debug_frame    0     : { *(.debug_frame) }
 147   .debug_str      0     : { *(.debug_str) }
 148   .debug_loc      0     : { *(.debug_loc) }
 149   .debug_macinfo  0     : { *(.debug_macinfo) }
 150
 151   /* SGI/MIPS DWARF 2 extensions */
 152   .debug_weaknames 0    : { *(.debug_weaknames) }
 153   .debug_funcnames 0    : { *(.debug_funcnames) }
 154   .debug_typenames 0    : { *(.debug_typenames) }
 155   .debug_varnames  0    : { *(.debug_varnames) }
 156
 157 /*  .stack 0xffffec00   : { _stack = .; *(.stack) }*/
 158   .stack 0x200000       : {
 159         ${RELOCATING+_stack = .;}
 160         *(.stack)
 161   }
 162   /* These must appear regardless of  .  */
 163 }
 164 EOF