libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([xmalloc.c])
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case "$MAKEINFO" in
  73       */missing\ makeinfo*)
  74         BUILD_INFO=
  75         AC_MSG_WARN([
  76 *** Makeinfo is missing. Info documentation will not be built.])
  77         ;;
  78       *)
  79         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  80           x*\ [[1-3]].* )
  81             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  82             BUILD_INFO=
  83             AC_MSG_WARN([
  84 *** Makeinfo is too old. Info documentation will not be built.])
  85           ;;
  86         esac
  87         ;;
  88     esac
  89 fi
  90 AC_SUBST(MAKEINFO)
  91 AC_SUBST(BUILD_INFO)
  92
  93 AC_CHECK_PROG(PERL, perl, perl, )
  94 if test x"$PERL" = x""; then
  95   HAVE_PERL='#'
  96 else
  97   HAVE_PERL=''
  98 fi
  99 AC_SUBST(HAVE_PERL)
 100
 101 AC_CANONICAL_HOST
 102
 103 dnl When we start using automake:
 104 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 105
 106 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 107 dnl to call AC_CHECK_PROG.
 108 AC_CHECK_TOOL(AR, ar)
 109 AC_CHECK_TOOL(RANLIB, ranlib, :)
 110
 111 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
 112 if test -n "$PLUGIN_OPTION"; then
 113   if $AR --help 2>&1 | grep -q "\--plugin"; then
 114     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
 115     AC_SUBST(AR_PLUGIN_OPTION)
 116   fi
 117   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
 118     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
 119     AC_SUBST(RANLIB_PLUGIN_OPTION)
 120   fi
 121 fi
 122
 123 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 124 # Add --enable-multilib to configure.
 125 # Default to --enable-multilib
 126 AC_ARG_ENABLE(multilib,
 127 [  --enable-multilib       build many library versions (default)],
 128 [case "$enableval" in
 129   yes) multilib=yes ;;
 130   no)  multilib=no ;;
 131   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 132  esac],
 133               [multilib=yes])
 134
 135 # Even if the default multilib is not a cross compilation,
 136 # it may be that some of the other multilibs are.
 137 if test $cross_compiling = no && test $multilib = yes \
 138    && test "x${with_multisubdir}" != x ; then
 139    cross_compiling=maybe
 140 fi
 141
 142 # We may wish to install the target headers somewhere.
 143 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 144 dnl install-libiberty is disabled by default
 145
 146 AC_ARG_ENABLE(install-libiberty,
 147 [  --enable-install-libiberty       Install headers and library for end users],
 148 enable_install_libiberty=$enableval,
 149 enable_install_libiberty=no)dnl
 150
 151 # Option parsed, now set things appropriately.
 152 case x"$enable_install_libiberty" in
 153   xyes|x)
 154     target_header_dir=libiberty
 155     ;;
 156   xno)
 157     target_header_dir=
 158     ;;
 159   *)
 160     # This could be sanity-checked in various ways...
 161     target_header_dir="${enable_install_libiberty}"
 162     ;;
 163 esac
 164 AC_MSG_RESULT($enable_install_libiberty)
 165 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 166
 167 GCC_NO_EXECUTABLES
 168 AC_PROG_CC
 169 AC_GNU_SOURCE
 170 AC_SYS_LARGEFILE
 171 AC_PROG_CPP_WERROR
 172
 173 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 174                           -Wstrict-prototypes \
 175                           -Wshadow=local], [ac_libiberty_warn_cflags])
 176 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 177
 178 AC_PROG_CC_C_O
 179 # autoconf is lame and doesn't give us any substitution variable for this.
 180 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 181   NO_MINUS_C_MINUS_O=yes
 182 else
 183   OUTPUT_OPTION='-o $@'
 184 fi
 185 AC_SUBST(NO_MINUS_C_MINUS_O)
 186 AC_SUBST(OUTPUT_OPTION)
 187
 188 AC_C_CONST
 189 AC_C_INLINE
 190 AC_C_BIGENDIAN
 191
 192 dnl When we start using libtool:
 193 dnl Default to a non shared library.  This may be overridden by the
 194 dnl configure option --enable-shared.
 195 dnl AM_DISABLE_SHARED
 196
 197 dnl When we start using libtool:
 198 dnl AM_PROG_LIBTOOL
 199
 200 dnl When we start using automake:
 201 dnl AM_CONFIG_HEADER(config.h:config.in)
 202 AC_CONFIG_HEADER(config.h:config.in)
 203
 204 dnl When we start using automake:
 205 dnl AM_MAINTAINER_MODE
 206 dnl AC_EXEEXT
 207
 208 dnl When we start using automake:
 209 dnl AM_PROG_INSTALL
 210 AC_PROG_INSTALL
 211
 212 # Don't build the shared library for build.
 213 if [[ -n "${with_build_subdir}" ]]; then
 214   enable_shared=no
 215 fi
 216
 217 frag=
 218 case "${host}" in
 219   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 220                         frag=mh-aix ;;
 221   *-*-cxux7*)           frag=mh-cxux7 ;;
 222   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 223   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 224   i370-*-opened*)       frag=mh-openedition ;;
 225   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 226 esac
 227
 228 if [[ -n "${frag}" ]]; then
 229   frag=${libiberty_topdir}/libiberty/config/$frag
 230 fi
 231
 232 GCC_PICFLAG
 233
 234 # If they didn't specify --enable-shared, don't generate shared libs.
 235 case "${enable_shared}" in
 236   yes) shared=yes ;;
 237   no) shared=no ;;
 238   "") shared=no ;;
 239   *) shared=yes ;;
 240 esac
 241
 242 # ...unless --enable-host-shared was passed from top-level config:
 243 if [[ "${enable_host_shared}" = "yes" ]]; then
 244   shared=yes
 245 fi
 246
 247 if [[ "${shared}" != "yes" ]]; then
 248   PICFLAG=
 249 fi
 250 AC_SUBST(PICFLAG)
 251
 252 NOASANFLAG=
 253 case " ${CFLAGS} " in
 254   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 255   *\ -fsanitize=hwaddress\ *) NOASANFLAG=-fno-sanitize=hwaddress ;;
 256 esac
 257 AC_SUBST(NOASANFLAG)
 258
 259 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
 260 AC_SUBST(CET_HOST_FLAGS)
 261
 262 echo "# Warning: this fragment is automatically generated" > temp-frag
 263
 264 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 265   echo "Appending ${frag} to xhost-mkfrag"
 266   echo "# Following fragment copied from ${frag}" >> temp-frag
 267   cat ${frag} >> temp-frag
 268 fi
 269
 270 # record if we want to build shared libs.
 271 if [[ "${shared}" = "yes" ]]; then
 272   echo enable_shared = yes >> temp-frag
 273 else
 274   echo enable_shared = no >> temp-frag
 275 fi
 276
 277 frag=xhost-mkfrag
 278 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 279
 280 host_makefile_frag=${frag}
 281 AC_SUBST_FILE(host_makefile_frag)
 282
 283 # It's OK to check for header files.  Although the compiler may not be
 284 # able to link anything, it had better be able to at least compile
 285 # something.
 286 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 287 AC_HEADER_SYS_WAIT
 288 AC_HEADER_TIME
 289
 290 libiberty_AC_DECLARE_ERRNO
 291
 292 # Determine sizes of some types.
 293 AC_CHECK_SIZEOF([int])
 294 AC_CHECK_SIZEOF([long])
 295 AC_CHECK_SIZEOF([size_t])
 296
 297 # Check for presense of long long
 298 AC_CHECK_TYPE([long long],
 299   [AC_DEFINE(HAVE_LONG_LONG, 1, [Define if you have the `long long' type.]) AC_CHECK_SIZEOF([long long])],
 300   [])
 301
 302 # Look for a 64-bit type.
 303 AC_MSG_CHECKING([for a 64-bit type])
 304 AC_CACHE_VAL(liberty_cv_uint64,
 305 [AC_TRY_COMPILE(
 306 [#ifdef HAVE_STDINT_H
 307 #include <stdint.h>
 308 #endif],
 309 [extern uint64_t foo;],
 310 liberty_cv_uint64=uint64_t,
 311 [AC_TRY_COMPILE(
 312 [#ifdef HAVE_LIMITS_H
 313 #include <limits.h>
 314 #endif
 315 #ifndef CHAR_BIT
 316 #define CHAR_BIT 8
 317 #endif],
 318 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 319 liberty_cv_uint64="unsigned long",
 320 [AC_TRY_COMPILE(
 321 [#ifdef HAVE_LIMITS_H
 322 #include <limits.h>
 323 #endif
 324 #ifndef CHAR_BIT
 325 #define CHAR_BIT 8
 326 #endif],
 327 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 328 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 329 AC_MSG_RESULT($liberty_cv_uint64)
 330 if test "$liberty_cv_uint64" != none; then
 331   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 332                      [Define to an unsigned 64-bit type available in the compiler.])
 333 fi
 334
 335 AC_TYPE_INTPTR_T
 336 AC_TYPE_UINTPTR_T
 337 AC_TYPE_SSIZE_T
 338
 339 # Given the above check, we always have uintptr_t or a fallback
 340 # definition.  So define HAVE_UINTPTR_T in case any imported code
 341 # relies on it.
 342 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 343
 344 AC_TYPE_PID_T
 345
 346 # This is the list of functions which libiberty will provide if they
 347 # are not available on the host.
 348
 349 funcs="asprintf"
 350 funcs="$funcs atexit"
 351 funcs="$funcs basename"
 352 funcs="$funcs bcmp"
 353 funcs="$funcs bcopy"
 354 funcs="$funcs bsearch"
 355 funcs="$funcs bzero"
 356 funcs="$funcs calloc"
 357 funcs="$funcs clock"
 358 funcs="$funcs ffs"
 359 funcs="$funcs getcwd"
 360 funcs="$funcs getpagesize"
 361 funcs="$funcs gettimeofday"
 362 funcs="$funcs index"
 363 funcs="$funcs insque"
 364 funcs="$funcs memchr"
 365 funcs="$funcs memcmp"
 366 funcs="$funcs memcpy"
 367 funcs="$funcs memmem"
 368 funcs="$funcs memmove"
 369 funcs="$funcs mempcpy"
 370 funcs="$funcs memset"
 371 funcs="$funcs mkstemps"
 372 funcs="$funcs putenv"
 373 funcs="$funcs random"
 374 funcs="$funcs rename"
 375 funcs="$funcs rindex"
 376 funcs="$funcs setenv"
 377 funcs="$funcs snprintf"
 378 funcs="$funcs sigsetmask"
 379 funcs="$funcs stpcpy"
 380 funcs="$funcs stpncpy"
 381 funcs="$funcs strcasecmp"
 382 funcs="$funcs strchr"
 383 funcs="$funcs strdup"
 384 funcs="$funcs strncasecmp"
 385 funcs="$funcs strndup"
 386 funcs="$funcs strnlen"
 387 funcs="$funcs strrchr"
 388 funcs="$funcs strstr"
 389 funcs="$funcs strtod"
 390 funcs="$funcs strtol"
 391 funcs="$funcs strtoul"
 392 funcs="$funcs strtoll"
 393 funcs="$funcs strtoull"
 394 funcs="$funcs strverscmp"
 395 funcs="$funcs tmpnam"
 396 funcs="$funcs vasprintf"
 397 funcs="$funcs vfprintf"
 398 funcs="$funcs vprintf"
 399 funcs="$funcs vsnprintf"
 400 funcs="$funcs vsprintf"
 401 funcs="$funcs waitpid"
 402 funcs="$funcs setproctitle"
 403
 404 # Also in the old function.def file: alloca, vfork, getopt.
 405
 406 vars="sys_errlist sys_nerr sys_siglist"
 407
 408 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 409  getsysinfo gettimeofday on_exit pipe2 psignal pstat_getdynamic pstat_getstatic \
 410  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 411  sysmp table times wait3 wait4"
 412
 413 # These are neither executed nor required, but they help keep
 414 # autoheader happy without adding a bunch of text to acconfig.h.
 415 if test "x" = "y"; then
 416   AC_CHECK_FUNCS(asprintf atexit \
 417     basename bcmp bcopy bsearch bzero \
 418     calloc canonicalize_file_name clock \
 419     dup3 \
 420     ffs __fsetlocking \
 421     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 422     index insque \
 423     memchr memcmp memcpy memmem memmove memset mkstemps \
 424     on_exit \
 425     pipe2 psignal pstat_getdynamic pstat_getstatic putenv \
 426     random realpath rename rindex \
 427     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 428      stpcpy stpncpy strcasecmp strchr strdup \
 429      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 430      strtol strtoul strtoll strtoull strverscmp sysconf sysctl sysmp \
 431     table times tmpnam \
 432     vasprintf vfprintf vprintf vsprintf \
 433     wait3 wait4 waitpid)
 434   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf, strtol, strtoul, strtoll, strtoull, strnlen])
 435   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 436   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 437   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 438 fi
 439
 440 # For each of these functions, if the host does not provide the
 441 # function we want to put FN.o in LIBOBJS, and if the host does
 442 # provide the function, we want to define HAVE_FN in config.h.
 443
 444 setobjs=
 445 CHECK=
 446 if test -n "${with_target_subdir}"; then
 447
 448   # We are being configured as a target library.  AC_REPLACE_FUNCS
 449   # may not work correctly, because the compiler may not be able to
 450   # link executables.  Note that we may still be being configured
 451   # native.
 452
 453   # If we are being configured for newlib, we know which functions
 454   # newlib provide and which ones we will be expected to provide.
 455
 456   if test "x${with_newlib}" = "xyes"; then
 457     AC_LIBOBJ([asprintf])
 458     AC_LIBOBJ([basename])
 459     AC_LIBOBJ([insque])
 460     AC_LIBOBJ([random])
 461     AC_LIBOBJ([strdup])
 462     AC_LIBOBJ([vasprintf])
 463
 464     for f in $funcs; do
 465       case "$f" in
 466         asprintf | basename | insque | random | strdup | vasprintf)
 467           ;;
 468         *)
 469           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 470           AC_DEFINE_UNQUOTED($n)
 471           ;;
 472       esac
 473     done
 474
 475     # newlib doesnt provide any of the variables in $vars, so we
 476     # dont have to check them here.
 477
 478     # Of the functions in $checkfuncs, newlib only has strerror.
 479     AC_DEFINE(HAVE_STRERROR)
 480
 481     setobjs=yes
 482
 483   fi
 484
 485   # If we are being configured for Mingw, we know which functions
 486   # Mingw provides and which ones we will be expected to provide.
 487
 488   case "${host}" in
 489   *-*-mingw*)
 490     AC_LIBOBJ([asprintf])
 491     AC_LIBOBJ([basename])
 492     AC_LIBOBJ([bcmp])
 493     AC_LIBOBJ([bcopy])
 494     AC_LIBOBJ([bzero])
 495     AC_LIBOBJ([clock])
 496     AC_LIBOBJ([ffs])
 497     AC_LIBOBJ([getpagesize])
 498     AC_LIBOBJ([index])
 499     AC_LIBOBJ([insque])
 500     AC_LIBOBJ([mempcpy])
 501     AC_LIBOBJ([mkstemps])
 502     AC_LIBOBJ([random])
 503     AC_LIBOBJ([rindex])
 504     AC_LIBOBJ([sigsetmask])
 505     AC_LIBOBJ([stpcpy])
 506     AC_LIBOBJ([stpncpy])
 507     AC_LIBOBJ([strndup])
 508     AC_LIBOBJ([strnlen])
 509     AC_LIBOBJ([strverscmp])
 510     AC_LIBOBJ([vasprintf])
 511     AC_LIBOBJ([waitpid])
 512
 513     for f in $funcs; do
 514       case "$f" in
 515         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 516           ;;
 517         *)
 518           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 519           AC_DEFINE_UNQUOTED($n)
 520           ;;
 521       esac
 522     done
 523
 524     # Mingw doesnt provide any of the variables in $vars, so we
 525     # dont have to check them here.
 526
 527     # Of the functions in $checkfuncs, Mingw only has strerror.
 528     AC_DEFINE(HAVE_STRERROR)
 529
 530     setobjs=yes
 531     ;;
 532
 533   *-*-msdosdjgpp)
 534     AC_LIBOBJ([vasprintf])
 535     AC_LIBOBJ([vsnprintf])
 536     AC_LIBOBJ([snprintf])
 537     AC_LIBOBJ([asprintf])
 538
 539     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 540              getcwd getpagesize getrusage gettimeofday \
 541              index insque memchr memcmp memcpy memmove memset psignal \
 542              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 543              strchr strdup strerror strncasecmp strrchr strstr strtod \
 544              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 545              vsprintf waitpid
 546     do
 547       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 548       AC_DEFINE_UNQUOTED($n)
 549     done
 550
 551
 552     setobjs=yes
 553     ;;
 554
 555   esac
 556
 557 else
 558
 559    # Not a target library, so we set things up to run the test suite.
 560    CHECK=really-check
 561
 562 fi
 563
 564 AC_SUBST(CHECK)
 565 AC_SUBST(target_header_dir)
 566
 567 case "${host}" in
 568   *-*-cygwin* | *-*-mingw*)
 569     AC_DEFINE(HAVE_SYS_ERRLIST)
 570     AC_DEFINE(HAVE_SYS_NERR)
 571     ;;
 572 esac
 573
 574 if test -z "${setobjs}"; then
 575   case "${host}" in
 576
 577   *-*-vxworks*)
 578     # Handle VxWorks configuration specially, since on VxWorks the
 579     # libraries are actually on the target board, not in the file
 580     # system.
 581     AC_LIBOBJ([basename])
 582     AC_LIBOBJ([getpagesize])
 583     AC_LIBOBJ([insque])
 584     AC_LIBOBJ([random])
 585     AC_LIBOBJ([strcasecmp])
 586     AC_LIBOBJ([strncasecmp])
 587     AC_LIBOBJ([strdup])
 588     AC_LIBOBJ([vfork])
 589     AC_LIBOBJ([waitpid])
 590     AC_LIBOBJ([vasprintf])
 591     for f in $funcs; do
 592       case "$f" in
 593         basename | getpagesize | insque | random | strcasecmp)
 594           ;;
 595         strncasecmp | strdup | vfork | waitpid | vasprintf)
 596           ;;
 597         *)
 598           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 599           AC_DEFINE_UNQUOTED($n)
 600           ;;
 601       esac
 602     done
 603
 604     # VxWorks doesn't provide any of the variables in $vars, so we
 605     # don't have to check them here.
 606
 607     # Of the functions in $checkfuncs, VxWorks only has strerror.
 608     AC_DEFINE(HAVE_STRERROR)
 609
 610     setobjs=yes
 611     ;;
 612
 613   esac
 614 fi
 615
 616 if test -z "${setobjs}"; then
 617
 618   case "${host}" in
 619
 620   *-*-android*)
 621     # On android, getpagesize is defined in unistd.h as a static inline
 622     # function, which AC_CHECK_FUNCS does not handle properly.
 623     ac_cv_func_getpagesize=yes
 624     ;;
 625
 626   *-*-mingw32*)
 627     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 628     # macros, so the test below won't find them.
 629     libiberty_cv_var_sys_nerr=yes
 630     libiberty_cv_var_sys_errlist=yes
 631     ;;
 632
 633   *-*-msdosdjgpp*)
 634     # vfork and fork are stubs.
 635     ac_cv_func_vfork_works=no
 636     ;;
 637
 638   *-*-uwin*)
 639     # Under some versions of uwin, vfork is notoriously buggy and the test
 640     # can hang configure; on other versions, vfork exists just as a stub.
 641     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 642     ac_cv_func_vfork_works=no
 643     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 644     # macros (actually, these are imported from a DLL, but the end effect
 645     # is the same), so the test below won't find them.
 646     libiberty_cv_var_sys_nerr=yes
 647     libiberty_cv_var_sys_errlist=yes
 648     ;;
 649
 650   *-*-*vms*)
 651     # Under VMS, vfork works very different than on Unix. The standard test
 652     # won't work, and it isn't easily adaptable. It makes more sense to
 653     # just force it.
 654     ac_cv_func_vfork_works=yes
 655     ;;
 656
 657   esac
 658
 659   # We haven't set the list of objects yet.  Use the standard autoconf
 660   # tests.  This will only work if the compiler works.
 661   AC_ISC_POSIX
 662   AC_REPLACE_FUNCS($funcs)
 663   libiberty_AC_FUNC_C_ALLOCA
 664   AC_FUNC_FORK
 665   if test $ac_cv_func_vfork_works = no; then
 666     AC_LIBOBJ([vfork])
 667   fi
 668   # We only need _doprnt if we might use it to implement v*printf.
 669   if test $ac_cv_func_vprintf != yes \
 670      || test $ac_cv_func_vfprintf != yes \
 671      || test $ac_cv_func_vsprintf != yes; then
 672     AC_REPLACE_FUNCS(_doprnt)
 673   else
 674     AC_CHECK_FUNCS(_doprnt)
 675   fi
 676
 677   for v in $vars; do
 678     AC_MSG_CHECKING([for $v])
 679     AC_CACHE_VAL(libiberty_cv_var_$v,
 680       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 681                       [eval "libiberty_cv_var_$v=yes"],
 682                       [eval "libiberty_cv_var_$v=no"])])
 683     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 684       AC_MSG_RESULT(yes)
 685       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 686       AC_DEFINE_UNQUOTED($n)
 687     else
 688       AC_MSG_RESULT(no)
 689     fi
 690   done
 691
 692   # special check for _system_configuration because AIX <4.3.2 do not
 693   # contain the `physmem' member.
 694   AC_MSG_CHECKING([for external symbol _system_configuration])
 695   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 696                         [[double x = _system_configuration.physmem;]])],
 697     [AC_MSG_RESULT([yes])
 698     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 699               [Define if you have the _system_configuration variable.])],
 700     [AC_MSG_RESULT([no])])
 701
 702   AC_CHECK_FUNCS($checkfuncs)
 703   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 704   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 705   AC_CHECK_DECLS([strtol, strtoul, strtoll, strtoull])
 706   AC_CHECK_DECLS([strverscmp])
 707   AC_CHECK_DECLS([strnlen])
 708   libiberty_NEED_DECLARATION(canonicalize_file_name)
 709 fi
 710
 711 # Figure out which version of pexecute to use.
 712 case "${host}" in
 713      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 714      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 715      *-*-msdos*)                pexecute=pex-msdos  ;;
 716      *)                         pexecute=pex-unix   ;;
 717 esac
 718 AC_SUBST(pexecute)
 719
 720 libiberty_AC_FUNC_STRNCMP
 721
 722 # Install a library built with a cross compiler in $(tooldir) rather
 723 # than $(libdir).
 724 if test -z "${with_cross_host}"; then
 725   INSTALL_DEST=libdir
 726 else
 727   INSTALL_DEST=tooldir
 728 fi
 729 AC_SUBST(INSTALL_DEST)
 730
 731 m4_pattern_allow(LIBOBJS)
 732 L=""
 733 for l in x $LIBOBJS; do
 734   case $l in
 735     x) ;;
 736     *) L="$L ./$l" ;;
 737   esac
 738 done
 739 LIBOBJS="$L"
 740
 741 dnl Required by html and install-html
 742 AC_SUBST(datarootdir)
 743 AC_SUBST(docdir)
 744 AC_SUBST(htmldir)
 745
 746 # We need multilib support, but only if configuring for the target.
 747 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 748 AC_CONFIG_COMMANDS([default],
 749   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 750 if test -n "$CONFIG_FILES"; then
 751   if test -n "${with_target_subdir}"; then
 752     # FIXME: We shouldn't need to set ac_file
 753     ac_file=Makefile
 754     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 755     . ${libiberty_topdir}/config-ml.in
 756   fi
 757 fi]],
 758 [[srcdir=${srcdir}
 759 host=${host}
 760 target=${target}
 761 with_target_subdir=${with_target_subdir}
 762 with_multisubdir=${with_multisubdir}
 763 ac_configure_args="--enable-multilib ${ac_configure_args}"
 764 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 765 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 766 libiberty_topdir=${libiberty_topdir}
 767 ]])
 768 AC_OUTPUT