libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT(xmalloc.c)
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case "$MAKEINFO" in
  73       */missing\ makeinfo*)
  74         BUILD_INFO=
  75         AC_MSG_WARN([
  76 *** Makeinfo is missing. Info documentation will not be built.])
  77         ;;
  78       *)
  79         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  80           x*\ [[1-3]].* )
  81             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  82             BUILD_INFO=
  83             AC_MSG_WARN([
  84 *** Makeinfo is too old. Info documentation will not be built.])
  85           ;;
  86         esac
  87         ;;
  88     esac
  89 fi
  90 AC_SUBST(MAKEINFO)
  91 AC_SUBST(BUILD_INFO)
  92
  93 AC_CHECK_PROG(PERL, perl, perl, )
  94 if test x"$PERL" = x""; then
  95   HAVE_PERL='#'
  96 else
  97   HAVE_PERL=''
  98 fi
  99 AC_SUBST(HAVE_PERL)
 100
 101 AC_CANONICAL_HOST
 102
 103 dnl When we start using automake:
 104 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 105
 106 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 107 dnl to call AC_CHECK_PROG.
 108 AC_CHECK_TOOL(AR, ar)
 109 AC_CHECK_TOOL(RANLIB, ranlib, :)
 110
 111 GCC_NO_EXECUTABLES
 112 AC_PROG_CC
 113 AC_PROG_CPP_WERROR
 114
 115 if test x$GCC = xyes; then
 116   ac_libiberty_warn_cflags='-W -Wall -Wtraditional -pedantic'
 117 fi
 118 AC_SUBST(ac_libiberty_warn_cflags)
 119
 120 AC_PROG_CC_C_O
 121 # autoconf is lame and doesn't give us any substitution variable for this.
 122 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 123   NO_MINUS_C_MINUS_O=yes
 124 else
 125   OUTPUT_OPTION='-o $@'
 126 fi
 127 AC_SUBST(NO_MINUS_C_MINUS_O)
 128 AC_SUBST(OUTPUT_OPTION)
 129
 130 AC_C_CONST
 131 AC_C_INLINE
 132 AC_C_BIGENDIAN_CROSS
 133
 134 dnl When we start using libtool:
 135 dnl Default to a non shared library.  This may be overridden by the
 136 dnl configure option --enable-shared.
 137 dnl AM_DISABLE_SHARED
 138
 139 dnl When we start using libtool:
 140 dnl AM_PROG_LIBTOOL
 141
 142 dnl When we start using automake:
 143 dnl AM_CONFIG_HEADER(config.h:config.in)
 144 AC_CONFIG_HEADER(config.h:config.in)
 145
 146 dnl When we start using automake:
 147 dnl AM_MAINTAINER_MODE
 148 dnl AC_EXEEXT
 149
 150 dnl When we start using automake:
 151 dnl AM_PROG_INSTALL
 152 AC_PROG_INSTALL
 153
 154 . ${srcdir}/config.table
 155 host_makefile_frag=${frag}
 156 AC_SUBST_FILE(host_makefile_frag)
 157
 158 # It's OK to check for header files.  Although the compiler may not be
 159 # able to link anything, it had better be able to at least compile
 160 # something.
 161 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h)
 162 AC_HEADER_SYS_WAIT
 163 AC_HEADER_TIME
 164
 165 libiberty_AC_DECLARE_ERRNO
 166
 167 AC_CHECK_TYPE(uintptr_t, unsigned long)
 168 # Given the above check, we always have uintptr_t or a fallback
 169 # definition.  So define HAVE_UINTPTR_T in case any imported code
 170 # relies on it.
 171 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 172
 173 AC_TYPE_PID_T
 174
 175 # This is the list of functions which libiberty will provide if they
 176 # are not available on the host.
 177
 178 funcs="asprintf"
 179 funcs="$funcs atexit"
 180 funcs="$funcs basename"
 181 funcs="$funcs bcmp"
 182 funcs="$funcs bcopy"
 183 funcs="$funcs bsearch"
 184 funcs="$funcs bzero"
 185 funcs="$funcs calloc"
 186 funcs="$funcs clock"
 187 funcs="$funcs ffs"
 188 funcs="$funcs getcwd"
 189 funcs="$funcs getpagesize"
 190 funcs="$funcs index"
 191 funcs="$funcs insque"
 192 funcs="$funcs memchr"
 193 funcs="$funcs memcmp"
 194 funcs="$funcs memcpy"
 195 funcs="$funcs memmove"
 196 funcs="$funcs mempcpy"
 197 funcs="$funcs memset"
 198 funcs="$funcs mkstemps"
 199 funcs="$funcs putenv"
 200 funcs="$funcs random"
 201 funcs="$funcs rename"
 202 funcs="$funcs rindex"
 203 funcs="$funcs setenv"
 204 funcs="$funcs snprintf"
 205 funcs="$funcs sigsetmask"
 206 funcs="$funcs stpcpy"
 207 funcs="$funcs stpncpy"
 208 funcs="$funcs strcasecmp"
 209 funcs="$funcs strchr"
 210 funcs="$funcs strdup"
 211 funcs="$funcs strncasecmp"
 212 funcs="$funcs strrchr"
 213 funcs="$funcs strstr"
 214 funcs="$funcs strtod"
 215 funcs="$funcs strtol"
 216 funcs="$funcs strtoul"
 217 funcs="$funcs tmpnam"
 218 funcs="$funcs vasprintf"
 219 funcs="$funcs vfprintf"
 220 funcs="$funcs vprintf"
 221 funcs="$funcs vsnprintf"
 222 funcs="$funcs vsprintf"
 223 funcs="$funcs waitpid"
 224
 225 # Also in the old function.def file: alloca, vfork, getopt.
 226
 227 vars="sys_errlist sys_nerr sys_siglist"
 228
 229 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 230 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 231 checkfuncs="$checkfuncs getsysinfo table sysctl"
 232
 233 # These are neither executed nor required, but they help keep
 234 # autoheader happy without adding a bunch of text to acconfig.h.
 235 if test "x" = "y"; then
 236   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock \
 237   getcwd getpagesize index insque mkstemps memchr memcmp memcpy \
 238   memmove mempcpy memset putenv random rename rindex sigsetmask \
 239   strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strrchr strstr \
 240   strtod strtol strtoul tmpnam vasprintf vfprintf vprintf \
 241   vsprintf waitpid getrusage on_exit psignal strerror strsignal \
 242   sysconf times sbrk gettimeofday ffs snprintf vsnprintf \
 243   pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl \
 244   realpath canonicalize_file_name)
 245   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 246   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 247   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 248 fi
 249
 250 # For each of these functions, if the host does not provide the
 251 # function we want to put FN.o in LIBOBJS, and if the host does
 252 # provide the function, we want to define HAVE_FN in config.h.
 253
 254 setobjs=
 255 CHECK=
 256 target_header_dir=
 257 if test -n "${with_target_subdir}"; then
 258
 259   # We are being configured as a target library.  AC_REPLACE_FUNCS
 260   # may not work correctly, because the compiler may not be able to
 261   # link executables.  Note that we may still be being configured
 262   # native.
 263
 264   # If we are being configured for newlib, we know which functions
 265   # newlib provide and which ones we will be expected to provide.
 266
 267   if test "x${with_newlib}" = "xyes"; then
 268     AC_LIBOBJ([asprintf])
 269     AC_LIBOBJ([basename])
 270     AC_LIBOBJ([insque])
 271     AC_LIBOBJ([random])
 272     AC_LIBOBJ([strdup])
 273     AC_LIBOBJ([vasprintf])
 274
 275     for f in $funcs; do
 276       case "$f" in
 277         asprintf | basename | insque | random | strdup | vasprintf)
 278           ;;
 279         *)
 280           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 281           AC_DEFINE_UNQUOTED($n)
 282           ;;
 283       esac
 284     done
 285
 286     # newlib doesnt provide any of the variables in $vars, so we
 287     # dont have to check them here.
 288
 289     # Of the functions in $checkfuncs, newlib only has strerror.
 290     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 291
 292     setobjs=yes
 293
 294   fi
 295
 296   # We may wish to install the target headers somewhere.
 297   AC_ARG_ENABLE(install-libiberty,
 298   [  --enable-install-libiberty       Install headers for end users],
 299   enable_install_libiberty=$enableval,
 300   enable_install_libiberty=no)dnl
 301
 302   # Option parsed, now set things appropriately.
 303   case x"$enable_install_libiberty" in
 304     xyes|x)
 305       target_header_dir=libiberty
 306       ;;
 307     xno)
 308       target_header_dir=
 309       ;;
 310     *)
 311       # This could be sanity-checked in various ways...
 312       target_header_dir="${enable_install_libiberty}"
 313       ;;
 314   esac
 315
 316
 317 else
 318
 319    # Not a target library, so we set things up to run the test suite.
 320    CHECK=check-cplus-dem
 321
 322 fi
 323
 324 AC_SUBST(CHECK)
 325 AC_SUBST(target_header_dir)
 326
 327 case "${host}" in
 328   *-*-cygwin* | *-*-mingw*)
 329     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST)
 330     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR)
 331     ;;
 332 esac
 333
 334 if test -z "${setobjs}"; then
 335   case "${host}" in
 336
 337   *-*-vxworks*)
 338     # Handle VxWorks configuration specially, since on VxWorks the
 339     # libraries are actually on the target board, not in the file
 340     # system.
 341     AC_LIBOBJ([basename])
 342     AC_LIBOBJ([getpagesize])
 343     AC_LIBOBJ([insque])
 344     AC_LIBOBJ([random])
 345     AC_LIBOBJ([strcasecmp])
 346     AC_LIBOBJ([strncasecmp])
 347     AC_LIBOBJ([strdup])
 348     AC_LIBOBJ([vfork])
 349     AC_LIBOBJ([waitpid])
 350     AC_LIBOBJ([vasprintf])
 351     for f in $funcs; do
 352       case "$f" in
 353         basename | getpagesize | insque | random | strcasecmp)
 354           ;;
 355         strncasecmp | strdup | vfork | waitpid | vasprintf)
 356           ;;
 357         *)
 358           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 359           AC_DEFINE_UNQUOTED($n)
 360           ;;
 361       esac
 362     done
 363
 364     # VxWorks doesn't provide any of the variables in $vars, so we
 365     # don't have to check them here.
 366
 367     # Of the functions in $checkfuncs, VxWorks only has strerror.
 368     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 369
 370     setobjs=yes
 371     ;;
 372
 373   esac
 374 fi
 375
 376 if test -z "${setobjs}"; then
 377
 378   case "${host}" in
 379
 380   *-*-cygwin*)
 381     # The Cygwin library actually uses a couple of files from
 382     # libiberty when it is built.  If we are building a native
 383     # Cygwin, and we run the tests, we will appear to have these
 384     # files.  However, when we go on to build winsup, we will wind up
 385     # with a library which does not have the files, since they should
 386     # have come from libiberty.
 387
 388     # We handle this by removing the functions the winsup library
 389     # provides from our shell variables, so that they appear to be
 390     # missing.
 391
 392     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 393
 394     if test -n "${with_target_subdir}"
 395     then
 396       funcs="`echo $funcs | sed -e 's/random//'`"
 397       AC_LIBOBJ([random])
 398       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 399       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 400     fi
 401     ;;
 402
 403   *-*-mingw32*)
 404     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 405     # macros, so the test below won't find them.
 406     libiberty_cv_var_sys_nerr=yes
 407     libiberty_cv_var_sys_errlist=yes
 408     ;;
 409
 410   *-*-uwin*)
 411     # Under some versions of uwin, vfork is notoriously buggy and the test
 412     # can hang configure; on other versions, vfork exists just as a stub.
 413     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 414     ac_cv_func_vfork_works=no
 415     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 416     # macros (actually, these are imported from a DLL, but the end effect
 417     # is the same), so the test below won't find them.
 418     libiberty_cv_var_sys_nerr=yes
 419     libiberty_cv_var_sys_errlist=yes
 420     ;;
 421
 422   *-*-*vms*)
 423     # Under VMS, vfork works very different than on Unix. The standard test
 424     # won't work, and it isn't easily adaptable. It makes more sense to
 425     # just force it.
 426     ac_cv_func_vfork_works=yes
 427     ;;
 428
 429   esac
 430
 431   # We haven't set the list of objects yet.  Use the standard autoconf
 432   # tests.  This will only work if the compiler works.
 433   AC_ISC_POSIX
 434   AC_REPLACE_FUNCS($funcs)
 435   libiberty_AC_FUNC_C_ALLOCA
 436   AC_FUNC_VFORK
 437   if test $ac_cv_func_vfork_works = no; then
 438     AC_LIBOBJ([vfork])
 439   fi
 440   # We only need _doprnt if we might use it to implement v*printf.
 441   if test $ac_cv_func_vprintf != yes \
 442      || test $ac_cv_func_vfprintf != yes \
 443      || test $ac_cv_func_vsprintf != yes; then
 444     AC_REPLACE_FUNCS(_doprnt)
 445   else
 446     AC_CHECK_FUNCS(_doprnt)
 447   fi
 448
 449   for v in $vars; do
 450     AC_MSG_CHECKING([for $v])
 451     AC_CACHE_VAL(libiberty_cv_var_$v,
 452       [AC_TRY_LINK([int *p;], [extern int $v []; p = $v;],
 453                    [eval "libiberty_cv_var_$v=yes"],
 454                    [eval "libiberty_cv_var_$v=no"])])
 455     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 456       AC_MSG_RESULT(yes)
 457       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 458       AC_DEFINE_UNQUOTED($n)
 459     else
 460       AC_MSG_RESULT(no)
 461     fi
 462   done
 463
 464   # special check for _system_configuration because AIX <4.3.2 do not
 465   # contain the `physmem' member.
 466   AC_MSG_CHECKING([for external symbol _system_configuration])
 467   AC_TRY_COMPILE([#include <sys/systemcfg.h>],
 468                  [double x = _system_configuration.physmem;],
 469     [AC_MSG_RESULT([yes])
 470     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 471               [Define if you have the _system_configuration variable.])],
 472     [AC_MSG_RESULT([no])])
 473
 474   AC_CHECK_FUNCS($checkfuncs)
 475   libiberty_NEED_DECLARATION(canonicalize_file_name)
 476 fi
 477
 478 # Figure out which version of pexecute to use.
 479 case "${host}" in
 480      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32.o  ;;
 481      *-*-msdosdjgpp*)           pexecute=pex-djgpp.o  ;;
 482      *-*-msdos*)                pexecute=pex-msdos.o  ;;
 483      *-*-os2-emx*)              pexecute=pex-os2.o    ;;
 484      *)                         pexecute=pex-unix.o   ;;
 485 esac
 486 AC_SUBST(pexecute)
 487
 488 libiberty_AC_FUNC_STRNCMP
 489
 490 # Install a library built with a cross compiler in $(tooldir) rather
 491 # than $(libdir).
 492 if test -z "${with_cross_host}"; then
 493   INSTALL_DEST=libdir
 494 else
 495   INSTALL_DEST=tooldir
 496 fi
 497 AC_SUBST(INSTALL_DEST)
 498
 499 # We need multilib support, but only if configuring for the target.
 500 AC_OUTPUT(Makefile testsuite/Makefile,
 501 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 502 if test -n "$CONFIG_FILES"; then
 503   if test -n "${with_build_subdir}" || test -n "${with_target_subdir}"; then
 504     # FIXME: We shouldn't need to set ac_file
 505     ac_file=Makefile
 506     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 507     . ${libiberty_topdir}/config-ml.in
 508   fi
 509 fi],
 510 srcdir=${srcdir}
 511 host=${host}
 512 target=${target}
 513 with_target_subdir=${with_target_subdir}
 514 with_build_subdir=${with_build_subdir}
 515 with_multisubdir=${with_multisubdir}
 516 ac_configure_args="--enable-multilib ${ac_configure_args}"
 517 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 518 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 519 libiberty_topdir=${libiberty_topdir}
 520 )