m4/ax_pthread.m4

   1 # ===========================================================================
   2 #        https://www.gnu.org/software/autoconf-archive/ax_pthread.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro figures out how to build C programs using POSIX threads. It
  12 #   sets the PTHREAD_LIBS output variable to the threads library and linker
  13 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  14 #   flags that are needed. (The user can also force certain compiler
  15 #   flags/libs to be tested by setting these environment variables.)
  16 #
  17 #   Also sets PTHREAD_CC to any special C compiler that is needed for
  18 #   multi-threaded programs (defaults to the value of CC otherwise). (This
  19 #   is necessary on AIX to use the special cc_r compiler alias.)
  20 #
  21 #   NOTE: You are assumed to not only compile your program with these flags,
  22 #   but also to link with them as well. For example, you might link with
  23 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  24 #
  25 #   If you are only building threaded programs, you may wish to use these
  26 #   variables in your default LIBS, CFLAGS, and CC:
  27 #
  28 #     LIBS="$PTHREAD_LIBS $LIBS"
  29 #     CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  30 #     CC="$PTHREAD_CC"
  31 #
  32 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  33 #   has a nonstandard name, this macro defines PTHREAD_CREATE_JOINABLE to
  34 #   that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  35 #
  36 #   Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the
  37 #   PTHREAD_PRIO_INHERIT symbol is defined when compiling with
  38 #   PTHREAD_CFLAGS.
  39 #
  40 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
  41 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  42 #   is not found. If ACTION-IF-FOUND is not specified, the default action
  43 #   will define HAVE_PTHREAD.
  44 #
  45 #   Please let the authors know if this macro fails on any platform, or if
  46 #   you have any other suggestions or comments. This macro was based on work
  47 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  48 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  49 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
  50 #   grateful for the helpful feedback of numerous users.
  51 #
  52 #   Updated for Autoconf 2.68 by Daniel Richard G.
  53 #
  54 # LICENSE
  55 #
  56 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  57 #   Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG>
  58 #
  59 #   This program is free software: you can redistribute it and/or modify it
  60 #   under the terms of the GNU General Public License as published by the
  61 #   Free Software Foundation, either version 3 of the License, or (at your
  62 #   option) any later version.
  63 #
  64 #   This program is distributed in the hope that it will be useful, but
  65 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  66 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  67 #   Public License for more details.
  68 #
  69 #   You should have received a copy of the GNU General Public License along
  70 #   with this program. If not, see <https://www.gnu.org/licenses/>.
  71 #
  72 #   As a special exception, the respective Autoconf Macro's copyright owner
  73 #   gives unlimited permission to copy, distribute and modify the configure
  74 #   scripts that are the output of Autoconf when processing the Macro. You
  75 #   need not follow the terms of the GNU General Public License when using
  76 #   or distributing such scripts, even though portions of the text of the
  77 #   Macro appear in them. The GNU General Public License (GPL) does govern
  78 #   all other use of the material that constitutes the Autoconf Macro.
  79 #
  80 #   This special exception to the GPL applies to versions of the Autoconf
  81 #   Macro released by the Autoconf Archive. When you make and distribute a
  82 #   modified version of the Autoconf Macro, you may extend this special
  83 #   exception to the GPL to apply to your modified version as well.
  84
  85 #serial 26
  86
  87 AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
  88 AC_DEFUN([AX_PTHREAD], [
  89 AC_REQUIRE([AC_CANONICAL_HOST])
  90 AC_REQUIRE([AC_PROG_CC])
  91 AC_REQUIRE([AC_PROG_SED])
  92 AC_LANG_PUSH([C])
  93 ax_pthread_ok=no
  94
  95 # We used to check for pthread.h first, but this fails if pthread.h
  96 # requires special compiler flags (e.g. on Tru64 or Sequent).
  97 # It gets checked for in the link test anyway.
  98
  99 # First of all, check if the user has set any of the PTHREAD_LIBS,
 100 # etcetera environment variables, and if threads linking works using
 101 # them:
 102 if test "x$PTHREAD_CFLAGS$PTHREAD_LIBS" != "x"; then
 103         ax_pthread_save_CC="$CC"
 104         ax_pthread_save_CFLAGS="$CFLAGS"
 105         ax_pthread_save_LIBS="$LIBS"
 106         AS_IF([test "x$PTHREAD_CC" != "x"], [CC="$PTHREAD_CC"])
 107         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 108         LIBS="$PTHREAD_LIBS $LIBS"
 109         AC_MSG_CHECKING([for pthread_join using $CC $PTHREAD_CFLAGS $PTHREAD_LIBS])
 110         AC_LINK_IFELSE([AC_LANG_CALL([], [pthread_join])], [ax_pthread_ok=yes])
 111         AC_MSG_RESULT([$ax_pthread_ok])
 112         if test "x$ax_pthread_ok" = "xno"; then
 113                 PTHREAD_LIBS=""
 114                 PTHREAD_CFLAGS=""
 115         fi
 116         CC="$ax_pthread_save_CC"
 117         CFLAGS="$ax_pthread_save_CFLAGS"
 118         LIBS="$ax_pthread_save_LIBS"
 119 fi
 120
 121 # We must check for the threads library under a number of different
 122 # names; the ordering is very important because some systems
 123 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 124 # libraries is broken (non-POSIX).
 125
 126 # Create a list of thread flags to try.  Items starting with a "-" are
 127 # C compiler flags, and other items are library names, except for "none"
 128 # which indicates that we try without any flags at all, and "pthread-config"
 129 # which is a program returning the flags for the Pth emulation library.
 130
 131 ax_pthread_flags="pthreads none -Kthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
 132
 133 # The ordering *is* (sometimes) important.  Some notes on the
 134 # individual items follow:
 135
 136 # pthreads: AIX (must check this before -lpthread)
 137 # none: in case threads are in libc; should be tried before -Kthread and
 138 #       other compiler flags to prevent continual compiler warnings
 139 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 140 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads), Tru64
 141 #           (Note: HP C rejects this with "bad form for `-t' option")
 142 # -pthreads: Solaris/gcc (Note: HP C also rejects)
 143 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 144 #      doesn't hurt to check since this sometimes defines pthreads and
 145 #      -D_REENTRANT too), HP C (must be checked before -lpthread, which
 146 #      is present but should not be used directly; and before -mthreads,
 147 #      because the compiler interprets this as "-mt" + "-hreads")
 148 # -mthreads: Mingw32/gcc, Lynx/gcc
 149 # pthread: Linux, etcetera
 150 # --thread-safe: KAI C++
 151 # pthread-config: use pthread-config program (for GNU Pth library)
 152
 153 case $host_os in
 154
 155         freebsd*)
 156
 157         # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 158         # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 159
 160         ax_pthread_flags="-kthread lthread $ax_pthread_flags"
 161         ;;
 162
 163         hpux*)
 164
 165         # From the cc(1) man page: "[-mt] Sets various -D flags to enable
 166         # multi-threading and also sets -lpthread."
 167
 168         ax_pthread_flags="-mt -pthread pthread $ax_pthread_flags"
 169         ;;
 170
 171         openedition*)
 172
 173         # IBM z/OS requires a feature-test macro to be defined in order to
 174         # enable POSIX threads at all, so give the user a hint if this is
 175         # not set. (We don't define these ourselves, as they can affect
 176         # other portions of the system API in unpredictable ways.)
 177
 178         AC_EGREP_CPP([AX_PTHREAD_ZOS_MISSING],
 179             [
 180 #            if !defined(_OPEN_THREADS) && !defined(_UNIX03_THREADS)
 181              AX_PTHREAD_ZOS_MISSING
 182 #            endif
 183             ],
 184             [AC_MSG_WARN([IBM z/OS requires -D_OPEN_THREADS or -D_UNIX03_THREADS to enable pthreads support.])])
 185         ;;
 186
 187         solaris*)
 188
 189         # On Solaris (at least, for some versions), libc contains stubbed
 190         # (non-functional) versions of the pthreads routines, so link-based
 191         # tests will erroneously succeed. (N.B.: The stubs are missing
 192         # pthread_cleanup_push, or rather a function called by this macro,
 193         # so we could check for that, but who knows whether they'll stub
 194         # that too in a future libc.)  So we'll check first for the
 195         # standard Solaris way of linking pthreads (-mt -lpthread).
 196
 197         ax_pthread_flags="-mt,pthread pthread $ax_pthread_flags"
 198         ;;
 199 esac
 200
 201 # GCC generally uses -pthread, or -pthreads on some platforms (e.g. SPARC)
 202
 203 AS_IF([test "x$GCC" = "xyes"],
 204       [ax_pthread_flags="-pthread -pthreads $ax_pthread_flags"])
 205
 206 # The presence of a feature test macro requesting re-entrant function
 207 # definitions is, on some systems, a strong hint that pthreads support is
 208 # correctly enabled
 209
 210 case $host_os in
 211         darwin* | hpux* | linux* | osf* | solaris*)
 212         ax_pthread_check_macro="_REENTRANT"
 213         ;;
 214
 215         aix*)
 216         ax_pthread_check_macro="_THREAD_SAFE"
 217         ;;
 218
 219         *)
 220         ax_pthread_check_macro="--"
 221         ;;
 222 esac
 223 AS_IF([test "x$ax_pthread_check_macro" = "x--"],
 224       [ax_pthread_check_cond=0],
 225       [ax_pthread_check_cond="!defined($ax_pthread_check_macro)"])
 226
 227 # Are we compiling with Clang?
 228
 229 AC_CACHE_CHECK([whether $CC is Clang],
 230     [ax_cv_PTHREAD_CLANG],
 231     [ax_cv_PTHREAD_CLANG=no
 232      # Note that Autoconf sets GCC=yes for Clang as well as GCC
 233      if test "x$GCC" = "xyes"; then
 234         AC_EGREP_CPP([AX_PTHREAD_CC_IS_CLANG],
 235             [/* Note: Clang 2.7 lacks __clang_[a-z]+__ */
 236 #            if defined(__clang__) && defined(__llvm__)
 237              AX_PTHREAD_CC_IS_CLANG
 238 #            endif
 239             ],
 240             [ax_cv_PTHREAD_CLANG=yes])
 241      fi
 242     ])
 243 ax_pthread_clang="$ax_cv_PTHREAD_CLANG"
 244
 245 ax_pthread_clang_warning=no
 246
 247 # Clang needs special handling, because older versions handle the -pthread
 248 # option in a rather... idiosyncratic way
 249
 250 if test "x$ax_pthread_clang" = "xyes"; then
 251
 252         # Clang takes -pthread; it has never supported any other flag
 253
 254         # (Note 1: This will need to be revisited if a system that Clang
 255         # supports has POSIX threads in a separate library.  This tends not
 256         # to be the way of modern systems, but it's conceivable.)
 257
 258         # (Note 2: On some systems, notably Darwin, -pthread is not needed
 259         # to get POSIX threads support; the API is always present and
 260         # active.  We could reasonably leave PTHREAD_CFLAGS empty.  But
 261         # -pthread does define _REENTRANT, and while the Darwin headers
 262         # ignore this macro, third-party headers might not.)
 263
 264         PTHREAD_CFLAGS="-pthread"
 265         PTHREAD_LIBS=
 266
 267         ax_pthread_ok=yes
 268
 269         # However, older versions of Clang make a point of warning the user
 270         # that, in an invocation where only linking and no compilation is
 271         # taking place, the -pthread option has no effect ("argument unused
 272         # during compilation").  They expect -pthread to be passed in only
 273         # when source code is being compiled.
 274         #
 275         # Problem is, this is at odds with the way Automake and most other
 276         # C build frameworks function, which is that the same flags used in
 277         # compilation (CFLAGS) are also used in linking.  Many systems
 278         # supported by AX_PTHREAD require exactly this for POSIX threads
 279         # support, and in fact it is often not straightforward to specify a
 280         # flag that is used only in the compilation phase and not in
 281         # linking.  Such a scenario is extremely rare in practice.
 282         #
 283         # Even though use of the -pthread flag in linking would only print
 284         # a warning, this can be a nuisance for well-run software projects
 285         # that build with -Werror.  So if the active version of Clang has
 286         # this misfeature, we search for an option to squash it.
 287
 288         AC_CACHE_CHECK([whether Clang needs flag to prevent "argument unused" warning when linking with -pthread],
 289             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG],
 290             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG=unknown
 291              # Create an alternate version of $ac_link that compiles and
 292              # links in two steps (.c -> .o, .o -> exe) instead of one
 293              # (.c -> exe), because the warning occurs only in the second
 294              # step
 295              ax_pthread_save_ac_link="$ac_link"
 296              ax_pthread_sed='s/conftest\.\$ac_ext/conftest.$ac_objext/g'
 297              ax_pthread_link_step=`$as_echo "$ac_link" | sed "$ax_pthread_sed"`
 298              ax_pthread_2step_ac_link="($ac_compile) && (echo ==== >&5) && ($ax_pthread_link_step)"
 299              ax_pthread_save_CFLAGS="$CFLAGS"
 300              for ax_pthread_try in '' -Qunused-arguments -Wno-unused-command-line-argument unknown; do
 301                 AS_IF([test "x$ax_pthread_try" = "xunknown"], [break])
 302                 CFLAGS="-Werror -Wunknown-warning-option $ax_pthread_try -pthread $ax_pthread_save_CFLAGS"
 303                 ac_link="$ax_pthread_save_ac_link"
 304                 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
 305                     [ac_link="$ax_pthread_2step_ac_link"
 306                      AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
 307                          [break])
 308                     ])
 309              done
 310              ac_link="$ax_pthread_save_ac_link"
 311              CFLAGS="$ax_pthread_save_CFLAGS"
 312              AS_IF([test "x$ax_pthread_try" = "x"], [ax_pthread_try=no])
 313              ax_cv_PTHREAD_CLANG_NO_WARN_FLAG="$ax_pthread_try"
 314             ])
 315
 316         case "$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG" in
 317                 no | unknown) ;;
 318                 *) PTHREAD_CFLAGS="$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG $PTHREAD_CFLAGS" ;;
 319         esac
 320
 321 fi # $ax_pthread_clang = yes
 322
 323 if test "x$ax_pthread_ok" = "xno"; then
 324 for ax_pthread_try_flag in $ax_pthread_flags; do
 325
 326         case $ax_pthread_try_flag in
 327                 none)
 328                 AC_MSG_CHECKING([whether pthreads work without any flags])
 329                 ;;
 330
 331                 -mt,pthread)
 332                 AC_MSG_CHECKING([whether pthreads work with -mt -lpthread])
 333                 PTHREAD_CFLAGS="-mt"
 334                 PTHREAD_LIBS="-lpthread"
 335                 ;;
 336
 337                 -*)
 338                 AC_MSG_CHECKING([whether pthreads work with $ax_pthread_try_flag])
 339                 PTHREAD_CFLAGS="$ax_pthread_try_flag"
 340                 ;;
 341
 342                 pthread-config)
 343                 AC_CHECK_PROG([ax_pthread_config], [pthread-config], [yes], [no])
 344                 AS_IF([test "x$ax_pthread_config" = "xno"], [continue])
 345                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 346                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 347                 ;;
 348
 349                 *)
 350                 AC_MSG_CHECKING([for the pthreads library -l$ax_pthread_try_flag])
 351                 PTHREAD_LIBS="-l$ax_pthread_try_flag"
 352                 ;;
 353         esac
 354
 355         ax_pthread_save_CFLAGS="$CFLAGS"
 356         ax_pthread_save_LIBS="$LIBS"
 357         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 358         LIBS="$PTHREAD_LIBS $LIBS"
 359
 360         # Check for various functions.  We must include pthread.h,
 361         # since some functions may be macros.  (On the Sequent, we
 362         # need a special flag -Kthread to make this header compile.)
 363         # We check for pthread_join because it is in -lpthread on IRIX
 364         # while pthread_create is in libc.  We check for pthread_attr_init
 365         # due to DEC craziness with -lpthreads.  We check for
 366         # pthread_cleanup_push because it is one of the few pthread
 367         # functions on Solaris that doesn't have a non-functional libc stub.
 368         # We try pthread_create on general principles.
 369
 370         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>
 371 #                       if $ax_pthread_check_cond
 372 #                        error "$ax_pthread_check_macro must be defined"
 373 #                       endif
 374                         static void *some_global = NULL;
 375                         static void routine(void *a)
 376                           {
 377                              /* To avoid any unused-parameter or
 378                                 unused-but-set-parameter warning.  */
 379                              some_global = a;
 380                           }
 381                         static void *start_routine(void *a) { return a; }],
 382                        [pthread_t th; pthread_attr_t attr;
 383                         pthread_create(&th, 0, start_routine, 0);
 384                         pthread_join(th, 0);
 385                         pthread_attr_init(&attr);
 386                         pthread_cleanup_push(routine, 0);
 387                         pthread_cleanup_pop(0) /* ; */])],
 388             [ax_pthread_ok=yes],
 389             [])
 390
 391         CFLAGS="$ax_pthread_save_CFLAGS"
 392         LIBS="$ax_pthread_save_LIBS"
 393
 394         AC_MSG_RESULT([$ax_pthread_ok])
 395         AS_IF([test "x$ax_pthread_ok" = "xyes"], [break])
 396
 397         PTHREAD_LIBS=""
 398         PTHREAD_CFLAGS=""
 399 done
 400 fi
 401
 402 # Various other checks:
 403 if test "x$ax_pthread_ok" = "xyes"; then
 404         ax_pthread_save_CFLAGS="$CFLAGS"
 405         ax_pthread_save_LIBS="$LIBS"
 406         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 407         LIBS="$PTHREAD_LIBS $LIBS"
 408
 409         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 410         AC_CACHE_CHECK([for joinable pthread attribute],
 411             [ax_cv_PTHREAD_JOINABLE_ATTR],
 412             [ax_cv_PTHREAD_JOINABLE_ATTR=unknown
 413              for ax_pthread_attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 414                  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>],
 415                                                  [int attr = $ax_pthread_attr; return attr /* ; */])],
 416                                 [ax_cv_PTHREAD_JOINABLE_ATTR=$ax_pthread_attr; break],
 417                                 [])
 418              done
 419             ])
 420         AS_IF([test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xunknown" && \
 421                test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xPTHREAD_CREATE_JOINABLE" && \
 422                test "x$ax_pthread_joinable_attr_defined" != "xyes"],
 423               [AC_DEFINE_UNQUOTED([PTHREAD_CREATE_JOINABLE],
 424                                   [$ax_cv_PTHREAD_JOINABLE_ATTR],
 425                                   [Define to necessary symbol if this constant
 426                                    uses a non-standard name on your system.])
 427                ax_pthread_joinable_attr_defined=yes
 428               ])
 429
 430         AC_CACHE_CHECK([whether more special flags are required for pthreads],
 431             [ax_cv_PTHREAD_SPECIAL_FLAGS],
 432             [ax_cv_PTHREAD_SPECIAL_FLAGS=no
 433              case $host_os in
 434              solaris*)
 435              ax_cv_PTHREAD_SPECIAL_FLAGS="-D_POSIX_PTHREAD_SEMANTICS"
 436              ;;
 437              esac
 438             ])
 439         AS_IF([test "x$ax_cv_PTHREAD_SPECIAL_FLAGS" != "xno" && \
 440                test "x$ax_pthread_special_flags_added" != "xyes"],
 441               [PTHREAD_CFLAGS="$ax_cv_PTHREAD_SPECIAL_FLAGS $PTHREAD_CFLAGS"
 442                ax_pthread_special_flags_added=yes])
 443
 444         AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 445             [ax_cv_PTHREAD_PRIO_INHERIT],
 446             [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
 447                                              [[int i = PTHREAD_PRIO_INHERIT;
 448                                                return i;]])],
 449                             [ax_cv_PTHREAD_PRIO_INHERIT=yes],
 450                             [ax_cv_PTHREAD_PRIO_INHERIT=no])
 451             ])
 452         AS_IF([test "x$ax_cv_PTHREAD_PRIO_INHERIT" = "xyes" && \
 453                test "x$ax_pthread_prio_inherit_defined" != "xyes"],
 454               [AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], [1], [Have PTHREAD_PRIO_INHERIT.])
 455                ax_pthread_prio_inherit_defined=yes
 456               ])
 457
 458         CFLAGS="$ax_pthread_save_CFLAGS"
 459         LIBS="$ax_pthread_save_LIBS"
 460
 461         # More AIX lossage: compile with *_r variant
 462         if test "x$GCC" != "xyes"; then
 463             case $host_os in
 464                 aix*)
 465                 AS_CASE(["x/$CC"],
 466                     [x*/c89|x*/c89_128|x*/c99|x*/c99_128|x*/cc|x*/cc128|x*/xlc|x*/xlc_v6|x*/xlc128|x*/xlc128_v6],
 467                     [#handle absolute path differently from PATH based program lookup
 468                      AS_CASE(["x$CC"],
 469                          [x/*],
 470                          [AS_IF([AS_EXECUTABLE_P([${CC}_r])],[PTHREAD_CC="${CC}_r"])],
 471                          [AC_CHECK_PROGS([PTHREAD_CC],[${CC}_r],[$CC])])])
 472                 ;;
 473             esac
 474         fi
 475 fi
 476
 477 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
 478
 479 AC_SUBST([PTHREAD_LIBS])
 480 AC_SUBST([PTHREAD_CFLAGS])
 481 AC_SUBST([PTHREAD_CC])
 482
 483 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 484 if test "x$ax_pthread_ok" = "xyes"; then
 485         ifelse([$1],,[AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])],[$1])
 486         :
 487 else
 488         ax_pthread_ok=no
 489         $2
 490 fi
 491 AC_LANG_POP
 492 ])dnl AX_PTHREAD