opcodes/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2020 Free Software Foundation, Inc.
   4 dnl   Copyright (C) 2019-2020 Advanced Micro Devices, Inc. All rights reserved.
   5 dnl
   6 dnl This file is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; see the file COPYING3.  If not see
  18 dnl <http://www.gnu.org/licenses/>.
  19 dnl
  20
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([opcodes], BFD_VERSION)
  23 AC_CONFIG_SRCDIR([z8k-dis.c])
  24
  25 AC_CANONICAL_TARGET
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 dnl These must be called before LT_INIT, because it may want
  35 dnl to call AC_CHECK_PROG.
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_CHECK_TOOL(RANLIB, ranlib, :)
  38
  39 dnl Default to a non shared library.  This may be overridden by the
  40 dnl configure option --enable-shared.
  41 AC_DISABLE_SHARED
  42
  43 LT_INIT
  44
  45 AC_ARG_ENABLE(targets,
  46 [  --enable-targets        alternative target configurations],
  47 [case "${enableval}" in
  48   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  49             ;;
  50   no)       enable_targets= ;;
  51   *)        enable_targets=$enableval ;;
  52 esac])dnl
  53
  54 AM_BINUTILS_WARNINGS
  55
  56 AC_CONFIG_HEADERS(config.h:config.in)
  57
  58 # PR 14072
  59 AH_VERBATIM([00_CONFIG_H_CHECK],
  60 [/* Check that config.h is #included before system headers
  61    (this works only for glibc, but that should be enough).  */
  62 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  63 #  error config.h must be #included before system headers
  64 #endif
  65 #define __CONFIG_H__ 1])
  66
  67 if test -z "$target" ; then
  68     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  69 fi
  70
  71 AM_MAINTAINER_MODE
  72 AM_INSTALL_LIBBFD
  73 AC_EXEEXT
  74
  75 # host-specific stuff:
  76
  77 ALL_LINGUAS="da de es fi fr ga id it nl pt_BR ro sr sv tr uk vi zh_CN"
  78 ZW_GNU_GETTEXT_SISTER_DIR
  79 AM_PO_SUBDIRS
  80
  81 . ${srcdir}/../bfd/configure.host
  82
  83 BFD_CC_FOR_BUILD
  84
  85 AC_SUBST(HDEFINES)
  86 AC_PROG_INSTALL
  87
  88 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  89 ACX_HEADER_STRING
  90
  91 AC_CHECK_DECLS([basename, stpcpy])
  92
  93 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
  94 # since sigsetjmp might only be defined as a macro.
  95 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
  96 [AC_TRY_COMPILE([
  97 #include <setjmp.h>
  98 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
  99 bfd_cv_func_sigsetjmp=yes, bfd_cv_func_sigsetjmp=no)])
 100 if test $bfd_cv_func_sigsetjmp = yes; then
 101   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 102 fi
 103
 104 cgen_maint=no
 105 cgendir='$(srcdir)/../cgen'
 106
 107 AC_ARG_ENABLE(cgen-maint,
 108 [  --enable-cgen-maint[=dir]    build cgen generated files],
 109 [case "${enableval}" in
 110   yes)  cgen_maint=yes ;;
 111   no)   cgen_maint=no ;;
 112   *)
 113         # Argument is a directory where cgen can be found.  In some
 114         # future world cgen could be installable, but right now this
 115         # is not the case.  Instead we assume the directory is a path
 116         # to the cgen source tree.
 117         cgen_maint=yes
 118         if test -r ${enableval}/iformat.scm; then
 119           # This looks like a cgen source tree.
 120           cgendir=${enableval}
 121         else
 122           AC_MSG_ERROR(${enableval} doesn't look like a cgen source tree)
 123         fi
 124         ;;
 125 esac])dnl
 126 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 127 AC_SUBST(cgendir)
 128
 129 using_cgen=no
 130
 131 # Check if linker supports --as-needed and --no-as-needed options
 132 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
 133         [bfd_cv_ld_as_needed=no
 134         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
 135                 bfd_cv_ld_as_needed=yes
 136         fi
 137         ])
 138
 139 LT_LIB_M
 140
 141 #Libs for generator progs
 142 if test "x$cross_compiling" = "xno"; then
 143   BUILD_LIBS=../libiberty/libiberty.a
 144   BUILD_LIB_DEPS=$BUILD_LIBS
 145 else
 146   # if cross-compiling, assume that the system provides -liberty
 147   # and that the version is compatible with new headers.
 148   BUILD_LIBS=-liberty
 149   BUILD_LIB_DEPS=
 150 fi
 151 BUILD_LIBS="$BUILD_LIBS $LIBINTL"
 152 BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP"
 153
 154 AC_SUBST(BUILD_LIBS)
 155 AC_SUBST(BUILD_LIB_DEPS)
 156
 157 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 158 SHARED_LDFLAGS=
 159 SHARED_LIBADD=
 160 SHARED_DEPENDENCIES=
 161 if test "$enable_shared" = "yes"; then
 162 # When building a shared libopcodes, link against the pic version of libiberty
 163 # so that apps that use libopcodes won't need libiberty just to satisfy any
 164 # libopcodes references.
 165 # We can't do that if a pic libiberty is unavailable since including non-pic
 166 # code would insert text relocations into libopcodes.
 167 # Note that linking against libbfd as we do here, which is itself linked
 168 # against libiberty, may not satisfy all the libopcodes libiberty references
 169 # since libbfd may not pull in the entirety of libiberty.
 170 changequote(,)dnl
 171   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 172 changequote([,])dnl
 173   if test -n "$x"; then
 174     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 175   fi
 176
 177   case "${host}" in
 178     *-*-cygwin*)
 179       SHARED_LDFLAGS="-no-undefined"
 180       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 181       ;;
 182    *-*-darwin*)
 183      SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib ${SHARED_LIBADD}"
 184      SHARED_DEPENDENCIES="../bfd/libbfd.la"
 185      ;;
 186     *)
 187       case "$host_vendor" in
 188         hp)
 189           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl ${SHARED_LIBADD}"
 190           ;;
 191         *)
 192           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so ${SHARED_LIBADD}"
 193           ;;
 194       esac
 195       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 196       ;;
 197   esac
 198
 199   if test -n "$SHARED_LIBADD"; then
 200     if test -n "$LIBM"; then
 201       if test x"$bfd_cv_ld_as_needed" = xyes; then
 202         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 203         # to stop libtool reordering these options.
 204         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 205       else
 206         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 207       fi
 208     fi
 209   fi
 210 fi
 211 AC_SUBST(SHARED_LDFLAGS)
 212 AC_SUBST(SHARED_LIBADD)
 213 AC_SUBST(SHARED_DEPENDENCIES)
 214
 215 # target-specific stuff:
 216
 217 # Canonicalize the secondary target names.
 218 if test -n "$enable_targets" ; then
 219     for targ in `echo $enable_targets | sed 's/,/ /g'`
 220     do
 221         result=`$ac_config_sub $targ 2>/dev/null`
 222         if test -n "$result" ; then
 223             canon_targets="$canon_targets $result"
 224         else
 225             # Allow targets that config.sub doesn't recognize, like "all".
 226             canon_targets="$canon_targets $targ"
 227         fi
 228     done
 229 fi
 230
 231 all_targets=false
 232 selarchs=
 233 for targ in $target $canon_targets
 234 do
 235     if test "x$targ" = "xall" ; then
 236         all_targets=true
 237     else
 238         . $srcdir/../bfd/config.bfd
 239         selarchs="$selarchs $targ_archs"
 240     fi
 241 done
 242
 243 # Utility var, documents generic cgen support files.
 244
 245 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 246
 247 # We don't do any links based on the target system, just makefile config.
 248
 249 if test x${all_targets} = xfalse ; then
 250
 251     # Target architecture .o files.
 252     ta=
 253
 254     for arch in $selarchs
 255     do
 256         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 257         archdefs="$archdefs -DARCH_$ad"
 258         case "$arch" in
 259         bfd_aarch64_arch)       ta="$ta aarch64-asm.lo aarch64-dis.lo aarch64-opc.lo aarch64-asm-2.lo aarch64-dis-2.lo aarch64-opc-2.lo" ;;
 260         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 261         bfd_amdgcn_arch)        ;;
 262         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 263         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 264         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 265         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 266         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 267         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 268         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 269         bfd_csky_arch)          ta="$ta csky-dis.lo" ;;
 270         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 271         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 272         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 273         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 274         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 275         bfd_ft32_arch)          ta="$ta ft32-opc.lo ft32-dis.lo" ;;
 276         bfd_moxie_arch)         ta="$ta moxie-dis.lo moxie-opc.lo" ;;
 277         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 278         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 279         bfd_i386_arch|bfd_iamcu_arch|bfd_l1om_arch|bfd_k1om_arch)
 280                                 ta="$ta i386-dis.lo i386-opc.lo" ;;
 281         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 282         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 283         bfd_epiphany_arch)      ta="$ta epiphany-asm.lo epiphany-desc.lo epiphany-dis.lo epiphany-ibld.lo epiphany-opc.lo" using_cgen=yes ;;
 284         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 285         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 286         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 287         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 288         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 289         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 290         bfd_m9s12x_arch)        ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 291         bfd_m9s12xg_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 292         bfd_s12z_arch)          ta="$ta s12z-dis.lo s12z-opc.lo" ;;
 293         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 294         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 295         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 296         bfd_metag_arch)         ta="$ta metag-dis.lo" ;;
 297         bfd_microblaze_arch)    ta="$ta microblaze-dis.lo" ;;
 298         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo micromips-opc.lo" ;;
 299         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 300         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 301         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 302         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 303         bfd_msp430_arch)        ta="$ta msp430-dis.lo msp430-decode.lo" ;;
 304         bfd_nds32_arch)         ta="$ta nds32-asm.lo nds32-dis.lo" ;;
 305         bfd_nfp_arch)           ta="$ta nfp-dis.lo" ;;
 306         bfd_nios2_arch)         ta="$ta nios2-dis.lo nios2-opc.lo" ;;
 307         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 308         bfd_or1k_arch)          ta="$ta or1k-asm.lo or1k-desc.lo or1k-dis.lo or1k-ibld.lo or1k-opc.lo" using_cgen=yes ;;
 309         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 310         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 311         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 312         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 313         bfd_pru_arch)           ta="$ta pru-dis.lo pru-opc.lo" ;;
 314         bfd_pyramid_arch)       ;;
 315         bfd_romp_arch)          ;;
 316         bfd_riscv_arch)         ta="$ta riscv-dis.lo riscv-opc.lo" ;;
 317         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 318         bfd_rl78_arch)          ta="$ta rl78-dis.lo rl78-decode.lo";;
 319         bfd_rx_arch)            ta="$ta rx-dis.lo rx-decode.lo";;
 320         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 321         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 322         bfd_sh_arch)            ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 323         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 324         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 325         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 326         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 327         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 328         bfd_tic6x_arch)         ta="$ta tic6x-dis.lo" ;;
 329         bfd_tilegx_arch)        ta="$ta tilegx-dis.lo tilegx-opc.lo" ;;
 330         bfd_tilepro_arch)       ta="$ta tilepro-dis.lo tilepro-opc.lo" ;;
 331         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 332         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 333         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 334         bfd_v850_rh850_arch)    ta="$ta v850-opc.lo v850-dis.lo" ;;
 335         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 336         bfd_visium_arch)        ta="$ta visium-dis.lo visium-opc.lo" ;;
 337         bfd_wasm32_arch)        ta="$ta wasm32-dis.lo" ;;
 338         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 339         bfd_xgate_arch)         ta="$ta xgate-dis.lo xgate-opc.lo" ;;
 340         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 341         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 342         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 343         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 344         bfd_bpf_arch)           ta="$ta bpf-asm.lo bpf-desc.lo bpf-dis.lo bpf-ibld.lo bpf-opc.lo" using_cgen=yes ;;
 345
 346         "")                     ;;
 347         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 348         esac
 349     done
 350
 351     if test $using_cgen = yes ; then
 352         ta="$ta $cgen_files"
 353     fi
 354
 355     # Weed out duplicate .o files.
 356     f=""
 357     for i in $ta ; do
 358         case " $f " in
 359         *" $i "*) ;;
 360         *) f="$f $i" ;;
 361         esac
 362     done
 363     ta="$f"
 364
 365     # And duplicate -D flags.
 366     f=""
 367     for i in $archdefs ; do
 368         case " $f " in
 369         *" $i "*) ;;
 370         *) f="$f $i" ;;
 371         esac
 372     done
 373     archdefs="$f"
 374
 375     BFD_MACHINES="$ta"
 376
 377 else    # all_targets is true
 378     archdefs=-DARCH_all
 379     BFD_MACHINES='$(ALL_MACHINES)'
 380 fi
 381
 382 AC_SUBST(archdefs)
 383 AC_SUBST(BFD_MACHINES)
 384
 385 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 386 AC_OUTPUT