opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([z8k-dis.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 # We currently only use the version number for the name of any shared
  12 # library.  For user convenience, we always use the same version
  13 # number that BFD is using.
  14 changequote(,)dnl
  15 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  16 changequote([,])dnl
  17
  18 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_USE_SYSTEM_EXTENSIONS
  23
  24 dnl These must be called before LT_INIT, because it may want
  25 dnl to call AC_CHECK_PROG.
  26 AC_CHECK_TOOL(AR, ar)
  27 AC_CHECK_TOOL(RANLIB, ranlib, :)
  28
  29 dnl Default to a non shared library.  This may be overridden by the
  30 dnl configure option --enable-shared.
  31 AC_DISABLE_SHARED
  32
  33 LT_INIT
  34
  35 AC_ARG_ENABLE(targets,
  36 [  --enable-targets        alternative target configurations],
  37 [case "${enableval}" in
  38   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  39             ;;
  40   no)       enable_targets= ;;
  41   *)        enable_targets=$enableval ;;
  42 esac])dnl
  43
  44 AM_BINUTILS_WARNINGS
  45 ACX_PROG_CC_WARNING_OPTS([-Wno-missing-field-initializers],
  46                          [NO_WMISSING_FIELD_INITIALIZERS])
  47
  48 AC_CONFIG_HEADERS(config.h:config.in)
  49
  50 # PR 14072
  51 AH_VERBATIM([00_CONFIG_H_CHECK],
  52 [/* Check that config.h is #included before system headers
  53    (this works only for glibc, but that should be enough).  */
  54 #if defined(__GLIBC__) && !defined(__CONFIG_H__)
  55 #  error config.h must be #included before system headers
  56 #endif
  57 #define __CONFIG_H__ 1])
  58
  59 if test -z "$target" ; then
  60     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  61 fi
  62
  63 AM_MAINTAINER_MODE
  64 AM_INSTALL_LIBBFD
  65 AC_EXEEXT
  66
  67 # host-specific stuff:
  68
  69 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN it"
  70 ZW_GNU_GETTEXT_SISTER_DIR
  71 AM_PO_SUBDIRS
  72
  73 . ${srcdir}/../bfd/configure.host
  74
  75 BFD_CC_FOR_BUILD
  76
  77 AC_SUBST(HDEFINES)
  78 AC_PROG_INSTALL
  79
  80 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  81 ACX_HEADER_STRING
  82
  83 AC_CHECK_DECLS([basename, stpcpy])
  84
  85 cgen_maint=no
  86 cgendir='$(srcdir)/../cgen'
  87
  88 AC_ARG_ENABLE(cgen-maint,
  89 [  --enable-cgen-maint[=dir]    build cgen generated files],
  90 [case "${enableval}" in
  91   yes)  cgen_maint=yes ;;
  92   no)   cgen_maint=no ;;
  93   *)
  94         # argument is cgen install directory (not implemented yet).
  95         # Having a `share' directory might be more appropriate for the .scm,
  96         # .cpu, etc. files.
  97         cgen_maint=yes
  98         cgendir=${cgen_maint}/lib/cgen
  99         ;;
 100 esac])dnl
 101 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 102 AC_SUBST(cgendir)
 103
 104 using_cgen=no
 105
 106 # Check if linker supports --as-needed and --no-as-needed options
 107 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
 108         [bfd_cv_ld_as_needed=no
 109         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
 110                 bfd_cv_ld_as_needed=yes
 111         fi
 112         ])
 113
 114 LT_LIB_M
 115
 116 #Libs for generator progs
 117 if test "x$cross_compiling" = "xno"; then
 118   BUILD_LIBS=../libiberty/libiberty.a
 119   BUILD_LIB_DEPS=$BUILD_LIBS
 120 else
 121   # if cross-compiling, assume that the system provides -liberty
 122   # and that the version is compatible with new headers.
 123   BUILD_LIBS=-liberty
 124   BUILD_LIB_DEPS=
 125 fi
 126 BUILD_LIBS="$BUILD_LIBS $LIBINTL"
 127 BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP"
 128
 129 AC_SUBST(BUILD_LIBS)
 130 AC_SUBST(BUILD_LIB_DEPS)
 131
 132 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 133 SHARED_LDFLAGS=
 134 SHARED_LIBADD=
 135 SHARED_DEPENDENCIES=
 136 if test "$enable_shared" = "yes"; then
 137 # When building a shared libopcodes, link against the pic version of libiberty
 138 # so that apps that use libopcodes won't need libiberty just to satisfy any
 139 # libopcodes references.
 140 # We can't do that if a pic libiberty is unavailable since including non-pic
 141 # code would insert text relocations into libopcodes.
 142 # Note that linking against libbfd as we do here, which is itself linked
 143 # against libiberty, may not satisfy all the libopcodes libiberty references
 144 # since libbfd may not pull in the entirety of libiberty.
 145 changequote(,)dnl
 146   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 147 changequote([,])dnl
 148   if test -n "$x"; then
 149     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 150   fi
 151
 152   case "${host}" in
 153     *-*-cygwin*)
 154       SHARED_LDFLAGS="-no-undefined"
 155       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 156       ;;
 157    *-*-darwin*)
 158      SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib ${SHARED_LIBADD}"
 159      SHARED_DEPENDENCIES="../bfd/libbfd.la"
 160      ;;
 161     *)
 162       case "$host_vendor" in
 163         hp)
 164           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl ${SHARED_LIBADD}"
 165           ;;
 166         *)
 167           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so ${SHARED_LIBADD}"
 168           ;;
 169       esac
 170       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 171       ;;
 172   esac
 173
 174   if test -n "$SHARED_LIBADD"; then
 175     if test -n "$LIBM"; then
 176       if test x"$bfd_cv_ld_as_needed" = xyes; then
 177         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 178         # to stop libtool reordering these options.
 179         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 180       else
 181         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 182       fi
 183     fi
 184   fi
 185 fi
 186 AC_SUBST(SHARED_LDFLAGS)
 187 AC_SUBST(SHARED_LIBADD)
 188 AC_SUBST(SHARED_DEPENDENCIES)
 189
 190 # target-specific stuff:
 191
 192 # Canonicalize the secondary target names.
 193 if test -n "$enable_targets" ; then
 194     for targ in `echo $enable_targets | sed 's/,/ /g'`
 195     do
 196         result=`$ac_config_sub $targ 2>/dev/null`
 197         if test -n "$result" ; then
 198             canon_targets="$canon_targets $result"
 199         else
 200             # Allow targets that config.sub doesn't recognize, like "all".
 201             canon_targets="$canon_targets $targ"
 202         fi
 203     done
 204 fi
 205
 206 all_targets=false
 207 selarchs=
 208 for targ in $target $canon_targets
 209 do
 210     if test "x$targ" = "xall" ; then
 211         all_targets=true
 212     else
 213         . $srcdir/../bfd/config.bfd
 214         selarchs="$selarchs $targ_archs"
 215     fi
 216 done
 217
 218 # Utility var, documents generic cgen support files.
 219
 220 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 221
 222 # We don't do any links based on the target system, just makefile config.
 223
 224 if test x${all_targets} = xfalse ; then
 225
 226     # Target architecture .o files.
 227     ta=
 228
 229     for arch in $selarchs
 230     do
 231         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 232         archdefs="$archdefs -DARCH_$ad"
 233         case "$arch" in
 234         bfd_aarch64_arch)       ta="$ta aarch64-asm.lo aarch64-dis.lo aarch64-opc.lo aarch64-asm-2.lo aarch64-dis-2.lo aarch64-opc-2.lo" ;;
 235         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 236         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 237         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 238         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 239         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 240         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 241         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 242         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 243         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 244         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 245         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 246         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 247         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 248         bfd_moxie_arch)         ta="$ta moxie-dis.lo moxie-opc.lo" ;;
 249         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 250         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 251         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 252         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 253         bfd_i386_arch|bfd_l1om_arch|bfd_k1om_arch)
 254                                 ta="$ta i386-dis.lo i386-opc.lo" ;;
 255         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 256         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 257         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 258         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 259         bfd_epiphany_arch)      ta="$ta epiphany-asm.lo epiphany-desc.lo epiphany-dis.lo epiphany-ibld.lo epiphany-opc.lo" using_cgen=yes ;;
 260         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 261         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 262         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 263         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 264         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 265         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 266         bfd_m9s12x_arch)        ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 267         bfd_m9s12xg_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 268         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 269         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 270         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 271         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 272         bfd_microblaze_arch)    ta="$ta microblaze-dis.lo" ;;
 273         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo micromips-opc.lo" ;;
 274         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 275         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 276         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 277         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 278         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 279         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 280         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 281         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 282         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 283         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 284         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 285         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 286         bfd_pyramid_arch)       ;;
 287         bfd_romp_arch)          ;;
 288         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 289         bfd_rl78_arch)          ta="$ta rl78-dis.lo rl78-decode.lo";;
 290         bfd_rx_arch)            ta="$ta rx-dis.lo rx-decode.lo";;
 291         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 292         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 293         bfd_sh_arch)
 294           # We can't decide what we want just from the CPU family.
 295           # We want SH5 support unless a specific version of sh is
 296           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 297           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 298           for t in $target $canon_targets; do
 299             case $t in
 300               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 301               sh-*-linux* | shl-*-linux*)
 302                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 303                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 304                                 break;;
 305             esac;
 306           done
 307                                 ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 308         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 309         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 310         bfd_tahoe_arch)         ;;
 311         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 312         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 313         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 314         bfd_tic6x_arch)         ta="$ta tic6x-dis.lo" ;;
 315         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 316         bfd_tilegx_arch)        ta="$ta tilegx-dis.lo tilegx-opc.lo" ;;
 317         bfd_tilepro_arch)       ta="$ta tilepro-dis.lo tilepro-opc.lo" ;;
 318         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 319         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 320         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 321         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 322         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 323         bfd_we32k_arch)         ;;
 324         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 325         bfd_xgate_arch)         ta="$ta xgate-dis.lo xgate-opc.lo" ;;
 326         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 327         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 328         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 329         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 330
 331         "")                     ;;
 332         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 333         esac
 334     done
 335
 336     if test $using_cgen = yes ; then
 337         ta="$ta $cgen_files"
 338     fi
 339
 340     # Weed out duplicate .o files.
 341     f=""
 342     for i in $ta ; do
 343         case " $f " in
 344         *" $i "*) ;;
 345         *) f="$f $i" ;;
 346         esac
 347     done
 348     ta="$f"
 349
 350     # And duplicate -D flags.
 351     f=""
 352     for i in $archdefs ; do
 353         case " $f " in
 354         *" $i "*) ;;
 355         *) f="$f $i" ;;
 356         esac
 357     done
 358     archdefs="$f"
 359
 360     BFD_MACHINES="$ta"
 361
 362 else    # all_targets is true
 363     archdefs=-DARCH_all
 364     BFD_MACHINES='$(ALL_MACHINES)'
 365 fi
 366
 367 AC_SUBST(archdefs)
 368 AC_SUBST(BFD_MACHINES)
 369
 370 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 371 AC_OUTPUT