opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([z8k-dis.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 # We currently only use the version number for the name of any shared
  12 # library.  For user convenience, we always use the same version
  13 # number that BFD is using.
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17
  18 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  19
  20 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  21 dnl to call AC_CHECK_PROG.
  22 AC_CHECK_TOOL(AR, ar)
  23 AC_CHECK_TOOL(RANLIB, ranlib, :)
  24
  25 dnl Default to a non shared library.  This may be overridden by the
  26 dnl configure option --enable-shared.
  27 AM_DISABLE_SHARED
  28
  29 AM_PROG_LIBTOOL
  30
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  45 esac])dnl
  46
  47 AM_BINUTILS_WARNINGS
  48
  49 AM_CONFIG_HEADER(config.h:config.in)
  50
  51 if test -z "$target" ; then
  52     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  53 fi
  54
  55 AM_MAINTAINER_MODE
  56 AM_INSTALL_LIBBFD
  57 AC_EXEEXT
  58
  59 # host-specific stuff:
  60
  61 AC_PROG_CC
  62
  63 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN"
  64 ZW_GNU_GETTEXT_SISTER_DIR
  65 AM_PO_SUBDIRS
  66
  67 . ${srcdir}/../bfd/configure.host
  68
  69 BFD_CC_FOR_BUILD
  70
  71 AC_SUBST(HDEFINES)
  72 AC_PROG_INSTALL
  73
  74 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
  75
  76 AC_CHECK_DECLS(basename)
  77
  78 cgen_maint=no
  79 cgendir='$(srcdir)/../cgen'
  80
  81 AC_ARG_ENABLE(cgen-maint,
  82 [  --enable-cgen-maint[=dir]    build cgen generated files],
  83 [case "${enableval}" in
  84   yes)  cgen_maint=yes ;;
  85   no)   cgen_maint=no ;;
  86   *)
  87         # argument is cgen install directory (not implemented yet).
  88         # Having a `share' directory might be more appropriate for the .scm,
  89         # .cpu, etc. files.
  90         cgen_maint=yes
  91         cgendir=${cgen_maint}/lib/cgen
  92         ;;
  93 esac])dnl
  94 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
  95 AC_SUBST(cgendir)
  96
  97 using_cgen=no
  98
  99 # Horrible hacks to build DLLs on Windows.
 100 WIN32LDFLAGS=
 101 WIN32LIBADD=
 102 case "${host}" in
 103 *-*-cygwin*)
 104   if test "$enable_shared" = "yes"; then
 105     WIN32LDFLAGS="-no-undefined"
 106     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 107   fi
 108   ;;
 109 esac
 110 AC_SUBST(WIN32LDFLAGS)
 111 AC_SUBST(WIN32LIBADD)
 112
 113 # target-specific stuff:
 114
 115 # Canonicalize the secondary target names.
 116 if test -n "$enable_targets" ; then
 117     for targ in `echo $enable_targets | sed 's/,/ /g'`
 118     do
 119         result=`$ac_config_sub $targ 2>/dev/null`
 120         if test -n "$result" ; then
 121             canon_targets="$canon_targets $result"
 122         else
 123             # Allow targets that config.sub doesn't recognize, like "all".
 124             canon_targets="$canon_targets $targ"
 125         fi
 126     done
 127 fi
 128
 129 all_targets=false
 130 selarchs=
 131 for targ in $target $canon_targets
 132 do
 133     if test "x$targ" = "xall" ; then
 134         all_targets=true
 135     else
 136         . $srcdir/../bfd/config.bfd
 137         selarchs="$selarchs $targ_archs"
 138     fi
 139 done
 140
 141 # Utility var, documents generic cgen support files.
 142
 143 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 144
 145 # We don't do any links based on the target system, just makefile config.
 146
 147 if test x${all_targets} = xfalse ; then
 148
 149     # Target architecture .o files.
 150     ta=
 151
 152     for arch in $selarchs
 153     do
 154         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 155         archdefs="$archdefs -DARCH_$ad"
 156         case "$arch" in
 157         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 158         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 159         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 160         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 161         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 162         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 163         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 164         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 165         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 166         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 167         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 168         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 169         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 170         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 171         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 172         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 173         bfd_i386_arch)          ta="$ta i386-dis.lo i386-opc.lo" ;;
 174         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 175         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 176         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 177         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 178         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 179         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 180         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 181         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 182         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 183         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 184         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 185         bfd_maxq_arch)          ta="$ta maxq-dis.lo" ;;
 186         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 187         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 188         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 189         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 190         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 191         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 192         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 193         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 194         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 195         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 196         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 197         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 198         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 199         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 200         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 201         bfd_pyramid_arch)       ;;
 202         bfd_romp_arch)          ;;
 203         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 204         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 205         bfd_score_arch)         ta="$ta score-dis.lo" ;;
 206         bfd_sh_arch)
 207           # We can't decide what we want just from the CPU family.
 208           # We want SH5 support unless a specific version of sh is
 209           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 210           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 211           for t in $target $canon_targets; do
 212             case $t in
 213               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 214               sh-*-linux* | shl-*-linux*)
 215                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 216                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 217                                 break;;
 218             esac;
 219           done
 220                                 ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 221         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 222         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 223         bfd_tahoe_arch)         ;;
 224         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 225         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 226         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 227         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 228         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 229         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 230         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 231         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 232         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 233         bfd_we32k_arch)         ;;
 234         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 235         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 236         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 237         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 238         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 239
 240         "")                     ;;
 241         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 242         esac
 243     done
 244
 245     if test $using_cgen = yes ; then
 246         ta="$ta $cgen_files"
 247     fi
 248
 249     # Weed out duplicate .o files.
 250     f=""
 251     for i in $ta ; do
 252         case " $f " in
 253         *" $i "*) ;;
 254         *) f="$f $i" ;;
 255         esac
 256     done
 257     ta="$f"
 258
 259     # And duplicate -D flags.
 260     f=""
 261     for i in $archdefs ; do
 262         case " $f " in
 263         *" $i "*) ;;
 264         *) f="$f $i" ;;
 265         esac
 266     done
 267     archdefs="$f"
 268
 269     BFD_MACHINES="$ta"
 270
 271 else    # all_targets is true
 272     archdefs=-DARCH_all
 273     BFD_MACHINES='$(ALL_MACHINES)'
 274 fi
 275
 276 AC_SUBST(archdefs)
 277 AC_SUBST(BFD_MACHINES)
 278
 279 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 280 AC_OUTPUT