readline/configure.in

   1 dnl
   2 dnl Configure script for readline library
   3 dnl
   4 dnl report bugs to chet@po.cwru.edu
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 AC_REVISION([for Readline 4.3, version 2.45, from autoconf version] AC_ACVERSION)
   8
   9 AC_INIT(readline, 4.3, bug-readline@gnu.org)
  10
  11 dnl make sure we are using a recent autoconf version
  12 AC_PREREQ(2.50)
  13
  14 AC_CONFIG_SRCDIR(readline.h)
  15 dnl AC_CONFIG_AUX_DIR(./support)
  16 AC_CONFIG_HEADERS(config.h)
  17
  18 dnl update the value of RL_READLINE_VERSION in readline.h when this changes
  19 LIBVERSION=4.3
  20
  21 AC_CANONICAL_HOST
  22
  23 dnl configure defaults
  24 opt_curses=no
  25
  26 dnl arguments to configure
  27 AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
  28
  29 if test "$opt_curses" = "yes"; then
  30         prefer_curses=yes
  31 fi
  32
  33 dnl option parsing for optional features
  34 opt_static_libs=yes
  35 opt_shared_libs=yes
  36
  37 AC_ARG_ENABLE(shared, AC_HELP_STRING([--enable-shared], [build shared libraries [[default=YES]]]), opt_shared_libs=$enableval)
  38 AC_ARG_ENABLE(static, AC_HELP_STRING([--enable-static], [build static libraries [[default=YES]]]), opt_static_libs=$enableval)
  39
  40 echo ""
  41 echo "Beginning configuration for readline-$LIBVERSION for ${host_cpu}-${host_vendor}-${host_os}"
  42 echo ""
  43
  44 # We want these before the checks, so the checks can modify their values.
  45 test -z "$CFLAGS" && CFLAGS=-g auto_cflags=1
  46
  47 AC_PROG_MAKE_SET
  48 AC_PROG_CC
  49 dnl AC_AIX
  50 AC_MINIX
  51
  52 dnl BEGIN changes for CYGNUS cross-building for Cygwin
  53
  54 dnl load up the cross-building cache file -- add more cases and cache
  55 dnl files as necessary
  56 if test "x$cross_compiling" = "xyes"; then
  57     case "${host}" in
  58     *-cygwin*)
  59         cross_cache=${srcdir}/cross-build/cygwin.cache
  60         if test -r "${cross_cache}"; then
  61             echo "loading cross-build cache file ${cross_cache}"
  62             . ${cross_cache}
  63         fi
  64         LOCAL_CFLAGS="$LOCAL_CFLAGS -I${srcdir}/../libtermcap"
  65         unset cross_cache
  66         ;;
  67     *)  echo "configure: cross-compiling for a non-cygwin target is not supported" >&2
  68         ;;
  69     esac
  70 fi
  71
  72 if test "x$cross_compiling" = "xyes"; then
  73   CROSS_COMPILING_FLAG=-DCROSS_COMPILING
  74 else
  75   CROSS_COMPILING_FLAG=
  76 fi
  77 AC_SUBST(CROSS_COMPILING_FLAG)
  78
  79 if test -z "$CC_FOR_BUILD"; then
  80     if test "x$cross_compiling" = "xno"; then
  81         CC_FOR_BUILD='$(CC)'
  82     else
  83         CC_FOR_BUILD=gcc
  84     fi
  85 fi
  86 AC_SUBST(CC_FOR_BUILD)
  87
  88 dnl END changes for CYGNUS cross-building for Cygwin
  89
  90 # If we're using gcc and the user hasn't specified CFLAGS, add -O to CFLAGS.
  91 test -n "$GCC" && test -n "$auto_cflags" && CFLAGS="$CFLAGS -O"
  92
  93 AC_PROG_GCC_TRADITIONAL
  94 AC_PROG_INSTALL
  95 AC_CHECK_PROG(AR, ar, , ar)
  96 dnl Set default for ARFLAGS, since autoconf does not have a macro for it.
  97 dnl This allows people to set it when running configure or make
  98 test -n "$ARFLAGS" || ARFLAGS="cr"
  99 AC_PROG_RANLIB
 100
 101 MAKE_SHELL=/bin/sh
 102 AC_SUBST(MAKE_SHELL)
 103
 104 AC_C_CONST
 105 AC_C_PROTOTYPES
 106 AC_C_CHAR_UNSIGNED
 107
 108 AC_TYPE_SIGNAL
 109
 110 AC_TYPE_SIZE_T
 111 AC_CHECK_TYPE(ssize_t, int)
 112
 113 AC_HEADER_STAT
 114 AC_HEADER_DIRENT
 115
 116 AC_CHECK_FUNCS(lstat memmove putenv select setenv setlocale \
 117                 strcasecmp strpbrk tcgetattr vsnprintf isascii isxdigit)
 118
 119 AC_FUNC_STRCOLL
 120
 121 AC_CHECK_HEADERS(unistd.h stdlib.h varargs.h stdarg.h string.h strings.h \
 122                 limits.h sys/ptem.h sys/pte.h sys/stream.h sys/select.h \
 123                 termcap.h termios.h termio.h sys/file.h locale.h memory.h )
 124
 125 BASH_SYS_SIGNAL_VINTAGE
 126 BASH_SYS_REINSTALL_SIGHANDLERS
 127
 128 BASH_FUNC_POSIX_SETJMP
 129 BASH_FUNC_LSTAT
 130 BASH_FUNC_STRCOLL
 131
 132 BASH_CHECK_GETPW_FUNCS
 133
 134 AC_HEADER_TIOCGWINSZ
 135
 136 BASH_TYPE_SIGHANDLER
 137 BASH_HAVE_TIOCSTAT
 138 BASH_HAVE_FIONREAD
 139 BASH_CHECK_SPEED_T
 140 BASH_STRUCT_WINSIZE
 141 BASH_STRUCT_DIRENT_D_INO
 142 BASH_STRUCT_DIRENT_D_FILENO
 143
 144 dnl yuck
 145 case "$host_os" in
 146 aix*)   prefer_curses=yes ;;
 147 esac
 148 BASH_CHECK_LIB_TERMCAP
 149 if test "$TERMCAP_LIB" = "./lib/termcap/libtermcap.a"; then
 150         if test "$prefer_curses" = yes; then
 151                 TERMCAP_LIB=-lcurses
 152         else
 153                 TERMCAP_LIB=-ltermcap   #default
 154         fi
 155 fi
 156
 157 BASH_CHECK_MULTIBYTE
 158
 159 case "$host_cpu" in
 160 *cray*) LOCAL_CFLAGS=-DCRAY ;;
 161 *s390*) LOCAL_CFLAGS=-fsigned-char ;;
 162 esac
 163
 164 case "$host_os" in
 165 isc*)   LOCAL_CFLAGS=-Disc386 ;;
 166 esac
 167
 168 # shared library configuration section
 169 #
 170 # Shared object configuration section.  These values are generated by
 171 # ${srcdir}/support/shobj-conf
 172 #
 173 if test -f ${srcdir}/support/shobj-conf; then
 174         AC_MSG_CHECKING(configuration for building shared libraries)
 175         eval `${CONFIG_SHELL-/bin/sh} ${srcdir}/support/shobj-conf -C "${CC}" -c ${host_cpu} -o ${host_os} -v ${host_vendor}`
 176         AC_SUBST(SHOBJ_CC)
 177         AC_SUBST(SHOBJ_CFLAGS)
 178         AC_SUBST(SHOBJ_LD)
 179         AC_SUBST(SHOBJ_LDFLAGS)
 180         AC_SUBST(SHOBJ_XLDFLAGS)
 181         AC_SUBST(SHOBJ_LIBS)
 182         AC_SUBST(SHOBJ_STATUS)
 183         AC_SUBST(SHLIB_STATUS)
 184         AC_SUBST(SHLIB_XLDFLAGS)
 185         AC_SUBST(SHLIB_LIBSUFF)
 186         AC_SUBST(SHLIB_LIBVERSION)
 187         AC_SUBST(SHLIB_LIBS)
 188         AC_MSG_RESULT($SHLIB_STATUS)
 189
 190         # SHLIB_STATUS is either `supported' or `unsupported'.  If it's
 191         # `unsupported', turn off any default shared library building
 192         if test "$SHLIB_STATUS" = 'unsupported'; then
 193                 opt_shared_libs=no
 194         fi
 195
 196         # shared library versioning
 197         # quoted for m4 so I can use character classes
 198         SHLIB_MAJOR=[`expr "$LIBVERSION" : '\([0-9]\)\..*'`]
 199         SHLIB_MINOR=[`expr "$LIBVERSION" : '[0-9]\.\([0-9]\).*'`]
 200         AC_SUBST(SHLIB_MAJOR)
 201         AC_SUBST(SHLIB_MINOR)
 202 fi
 203
 204 if test "$opt_static_libs" = "yes"; then
 205         STATIC_TARGET=static
 206         STATIC_INSTALL_TARGET=install-static
 207 fi
 208 if test "$opt_shared_libs" = "yes"; then
 209         SHARED_TARGET=shared
 210         SHARED_INSTALL_TARGET=install-shared
 211 fi
 212
 213 AC_SUBST(STATIC_TARGET)
 214 AC_SUBST(SHARED_TARGET)
 215 AC_SUBST(STATIC_INSTALL_TARGET)
 216 AC_SUBST(SHARED_INSTALL_TARGET)
 217
 218 case "$host_os" in
 219 msdosdjgpp*)    BUILD_DIR=`pwd.exe` ;;  # to prevent //d/path/file
 220 *)              BUILD_DIR=`pwd` ;;
 221 esac
 222
 223 AC_SUBST(BUILD_DIR)
 224
 225 AC_SUBST(CFLAGS)
 226 AC_SUBST(LOCAL_CFLAGS)
 227 AC_SUBST(LOCAL_LDFLAGS)
 228 AC_SUBST(LOCAL_DEFS)
 229
 230 AC_SUBST(AR)
 231 AC_SUBST(ARFLAGS)
 232
 233 AC_SUBST(host_cpu)
 234 AC_SUBST(host_os)
 235
 236 AC_SUBST(LIBVERSION)
 237
 238 AC_SUBST(TERMCAP_LIB)
 239
 240 AC_OUTPUT([Makefile doc/Makefile examples/Makefile shlib/Makefile],
 241 [
 242 # Makefile uses this timestamp file to record whether config.h is up to date.
 243 echo > stamp-h
 244 ])