readline/configure.in

   1 dnl
   2 dnl Configure script for readline library
   3 dnl
   4 dnl report bugs to chet@po.cwru.edu
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 AC_REVISION([for Readline 4.3, version 2.45, from autoconf version] AC_ACVERSION)
   8
   9 AC_INIT(readline, 4.3, bug-readline@gnu.org)
  10
  11 dnl make sure we are using a recent autoconf version
  12 AC_PREREQ(2.50)
  13
  14 AC_CONFIG_SRCDIR(readline.h)
  15 dnl AC_CONFIG_AUX_DIR(./support)
  16 AC_CONFIG_HEADERS(config.h)
  17
  18 dnl update the value of RL_READLINE_VERSION in readline.h when this changes
  19 LIBVERSION=4.3
  20
  21 AC_CANONICAL_HOST
  22
  23 dnl configure defaults
  24 opt_curses=no
  25
  26 dnl arguments to configure
  27 AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
  28
  29 if test "$opt_curses" = "yes"; then
  30         prefer_curses=yes
  31 fi
  32
  33 dnl option parsing for optional features
  34 opt_static_libs=yes
  35 opt_shared_libs=no
  36
  37 AC_ARG_ENABLE(static, AC_HELP_STRING([--enable-static], [build static libraries [[default=YES]]]), opt_static_libs=$enableval)
  38
  39 echo ""
  40 echo "Beginning configuration for readline-$LIBVERSION for ${host_cpu}-${host_vendor}-${host_os}"
  41 echo ""
  42
  43 # We want these before the checks, so the checks can modify their values.
  44 test -z "$CFLAGS" && CFLAGS=-g auto_cflags=1
  45
  46 AC_PROG_MAKE_SET
  47 AC_PROG_CC
  48 dnl AC_AIX
  49 AC_MINIX
  50
  51 dnl BEGIN changes for CYGNUS cross-building for Cygwin
  52
  53 dnl load up the cross-building cache file -- add more cases and cache
  54 dnl files as necessary
  55 if test "x$cross_compiling" = "xyes"; then
  56     case "${host}" in
  57     *-cygwin*)
  58         cross_cache=${srcdir}/cross-build/cygwin.cache
  59         LOCAL_CFLAGS="$LOCAL_CFLAGS -I${srcdir}/../libtermcap"
  60         ;;
  61    *-mingw32*)
  62         cross_cache=${srcdir}/cross-build/mingw.cache
  63         ;;
  64     *)  echo "configure: cross-compiling for a non-cygwin target is not supported" >&2
  65         ;;
  66     esac
  67
  68     if test "x$cross_cache" != "x"; then
  69         if test -r "${cross_cache}"; then
  70             echo "loading cross-build cache file ${cross_cache}"
  71             . ${cross_cache}
  72         fi
  73         unset cross_cache
  74     fi
  75 fi
  76
  77 if test "x$cross_compiling" = "xyes"; then
  78   CROSS_COMPILING_FLAG=-DCROSS_COMPILING
  79 else
  80   CROSS_COMPILING_FLAG=
  81 fi
  82 AC_SUBST(CROSS_COMPILING_FLAG)
  83
  84 if test -z "$CC_FOR_BUILD"; then
  85     if test "x$cross_compiling" = "xno"; then
  86         CC_FOR_BUILD='$(CC)'
  87     else
  88         CC_FOR_BUILD=gcc
  89     fi
  90 fi
  91 AC_SUBST(CC_FOR_BUILD)
  92
  93 dnl END changes for CYGNUS cross-building for Cygwin
  94
  95 # If we're using gcc and the user hasn't specified CFLAGS, add -O to CFLAGS.
  96 test -n "$GCC" && test -n "$auto_cflags" && CFLAGS="$CFLAGS -O"
  97
  98 AC_PROG_GCC_TRADITIONAL
  99 AC_PROG_INSTALL
 100 AC_CHECK_PROG(AR, ar, , ar)
 101 dnl Set default for ARFLAGS, since autoconf does not have a macro for it.
 102 dnl This allows people to set it when running configure or make
 103 test -n "$ARFLAGS" || ARFLAGS="cr"
 104 AC_PROG_RANLIB
 105
 106 MAKE_SHELL=/bin/sh
 107 AC_SUBST(MAKE_SHELL)
 108
 109 AC_C_CONST
 110 AC_C_PROTOTYPES
 111 AC_C_CHAR_UNSIGNED
 112
 113 AC_TYPE_SIGNAL
 114
 115 AC_TYPE_SIZE_T
 116 AC_CHECK_TYPE(ssize_t, int)
 117
 118 AC_HEADER_STAT
 119 AC_HEADER_DIRENT
 120
 121 AC_CHECK_FUNCS(fcntl kill lstat memmove putenv select setenv setlocale \
 122                strcasecmp strpbrk tcgetattr vsnprintf isascii isxdigit \
 123                getpwnam getpwent getpwuid)
 124
 125 AC_FUNC_STRCOLL
 126
 127 AC_CHECK_HEADERS(unistd.h stdlib.h varargs.h stdarg.h string.h strings.h \
 128                 limits.h sys/ptem.h sys/pte.h sys/stream.h sys/select.h \
 129                 termcap.h termios.h termio.h sys/file.h locale.h memory.h \
 130                 pwd.h)
 131
 132 BASH_SYS_SIGNAL_VINTAGE
 133 BASH_SYS_REINSTALL_SIGHANDLERS
 134
 135 BASH_FUNC_POSIX_SETJMP
 136 BASH_FUNC_LSTAT
 137 BASH_FUNC_STRCOLL
 138
 139 BASH_CHECK_GETPW_FUNCS
 140
 141 AC_HEADER_TIOCGWINSZ
 142
 143 BASH_TYPE_SIGHANDLER
 144 BASH_HAVE_TIOCSTAT
 145 BASH_HAVE_FIONREAD
 146 BASH_CHECK_SPEED_T
 147 BASH_STRUCT_WINSIZE
 148 BASH_STRUCT_DIRENT_D_INO
 149 BASH_STRUCT_DIRENT_D_FILENO
 150
 151 dnl yuck
 152 case "$host_os" in
 153 aix*)   prefer_curses=yes ;;
 154 esac
 155 BASH_CHECK_LIB_TERMCAP
 156 if test "$TERMCAP_LIB" = "./lib/termcap/libtermcap.a"; then
 157         if test "$prefer_curses" = yes; then
 158                 TERMCAP_LIB=-lcurses
 159         else
 160                 TERMCAP_LIB=-ltermcap   #default
 161         fi
 162 fi
 163
 164 BASH_CHECK_MULTIBYTE
 165
 166 case "$host_cpu" in
 167 *cray*) LOCAL_CFLAGS=-DCRAY ;;
 168 *s390*) LOCAL_CFLAGS=-fsigned-char ;;
 169 esac
 170
 171 case "$host_os" in
 172 isc*)   LOCAL_CFLAGS=-Disc386 ;;
 173 esac
 174
 175 # shared library configuration section
 176 #
 177 # Shared object configuration section.  These values are generated by
 178 # ${srcdir}/support/shobj-conf
 179 #
 180 if test -f ${srcdir}/support/shobj-conf; then
 181         AC_MSG_CHECKING(configuration for building shared libraries)
 182         eval `${CONFIG_SHELL-/bin/sh} ${srcdir}/support/shobj-conf -C "${CC}" -c ${host_cpu} -o ${host_os} -v ${host_vendor}`
 183         AC_SUBST(SHOBJ_CC)
 184         AC_SUBST(SHOBJ_CFLAGS)
 185         AC_SUBST(SHOBJ_LD)
 186         AC_SUBST(SHOBJ_LDFLAGS)
 187         AC_SUBST(SHOBJ_XLDFLAGS)
 188         AC_SUBST(SHOBJ_LIBS)
 189         AC_SUBST(SHOBJ_STATUS)
 190         AC_SUBST(SHLIB_STATUS)
 191         AC_SUBST(SHLIB_XLDFLAGS)
 192         AC_SUBST(SHLIB_LIBSUFF)
 193         AC_SUBST(SHLIB_LIBVERSION)
 194         AC_SUBST(SHLIB_LIBS)
 195         AC_MSG_RESULT($SHLIB_STATUS)
 196
 197         # SHLIB_STATUS is either `supported' or `unsupported'.  If it's
 198         # `unsupported', turn off any default shared library building
 199         if test "$SHLIB_STATUS" = 'unsupported'; then
 200                 opt_shared_libs=no
 201         fi
 202
 203         # shared library versioning
 204         # quoted for m4 so I can use character classes
 205         SHLIB_MAJOR=[`expr "$LIBVERSION" : '\([0-9]\)\..*'`]
 206         SHLIB_MINOR=[`expr "$LIBVERSION" : '[0-9]\.\([0-9]\).*'`]
 207         AC_SUBST(SHLIB_MAJOR)
 208         AC_SUBST(SHLIB_MINOR)
 209 fi
 210
 211 if test "$opt_static_libs" = "yes"; then
 212         STATIC_TARGET=static
 213         STATIC_INSTALL_TARGET=install-static
 214 fi
 215 if test "$opt_shared_libs" = "yes"; then
 216         SHARED_TARGET=shared
 217         SHARED_INSTALL_TARGET=install-shared
 218 fi
 219
 220 AC_SUBST(STATIC_TARGET)
 221 AC_SUBST(SHARED_TARGET)
 222 AC_SUBST(STATIC_INSTALL_TARGET)
 223 AC_SUBST(SHARED_INSTALL_TARGET)
 224
 225 case "$host_os" in
 226 msdosdjgpp*)    BUILD_DIR=`pwd.exe` ;;  # to prevent //d/path/file
 227 *)              BUILD_DIR=`pwd` ;;
 228 esac
 229
 230 AC_SUBST(BUILD_DIR)
 231
 232 AC_SUBST(CFLAGS)
 233 AC_SUBST(LOCAL_CFLAGS)
 234 AC_SUBST(LOCAL_LDFLAGS)
 235 AC_SUBST(LOCAL_DEFS)
 236
 237 AC_SUBST(AR)
 238 AC_SUBST(ARFLAGS)
 239
 240 AC_SUBST(host_cpu)
 241 AC_SUBST(host_os)
 242
 243 AC_SUBST(LIBVERSION)
 244
 245 AC_SUBST(TERMCAP_LIB)
 246
 247 AC_OUTPUT([Makefile doc/Makefile examples/Makefile shlib/Makefile],
 248 [
 249 # Makefile uses this timestamp file to record whether config.h is up to date.
 250 echo > stamp-h
 251 ])