[babeltrace.git] / src / plugins / ctf / common / metadata / lexer.l

%{
/*
 * SPDX-License-Identifier: MIT
 *
 * Copyright 2010 Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
 *
 * Common Trace Formal Lexer
 */

#define BT_LOG_OUTPUT_LEVEL ctf_plugin_metadata_log_level
#define BT_LOG_TAG "PLUGIN-CTF-METADATA-LEXER"
#include "logging.h"

#include <stdio.h>
#include <ctype.h>
#include "scanner.h"
#include "parser-wrap.h"
#include "ast.h"

#define YY_FATAL_ERROR(_msg)	BT_LOGF_STR(_msg)

#define PARSE_INTEGER_LITERAL(base)					\
	do {								\
		errno = 0;						\
		yylval->ull = strtoull(yytext, NULL, base);		\
		if (errno) {						\
			_BT_LOGE_LINENO(yylineno,			\
				"Cannot parser constant integer: " 	\
				"base=%d, text=\"%s\"", base, yytext);	\
			return CTF_ERROR;				\
		}							\
	} while (0)
%}

%x comment_ml comment_sl string_lit char_const
%option reentrant yylineno noyywrap bison-bridge
%option extra-type="struct ctf_scanner *"
	/* bison-locations */
INTEGER_SUFFIX			(U|UL|ULL|LU|LLU|Ul|Ull|lU|llU|u|uL|uLL|Lu|LLu|ul|ull|lu|llu)
DIGIT				[0-9]
NONDIGIT			[a-zA-Z_]
HEXDIGIT			[0-9A-Fa-f]
OCTALDIGIT			[0-7]
UCHARLOWERCASE			\\u{HEXDIGIT}{4}
UCHARUPPERCASE			\\U{HEXDIGIT}{8}
ID_NONDIGIT			{NONDIGIT}|{UCHARLOWERCASE}|{UCHARUPPERCASE}
IDENTIFIER			{ID_NONDIGIT}({ID_NONDIGIT}|{DIGIT})*
%%

				/*
				 * Using start conditions to deal with comments
				 * and strings.
				 */

"/*"				BEGIN(comment_ml);
<comment_ml>[^*\n]*		/* eat anything that's not a '*' */
<comment_ml>"*"+[^*/\n]*	/* eat up '*'s not followed by '/'s */
<comment_ml>\n
<comment_ml>"*"+"/"		BEGIN(INITIAL);

"//"[^\n]*\n			/* skip comment */

L?\"(\\.|[^\\"])*\"		{ if (import_string(yyextra, yylval, yytext, '\"') < 0) return CTF_ERROR; else return CTF_STRING_LITERAL; }
L?\'(\\.|[^\\'])*\'		{ if (import_string(yyextra, yylval, yytext, '\'') < 0) return CTF_ERROR; else return CTF_CHARACTER_LITERAL; }

"["				return CTF_LSBRAC;
"]"				return CTF_RSBRAC;
"("				return CTF_LPAREN;
")"				return CTF_RPAREN;
"{"				return CTF_LBRAC;
"}"				return CTF_RBRAC;
"->"				return CTF_RARROW;
"*"				return CTF_STAR;
"+"				return CTF_PLUS;
"-"				return CTF_MINUS;
"<"				return CTF_LT;
">"				return CTF_GT;
:=				return CTF_TYPEASSIGN;
:				return CTF_COLON;
;				return CTF_SEMICOLON;
"..."				return CTF_DOTDOTDOT;
"."				return CTF_DOT;
=				return CTF_EQUAL;
","				return CTF_COMMA;
align				setstring(yyextra, yylval, yytext); return CTF_TOK_ALIGN;
const				setstring(yyextra, yylval, yytext); return CTF_CONST;
char				setstring(yyextra, yylval, yytext); return CTF_CHAR;
clock				setstring(yyextra, yylval, yytext); return CTF_CLOCK;
double				setstring(yyextra, yylval, yytext); return CTF_DOUBLE;
enum				setstring(yyextra, yylval, yytext); return CTF_ENUM;
env				setstring(yyextra, yylval, yytext); return CTF_ENV;
event				setstring(yyextra, yylval, yytext); return CTF_EVENT;
floating_point			setstring(yyextra, yylval, yytext); return CTF_FLOATING_POINT;
float				setstring(yyextra, yylval, yytext); return CTF_FLOAT;
integer				setstring(yyextra, yylval, yytext); return CTF_INTEGER;
int				setstring(yyextra, yylval, yytext); return CTF_INT;
long				setstring(yyextra, yylval, yytext); return CTF_LONG;
short				setstring(yyextra, yylval, yytext); return CTF_SHORT;
signed				setstring(yyextra, yylval, yytext); return CTF_SIGNED;
stream				setstring(yyextra, yylval, yytext); return CTF_STREAM;
string				setstring(yyextra, yylval, yytext); return CTF_STRING;
struct				setstring(yyextra, yylval, yytext); return CTF_STRUCT;
trace				setstring(yyextra, yylval, yytext); return CTF_TRACE;
callsite			setstring(yyextra, yylval, yytext); return CTF_CALLSITE;
typealias			setstring(yyextra, yylval, yytext); return CTF_TYPEALIAS;
typedef				setstring(yyextra, yylval, yytext); return CTF_TYPEDEF;
unsigned			setstring(yyextra, yylval, yytext); return CTF_UNSIGNED;
variant				setstring(yyextra, yylval, yytext); return CTF_VARIANT;
void				setstring(yyextra, yylval, yytext); return CTF_VOID;
_Bool				setstring(yyextra, yylval, yytext); return CTF_BOOL;
_Complex			setstring(yyextra, yylval, yytext); return CTF_COMPLEX;
_Imaginary			setstring(yyextra, yylval, yytext); return CTF_IMAGINARY;
[1-9]{DIGIT}*{INTEGER_SUFFIX}?	PARSE_INTEGER_LITERAL(10); return CTF_INTEGER_LITERAL;
0{OCTALDIGIT}*{INTEGER_SUFFIX}?	PARSE_INTEGER_LITERAL(8); return CTF_INTEGER_LITERAL;
0[xX]{HEXDIGIT}+{INTEGER_SUFFIX}?	PARSE_INTEGER_LITERAL(16); return CTF_INTEGER_LITERAL;

{IDENTIFIER}			BT_LOGT("Got identifier: id=\"%s\"", yytext); setstring(yyextra, yylval, yytext); if (is_type(yyextra, yytext)) return ID_TYPE; else return IDENTIFIER;
[ \t\r\n]			; /* ignore */
.				_BT_LOGE_LINENO(yylineno, "Invalid character: char=\"%c\", val=0x%02x", isprint((unsigned char) yytext[0]) ? yytext[0] : '\0', yytext[0]); return CTF_ERROR;
%%
Commit	Line	Data
e98a2d6e PP	1	%{
e98a2d6e PP	2	/*
0235b0db	3	* SPDX-License-Identifier: MIT
e98a2d6e	4	*
0235b0db	5	* Copyright 2010 Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
e98a2d6e	6	*
0235b0db	7	* Common Trace Formal Lexer
e98a2d6e PP	8	*/
e98a2d6e PP	9
0746848c	10	#define BT_LOG_OUTPUT_LEVEL ctf_plugin_metadata_log_level
f73367f8 PP	11	#define BT_LOG_TAG "PLUGIN-CTF-METADATA-LEXER"
	12	#include "logging.h"
	13
e98a2d6e PP	14	#include <stdio.h>
e98a2d6e PP	15	#include <ctype.h>
06a626b8	16	#include "scanner.h"
9103e903	17	#include "parser-wrap.h"
06a626b8	18	#include "ast.h"
e98a2d6e	19
f73367f8 PP	20	#define YY_FATAL_ERROR(_msg) BT_LOGF_STR(_msg)
f73367f8 PP	21
e98a2d6e PP	22	#define PARSE_INTEGER_LITERAL(base) \
	23	do { \
	24	errno = 0; \
	25	yylval->ull = strtoull(yytext, NULL, base); \
	26	if (errno) { \
f73367f8 PP	27	_BT_LOGE_LINENO(yylineno, \
	28	"Cannot parser constant integer: " \
	29	"base=%d, text=\"%s\"", base, yytext); \
	30	return CTF_ERROR; \
e98a2d6e PP	31	} \
e98a2d6e PP	32	} while (0)
e98a2d6e PP	33	%}
	34
	35	%x comment_ml comment_sl string_lit char_const
	36	%option reentrant yylineno noyywrap bison-bridge
	37	%option extra-type="struct ctf_scanner *"
	38	/* bison-locations */
	39	INTEGER_SUFFIX (U\|UL\|ULL\|LU\|LLU\|Ul\|Ull\|lU\|llU\|u\|uL\|uLL\|Lu\|LLu\|ul\|ull\|lu\|llu)
	40	DIGIT [0-9]
	41	NONDIGIT [a-zA-Z_]
	42	HEXDIGIT [0-9A-Fa-f]
	43	OCTALDIGIT [0-7]
	44	UCHARLOWERCASE \\u{HEXDIGIT}{4}
	45	UCHARUPPERCASE \\U{HEXDIGIT}{8}
	46	ID_NONDIGIT {NONDIGIT}\|{UCHARLOWERCASE}\|{UCHARUPPERCASE}
	47	IDENTIFIER {ID_NONDIGIT}({ID_NONDIGIT}\|{DIGIT})*
	48	%%
	49
	50	/*
	51	* Using start conditions to deal with comments
	52	* and strings.
f73367f8	53	*/
e98a2d6e PP	54
	55	"/*" BEGIN(comment_ml);
	56	<comment_ml>[^\n] /* eat anything that's not a '' /
	57	<comment_ml>""+[^/\n]* /* eat up ''s not followed by '/'s /
	58	<comment_ml>\n
	59	<comment_ml>"*"+"/" BEGIN(INITIAL);
	60
	61	"//"[^\n]\n / skip comment */
	62
d4c6eae5 MJ	63	L?\"(\\.\|[^\\"])*\" { if (import_string(yyextra, yylval, yytext, '\"') < 0) return CTF_ERROR; else return CTF_STRING_LITERAL; }
d4c6eae5 MJ	64	L?\'(\\.\|[^\\'])*\' { if (import_string(yyextra, yylval, yytext, '\'') < 0) return CTF_ERROR; else return CTF_CHARACTER_LITERAL; }
e98a2d6e	65
d4c6eae5 MJ	66	"[" return CTF_LSBRAC;
	67	"]" return CTF_RSBRAC;
	68	"(" return CTF_LPAREN;
	69	")" return CTF_RPAREN;
	70	"{" return CTF_LBRAC;
	71	"}" return CTF_RBRAC;
	72	"->" return CTF_RARROW;
	73	"*" return CTF_STAR;
	74	"+" return CTF_PLUS;
	75	"-" return CTF_MINUS;
	76	"<" return CTF_LT;
	77	">" return CTF_GT;
	78	:= return CTF_TYPEASSIGN;
	79	: return CTF_COLON;
	80	; return CTF_SEMICOLON;
	81	"..." return CTF_DOTDOTDOT;
	82	"." return CTF_DOT;
	83	= return CTF_EQUAL;
	84	"," return CTF_COMMA;
	85	align setstring(yyextra, yylval, yytext); return CTF_TOK_ALIGN;
	86	const setstring(yyextra, yylval, yytext); return CTF_CONST;
	87	char setstring(yyextra, yylval, yytext); return CTF_CHAR;
	88	clock setstring(yyextra, yylval, yytext); return CTF_CLOCK;
	89	double setstring(yyextra, yylval, yytext); return CTF_DOUBLE;
	90	enum setstring(yyextra, yylval, yytext); return CTF_ENUM;
	91	env setstring(yyextra, yylval, yytext); return CTF_ENV;
	92	event setstring(yyextra, yylval, yytext); return CTF_EVENT;
	93	floating_point setstring(yyextra, yylval, yytext); return CTF_FLOATING_POINT;
	94	float setstring(yyextra, yylval, yytext); return CTF_FLOAT;
	95	integer setstring(yyextra, yylval, yytext); return CTF_INTEGER;
	96	int setstring(yyextra, yylval, yytext); return CTF_INT;
	97	long setstring(yyextra, yylval, yytext); return CTF_LONG;
	98	short setstring(yyextra, yylval, yytext); return CTF_SHORT;
	99	signed setstring(yyextra, yylval, yytext); return CTF_SIGNED;
	100	stream setstring(yyextra, yylval, yytext); return CTF_STREAM;
	101	string setstring(yyextra, yylval, yytext); return CTF_STRING;
	102	struct setstring(yyextra, yylval, yytext); return CTF_STRUCT;
	103	trace setstring(yyextra, yylval, yytext); return CTF_TRACE;
	104	callsite setstring(yyextra, yylval, yytext); return CTF_CALLSITE;
	105	typealias setstring(yyextra, yylval, yytext); return CTF_TYPEALIAS;
	106	typedef setstring(yyextra, yylval, yytext); return CTF_TYPEDEF;
	107	unsigned setstring(yyextra, yylval, yytext); return CTF_UNSIGNED;
	108	variant setstring(yyextra, yylval, yytext); return CTF_VARIANT;
	109	void setstring(yyextra, yylval, yytext); return CTF_VOID;
	110	_Bool setstring(yyextra, yylval, yytext); return CTF_BOOL;
	111	_Complex setstring(yyextra, yylval, yytext); return CTF_COMPLEX;
	112	_Imaginary setstring(yyextra, yylval, yytext); return CTF_IMAGINARY;
	113	[1-9]{DIGIT}*{INTEGER_SUFFIX}? PARSE_INTEGER_LITERAL(10); return CTF_INTEGER_LITERAL;
	114	0{OCTALDIGIT}*{INTEGER_SUFFIX}? PARSE_INTEGER_LITERAL(8); return CTF_INTEGER_LITERAL;
	115	0[xX]{HEXDIGIT}+{INTEGER_SUFFIX}? PARSE_INTEGER_LITERAL(16); return CTF_INTEGER_LITERAL;
e98a2d6e	116
ef267d12	117	{IDENTIFIER} BT_LOGT("Got identifier: id=\"%s\"", yytext); setstring(yyextra, yylval, yytext); if (is_type(yyextra, yytext)) return ID_TYPE; else return IDENTIFIER;
e98a2d6e	118	[ \t\r\n] ; /* ignore */
994cd345	119	. _BT_LOGE_LINENO(yylineno, "Invalid character: char=\"%c\", val=0x%02x", isprint((unsigned char) yytext[0]) ? yytext[0] : '\0', yytext[0]); return CTF_ERROR;
e98a2d6e	120	%%