[babeltrace.git] / configure.ac

AC_PREREQ([2.50])
AC_INIT([babeltrace],[1.4.0-pre],[jeremie.galarneau@efficios.com],[],[https://diamon.org/babeltrace])
AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])

AC_CONFIG_HEADERS([config.h])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET
AC_CANONICAL_HOST

AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
AM_MAINTAINER_MODE([enable])

# Enable silent rules if available (Introduced in AM 1.11)
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

AC_REQUIRE_AUX_FILE([tap-driver.sh])

# Checks for C compiler
AC_USE_SYSTEM_EXTENSIONS
AC_SYS_LARGEFILE
AC_PROG_CC
AC_PROG_CC_STDC

# Checks for programs.
AC_PROG_MAKE_SET
LT_INIT
AC_PROG_YACC
AC_PROG_LEX
AC_PROG_MKDIR_P
AC_PROG_LN_S

AX_C___ATTRIBUTE__
AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	[:],
	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])

AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
LIBS="$PTHREAD_LIBS $LIBS"
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
CC="$PTHREAD_CC"

# Check linker option
AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
AC_SUBST([LD_NO_AS_NEEDED])

AC_HEADER_STDBOOL
AC_CHECK_HEADERS([ \
	fcntl.h \
	float.h \
	libintl.h \
	limits.h \
	malloc.h \
	netdb.h \
	netinet/in.h \
	stddef.h \
	sys/socket.h \
])

if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
        if test x"$(basename "$YACC")" != "xbison -y"; then
                AC_MSG_ERROR([[bison not found and is required when building from git.
                Please install bison]])
        fi
        AC_PATH_PROG([BISON],[bison])
        AX_PROG_BISON_VERSION([2.4], [],[
                AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
        ])
fi

if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
        if test x"$LEX" != "xflex"; then
                AC_MSG_ERROR([[flex not found and is required when building from git.
                Please install flex]])
        fi
        AC_PATH_PROG([FLEX],[flex])
        AX_PROG_FLEX_VERSION([2.5.35], [],[
                AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
        ])
fi

AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)

# Check what libraries are required on this platform to link sockets programs.
AX_LIB_SOCKET_NSL

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T

# Checks for library functions.
AC_FUNC_ALLOCA
AC_FUNC_FORK
AC_FUNC_MALLOC
AC_FUNC_MKTIME
AC_FUNC_MMAP
AC_FUNC_REALLOC
AC_FUNC_STRERROR_R
AC_CHECK_FUNCS([ \
	atexit \
	dirfd \
	dup2 \
	ftruncate \
	gethostbyname \
	gethostname \
	gettimeofday \
	localtime_r \
	memchr \
	memset \
	mkdir \
	mkdtemp \
	munmap \
	rmdir \
	setenv \
	socket \
	strchr \
	strdup \
	strerror \
	strndup \
	strnlen \
	strrchr \
	strtoul \
	strtoull \
	tzset \
	uname \
])

MINGW32=no
DEFAULT_ENABLE_DEBUGINFO=yes
AS_CASE([$host_os],
  [solaris*|darwin*],
    [
	DEFAULT_ENABLE_DEBUGINFO=no
    ],
  [mingw*],
    [
	MINGW32=yes
    ]
)

AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])

# Check for libuuid
AC_CHECK_LIB([uuid], [uuid_generate],
[
	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
	have_libuuid=yes
],
[
	# libuuid not found, check for uuid_create in libc.
	AC_CHECK_LIB([c], [uuid_create],
	[
		AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
		have_libc_uuid=yes
	],
	[
		# for MinGW32 we have our own internal implemenation of uuid using Windows functions.
		if test "x$MINGW32" = xno; then
			AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
		fi
	])
]
)
AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])

# Check for fmemopen
AC_CHECK_LIB([c], [fmemopen],
[
	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
]
)

# Check for open_memstream
AC_CHECK_LIB([c], [open_memstream],
[
	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
]
)

# Check for posix_fallocate
AC_CHECK_LIB([c], [posix_fallocate],
[
	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
]
)

# Check for faccessat
AC_CHECK_LIB([c], [faccessat],
[
	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
]
)

AC_CHECK_LIB([popt], [poptGetContext], [],
        [AC_MSG_ERROR([Cannot find popt.])]
)

# For Python
# SWIG version needed or newer:
swig_version=2.0.0

AC_ARG_ENABLE([python-bindings],
              [AC_HELP_STRING([--enable-python-bindings],
                              [generate Python bindings])],
              [enable_python=yes], [enable_python=no])

AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])

if test "x${enable_python:-yes}" = xyes; then
  AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
  AM_PATH_PYTHON

  AM_PATH_PYTHON_MODULES([PYTHON])
  # pythondir is the path where extra modules are to be installed
  pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
  # pyexecdir is the path that contains shared objects used by the extra modules
  pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
  AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
  AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
  AS_IF([test -z "$PYTHON_INCLUDE"], [
    AS_IF([test -z "$PYTHON_CONFIG"], [
      AC_PATH_PROGS([PYTHON_CONFIG],
                    [python$PYTHON_VERSION-config python-config],
                    [no],
                    [`dirname $PYTHON`])
      AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
    ])
    AC_MSG_CHECKING([python include flags])
    PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
    AC_MSG_RESULT([$PYTHON_INCLUDE])
  ])

else
    AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
[if you want Python bindings.])

fi

# Optional debuginfo feature (enabled by default)
AS_IF([test "x$DEFAULT_ENABLE_DEBUGINFO" = xyes],
    [AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--disable-debug-info], [disable the debug-info feature (default on OS X and Solaris)])], [], [enable_debuginfo=yes])],
    [AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--enable-debug-info], [enable the debug-info feature (default on Linux)])], [], [enable_debuginfo=no])]
)

AM_CONDITIONAL([ENABLE_DEBUGINFO], [test "x$enable_debuginfo" = xyes])
AS_IF([test "x$enable_debuginfo" = xyes], [
	    # Check if libelf and libdw are present
	    AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
	    AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
	    AX_LIB_ELFUTILS([0], [154], [], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug-info feature. You can disable this feature using --disable-debuginfo.)])
            AC_DEFINE([ENABLE_DEBUGINFO], [1], [Define to 1 if you enable the 'debug-info' feature])
], [])

PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
AC_SUBST(PACKAGE_LIBS)

LIBS="$LIBS $GMODULE_LIBS"
PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
AC_SUBST(PACKAGE_CFLAGS)

DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
AC_SUBST(DEFAULT_INCLUDES)

babeltraceincludedir="${includedir}/babeltrace"
AC_SUBST(babeltraceincludedir)

babeltracectfincludedir="${includedir}/babeltrace/ctf"
AC_SUBST(babeltracectfincludedir)

babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
AC_SUBST(babeltracectfwriterincludedir)

AC_CONFIG_FILES([
	Makefile
	types/Makefile
	compat/Makefile
	formats/Makefile
	formats/ctf/Makefile
	formats/ctf/types/Makefile
	formats/ctf-text/Makefile
	formats/ctf-text/types/Makefile
	formats/ctf-metadata/Makefile
	formats/bt-dummy/Makefile
	formats/lttng-live/Makefile
	formats/ctf/metadata/Makefile
	formats/ctf/writer/Makefile
	converter/Makefile
	doc/Makefile
	lib/Makefile
	lib/prio_heap/Makefile
	include/Makefile
	bindings/Makefile
	bindings/python/Makefile
	tests/Makefile
	tests/bin/Makefile
	tests/lib/Makefile
	tests/utils/Makefile
	tests/utils/tap/Makefile
	extras/Makefile
	extras/valgrind/Makefile
	babeltrace.pc
	babeltrace-ctf.pc
])

AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])

AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
AC_CONFIG_FILES([tests/bin/test_intersection], [chmod +x tests/bin/test_intersection])
AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])

AC_OUTPUT

#
# Mini-report on what will be built.
#

PPRINT_INIT
PPRINT_SET_INDENT(1)
PPRINT_SET_TS(38)

AS_ECHO
AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
AS_ECHO

PPRINT_SUBTITLE([Features])

# Target architecture we're building for.
target_arch=$host_cpu
[
for f in $CFLAGS; do
	if test $f = "-m32"; then
		target_arch="32-bit"
	elif test $f = "-m64"; then
		target_arch="64-bit"
	fi
done
]
PPRINT_PROP_STRING([Target architecture], $target_arch)

# python bindings enabled/disabled
test "x$enable_python" = "xyes" && value=1 || value=0
PPRINT_PROP_BOOL([Python bindings], $value)

# python bindings doc enabled/disabled
test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
PPRINT_PROP_BOOL([Python bindings doc], $value)

# debug-info enabled/disabled
test "x$enable_debuginfo" = "xyes" && value=1 || value=0
PPRINT_PROP_BOOL([Debug information output], $value)


report_bindir="`eval eval echo $bindir`"
report_libdir="`eval eval echo $libdir`"

# Print the bindir and libdir this `make install' will install into.
AS_ECHO
PPRINT_SUBTITLE([Install directories])
PPRINT_PROP_STRING([Binaries], [$report_bindir])
PPRINT_PROP_STRING([Libraries], [$report_libdir])
Commit	Line	Data
	1	AC_PREREQ([2.50])
	2	AC_INIT([babeltrace],[1.4.0-pre],[jeremie.galarneau@efficios.com],[],[https://diamon.org/babeltrace])
	3	AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
	4
	5	AC_CONFIG_HEADERS([config.h])
	6	AC_CONFIG_AUX_DIR([config])
	7	AC_CONFIG_MACRO_DIR([m4])
	8
	9	AC_CANONICAL_TARGET
	10	AC_CANONICAL_HOST
	11
	12	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
	13	AM_MAINTAINER_MODE([enable])
	14
	15	# Enable silent rules if available (Introduced in AM 1.11)
	16	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	17
	18	AC_REQUIRE_AUX_FILE([tap-driver.sh])
	19
	20	# Checks for C compiler
	21	AC_USE_SYSTEM_EXTENSIONS
	22	AC_SYS_LARGEFILE
	23	AC_PROG_CC
	24	AC_PROG_CC_STDC
	25
	26	# Checks for programs.
	27	AC_PROG_MAKE_SET
	28	LT_INIT
	29	AC_PROG_YACC
	30	AC_PROG_LEX
	31	AC_PROG_MKDIR_P
	32	AC_PROG_LN_S
	33
	34	AX_C___ATTRIBUTE__
	35	AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	36	[:],
	37	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
	38
	39	AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
	40	LIBS="$PTHREAD_LIBS $LIBS"
	41	CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
	42	CC="$PTHREAD_CC"
	43
	44	# Check linker option
	45	AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
	46	AC_SUBST([LD_NO_AS_NEEDED])
	47
	48	AC_HEADER_STDBOOL
	49	AC_CHECK_HEADERS([ \
	50	fcntl.h \
	51	float.h \
	52	libintl.h \
	53	limits.h \
	54	malloc.h \
	55	netdb.h \
	56	netinet/in.h \
	57	stddef.h \
	58	sys/socket.h \
	59	])
	60
	61	if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
	62	if test x"$(basename "$YACC")" != "xbison -y"; then
	63	AC_MSG_ERROR([[bison not found and is required when building from git.
	64	Please install bison]])
	65	fi
	66	AC_PATH_PROG([BISON],[bison])
	67	AX_PROG_BISON_VERSION([2.4], [],[
	68	AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
	69	])
	70	fi
	71
	72	if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
	73	if test x"$LEX" != "xflex"; then
	74	AC_MSG_ERROR([[flex not found and is required when building from git.
	75	Please install flex]])
	76	fi
	77	AC_PATH_PROG([FLEX],[flex])
	78	AX_PROG_FLEX_VERSION([2.5.35], [],[
	79	AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
	80	])
	81	fi
	82
	83	AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
	84
	85	# Check what libraries are required on this platform to link sockets programs.
	86	AX_LIB_SOCKET_NSL
	87
	88	# Checks for typedefs, structures, and compiler characteristics.
	89	AC_C_INLINE
	90	AC_TYPE_PID_T
	91	AC_TYPE_SIZE_T
	92
	93	# Checks for library functions.
	94	AC_FUNC_ALLOCA
	95	AC_FUNC_FORK
	96	AC_FUNC_MALLOC
	97	AC_FUNC_MKTIME
	98	AC_FUNC_MMAP
	99	AC_FUNC_REALLOC
	100	AC_FUNC_STRERROR_R
	101	AC_CHECK_FUNCS([ \
	102	atexit \
	103	dirfd \
	104	dup2 \
	105	ftruncate \
	106	gethostbyname \
	107	gethostname \
	108	gettimeofday \
	109	localtime_r \
	110	memchr \
	111	memset \
	112	mkdir \
	113	mkdtemp \
	114	munmap \
	115	rmdir \
	116	setenv \
	117	socket \
	118	strchr \
	119	strdup \
	120	strerror \
	121	strndup \
	122	strnlen \
	123	strrchr \
	124	strtoul \
	125	strtoull \
	126	tzset \
	127	uname \
	128	])
	129
	130	MINGW32=no
	131	DEFAULT_ENABLE_DEBUGINFO=yes
	132	AS_CASE([$host_os],
	133	[solaris\|darwin],
	134	[
	135	DEFAULT_ENABLE_DEBUGINFO=no
	136	],
	137	[mingw*],
	138	[
	139	MINGW32=yes
	140	]
	141	)
	142
	143	AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
	144
	145	# Check for libuuid
	146	AC_CHECK_LIB([uuid], [uuid_generate],
	147	[
	148	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
	149	have_libuuid=yes
	150	],
	151	[
	152	# libuuid not found, check for uuid_create in libc.
	153	AC_CHECK_LIB([c], [uuid_create],
	154	[
	155	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
	156	have_libc_uuid=yes
	157	],
	158	[
	159	# for MinGW32 we have our own internal implemenation of uuid using Windows functions.
	160	if test "x$MINGW32" = xno; then
	161	AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
	162	fi
	163	])
	164	]
	165	)
	166	AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
	167	AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
	168
	169	# Check for fmemopen
	170	AC_CHECK_LIB([c], [fmemopen],
	171	[
	172	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
	173	]
	174	)
	175
	176	# Check for open_memstream
	177	AC_CHECK_LIB([c], [open_memstream],
	178	[
	179	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
	180	]
	181	)
	182
	183	# Check for posix_fallocate
	184	AC_CHECK_LIB([c], [posix_fallocate],
	185	[
	186	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
	187	]
	188	)
	189
	190	# Check for faccessat
	191	AC_CHECK_LIB([c], [faccessat],
	192	[
	193	AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
	194	]
	195	)
	196
	197	AC_CHECK_LIB([popt], [poptGetContext], [],
	198	[AC_MSG_ERROR([Cannot find popt.])]
	199	)
	200
	201	# For Python
	202	# SWIG version needed or newer:
	203	swig_version=2.0.0
	204
	205	AC_ARG_ENABLE([python-bindings],
	206	[AC_HELP_STRING([--enable-python-bindings],
	207	[generate Python bindings])],
	208	[enable_python=yes], [enable_python=no])
	209
	210	AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
	211
	212	if test "x${enable_python:-yes}" = xyes; then
	213	AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
	214	AM_PATH_PYTHON
	215
	216	AM_PATH_PYTHON_MODULES([PYTHON])
	217	# pythondir is the path where extra modules are to be installed
	218	pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
	219	# pyexecdir is the path that contains shared objects used by the extra modules
	220	pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
	221	AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
	222	AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
	223	AS_IF([test -z "$PYTHON_INCLUDE"], [
	224	AS_IF([test -z "$PYTHON_CONFIG"], [
	225	AC_PATH_PROGS([PYTHON_CONFIG],
	226	[python$PYTHON_VERSION-config python-config],
	227	[no],
	228	[`dirname $PYTHON`])
	229	AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
	230	])
	231	AC_MSG_CHECKING([python include flags])
	232	PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
	233	AC_MSG_RESULT([$PYTHON_INCLUDE])
	234	])
	235
	236	else
	237	AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
	238	[if you want Python bindings.])
	239
	240	fi
	241
	242	# Optional debuginfo feature (enabled by default)
	243	AS_IF([test "x$DEFAULT_ENABLE_DEBUGINFO" = xyes],
	244	[AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--disable-debug-info], [disable the debug-info feature (default on OS X and Solaris)])], [], [enable_debuginfo=yes])],
	245	[AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--enable-debug-info], [enable the debug-info feature (default on Linux)])], [], [enable_debuginfo=no])]
	246	)
	247
	248	AM_CONDITIONAL([ENABLE_DEBUGINFO], [test "x$enable_debuginfo" = xyes])
	249	AS_IF([test "x$enable_debuginfo" = xyes], [
	250	# Check if libelf and libdw are present
	251	AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
	252	AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
	253	AX_LIB_ELFUTILS([0], [154], [], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug-info feature. You can disable this feature using --disable-debuginfo.)])
	254	AC_DEFINE([ENABLE_DEBUGINFO], [1], [Define to 1 if you enable the 'debug-info' feature])
	255	], [])
	256
	257	PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
	258	AC_SUBST(PACKAGE_LIBS)
	259
	260	LIBS="$LIBS $GMODULE_LIBS"
	261	PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
	262	AC_SUBST(PACKAGE_CFLAGS)
	263
	264	DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
	265	AC_SUBST(DEFAULT_INCLUDES)
	266
	267	babeltraceincludedir="${includedir}/babeltrace"
	268	AC_SUBST(babeltraceincludedir)
	269
	270	babeltracectfincludedir="${includedir}/babeltrace/ctf"
	271	AC_SUBST(babeltracectfincludedir)
	272
	273	babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
	274	AC_SUBST(babeltracectfwriterincludedir)
	275
	276	AC_CONFIG_FILES([
	277	Makefile
	278	types/Makefile
	279	compat/Makefile
	280	formats/Makefile
	281	formats/ctf/Makefile
	282	formats/ctf/types/Makefile
	283	formats/ctf-text/Makefile
	284	formats/ctf-text/types/Makefile
	285	formats/ctf-metadata/Makefile
	286	formats/bt-dummy/Makefile
	287	formats/lttng-live/Makefile
	288	formats/ctf/metadata/Makefile
	289	formats/ctf/writer/Makefile
	290	converter/Makefile
	291	doc/Makefile
	292	lib/Makefile
	293	lib/prio_heap/Makefile
	294	include/Makefile
	295	bindings/Makefile
	296	bindings/python/Makefile
	297	tests/Makefile
	298	tests/bin/Makefile
	299	tests/lib/Makefile
	300	tests/utils/Makefile
	301	tests/utils/tap/Makefile
	302	extras/Makefile
	303	extras/valgrind/Makefile
	304	babeltrace.pc
	305	babeltrace-ctf.pc
	306	])
	307
	308	AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
	309	AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
	310	AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
	311	AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
	312	AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
	313
	314	AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
	315	AC_CONFIG_FILES([tests/bin/test_intersection], [chmod +x tests/bin/test_intersection])
	316	AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
	317
	318	AC_OUTPUT
	319
	320	#
	321	# Mini-report on what will be built.
	322	#
	323
	324	PPRINT_INIT
	325	PPRINT_SET_INDENT(1)
	326	PPRINT_SET_TS(38)
	327
	328	AS_ECHO
	329	AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
	330	AS_ECHO
	331
	332	PPRINT_SUBTITLE([Features])
	333
	334	# Target architecture we're building for.
	335	target_arch=$host_cpu
	336	[
	337	for f in $CFLAGS; do
	338	if test $f = "-m32"; then
	339	target_arch="32-bit"
	340	elif test $f = "-m64"; then
	341	target_arch="64-bit"
	342	fi
	343	done
	344	]
	345	PPRINT_PROP_STRING([Target architecture], $target_arch)
	346
	347	# python bindings enabled/disabled
	348	test "x$enable_python" = "xyes" && value=1 \|\| value=0
	349	PPRINT_PROP_BOOL([Python bindings], $value)
	350
	351	# python bindings doc enabled/disabled
	352	test "x$enable_python_bindings_doc" = "xyes" && value=1 \|\| value=0
	353	PPRINT_PROP_BOOL([Python bindings doc], $value)
	354
	355	# debug-info enabled/disabled
	356	test "x$enable_debuginfo" = "xyes" && value=1 \|\| value=0
	357	PPRINT_PROP_BOOL([Debug information output], $value)
	358
	359
	360	report_bindir="`eval eval echo $bindir`"
	361	report_libdir="`eval eval echo $libdir`"
	362
	363	# Print the bindir and libdir this `make install' will install into.
	364	AS_ECHO
	365	PPRINT_SUBTITLE([Install directories])
	366	PPRINT_PROP_STRING([Binaries], [$report_bindir])
	367	PPRINT_PROP_STRING([Libraries], [$report_libdir])