| 1 | # -*- Autoconf -*- |
| 2 | # Process this file with autoconf to produce a configure script. |
| 3 | |
| 4 | AC_PREREQ([2.50]) |
| 5 | AC_INIT([babeltrace],[1.3.0-pre],[jeremie dot galarneau at efficios dot com]) |
| 6 | |
| 7 | # Following the numbering scheme proposed by libtool for the library version |
| 8 | # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html |
| 9 | AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0]) |
| 10 | |
| 11 | AC_CONFIG_AUX_DIR([config]) |
| 12 | AC_CANONICAL_TARGET |
| 13 | AC_CANONICAL_HOST |
| 14 | AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip]) |
| 15 | AM_MAINTAINER_MODE([enable]) |
| 16 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| 17 | |
| 18 | AC_CONFIG_MACRO_DIR([m4]) |
| 19 | |
| 20 | AC_PROG_MKDIR_P |
| 21 | AC_PROG_LN_S |
| 22 | |
| 23 | AC_CONFIG_HEADERS([config.h]) |
| 24 | |
| 25 | AC_CHECK_HEADERS([fcntl.h limits.h netdb.h netinet/in.h stddef.h sys/socket.h]) |
| 26 | |
| 27 | AC_SYS_LARGEFILE |
| 28 | |
| 29 | # Checks for programs. |
| 30 | AC_PROG_CC_STDC |
| 31 | AC_PROG_MAKE_SET |
| 32 | LT_INIT |
| 33 | AC_PROG_YACC |
| 34 | AC_PROG_LEX |
| 35 | |
| 36 | # Check linker option |
| 37 | AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED]) |
| 38 | AC_SUBST([LD_NO_AS_NEEDED]) |
| 39 | |
| 40 | if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then |
| 41 | if test x"$YACC" != "xbison -y"; then |
| 42 | AC_MSG_ERROR([[bison not found and is required when building from git. |
| 43 | Please install bison]]) |
| 44 | fi |
| 45 | AC_PATH_PROG([BISON],[bison]) |
| 46 | AX_PROG_BISON_VERSION([2.4], [],[ |
| 47 | AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]]) |
| 48 | ]) |
| 49 | fi |
| 50 | |
| 51 | if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then |
| 52 | if test x"$LEX" != "xflex"; then |
| 53 | AC_MSG_ERROR([[flex not found and is required when building from git. |
| 54 | Please install flex]]) |
| 55 | fi |
| 56 | AC_PATH_PROG([FLEX],[flex]) |
| 57 | AX_PROG_FLEX_VERSION([2.5.35], [],[ |
| 58 | AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]]) |
| 59 | ]) |
| 60 | fi |
| 61 | |
| 62 | |
| 63 | AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule) |
| 64 | |
| 65 | # Checks for typedefs, structures, and compiler characteristics. |
| 66 | AC_C_INLINE |
| 67 | AC_TYPE_PID_T |
| 68 | AC_TYPE_SIZE_T |
| 69 | AC_TYPE_INT16_T |
| 70 | AC_TYPE_INT32_T |
| 71 | AC_TYPE_INT64_T |
| 72 | AC_TYPE_INT8_T |
| 73 | AC_TYPE_OFF_T |
| 74 | AC_TYPE_SSIZE_T |
| 75 | AC_TYPE_UINT16_T |
| 76 | AC_TYPE_UINT32_T |
| 77 | AC_TYPE_UINT64_T |
| 78 | AC_TYPE_UINT8_T |
| 79 | |
| 80 | # Checks for library functions. |
| 81 | AC_FUNC_MALLOC |
| 82 | AC_FUNC_MMAP |
| 83 | AC_CHECK_FUNCS([ \ |
| 84 | gettimeofday munmap strtoul ftruncate gethostbyname \ |
| 85 | localtime_r memset mkdir rmdir setenv socket \ |
| 86 | strchr strdup strerror strndup strrchr strtoull tzset \ |
| 87 | ]) |
| 88 | |
| 89 | # Check for MinGW32. |
| 90 | MINGW32=no |
| 91 | case $host in |
| 92 | *-*-mingw*) |
| 93 | MINGW32=yes;; |
| 94 | esac |
| 95 | |
| 96 | AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"]) |
| 97 | |
| 98 | # Check what libraries are required on this platform to link sockets programs. |
| 99 | AX_LIB_SOCKET_NSL |
| 100 | |
| 101 | # Check for libuuid |
| 102 | AC_CHECK_LIB([uuid], [uuid_generate], |
| 103 | [ |
| 104 | AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.]) |
| 105 | have_libuuid=yes |
| 106 | ], |
| 107 | [ |
| 108 | # libuuid not found, check for uuid_create in libc. |
| 109 | AC_CHECK_LIB([c], [uuid_create], |
| 110 | [ |
| 111 | AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.]) |
| 112 | have_libc_uuid=yes |
| 113 | ], |
| 114 | [ |
| 115 | # for MinGW32 we have our own internal implemenation of uuid using Windows functions. |
| 116 | if test "x$MINGW32" = xno; then |
| 117 | AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.]) |
| 118 | fi |
| 119 | ]) |
| 120 | ] |
| 121 | ) |
| 122 | AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"]) |
| 123 | AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"]) |
| 124 | |
| 125 | # Check for fmemopen |
| 126 | AC_CHECK_LIB([c], [fmemopen], |
| 127 | [ |
| 128 | AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| 129 | ] |
| 130 | ) |
| 131 | |
| 132 | # Check for open_memstream |
| 133 | AC_CHECK_LIB([c], [open_memstream], |
| 134 | [ |
| 135 | AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.]) |
| 136 | ] |
| 137 | ) |
| 138 | |
| 139 | AC_CHECK_LIB([popt], [poptGetContext], [], |
| 140 | [AC_MSG_ERROR([Cannot find popt.])] |
| 141 | ) |
| 142 | |
| 143 | |
| 144 | # For Python |
| 145 | # SWIG version needed or newer: |
| 146 | swig_version=2.0.0 |
| 147 | |
| 148 | AC_ARG_ENABLE([python-bindings], |
| 149 | [AC_HELP_STRING([--enable-python-bindings], |
| 150 | [generate Python bindings])], |
| 151 | [enable_python=yes], [enable_python=no]) |
| 152 | |
| 153 | AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes]) |
| 154 | |
| 155 | AC_ARG_ENABLE([python-bindings-doc], |
| 156 | [AC_HELP_STRING([--enable-python-bindings-doc], |
| 157 | [generate Python bindings documentation])], |
| 158 | [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no]) |
| 159 | |
| 160 | if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then |
| 161 | AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings]) |
| 162 | fi |
| 163 | |
| 164 | AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes]) |
| 165 | |
| 166 | if test "x${enable_python:-yes}" = xyes; then |
| 167 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| 168 | AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)]) |
| 169 | |
| 170 | AM_PATH_PYTHON_MODULES([PYTHON]) |
| 171 | # pythondir is the path where extra modules are to be installed |
| 172 | pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH |
| 173 | # pyexecdir is the path that contains shared objects used by the extra modules |
| 174 | pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH |
| 175 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| 176 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| 177 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| 178 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| 179 | AC_PATH_PROGS([PYTHON_CONFIG], |
| 180 | [python$PYTHON_VERSION-config python-config], |
| 181 | [no], |
| 182 | [`dirname $PYTHON`]) |
| 183 | AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| 184 | ]) |
| 185 | AC_MSG_CHECKING([python include flags]) |
| 186 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| 187 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| 188 | ]) |
| 189 | else |
| 190 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| 191 | [if you want Python bindings.]) |
| 192 | |
| 193 | fi |
| 194 | |
| 195 | if test "x${enable_python_bindings_doc:-yes}" = xyes; then |
| 196 | AM_CHECK_PYTHON_SPHINX([PYTHON]) |
| 197 | AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno], |
| 198 | AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation]) |
| 199 | ) |
| 200 | fi |
| 201 | |
| 202 | pkg_modules="gmodule-2.0 >= 2.0.0" |
| 203 | PKG_CHECK_MODULES(GMODULE, [$pkg_modules]) |
| 204 | AC_SUBST(PACKAGE_LIBS) |
| 205 | |
| 206 | LIBS="$LIBS $GMODULE_LIBS" |
| 207 | PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h" |
| 208 | AC_SUBST(PACKAGE_CFLAGS) |
| 209 | |
| 210 | babeltraceincludedir="${includedir}/babeltrace" |
| 211 | AC_SUBST(babeltraceincludedir) |
| 212 | |
| 213 | babeltracectfincludedir="${includedir}/babeltrace/ctf" |
| 214 | AC_SUBST(babeltracectfincludedir) |
| 215 | |
| 216 | babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer" |
| 217 | AC_SUBST(babeltracectfwriterincludedir) |
| 218 | |
| 219 | babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir" |
| 220 | AC_SUBST(babeltracectfirincludedir) |
| 221 | |
| 222 | AC_CONFIG_FILES([ |
| 223 | Makefile |
| 224 | types/Makefile |
| 225 | compat/Makefile |
| 226 | formats/Makefile |
| 227 | formats/ctf/Makefile |
| 228 | formats/ctf/types/Makefile |
| 229 | formats/ctf-text/Makefile |
| 230 | formats/ctf-text/types/Makefile |
| 231 | formats/ctf-metadata/Makefile |
| 232 | formats/bt-dummy/Makefile |
| 233 | formats/lttng-live/Makefile |
| 234 | formats/ctf/metadata/Makefile |
| 235 | formats/ctf/writer/Makefile |
| 236 | formats/ctf/ir/Makefile |
| 237 | converter/Makefile |
| 238 | doc/Makefile |
| 239 | doc/bindings/Makefile |
| 240 | doc/bindings/python/Makefile |
| 241 | lib/Makefile |
| 242 | lib/prio_heap/Makefile |
| 243 | include/Makefile |
| 244 | bindings/Makefile |
| 245 | bindings/python/Makefile |
| 246 | tests/Makefile |
| 247 | tests/bin/Makefile |
| 248 | tests/lib/Makefile |
| 249 | tests/utils/Makefile |
| 250 | tests/utils/tap/Makefile |
| 251 | extras/Makefile |
| 252 | extras/valgrind/Makefile |
| 253 | babeltrace.pc |
| 254 | babeltrace-ctf.pc |
| 255 | ]) |
| 256 | AC_OUTPUT |