Fix: cast of 64 bit addresses from trace to 32-bit pointer
[babeltrace.git] / configure.ac
1 AC_PREREQ([2.50])
2 AC_INIT([babeltrace],[1.3.2],[jeremie.galarneau@efficios.com],[],[https://diamon.org/babeltrace])
3 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
4
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([config])
7 AC_CONFIG_MACRO_DIR([m4])
8
9 AC_CANONICAL_TARGET
10 AC_CANONICAL_HOST
11
12 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
13 AM_MAINTAINER_MODE([enable])
14
15 # Enable silent rules if available (Introduced in AM 1.11)
16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17
18 # Checks for C compiler
19 AC_USE_SYSTEM_EXTENSIONS
20 AC_SYS_LARGEFILE
21 AC_PROG_CC
22 AC_PROG_CC_STDC
23
24 # Checks for programs.
25 AC_PROG_MAKE_SET
26 LT_INIT
27 AC_PROG_YACC
28 AC_PROG_LEX
29 AC_PROG_MKDIR_P
30 AC_PROG_LN_S
31
32 AX_C___ATTRIBUTE__
33 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
34 [:],
35 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
36
37 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
38 LIBS="$PTHREAD_LIBS $LIBS"
39 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
40 CC="$PTHREAD_CC"
41
42 # Check linker option
43 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
44 AC_SUBST([LD_NO_AS_NEEDED])
45
46 AC_HEADER_STDBOOL
47 AC_CHECK_HEADERS([ \
48 fcntl.h \
49 float.h \
50 libintl.h \
51 limits.h \
52 malloc.h \
53 netdb.h \
54 netinet/in.h \
55 stddef.h \
56 sys/socket.h \
57 ])
58
59 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
60 if test x"$(basename "$YACC")" != "xbison -y"; then
61 AC_MSG_ERROR([[bison not found and is required when building from git.
62 Please install bison]])
63 fi
64 AC_PATH_PROG([BISON],[bison])
65 AX_PROG_BISON_VERSION([2.4], [],[
66 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
67 ])
68 fi
69
70 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
71 if test x"$LEX" != "xflex"; then
72 AC_MSG_ERROR([[flex not found and is required when building from git.
73 Please install flex]])
74 fi
75 AC_PATH_PROG([FLEX],[flex])
76 AX_PROG_FLEX_VERSION([2.5.35], [],[
77 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
78 ])
79 fi
80
81 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
82
83 # Check what libraries are required on this platform to link sockets programs.
84 AX_LIB_SOCKET_NSL
85
86 # Checks for typedefs, structures, and compiler characteristics.
87 AC_C_INLINE
88 AC_TYPE_PID_T
89 AC_TYPE_SIZE_T
90
91 # Checks for library functions.
92 AC_FUNC_ALLOCA
93 AC_FUNC_FORK
94 AC_FUNC_MALLOC
95 AC_FUNC_MKTIME
96 AC_FUNC_MMAP
97 AC_FUNC_REALLOC
98 AC_FUNC_STRERROR_R
99 AC_CHECK_FUNCS([ \
100 atexit \
101 dirfd \
102 dup2 \
103 ftruncate \
104 gethostbyname \
105 gethostname \
106 gettimeofday \
107 localtime_r \
108 memchr \
109 memset \
110 mkdir \
111 mkdtemp \
112 munmap \
113 rmdir \
114 setenv \
115 socket \
116 strchr \
117 strdup \
118 strerror \
119 strndup \
120 strnlen \
121 strrchr \
122 strtoul \
123 strtoull \
124 tzset \
125 uname \
126 ])
127
128 # Check for MinGW32.
129 MINGW32=no
130 case $host in
131 *-*-mingw*)
132 MINGW32=yes;;
133 esac
134
135 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
136
137 # Check for libuuid
138 AC_CHECK_LIB([uuid], [uuid_generate],
139 [
140 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
141 have_libuuid=yes
142 ],
143 [
144 # libuuid not found, check for uuid_create in libc.
145 AC_CHECK_LIB([c], [uuid_create],
146 [
147 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
148 have_libc_uuid=yes
149 ],
150 [
151 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
152 if test "x$MINGW32" = xno; then
153 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
154 fi
155 ])
156 ]
157 )
158 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
159 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
160
161 # Check for fmemopen
162 AC_CHECK_LIB([c], [fmemopen],
163 [
164 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
165 ]
166 )
167
168 # Check for open_memstream
169 AC_CHECK_LIB([c], [open_memstream],
170 [
171 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
172 ]
173 )
174
175 # Check for posix_fallocate
176 AC_CHECK_LIB([c], [posix_fallocate],
177 [
178 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
179 ]
180 )
181
182 # Check for faccessat
183 AC_CHECK_LIB([c], [faccessat],
184 [
185 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
186 ]
187 )
188
189 AC_CHECK_LIB([popt], [poptGetContext], [],
190 [AC_MSG_ERROR([Cannot find popt.])]
191 )
192
193 # For Python
194 # SWIG version needed or newer:
195 swig_version=2.0.0
196
197 AC_ARG_ENABLE([python-bindings],
198 [AC_HELP_STRING([--enable-python-bindings],
199 [generate Python bindings])],
200 [enable_python=yes], [enable_python=no])
201
202 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
203
204 if test "x${enable_python:-yes}" = xyes; then
205 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
206 AM_PATH_PYTHON
207
208 AM_PATH_PYTHON_MODULES([PYTHON])
209 # pythondir is the path where extra modules are to be installed
210 pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
211 # pyexecdir is the path that contains shared objects used by the extra modules
212 pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
213 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
214 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
215 AS_IF([test -z "$PYTHON_INCLUDE"], [
216 AS_IF([test -z "$PYTHON_CONFIG"], [
217 AC_PATH_PROGS([PYTHON_CONFIG],
218 [python$PYTHON_VERSION-config python-config],
219 [no],
220 [`dirname $PYTHON`])
221 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
222 ])
223 AC_MSG_CHECKING([python include flags])
224 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
225 AC_MSG_RESULT([$PYTHON_INCLUDE])
226 ])
227
228 else
229 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
230 [if you want Python bindings.])
231
232 fi
233
234 # Optional debuginfo feature (enabled by default)
235 AC_ARG_ENABLE([debuginfo], [AC_HELP_STRING([--disable-debuginfo], [disable the debuginfo feature])], [], [enable_debuginfo=yes])
236
237 AM_CONDITIONAL([ENABLE_DEBUGINFO], [test "x$enable_debuginfo" = xyes])
238 AS_IF([test "x$enable_debuginfo" = xyes], [
239 AC_CHECK_LIB([elf], [elf_version], [], [])
240 AC_CHECK_LIB([dw], [dwarf_begin], [], [])
241 AS_IF([test "x$ac_cv_lib_elf_elf_version" = xno || test "x$ac_cv_lib_dw_dwarf_begin" = xno],
242 [AC_MSG_ERROR(Missing library from elfutils required for debuginfo. You can disable this feature with --disable-debuginfo.)]
243 )
244 AC_DEFINE([ENABLE_DEBUGINFO], [1], [Define to 1 if you enable the 'debuginfo' feature])
245 ], [])
246
247 pkg_modules="gmodule-2.0 >= 2.0.0"
248 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
249 AC_SUBST(PACKAGE_LIBS)
250
251 LIBS="$LIBS $GMODULE_LIBS"
252 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
253 AC_SUBST(PACKAGE_CFLAGS)
254
255 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
256 AC_SUBST(DEFAULT_INCLUDES)
257
258 babeltraceincludedir="${includedir}/babeltrace"
259 AC_SUBST(babeltraceincludedir)
260
261 babeltracectfincludedir="${includedir}/babeltrace/ctf"
262 AC_SUBST(babeltracectfincludedir)
263
264 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
265 AC_SUBST(babeltracectfwriterincludedir)
266
267 AC_CONFIG_FILES([
268 Makefile
269 types/Makefile
270 compat/Makefile
271 formats/Makefile
272 formats/ctf/Makefile
273 formats/ctf/types/Makefile
274 formats/ctf-text/Makefile
275 formats/ctf-text/types/Makefile
276 formats/ctf-metadata/Makefile
277 formats/bt-dummy/Makefile
278 formats/lttng-live/Makefile
279 formats/ctf/metadata/Makefile
280 formats/ctf/writer/Makefile
281 converter/Makefile
282 doc/Makefile
283 lib/Makefile
284 lib/prio_heap/Makefile
285 include/Makefile
286 bindings/Makefile
287 bindings/python/Makefile
288 tests/Makefile
289 tests/bin/Makefile
290 tests/lib/Makefile
291 tests/utils/Makefile
292 tests/utils/tap/Makefile
293 extras/Makefile
294 extras/valgrind/Makefile
295 babeltrace.pc
296 babeltrace-ctf.pc
297 ])
298 AC_OUTPUT
This page took 0.034616 seconds and 4 git commands to generate.