configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([babeltrace],[1.2.0-rc1],[mathieu dot desnoyers at efficios dot com])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CANONICAL_TARGET
   7 AC_CANONICAL_HOST
   8 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_PROG_MKDIR_P
  14
  15 AC_CONFIG_HEADERS([config.h])
  16
  17 AC_SYS_LARGEFILE
  18
  19 # Checks for programs.
  20 AC_PROG_CC_STDC
  21 AC_PROG_MAKE_SET
  22 LT_INIT
  23 AC_PROG_YACC
  24 AC_PROG_LEX
  25
  26 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  27         if test x"$YACC" != "xbison -y"; then
  28                 AC_MSG_ERROR([[bison not found and is required when building from git.
  29                 Please install bison]])
  30         fi
  31 fi
  32
  33 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  34         if test x"$LEX" != "xflex"; then
  35                 AC_MSG_ERROR([[flex not found and is required when building from git.
  36                 Please install flex]])
  37         fi
  38 fi
  39
  40
  41 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_PID_T
  46 AC_TYPE_SIZE_T
  47
  48 # Checks for library functions.
  49 AC_FUNC_MALLOC
  50 AC_FUNC_MMAP
  51 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  52
  53 # Check for MinGW32.
  54 MINGW32=no
  55 case $host in
  56   *-*-mingw*)
  57         MINGW32=yes;;
  58 esac
  59
  60 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  61
  62 # Check for libuuid
  63 AC_CHECK_LIB([uuid], [uuid_generate],
  64 [
  65         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  66         have_libuuid=yes
  67 ],
  68 [
  69         # libuuid not found, check for uuid_create in libc.
  70         AC_CHECK_LIB([c], [uuid_create],
  71         [
  72                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  73                 have_libc_uuid=yes
  74         ],
  75         [
  76                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  77                 if test "x$MINGW32" = xno; then
  78                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  79                 fi
  80         ])
  81 ]
  82 )
  83 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  84 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  85
  86 # Check for fmemopen
  87 AC_CHECK_LIB([c], [fmemopen],
  88 [
  89         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
  90 ]
  91 )
  92
  93 # Check for open_memstream
  94 AC_CHECK_LIB([c], [open_memstream],
  95 [
  96         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
  97 ]
  98 )
  99
 100 AC_CHECK_LIB([popt], [poptGetContext], [],
 101         [AC_MSG_ERROR([Cannot find popt.])]
 102 )
 103
 104
 105 # For Python
 106 # SWIG version needed or newer:
 107 swig_version=2.0.0
 108
 109 AC_ARG_ENABLE([python-bindings],
 110               [AC_HELP_STRING([--enable-python-bindings],
 111                               [generate Python bindings])],
 112               [enable_python=yes], [enable_python=no])
 113
 114 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 115
 116 if test "x${enable_python:-yes}" = xyes; then
 117   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 118   AM_PATH_PYTHON
 119
 120   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 121   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 122   AS_IF([test -z "$PYTHON_INCLUDE"], [
 123     AS_IF([test -z "$PYTHON_CONFIG"], [
 124       AC_PATH_PROGS([PYTHON_CONFIG],
 125                     [python$PYTHON_VERSION-config python-config],
 126                     [no],
 127                     [`dirname $PYTHON`])
 128       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 129     ])
 130     AC_MSG_CHECKING([python include flags])
 131     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 132     AC_MSG_RESULT([$PYTHON_INCLUDE])
 133   ])
 134
 135 else
 136     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 137 [if you want Python bindings.])
 138
 139 fi
 140
 141 pkg_modules="gmodule-2.0 >= 2.0.0"
 142 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 143 AC_SUBST(PACKAGE_LIBS)
 144
 145 LIBS="$LIBS $GMODULE_LIBS"
 146 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 147 AC_SUBST(PACKAGE_CFLAGS)
 148
 149 babeltraceincludedir="${includedir}/babeltrace"
 150 AC_SUBST(babeltraceincludedir)
 151
 152 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 153 AC_SUBST(babeltracectfincludedir)
 154
 155 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 156 AC_SUBST(babeltracectfwriterincludedir)
 157
 158 AC_CONFIG_FILES([
 159         Makefile
 160         types/Makefile
 161         compat/Makefile
 162         formats/Makefile
 163         formats/ctf/Makefile
 164         formats/ctf/types/Makefile
 165         formats/ctf-text/Makefile
 166         formats/ctf-text/types/Makefile
 167         formats/ctf-metadata/Makefile
 168         formats/bt-dummy/Makefile
 169         formats/lttng-live/Makefile
 170         formats/ctf/metadata/Makefile
 171         formats/ctf/writer/Makefile
 172         converter/Makefile
 173         doc/Makefile
 174         lib/Makefile
 175         lib/prio_heap/Makefile
 176         include/Makefile
 177         bindings/Makefile
 178         bindings/python/Makefile
 179         tests/Makefile
 180         tests/bin/Makefile
 181         tests/lib/Makefile
 182         tests/utils/Makefile
 183         tests/utils/tap/Makefile
 184         extras/Makefile
 185         extras/valgrind/Makefile
 186         babeltrace.pc
 187         babeltrace-ctf.pc
 188 ])
 189 AC_OUTPUT