349f8a16276215596e34bece1206d2dffdc3cb6f
[babeltrace.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4 AC_PREREQ([2.50])
5 AC_INIT([babeltrace],[1.2.4],[mathieu dot desnoyers at efficios dot com])
6
7 # Following the numbering scheme proposed by libtool for the library version
8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
10
11 AC_CONFIG_AUX_DIR([config])
12 AC_CANONICAL_TARGET
13 AC_CANONICAL_HOST
14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_CONFIG_MACRO_DIR([m4])
18
19 AC_PROG_MKDIR_P
20
21 AC_CONFIG_HEADERS([config.h])
22
23 AC_SYS_LARGEFILE
24
25 # Checks for programs.
26 AC_PROG_CC_STDC
27 AC_PROG_MAKE_SET
28 LT_INIT
29 AC_PROG_YACC
30 AC_PROG_LEX
31
32 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
33 if test x"$YACC" != "xbison -y"; then
34 AC_MSG_ERROR([[bison not found and is required when building from git.
35 Please install bison]])
36 fi
37 AC_PATH_PROG([BISON],[bison])
38 AX_PROG_BISON_VERSION([2.4], [],[
39 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
40 ])
41 fi
42
43 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
44 if test x"$LEX" != "xflex"; then
45 AC_MSG_ERROR([[flex not found and is required when building from git.
46 Please install flex]])
47 fi
48 fi
49
50
51 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
52
53 # Checks for typedefs, structures, and compiler characteristics.
54 AC_C_INLINE
55 AC_TYPE_PID_T
56 AC_TYPE_SIZE_T
57
58 # Checks for library functions.
59 AC_FUNC_MALLOC
60 AC_FUNC_MMAP
61 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
62
63 # Check for MinGW32.
64 MINGW32=no
65 case $host in
66 *-*-mingw*)
67 MINGW32=yes;;
68 esac
69
70 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
71
72 # Check for libuuid
73 AC_CHECK_LIB([uuid], [uuid_generate],
74 [
75 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
76 have_libuuid=yes
77 ],
78 [
79 # libuuid not found, check for uuid_create in libc.
80 AC_CHECK_LIB([c], [uuid_create],
81 [
82 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
83 have_libc_uuid=yes
84 ],
85 [
86 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
87 if test "x$MINGW32" = xno; then
88 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
89 fi
90 ])
91 ]
92 )
93 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
94 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
95
96 # Check for fmemopen
97 AC_CHECK_LIB([c], [fmemopen],
98 [
99 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
100 ]
101 )
102
103 # Check for open_memstream
104 AC_CHECK_LIB([c], [open_memstream],
105 [
106 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
107 ]
108 )
109
110 AC_CHECK_LIB([popt], [poptGetContext], [],
111 [AC_MSG_ERROR([Cannot find popt.])]
112 )
113
114
115 # For Python
116 # SWIG version needed or newer:
117 swig_version=2.0.0
118
119 AC_ARG_ENABLE([python-bindings],
120 [AC_HELP_STRING([--enable-python-bindings],
121 [generate Python bindings])],
122 [enable_python=yes], [enable_python=no])
123
124 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
125
126 if test "x${enable_python:-yes}" = xyes; then
127 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
128 AM_PATH_PYTHON
129
130 AM_PATH_PYTHON_MODULES([PYTHON])
131 # pythondir is the path where extra modules are to be installed
132 pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
133 # pyexecdir is the path that contains shared objects used by the extra modules
134 pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
135 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
136 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
137 AS_IF([test -z "$PYTHON_INCLUDE"], [
138 AS_IF([test -z "$PYTHON_CONFIG"], [
139 AC_PATH_PROGS([PYTHON_CONFIG],
140 [python$PYTHON_VERSION-config python-config],
141 [no],
142 [`dirname $PYTHON`])
143 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
144 ])
145 AC_MSG_CHECKING([python include flags])
146 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
147 AC_MSG_RESULT([$PYTHON_INCLUDE])
148 ])
149
150 else
151 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
152 [if you want Python bindings.])
153
154 fi
155
156 pkg_modules="gmodule-2.0 >= 2.0.0"
157 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
158 AC_SUBST(PACKAGE_LIBS)
159
160 LIBS="$LIBS $GMODULE_LIBS"
161 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
162 AC_SUBST(PACKAGE_CFLAGS)
163
164 babeltraceincludedir="${includedir}/babeltrace"
165 AC_SUBST(babeltraceincludedir)
166
167 babeltracectfincludedir="${includedir}/babeltrace/ctf"
168 AC_SUBST(babeltracectfincludedir)
169
170 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
171 AC_SUBST(babeltracectfwriterincludedir)
172
173 AC_CONFIG_FILES([
174 Makefile
175 types/Makefile
176 compat/Makefile
177 formats/Makefile
178 formats/ctf/Makefile
179 formats/ctf/types/Makefile
180 formats/ctf-text/Makefile
181 formats/ctf-text/types/Makefile
182 formats/ctf-metadata/Makefile
183 formats/bt-dummy/Makefile
184 formats/lttng-live/Makefile
185 formats/ctf/metadata/Makefile
186 formats/ctf/writer/Makefile
187 converter/Makefile
188 doc/Makefile
189 lib/Makefile
190 lib/prio_heap/Makefile
191 include/Makefile
192 bindings/Makefile
193 bindings/python/Makefile
194 tests/Makefile
195 tests/bin/Makefile
196 tests/lib/Makefile
197 tests/utils/Makefile
198 tests/utils/tap/Makefile
199 extras/Makefile
200 extras/valgrind/Makefile
201 babeltrace.pc
202 babeltrace-ctf.pc
203 ])
204 AC_OUTPUT
This page took 0.032265 seconds and 3 git commands to generate.