configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.2.4],[mathieu dot desnoyers at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 # Checks for C compiler
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_PROG_CC
  25 AC_PROG_CC_STDC
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34
  35 # Check linker option
  36 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  37 AC_SUBST([LD_NO_AS_NEEDED])
  38
  39 AC_CHECK_HEADERS([fcntl.h limits.h netdb.h netinet/in.h stddef.h sys/socket.h])
  40
  41 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  42         if test x"$YACC" != "xbison -y"; then
  43                 AC_MSG_ERROR([[bison not found and is required when building from git.
  44                 Please install bison]])
  45         fi
  46         AC_PATH_PROG([BISON],[bison])
  47         AX_PROG_BISON_VERSION([2.4], [],[
  48                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  49         ])
  50 fi
  51
  52 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  53         if test x"$LEX" != "xflex"; then
  54                 AC_MSG_ERROR([[flex not found and is required when building from git.
  55                 Please install flex]])
  56         fi
  57         AC_PATH_PROG([FLEX],[flex])
  58         AX_PROG_FLEX_VERSION([2.5.35], [],[
  59                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  60         ])
  61 fi
  62
  63
  64 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_C_INLINE
  68 AC_TYPE_PID_T
  69 AC_TYPE_SIZE_T
  70
  71 # Checks for library functions.
  72 AC_FUNC_MALLOC
  73 AC_FUNC_MMAP
  74 AC_CHECK_FUNCS([gettimeofday munmap strtoul])
  75
  76 # Check for MinGW32.
  77 MINGW32=no
  78 case $host in
  79   *-*-mingw*)
  80         MINGW32=yes;;
  81 esac
  82
  83 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  84
  85 # Check what libraries are required on this platform to link sockets programs.
  86 AX_LIB_SOCKET_NSL
  87
  88 # Check for libuuid
  89 AC_CHECK_LIB([uuid], [uuid_generate],
  90 [
  91         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  92         have_libuuid=yes
  93 ],
  94 [
  95         # libuuid not found, check for uuid_create in libc.
  96         AC_CHECK_LIB([c], [uuid_create],
  97         [
  98                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  99                 have_libc_uuid=yes
 100         ],
 101         [
 102                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 103                 if test "x$MINGW32" = xno; then
 104                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 105                 fi
 106         ])
 107 ]
 108 )
 109 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 110 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 111
 112 # Check for fmemopen
 113 AC_CHECK_LIB([c], [fmemopen],
 114 [
 115         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 116 ]
 117 )
 118
 119 # Check for open_memstream
 120 AC_CHECK_LIB([c], [open_memstream],
 121 [
 122         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 123 ]
 124 )
 125
 126 AC_CHECK_LIB([popt], [poptGetContext], [],
 127         [AC_MSG_ERROR([Cannot find popt.])]
 128 )
 129
 130
 131 # For Python
 132 # SWIG version needed or newer:
 133 swig_version=2.0.0
 134
 135 AC_ARG_ENABLE([python-bindings],
 136               [AC_HELP_STRING([--enable-python-bindings],
 137                               [generate Python bindings])],
 138               [enable_python=yes], [enable_python=no])
 139
 140 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 141
 142 if test "x${enable_python:-yes}" = xyes; then
 143   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 144   AM_PATH_PYTHON
 145
 146   AM_PATH_PYTHON_MODULES([PYTHON])
 147   # pythondir is the path where extra modules are to be installed
 148   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 149   # pyexecdir is the path that contains shared objects used by the extra modules
 150   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 151   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 152   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 153   AS_IF([test -z "$PYTHON_INCLUDE"], [
 154     AS_IF([test -z "$PYTHON_CONFIG"], [
 155       AC_PATH_PROGS([PYTHON_CONFIG],
 156                     [python$PYTHON_VERSION-config python-config],
 157                     [no],
 158                     [`dirname $PYTHON`])
 159       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 160     ])
 161     AC_MSG_CHECKING([python include flags])
 162     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 163     AC_MSG_RESULT([$PYTHON_INCLUDE])
 164   ])
 165
 166 else
 167     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 168 [if you want Python bindings.])
 169
 170 fi
 171
 172 pkg_modules="gmodule-2.0 >= 2.0.0"
 173 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 174 AC_SUBST(PACKAGE_LIBS)
 175
 176 LIBS="$LIBS $GMODULE_LIBS"
 177 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 178 AC_SUBST(PACKAGE_CFLAGS)
 179
 180 babeltraceincludedir="${includedir}/babeltrace"
 181 AC_SUBST(babeltraceincludedir)
 182
 183 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 184 AC_SUBST(babeltracectfincludedir)
 185
 186 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 187 AC_SUBST(babeltracectfwriterincludedir)
 188
 189 AC_CONFIG_FILES([
 190         Makefile
 191         types/Makefile
 192         compat/Makefile
 193         formats/Makefile
 194         formats/ctf/Makefile
 195         formats/ctf/types/Makefile
 196         formats/ctf-text/Makefile
 197         formats/ctf-text/types/Makefile
 198         formats/ctf-metadata/Makefile
 199         formats/bt-dummy/Makefile
 200         formats/lttng-live/Makefile
 201         formats/ctf/metadata/Makefile
 202         formats/ctf/writer/Makefile
 203         converter/Makefile
 204         doc/Makefile
 205         lib/Makefile
 206         lib/prio_heap/Makefile
 207         include/Makefile
 208         bindings/Makefile
 209         bindings/python/Makefile
 210         tests/Makefile
 211         tests/bin/Makefile
 212         tests/lib/Makefile
 213         tests/utils/Makefile
 214         tests/utils/tap/Makefile
 215         extras/Makefile
 216         extras/valgrind/Makefile
 217         babeltrace.pc
 218         babeltrace-ctf.pc
 219 ])
 220 AC_OUTPUT