configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.50])
   5 AC_INIT([babeltrace],[1.3.0-pre],[jeremie dot galarneau at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  15 AM_MAINTAINER_MODE([enable])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 AC_PROG_MKDIR_P
  21 AC_PROG_LN_S
  22
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AC_SYS_LARGEFILE
  26
  27 # Checks for programs.
  28 AC_PROG_CC_STDC
  29 AC_PROG_MAKE_SET
  30 LT_INIT
  31 AC_PROG_YACC
  32 AC_PROG_LEX
  33
  34 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  35         if test x"$YACC" != "xbison -y"; then
  36                 AC_MSG_ERROR([[bison not found and is required when building from git.
  37                 Please install bison]])
  38         fi
  39         AC_PATH_PROG([BISON],[bison])
  40         AX_PROG_BISON_VERSION([2.4], [],[
  41                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  42         ])
  43 fi
  44
  45 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  46         if test x"$LEX" != "xflex"; then
  47                 AC_MSG_ERROR([[flex not found and is required when building from git.
  48                 Please install flex]])
  49         fi
  50 fi
  51
  52
  53 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  54
  55 # Checks for typedefs, structures, and compiler characteristics.
  56 AC_C_INLINE
  57 AC_TYPE_PID_T
  58 AC_TYPE_SIZE_T
  59
  60 # Checks for library functions.
  61 AC_FUNC_MALLOC
  62 AC_FUNC_MMAP
  63 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  64
  65 # Check for MinGW32.
  66 MINGW32=no
  67 case $host in
  68   *-*-mingw*)
  69         MINGW32=yes;;
  70 esac
  71
  72 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  73
  74 # Check for libuuid
  75 AC_CHECK_LIB([uuid], [uuid_generate],
  76 [
  77         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  78         have_libuuid=yes
  79 ],
  80 [
  81         # libuuid not found, check for uuid_create in libc.
  82         AC_CHECK_LIB([c], [uuid_create],
  83         [
  84                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  85                 have_libc_uuid=yes
  86         ],
  87         [
  88                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  89                 if test "x$MINGW32" = xno; then
  90                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  91                 fi
  92         ])
  93 ]
  94 )
  95 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  96 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  97
  98 # Check for fmemopen
  99 AC_CHECK_LIB([c], [fmemopen],
 100 [
 101         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 102 ]
 103 )
 104
 105 # Check for open_memstream
 106 AC_CHECK_LIB([c], [open_memstream],
 107 [
 108         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 109 ]
 110 )
 111
 112 AC_CHECK_LIB([popt], [poptGetContext], [],
 113         [AC_MSG_ERROR([Cannot find popt.])]
 114 )
 115
 116
 117 # For Python
 118 # SWIG version needed or newer:
 119 swig_version=2.0.0
 120
 121 AC_ARG_ENABLE([python-bindings],
 122               [AC_HELP_STRING([--enable-python-bindings],
 123                               [generate Python bindings])],
 124               [enable_python=yes], [enable_python=no])
 125
 126 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 127
 128 AC_ARG_ENABLE([python-bindings-doc],
 129               [AC_HELP_STRING([--enable-python-bindings-doc],
 130                               [generate Python bindings documentation])],
 131               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 132
 133 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 134   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 135 fi
 136
 137 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 138
 139 if test "x${enable_python:-yes}" = xyes; then
 140   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 141   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 142
 143   AM_PATH_PYTHON_MODULES([PYTHON])
 144   # pythondir is the path where extra modules are to be installed
 145   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 146   # pyexecdir is the path that contains shared objects used by the extra modules
 147   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 148   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 149   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 150   AS_IF([test -z "$PYTHON_INCLUDE"], [
 151     AS_IF([test -z "$PYTHON_CONFIG"], [
 152       AC_PATH_PROGS([PYTHON_CONFIG],
 153                     [python$PYTHON_VERSION-config python-config],
 154                     [no],
 155                     [`dirname $PYTHON`])
 156       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 157     ])
 158     AC_MSG_CHECKING([python include flags])
 159     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 160     AC_MSG_RESULT([$PYTHON_INCLUDE])
 161   ])
 162 else
 163     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 164 [if you want Python bindings.])
 165
 166 fi
 167
 168 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 169     AM_CHECK_PYTHON_SPHINX([PYTHON])
 170     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 171       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 172     )
 173 fi
 174
 175 pkg_modules="gmodule-2.0 >= 2.0.0"
 176 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 177 AC_SUBST(PACKAGE_LIBS)
 178
 179 LIBS="$LIBS $GMODULE_LIBS"
 180 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 181 AC_SUBST(PACKAGE_CFLAGS)
 182
 183 babeltraceincludedir="${includedir}/babeltrace"
 184 AC_SUBST(babeltraceincludedir)
 185
 186 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 187 AC_SUBST(babeltracectfincludedir)
 188
 189 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 190 AC_SUBST(babeltracectfwriterincludedir)
 191
 192 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 193 AC_SUBST(babeltracectfirincludedir)
 194
 195 AC_CONFIG_FILES([
 196         Makefile
 197         types/Makefile
 198         compat/Makefile
 199         formats/Makefile
 200         formats/ctf/Makefile
 201         formats/ctf/types/Makefile
 202         formats/ctf-text/Makefile
 203         formats/ctf-text/types/Makefile
 204         formats/ctf-metadata/Makefile
 205         formats/bt-dummy/Makefile
 206         formats/lttng-live/Makefile
 207         formats/ctf/metadata/Makefile
 208         formats/ctf/writer/Makefile
 209         formats/ctf/ir/Makefile
 210         converter/Makefile
 211         doc/Makefile
 212         doc/bindings/Makefile
 213         doc/bindings/python/Makefile
 214         lib/Makefile
 215         lib/prio_heap/Makefile
 216         include/Makefile
 217         bindings/Makefile
 218         bindings/python/Makefile
 219         tests/Makefile
 220         tests/bin/Makefile
 221         tests/lib/Makefile
 222         tests/utils/Makefile
 223         tests/utils/tap/Makefile
 224         extras/Makefile
 225         extras/valgrind/Makefile
 226         babeltrace.pc
 227         babeltrace-ctf.pc
 228 ])
 229 AC_OUTPUT