configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.50])
   5 AC_INIT([babeltrace],[1.2.4],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 AC_PROG_MKDIR_P
  20
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 AC_SYS_LARGEFILE
  24
  25 # Checks for programs.
  26 AC_PROG_CC_STDC
  27 AC_PROG_MAKE_SET
  28 LT_INIT
  29 AC_PROG_YACC
  30 AC_PROG_LEX
  31
  32 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  33         if test x"$YACC" != "xbison -y"; then
  34                 AC_MSG_ERROR([[bison not found and is required when building from git.
  35                 Please install bison]])
  36         fi
  37         AC_PATH_PROG([BISON],[bison])
  38         AX_PROG_BISON_VERSION([2.4], [],[
  39                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  40         ])
  41 fi
  42
  43 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  44         if test x"$LEX" != "xflex"; then
  45                 AC_MSG_ERROR([[flex not found and is required when building from git.
  46                 Please install flex]])
  47         fi
  48         AC_PATH_PROG([FLEX],[flex])
  49         AX_PROG_FLEX_VERSION([2.5.35], [],[
  50                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  51         ])
  52 fi
  53
  54
  55 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  56
  57 # Checks for typedefs, structures, and compiler characteristics.
  58 AC_C_INLINE
  59 AC_TYPE_PID_T
  60 AC_TYPE_SIZE_T
  61
  62 # Checks for library functions.
  63 AC_FUNC_MALLOC
  64 AC_FUNC_MMAP
  65 AC_CHECK_FUNCS([gettimeofday munmap strtoul])
  66
  67 # Check for MinGW32.
  68 MINGW32=no
  69 case $host in
  70   *-*-mingw*)
  71         MINGW32=yes;;
  72 esac
  73
  74 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  75
  76 # Check what libraries are required on this platform to link sockets programs.
  77 AX_LIB_SOCKET_NSL
  78
  79 # Check for libuuid
  80 AC_CHECK_LIB([uuid], [uuid_generate],
  81 [
  82         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  83         have_libuuid=yes
  84 ],
  85 [
  86         # libuuid not found, check for uuid_create in libc.
  87         AC_CHECK_LIB([c], [uuid_create],
  88         [
  89                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  90                 have_libc_uuid=yes
  91         ],
  92         [
  93                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  94                 if test "x$MINGW32" = xno; then
  95                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  96                 fi
  97         ])
  98 ]
  99 )
 100 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 101 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 102
 103 # Check for fmemopen
 104 AC_CHECK_LIB([c], [fmemopen],
 105 [
 106         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 107 ]
 108 )
 109
 110 # Check for open_memstream
 111 AC_CHECK_LIB([c], [open_memstream],
 112 [
 113         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 114 ]
 115 )
 116
 117 AC_CHECK_LIB([popt], [poptGetContext], [],
 118         [AC_MSG_ERROR([Cannot find popt.])]
 119 )
 120
 121
 122 # For Python
 123 # SWIG version needed or newer:
 124 swig_version=2.0.0
 125
 126 AC_ARG_ENABLE([python-bindings],
 127               [AC_HELP_STRING([--enable-python-bindings],
 128                               [generate Python bindings])],
 129               [enable_python=yes], [enable_python=no])
 130
 131 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 132
 133 if test "x${enable_python:-yes}" = xyes; then
 134   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 135   AM_PATH_PYTHON
 136
 137   AM_PATH_PYTHON_MODULES([PYTHON])
 138   # pythondir is the path where extra modules are to be installed
 139   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 140   # pyexecdir is the path that contains shared objects used by the extra modules
 141   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 142   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 143   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 144   AS_IF([test -z "$PYTHON_INCLUDE"], [
 145     AS_IF([test -z "$PYTHON_CONFIG"], [
 146       AC_PATH_PROGS([PYTHON_CONFIG],
 147                     [python$PYTHON_VERSION-config python-config],
 148                     [no],
 149                     [`dirname $PYTHON`])
 150       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 151     ])
 152     AC_MSG_CHECKING([python include flags])
 153     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 154     AC_MSG_RESULT([$PYTHON_INCLUDE])
 155   ])
 156
 157 else
 158     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 159 [if you want Python bindings.])
 160
 161 fi
 162
 163 pkg_modules="gmodule-2.0 >= 2.0.0"
 164 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 165 AC_SUBST(PACKAGE_LIBS)
 166
 167 LIBS="$LIBS $GMODULE_LIBS"
 168 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 169 AC_SUBST(PACKAGE_CFLAGS)
 170
 171 babeltraceincludedir="${includedir}/babeltrace"
 172 AC_SUBST(babeltraceincludedir)
 173
 174 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 175 AC_SUBST(babeltracectfincludedir)
 176
 177 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 178 AC_SUBST(babeltracectfwriterincludedir)
 179
 180 AC_CONFIG_FILES([
 181         Makefile
 182         types/Makefile
 183         compat/Makefile
 184         formats/Makefile
 185         formats/ctf/Makefile
 186         formats/ctf/types/Makefile
 187         formats/ctf-text/Makefile
 188         formats/ctf-text/types/Makefile
 189         formats/ctf-metadata/Makefile
 190         formats/bt-dummy/Makefile
 191         formats/lttng-live/Makefile
 192         formats/ctf/metadata/Makefile
 193         formats/ctf/writer/Makefile
 194         converter/Makefile
 195         doc/Makefile
 196         lib/Makefile
 197         lib/prio_heap/Makefile
 198         include/Makefile
 199         bindings/Makefile
 200         bindings/python/Makefile
 201         tests/Makefile
 202         tests/bin/Makefile
 203         tests/lib/Makefile
 204         tests/utils/Makefile
 205         tests/utils/tap/Makefile
 206         extras/Makefile
 207         extras/valgrind/Makefile
 208         babeltrace.pc
 209         babeltrace-ctf.pc
 210 ])
 211 AC_OUTPUT