configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[2.0.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 # Checks for C compiler
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_PROG_CC
  25 AC_PROG_CC_STDC
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34
  35 AX_C___ATTRIBUTE__
  36 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  37         [:],
  38         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  41 LIBS="$PTHREAD_LIBS $LIBS"
  42 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  43 CC="$PTHREAD_CC"
  44
  45 # Check linker option
  46 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  47 AC_SUBST([LD_NO_AS_NEEDED])
  48
  49 AC_HEADER_STDBOOL
  50 AC_CHECK_HEADERS([ \
  51         fcntl.h \
  52         float.h \
  53         libintl.h \
  54         limits.h \
  55         malloc.h \
  56         netdb.h \
  57         netinet/in.h \
  58         stddef.h \
  59         sys/socket.h \
  60 ])
  61
  62 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  63         if test x"$(basename "$YACC")" != "xbison -y"; then
  64                 AC_MSG_ERROR([[bison not found and is required when building from git.
  65                 Please install bison]])
  66         fi
  67         AC_PATH_PROG([BISON],[bison])
  68         AX_PROG_BISON_VERSION([2.4], [],[
  69                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  70         ])
  71 fi
  72
  73 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  74         if test x"$LEX" != "xflex"; then
  75                 AC_MSG_ERROR([[flex not found and is required when building from git.
  76                 Please install flex]])
  77         fi
  78         AC_PATH_PROG([FLEX],[flex])
  79         AX_PROG_FLEX_VERSION([2.5.35], [],[
  80                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  81         ])
  82 fi
  83
  84
  85 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  86
  87 # Check what libraries are required on this platform to link sockets programs.
  88 AX_LIB_SOCKET_NSL
  89
  90 # Checks for typedefs, structures, and compiler characteristics.
  91 AC_C_INLINE
  92 AC_TYPE_PID_T
  93 AC_TYPE_SIZE_T
  94 AC_TYPE_INT16_T
  95 AC_TYPE_INT32_T
  96 AC_TYPE_INT64_T
  97 AC_TYPE_INT8_T
  98 AC_TYPE_OFF_T
  99 AC_TYPE_SSIZE_T
 100 AC_TYPE_UINT16_T
 101 AC_TYPE_UINT32_T
 102 AC_TYPE_UINT64_T
 103 AC_TYPE_UINT8_T
 104
 105 # Checks for library functions.
 106 AC_FUNC_ALLOCA
 107 AC_FUNC_FORK
 108 AC_FUNC_MALLOC
 109 AC_FUNC_MKTIME
 110 AC_FUNC_MMAP
 111 AC_FUNC_REALLOC
 112 AC_FUNC_STRERROR_R
 113 AC_CHECK_FUNCS([ \
 114         atexit \
 115         dirfd \
 116         dup2 \
 117         ftruncate \
 118         gethostbyname \
 119         gethostname \
 120         gettimeofday \
 121         localtime_r \
 122         memchr \
 123         memset \
 124         mkdir \
 125         mkdtemp \
 126         munmap \
 127         rmdir \
 128         setenv \
 129         socket \
 130         strchr \
 131         strdup \
 132         strerror \
 133         strndup \
 134         strnlen \
 135         strrchr \
 136         strtoul \
 137         strtoull \
 138         tzset \
 139         uname \
 140 ])
 141
 142 # Check for MinGW32.
 143 MINGW32=no
 144 case $host in
 145   *-*-mingw*)
 146         MINGW32=yes;;
 147 esac
 148
 149 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 150
 151 # Check for uuid in system libs
 152 AC_CHECK_FUNCS([uuid_generate],
 153 [
 154   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 155   link_with_libuuid=no
 156 ],
 157 [
 158   # Check for libuuid
 159   AC_CHECK_LIB([uuid], [uuid_generate],
 160   [
 161     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 162     link_with_libuuid=yes
 163   ],
 164   [
 165     # libuuid not found, check for uuid_create in libc.
 166     AC_CHECK_LIB([c], [uuid_create],
 167     [
 168       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 169       link_with_libc_uuid=yes
 170     ],
 171     [
 172       # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 173       if test "x$MINGW32" = xno; then
 174         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 175       fi
 176     ])
 177   ])
 178 ])
 179
 180 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 181 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 182
 183 # Check for fmemopen
 184 AC_CHECK_LIB([c], [fmemopen],
 185 [
 186         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 187 ]
 188 )
 189
 190 # Check for open_memstream
 191 AC_CHECK_LIB([c], [open_memstream],
 192 [
 193         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 194 ]
 195 )
 196
 197 # Check for posix_fallocate
 198 AC_CHECK_LIB([c], [posix_fallocate],
 199 [
 200         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 201 ]
 202 )
 203
 204 # Check for faccessat
 205 AC_CHECK_LIB([c], [faccessat],
 206 [
 207         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 208 ]
 209 )
 210
 211 AC_CHECK_LIB([popt], [poptGetContext], [],
 212         [AC_MSG_ERROR([Cannot find popt.])]
 213 )
 214
 215 # For Python
 216 # SWIG version needed or newer:
 217 swig_version=2.0.0
 218
 219 AC_ARG_ENABLE([python-bindings],
 220               [AC_HELP_STRING([--enable-python-bindings],
 221                               [generate Python bindings])],
 222               [enable_python=yes], [enable_python=no])
 223
 224 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 225
 226 AC_ARG_ENABLE([python-bindings-doc],
 227               [AC_HELP_STRING([--enable-python-bindings-doc],
 228                               [generate Python bindings documentation])],
 229               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 230
 231 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 232   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 233 fi
 234
 235 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 236
 237 if test "x${enable_python:-yes}" = xyes; then
 238   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 239   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 240
 241   AM_PATH_PYTHON_MODULES([PYTHON])
 242   # pythondir is the path where extra modules are to be installed
 243   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 244   # pyexecdir is the path that contains shared objects used by the extra modules
 245   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 246   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 247   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 248   AS_IF([test -z "$PYTHON_INCLUDE"], [
 249     AS_IF([test -z "$PYTHON_CONFIG"], [
 250       AC_PATH_PROGS([PYTHON_CONFIG],
 251                     [python$PYTHON_VERSION-config python-config],
 252                     [no],
 253                     [`dirname $PYTHON`])
 254       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 255     ])
 256     AC_MSG_CHECKING([python include flags])
 257     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 258     AC_MSG_RESULT([$PYTHON_INCLUDE])
 259   ])
 260 else
 261     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 262 [if you want Python bindings.])
 263
 264 fi
 265
 266 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 267     AM_CHECK_PYTHON_SPHINX([PYTHON])
 268     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 269       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 270     )
 271 fi
 272
 273 # Optional debuginfo feature (enabled by default)
 274 AC_ARG_ENABLE([debuginfo], [AC_HELP_STRING([--disable-debuginfo], [disable the debuginfo feature])], [], [enable_debuginfo=yes])
 275
 276 AM_CONDITIONAL([ENABLE_DEBUGINFO], [test "x$enable_debuginfo" = xyes])
 277 AS_IF([test "x$enable_debuginfo" = xyes], [
 278             AC_CHECK_LIB([elf], [elf_version], [], [])
 279             AC_CHECK_LIB([dw], [dwarf_begin], [], [])
 280             AS_IF([test "x$ac_cv_lib_elf_elf_version" = xno || test "x$ac_cv_lib_dw_dwarf_begin" = xno],
 281                         [AC_MSG_ERROR(Missing library from elfutils required for debuginfo. You can disable this feature with --disable-debuginfo.)]
 282             )
 283             AC_DEFINE([ENABLE_DEBUGINFO], [1], [Define to 1 if you enable the 'debuginfo' feature])
 284 ], [])
 285
 286 pkg_modules="gmodule-2.0 >= 2.0.0"
 287 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 288 AC_SUBST(PACKAGE_LIBS)
 289
 290 LIBS="$LIBS $GMODULE_LIBS"
 291 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 292 AC_SUBST(PACKAGE_CFLAGS)
 293
 294 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 295 AC_SUBST(DEFAULT_INCLUDES)
 296
 297 babeltraceincludedir="${includedir}/babeltrace"
 298 AC_SUBST(babeltraceincludedir)
 299
 300 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 301 AC_SUBST(babeltracectfincludedir)
 302
 303 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 304 AC_SUBST(babeltracectfwriterincludedir)
 305
 306 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 307 AC_SUBST(babeltracectfirincludedir)
 308
 309 AC_CONFIG_FILES([
 310         Makefile
 311         types/Makefile
 312         compat/Makefile
 313         formats/Makefile
 314         formats/ctf/Makefile
 315         formats/ctf/types/Makefile
 316         formats/ctf-text/Makefile
 317         formats/ctf-text/types/Makefile
 318         formats/ctf-metadata/Makefile
 319         formats/bt-dummy/Makefile
 320         formats/lttng-live/Makefile
 321         formats/ctf/metadata/Makefile
 322         formats/ctf/writer/Makefile
 323         formats/ctf/ir/Makefile
 324         converter/Makefile
 325         doc/Makefile
 326         doc/bindings/Makefile
 327         doc/bindings/python/Makefile
 328         doc/images/Makefile
 329         lib/Makefile
 330         lib/prio_heap/Makefile
 331         include/Makefile
 332         bindings/Makefile
 333         bindings/python/Makefile
 334         tests/Makefile
 335         tests/bin/Makefile
 336         tests/lib/Makefile
 337         tests/utils/Makefile
 338         tests/utils/tap/Makefile
 339         extras/Makefile
 340         extras/valgrind/Makefile
 341         babeltrace.pc
 342         babeltrace-ctf.pc
 343 ])
 344
 345 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 346 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 347 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 348 AC_CONFIG_FILES([tests/bin/test_intersection], [chmod +x tests/bin/test_intersection])
 349 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 350
 351 AC_OUTPUT