configure.ac

   1 dnl SPDX-License-Identifier: MIT
   2 dnl
   3 dnl Copyright (C) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7 ##                     ##
   8 ## Autoconf base setup ##
   9 ##                     ##
  10
  11 AC_PREREQ([2.69])
  12
  13 m4_define([bt_version_major], [2])
  14 m4_define([bt_version_minor], [1])
  15 m4_define([bt_version_patch], [0])
  16 m4_define([bt_version_dev_stage], [-rc1])
  17 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
  18 m4_define([bt_version_name], [])
  19
  20 AC_INIT([babeltrace2],[bt_version],[jeremie dot galarneau at efficios dot com],[],[https://efficios.com/babeltrace/])
  21
  22 # Following the numbering scheme proposed by libtool for the library version
  23 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  24 m4_define([bt_lib_version_current], [0])
  25 m4_define([bt_lib_version_revision], [0])
  26 m4_define([bt_lib_version_age], [0])
  27 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  28 m4_define([bt_version_description], [])
  29 m4_define([bt_version_description_c_safe], AS_ESCAPE(bt_version_description))
  30
  31 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  32
  33 AC_CONFIG_HEADERS([src/common/config.h])
  34 AC_CONFIG_AUX_DIR([config])
  35 AC_CONFIG_MACRO_DIR([m4])
  36
  37 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  38 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  39 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  40 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
  41 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
  42 AC_DEFINE([BT_VERSION_DESCRIPTION], ["]bt_version_description_c_safe["], [Babeltrace version description])
  43
  44 AC_CANONICAL_TARGET
  45 AC_CANONICAL_HOST
  46
  47
  48 ##                     ##
  49 ## Automake base setup ##
  50 ##                     ##
  51
  52 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  53 AM_MAINTAINER_MODE([enable])
  54
  55 # Enable silent rules by default
  56 AM_SILENT_RULES([yes])
  57
  58
  59 ##                      ##
  60 ## OS specific defaults ##
  61 ##                      ##
  62
  63 MINGW32=no
  64 DEFAULT_ENABLE_DEBUG_INFO=yes
  65 LT_NO_UNDEFINED=""
  66 AS_CASE([$host_os],
  67   [solaris*|darwin*],
  68     [
  69         DEFAULT_ENABLE_DEBUG_INFO=no
  70     ],
  71   [cygwin*],
  72     [
  73         DEFAULT_ENABLE_DEBUG_INFO=no
  74         LT_NO_UNDEFINED="-no-undefined"
  75     ],
  76   [mingw*],
  77     [
  78         MINGW32=yes
  79         DEFAULT_ENABLE_DEBUG_INFO=no
  80         LT_NO_UNDEFINED="-no-undefined"
  81     ]
  82 )
  83
  84 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  85 AC_SUBST(LT_NO_UNDEFINED)
  86
  87
  88 ##                   ##
  89 ## C compiler checks ##
  90 ##                   ##
  91
  92 # Choose the c compiler
  93 AC_PROG_CC_STDC
  94
  95 # Make sure the c compiler supports C99
  96 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  97
  98 # Enable available system extensions and LFS support
  99 AC_USE_SYSTEM_EXTENSIONS
 100 AC_SYS_LARGEFILE
 101
 102 # Make sure the c compiler supports __attributes__
 103 AX_C___ATTRIBUTE__
 104 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 105   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 106
 107 # Make sur we have pthread support
 108 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 109
 110 # Checks for typedefs, structures, and compiler characteristics.
 111 AC_C_INLINE
 112 AC_C_TYPEOF
 113 AC_TYPE_PID_T
 114 AC_TYPE_SIZE_T
 115 AC_TYPE_INT16_T
 116 AC_TYPE_INT32_T
 117 AC_TYPE_INT64_T
 118 AC_TYPE_INT8_T
 119 AC_TYPE_OFF_T
 120 AC_TYPE_SSIZE_T
 121 AC_TYPE_UINT16_T
 122 AC_TYPE_UINT32_T
 123 AC_TYPE_UINT64_T
 124 AC_TYPE_UINT8_T
 125 AC_CHECK_TYPES([ptrdiff_t])
 126
 127
 128 ##               ##
 129 ## Header checks ##
 130 ##               ##
 131
 132 AC_HEADER_STDBOOL
 133 AC_CHECK_HEADERS([ \
 134         fcntl.h \
 135         float.h \
 136         ftw.h \
 137         libintl.h \
 138         limits.h \
 139         malloc.h \
 140         netdb.h \
 141         netinet/in.h \
 142         stddef.h \
 143         sys/socket.h \
 144         sys/time.h
 145 ])
 146
 147
 148 ##               ##
 149 ## Linker checks ##
 150 ##               ##
 151
 152 # Check if the linker supports no-as-needed
 153 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 154 AC_SUBST([LD_NO_AS_NEEDED])
 155
 156 # Check if the linker supports whole-archive
 157 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 158   [
 159     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 160     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 161   ],[
 162     # Fallback to force_load for the macOS linker
 163     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 164       [
 165         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 166         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 167       ],[
 168         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 169       ]
 170     )
 171   ]
 172 )
 173
 174
 175 ##                 ##
 176 ## Programs checks ##
 177 ##                 ##
 178
 179 AM_PROG_AR
 180 AC_PROG_MAKE_SET
 181 AC_PROG_MKDIR_P
 182 AC_PROG_LN_S
 183 AC_PROG_SED
 184 AC_PATH_PROG([report_fold], [fold])
 185
 186 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 187 # is not distributed in tarballs
 188 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 189 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 190
 191 # check for bison
 192 AC_PROG_YACC
 193 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 194
 195 AS_IF([test "x$have_bison" != "xyes"], [
 196   AS_IF([test "x$in_git_repo" = "xyes"], [
 197     AC_MSG_FAILURE([dnl
 198 Bison >= 2.4 is required when building from the Git repository. You can
 199 set the YACC variable to override automatic detection.
 200     ])
 201   ], [
 202     AC_MSG_WARN([dnl
 203 Missing Bison >= 2.4. Note that the parser files are already built in
 204 this distribution tarball, so Bison is only needed if you intend to
 205 modify their sources. You can set the YACC variable to override automatic
 206 detection.
 207     ])
 208   ])
 209 ])
 210 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 211
 212 # check for flex
 213 AC_PROG_LEX
 214 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 215
 216 AS_IF([test "x$have_flex" != "xyes"], [
 217   AS_IF([test "x$in_git_repo" = "xyes"], [
 218     AC_MSG_FAILURE([dnl
 219 Flex >= 2.5.35 is required when building from the Git repository. You can
 220 set the LEX variable to override automatic detection.
 221     ])
 222   ], [
 223     AC_MSG_WARN([dnl
 224 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 225 this distribution tarball, so Flex is only needed if you intend to
 226 modify their sources. You can set the LEX variable to override automatic
 227 detection.
 228     ])
 229   ])
 230 ])
 231 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 232
 233 # Initialize and configure libtool
 234 LT_INIT([win32-dll])
 235
 236
 237 ##                ##
 238 ## Library checks ##
 239 ##                ##
 240
 241 # Check what libraries are required on this platform to link sockets programs.
 242 AX_LIB_SOCKET_NSL
 243
 244 # Check for glib >= 2.28 with gmodule support
 245 AM_PATH_GLIB_2_0([2.28.0], [],
 246   AC_MSG_ERROR([glib >= 2.28 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 247   [gmodule-no-export]
 248 )
 249
 250 # Checks for library functions.
 251 AC_FUNC_ALLOCA
 252 AC_FUNC_FORK
 253 AC_FUNC_MKTIME
 254 AC_FUNC_MMAP
 255 AC_FUNC_STRERROR_R
 256 AC_FUNC_STRNLEN
 257 AC_CHECK_FUNCS([ \
 258         atexit \
 259         dup2 \
 260         ftruncate \
 261         gethostbyname \
 262         gettimeofday \
 263         localtime_r \
 264         memchr \
 265         memset \
 266         mkdir \
 267         mkdtemp \
 268         munmap \
 269         rmdir \
 270         setenv \
 271         socket \
 272         strchr \
 273         strdup \
 274         strerror \
 275         strndup \
 276         strnlen \
 277         strrchr \
 278         strstr \
 279         strtoul \
 280         strtoull \
 281         tzset \
 282 ])
 283
 284 # AC_FUNC_MALLOC causes problems when cross-compiling.
 285 #AC_FUNC_MALLOC
 286 #AC_FUNC_REALLOC
 287
 288 # Check for fmemopen
 289 AC_CHECK_LIB([c], [fmemopen],
 290   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 291 )
 292
 293 # Check for open_memstream
 294 AC_CHECK_LIB([c], [open_memstream],
 295   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 296 )
 297
 298 # Check for posix_fallocate
 299 AC_CHECK_LIB([c], [posix_fallocate],
 300   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 301 )
 302
 303 ##                 ##
 304 ## User variables  ##
 305 ##                 ##
 306
 307 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 308 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 309 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 310
 311 # BABELTRACE_PLUGINS_DIR: Plugins directory
 312 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 313 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 314
 315 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 316 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 317 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 318
 319 # BABELTRACE_MINIMAL_LOG_LEVEL:
 320 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 321 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 322 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 323        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 324        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 325   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 326 )
 327 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 328
 329 # BABELTRACE_DEV_MODE:
 330 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 331 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 332         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 333 ], [BABELTRACE_DEV_MODE=0])
 334 AM_CONDITIONAL([DEV_MODE], [test "x$BABELTRACE_DEV_MODE" = x1])
 335
 336 # BABELTRACE_DEBUG_MODE:
 337 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 338 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 339         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 340 ], [BABELTRACE_DEBUG_MODE=0])
 341
 342
 343 ##                              ##
 344 ## Optionnal features selection ##
 345 ##                              ##
 346
 347 # Python bindings
 348 # Disabled by default
 349 AC_ARG_ENABLE([python-bindings],
 350   [AS_HELP_STRING([--enable-python-bindings],[build the Python bindings])],
 351   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 352   [enable_python_bindings=unspecified]
 353 )
 354
 355 # Python bindings documentation
 356 # Disabled by default
 357 AC_ARG_ENABLE([python-bindings-doc],
 358   [AS_HELP_STRING([--enable-python-bindings-doc],[build the Python bindings documentation])],
 359   [], dnl AC_ARG_ENABLE will fill enable_python_bindings_doc with the user choice
 360   [enable_python_bindings_doc=no]
 361 )
 362
 363 # Python plugins
 364 # Disabled by default
 365 AC_ARG_ENABLE([python-plugins],
 366   [AS_HELP_STRING([--enable-python-plugins],[enable the Python plugins support for the library and converter])]
 367   dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 368 )
 369
 370 # Debug info
 371 # Enabled by default, except on some platforms
 372 AC_ARG_ENABLE([debug-info],
 373   [AS_HELP_STRING([--disable-debug-info],[disable the debug info support (default on macOS, Solaris and Windows)])],
 374   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 375   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 376 )
 377
 378 # API documentation
 379 # Disabled by default
 380 AC_ARG_ENABLE([api-doc],
 381   [AS_HELP_STRING([--enable-api-doc],[build the HTML API documentation])],
 382   [enable_api_doc=$enableval]
 383 )
 384
 385 # Built-in plugins
 386 # Disabled by default
 387 AC_ARG_ENABLE([built-in-plugins],
 388   [AS_HELP_STRING([--enable-built-in-plugins],[Statically-link in-tree plug-ins into the babeltrace2 executable])]
 389   dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 390 )
 391
 392 # Built-in python plugin support
 393 # Disabled by default
 394 AC_ARG_ENABLE([built-in-python-plugin-support],
 395   [AS_HELP_STRING([--enable-built-in-python-plugin-support],[Statically-link Python plugin support into the babeltrace library])]
 396   dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 397 )
 398
 399 # Man pages
 400 # Enabled by default
 401 AC_ARG_ENABLE([man-pages],
 402   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 403   [], dnl AC_ARG_ENABLE will fill enable_man_pages with the user choice
 404   [enable_man_pages=yes]
 405 )
 406
 407
 408 # Set automake variables for optionnal feature conditionnals in Makefile.am
 409 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 410 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], [test "x$enable_python_bindings_doc" = xyes])
 411 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 412 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 413 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 414 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 415 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 416 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 417 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 418
 419 # Set defines for optionnal features conditionnals in the source code
 420
 421 AS_IF([test "x$enable_built_in_plugins" = xyes],
 422   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 423 )
 424
 425 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 426   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 427 )
 428
 429 AS_IF([test "x$enable_debug_info" = xyes],
 430   [ENABLE_DEBUG_INFO_VAL=1],
 431   [ENABLE_DEBUG_INFO_VAL=0]
 432 )
 433
 434 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 435
 436 # Check for conflicting Python related features user choices.
 437 AS_IF([test "x$enable_python_plugins" = xyes],
 438   [
 439     AS_IF([test "x$enable_python_bindings" = xunspecified],
 440       [
 441         # --enable-python-plugins was provided but --enable-python-bindings was
 442         # omitted. Turn the Python bindings ON anyway because it's needed to
 443         # use the Python plugins.
 444         enable_python_bindings=yes
 445       ],
 446       [
 447         AS_IF([test "x$enable_python_bindings" = xno],
 448           [
 449             # --enable-python-plugins _and_ --disable-python-bindings were
 450             # used. This is invalid because Python plugins need the Python
 451             # bindings to be useful.
 452             AC_MSG_ERROR(--enable-python-bindings must be used to support Python plugins)
 453           ]
 454         )
 455       ]
 456     )
 457   ]
 458 )
 459
 460 # Check for conflicting optional features user choices
 461
 462 AS_IF([test "x$enable_built_in_plugins" = xyes],
 463   [
 464     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 465     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 466     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 467   ]
 468 )
 469
 470 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 471   [
 472     AS_IF([test "x$enable_python_plugins" != xyes], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 473     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 474     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 475     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 476   ]
 477 )
 478
 479
 480 # Check for optionnal features dependencies
 481
 482 AS_IF([test "x$enable_python_bindings" = xyes],
 483   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 484 )
 485
 486 AM_PATH_PYTHON([3.0], [
 487   AM_PATH_PYTHON_MODULES([PYTHON])
 488
 489   # pythondir is the path where extra modules are to be installed
 490   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 491
 492   # pyexecdir is the path that contains shared objects used by the extra modules
 493   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 494
 495   AS_IF([test -z "$PYTHON_CONFIG"], [
 496     AC_PATH_PROGS([PYTHON_CONFIG],
 497                   [python$PYTHON_VERSION-config python-config],
 498                   [],
 499                   [`dirname $PYTHON`])
 500   ])
 501
 502   AS_IF([test -n "$PYTHON_CONFIG"], [
 503     AS_IF([test -z "$PYTHON_INCLUDE"], [
 504       AC_MSG_CHECKING([Python include flags])
 505       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 506       AC_MSG_RESULT([$PYTHON_INCLUDE])
 507     ])
 508
 509     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 510       AC_MSG_CHECKING([Python library flags])
 511       # Python 3.8+ requires that we pass --embed to get the -lpython3.x flag.
 512       AS_IF([! PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags --embed`], [
 513         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 514       ])
 515       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 516     ])
 517   ])
 518 ], [:])
 519
 520 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 521 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 522
 523 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 524 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 525
 526 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 527   AS_IF([test "x$have_python_dev" = xno], [
 528     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 529   ])
 530 ])
 531
 532 AS_IF([test "x$enable_python_bindings_doc" = xyes],
 533   [
 534     AM_CHECK_PYTHON_SPHINX([PYTHON])
 535     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno], [
 536       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])
 537     ])
 538
 539     AS_IF([test "x$enable_python_bindings" != xyes], [
 540       AC_MSG_ERROR([The Python bindings are required to build their documentation])
 541     ])
 542   ]
 543 )
 544
 545 AS_IF([test "x$enable_debug_info" = xyes], [
 546   # Check if libelf and libdw are present
 547   PKG_CHECK_MODULES([ELFUTILS], [libelf >= 0.154 libdw >= 0.154],
 548     [
 549       dnl PKG_CHECK_MODULES defines ELFUTILS_LIBS
 550     ],
 551     [
 552       AC_MSG_ERROR([elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.])
 553     ])
 554 ])
 555 AC_SUBST([ELFUTILS_LIBS])
 556
 557 AS_IF([test "x$enable_api_doc" = "xyes"],
 558   [
 559     DX_DOXYGEN_FEATURE(ON)
 560     DX_DOT_FEATURE(OFF)
 561     DX_HTML_FEATURE(ON)
 562     DX_CHM_FEATURE(OFF)
 563     DX_CHI_FEATURE(OFF)
 564     DX_MAN_FEATURE(OFF)
 565     DX_RTF_FEATURE(OFF)
 566     DX_XML_FEATURE(OFF)
 567     DX_PDF_FEATURE(OFF)
 568     DX_PS_FEATURE(OFF)
 569     DX_INIT_DOXYGEN([Babeltrace 2], [$(builddir)/Doxyfile], [output])
 570     AS_IF([test -z "$DX_DOXYGEN"],
 571           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 572     )
 573   ]
 574 )
 575
 576 have_asciidoc_xmlto=no
 577 warn_prebuilt_man_pages=no
 578
 579 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 580 AC_PATH_PROG([XMLTO], [xmlto], [no])
 581
 582 AS_IF([test "x$enable_man_pages" = "xyes"], [
 583   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 584     AS_IF([test "x$in_git_repo" = "xyes"], [
 585       # this is an error because we're in the Git repo, which
 586       # means the man pages are not already generated for us,
 587       # thus asciixmlto are required because we were asked
 588       # to build the man pages
 589       AC_MSG_ERROR([
 590 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 591 --disable-man-pages to disable building the man pages, in which case
 592 they will not be installed.
 593       ])
 594     ], [
 595       # only warn here: since we're in the tarball, the man
 596       # pages should already be generated at this point, thus
 597       # asciidoc/xmlto are not strictly required
 598       warn_prebuilt_man_pages=yes
 599     ])
 600   ], [
 601     have_asciidoc_xmlto=yes
 602   ])
 603 ])
 604
 605 # export AsciiDoc and xmlto existence
 606 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 607
 608 # a wonderful hack that seems necessary because $libdir is
 609 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 610 # by autoconf when it's not specified by the user
 611 AS_IF([test "x$exec_prefix" = xNONE], [
 612   AS_IF([test "x$prefix" = xNONE], [
 613     PREFIX="$ac_default_prefix"
 614   ], [
 615     PREFIX="$prefix"
 616   ])
 617
 618   LIBDIR="$PREFIX/lib"
 619 ], [
 620   LIBDIR="$libdir"
 621 ])
 622
 623 AC_SUBST(LIBDIR)
 624
 625 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 626 # test).
 627 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 628
 629 # Check that the current size_t matches the size that glib thinks it should
 630 # be. This catches problems on multi-arch where people try to do a 32-bit
 631 # build while pointing at 64-bit glib headers. This is a common error because
 632 # glib.h is not platform specific but it includes glibconfig.h which is and
 633 # is usually installed in a non-standard path.
 634
 635 # Do this before enabling all the warning flags, as the
 636 # AC_LANG_PROGRAM-generated program may generate some warning, which makes this
 637 # test fail unnecessarily.
 638
 639 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 640 # output. Specifically allow pkg_config_libdir to be able to print the
 641 # error message.
 642 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 643
 644 save_CFLAGS=${CFLAGS}
 645 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 646 AC_COMPILE_IFELSE([
 647   AC_LANG_PROGRAM([dnl
 648 #include <glib.h>
 649 #include <unistd.h>
 650   ], [dnl
 651 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 652   ])
 653 ],[:],[
 654   AC_MSG_ERROR([dnl
 655 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 656 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 657 target.
 658   ])
 659 ])
 660 CFLAGS=${save_CFLAGS}
 661
 662 # Detect C and LD warning flags supported by the compiler.
 663
 664 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
 665 #
 666 # Pass -Werror as an extra flag during the test: this is needed to make the
 667 # -Wunknown-warning-option diagnostic fatal with clang.
 668 AX_APPEND_COMPILE_FLAGS([ dnl
 669                 -Wall dnl
 670                 -Wextra dnl
 671                 -Wmissing-prototypes dnl
 672                 -Wmissing-declarations dnl
 673                 -Wnull-dereference dnl
 674                 -Wundef dnl
 675                 -Wredundant-decls dnl
 676                 -Wshadow dnl
 677                 -Wjump-misses-init dnl
 678                 -Wsuggest-attribute=format dnl
 679                 -Wtautological-constant-out-of-range-compare dnl
 680                 -Wnested-externs dnl
 681                 -Wwrite-strings dnl
 682                 -Wformat=2 dnl
 683                 -Wstrict-aliasing dnl
 684                 -Wmissing-noreturn dnl
 685                 -Winit-self dnl
 686                 -Wduplicated-cond dnl
 687                 -Wduplicated-branches dnl
 688                 -Wlogical-op dnl
 689                 -Wno-unused-parameter dnl
 690                 -Wno-sign-compare dnl
 691                 dnl
 692                 dnl Some versions of SWIG (like 3.0.12) generate code that produces
 693                 dnl -Wcast-function-type warnings.  This warning is present in gcc >= 8.  This
 694                 dnl combo happens on RHEL/Centos 8, for example.  Later versions of SWIG (like
 695                 dnl 4.0.1) have the correct function signatures to not produce this warning.
 696                 dnl It's simpler to just disable the warning globally.
 697                 dnl
 698                 dnl Note that the Debian/Ubuntu SWIG package 3.0.12-2 contains a local patch to
 699                 dnl fix this (python-fix-function-cast-warnings.patch), so you won't be able to
 700                 dnl reproduce the warning using that package.
 701                 dnl
 702                 dnl Ref: https://github.com/swig/swig/issues/1259
 703                 -Wno-cast-function-type dnl
 704                 -Wno-missing-field-initializers dnl
 705         ],
 706         [WARN_CFLAGS],
 707         [-Werror])
 708
 709 # When given, add -Werror to WARN_CFLAGS.
 710 AC_ARG_ENABLE([Werror],
 711         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
 712 )
 713 AS_IF([test "x$enable_Werror" = "xyes"],
 714         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
 715 )
 716
 717 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 718 # written in such a way that it triggers warnings with the following warning
 719 # flags.  So they would always end up disabled if we put them there, because
 720 # the test program would not build.
 721 #
 722 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 723 # Clang >= 4.0.
 724 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 725
 726 # CFLAGS from AX_APPEND_COMPILE_FLAGS.
 727 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 728
 729 # Done for AM_CFLAGS.
 730 AC_SUBST(AM_CFLAGS)
 731
 732 # Set global CPPFLAGS in AM_CPPFLAGS
 733 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 734 AC_SUBST(AM_CPPFLAGS)
 735
 736 # Add glib to global link libs
 737 LIBS="$LIBS $GLIB_LIBS"
 738
 739 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 740 # to rename babeltrace2.bin to babeltrace2 at install time.
 741 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 742 AC_SUBST(program_transform_name)
 743
 744 AC_CONFIG_FILES([
 745         doc/api/Makefile
 746         doc/api/libbabeltrace2/Doxyfile
 747         doc/api/libbabeltrace2/Makefile
 748         doc/bindings/Makefile
 749         doc/bindings/python/Makefile
 750         doc/contributing-images/Makefile
 751         doc/Makefile
 752         doc/man/asciidoc-attrs.conf
 753         doc/man/Makefile
 754         include/Makefile
 755         Makefile
 756         src/argpar/Makefile
 757         src/autodisc/Makefile
 758         src/babeltrace2-ctf-writer.pc
 759         src/babeltrace2.pc
 760         src/bindings/Makefile
 761         src/bindings/python/bt2/bt2/version.py
 762         src/bindings/python/bt2/Makefile
 763         src/bindings/python/bt2/setup.py
 764         src/bindings/python/Makefile
 765         src/cli/Makefile
 766         src/common/Makefile
 767         src/compat/Makefile
 768         src/ctfser/Makefile
 769         src/ctf-writer/Makefile
 770         src/fd-cache/Makefile
 771         src/lib/graph/Makefile
 772         src/lib/graph/message/Makefile
 773         src/lib/Makefile
 774         src/lib/plugin/Makefile
 775         src/lib/prio-heap/Makefile
 776         src/lib/trace-ir/Makefile
 777         src/logging/Makefile
 778         src/Makefile
 779         src/plugins/common/Makefile
 780         src/plugins/common/muxing/Makefile
 781         src/plugins/common/param-validation/Makefile
 782         src/plugins/ctf/common/bfcr/Makefile
 783         src/plugins/ctf/common/Makefile
 784         src/plugins/ctf/common/metadata/Makefile
 785         src/plugins/ctf/common/msg-iter/Makefile
 786         src/plugins/ctf/fs-sink/Makefile
 787         src/plugins/ctf/fs-src/Makefile
 788         src/plugins/ctf/lttng-live/Makefile
 789         src/plugins/ctf/Makefile
 790         src/plugins/lttng-utils/debug-info/Makefile
 791         src/plugins/lttng-utils/Makefile
 792         src/plugins/Makefile
 793         src/plugins/text/dmesg/Makefile
 794         src/plugins/text/Makefile
 795         src/plugins/text/pretty/Makefile
 796         src/plugins/text/details/Makefile
 797         src/plugins/utils/counter/Makefile
 798         src/plugins/utils/dummy/Makefile
 799         src/plugins/utils/Makefile
 800         src/plugins/utils/muxer/Makefile
 801         src/plugins/utils/trimmer/Makefile
 802         src/py-common/Makefile
 803         src/python-plugin-provider/Makefile
 804         src/param-parse/Makefile
 805         src/string-format/Makefile
 806         tests/bitfield/Makefile
 807         tests/ctf-writer/Makefile
 808         tests/lib/Makefile
 809         tests/lib/test-plugin-plugins/Makefile
 810         tests/lib/conds/Makefile
 811         tests/Makefile
 812         tests/param-validation/Makefile
 813         tests/plugins/Makefile
 814         tests/plugins/src.ctf.fs/Makefile
 815         tests/plugins/src.ctf.fs/succeed/Makefile
 816         tests/plugins/sink.ctf.fs/Makefile
 817         tests/plugins/sink.ctf.fs/succeed/Makefile
 818         tests/plugins/flt.lttng-utils.debug-info/Makefile
 819         tests/plugins/flt.utils.muxer/Makefile
 820         tests/plugins/flt.utils.muxer/succeed/Makefile
 821         tests/plugins/flt.utils.trimmer/Makefile
 822         tests/plugins/sink.text.pretty/Makefile
 823         tests/utils/Makefile
 824         tests/utils/tap/Makefile
 825 ])
 826
 827 AC_OUTPUT
 828
 829 #
 830 # Mini-report on what will be built.
 831 #
 832
 833 PPRINT_INIT
 834 PPRINT_SET_INDENT(1)
 835 PPRINT_SET_TS(38)
 836
 837 AS_ECHO
 838
 839 AS_IF([test -n "bt_version_name"], [
 840         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION \"bt_version_name\"$PPRINT_COLOR_RST")
 841 ], [
 842         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION")
 843 ])
 844
 845 AS_ECHO
 846
 847 AS_IF([test -n "bt_version_description"], [
 848         AS_IF([test -n "$report_fold"], [
 849                 AS_ECHO("`AS_ECHO("bt_version_description") | $report_fold -s`")
 850         ], [
 851                 AS_ECHO("bt_version_description")
 852         ])
 853
 854         AS_ECHO
 855 ])
 856
 857 PPRINT_SUBTITLE([System])
 858
 859 # Target architecture we're building for.
 860 target_arch=$host_cpu
 861 [
 862 for f in $CFLAGS; do
 863         if test $f = "-m32"; then
 864                 target_arch="32-bit"
 865         elif test $f = "-m64"; then
 866                 target_arch="64-bit"
 867         fi
 868 done
 869 ]
 870
 871 PPRINT_PROP_STRING([Target architecture], $target_arch)
 872
 873 AS_ECHO
 874 PPRINT_SUBTITLE([Python 3 language support])
 875 test "x$have_python" = "xyes" && value=1 || value=0
 876 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 877 test "x$have_python_dev" = "xyes" && value=1 || value=0
 878 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 879 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 880 PPRINT_PROP_BOOL_CUSTOM([Python bindings], $value, [To enable, use --enable-python-bindings])
 881 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 882 PPRINT_PROP_BOOL_CUSTOM([Python plugin support], $value, [To enable, use --enable-python-plugins])
 883 AS_IF([test "x$have_python" = "xyes"], [
 884   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 885 ])
 886 AS_IF([test "x$have_python_dev" = "xyes"], [
 887   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 888   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 889   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 890 ])
 891 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 892   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 893   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 894 ])
 895
 896 AS_ECHO
 897 PPRINT_SUBTITLE([Plugins])
 898 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 899 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 900 PPRINT_PROP_BOOL_CUSTOM(['lttng-utils' plugin], $value, [To enable, use --enable-debug-info])
 901 PPRINT_PROP_BOOL(['text' plugin], 1)
 902 PPRINT_PROP_BOOL(['utils' plugin], 1)
 903
 904 AS_ECHO
 905 PPRINT_SUBTITLE([Built-in features])
 906 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 907 PPRINT_PROP_BOOL_CUSTOM([Built-in plugins], $value, [To enable, use --enable-built-in-plugins])
 908 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 909 PPRINT_PROP_BOOL_CUSTOM([Built-in Python plugin support], $value, [To enable, use --enable-built-in-python-plugin-support])
 910
 911 AS_ECHO
 912 PPRINT_SUBTITLE([Documentation])
 913
 914 # man pages build enabled/disabled
 915 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 916
 917 AS_IF([test "x$enable_man_pages" != "xno"], [
 918   AS_IF([test "x$in_git_repo" = "xyes"], [
 919     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 920   ], [
 921     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 922       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 923     ], [
 924       PPRINT_PROP_STRING([build_man_pages_msg],
 925         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 926         $PPRINT_COLOR_SUBTITLE)
 927     ])
 928   ])
 929 ], [
 930   PPRINT_PROP_BOOL_CUSTOM([build_man_pages_msg], 0, [To build man pages, use --enable-man-pages])
 931 ])
 932
 933 m4_popdef([build_man_pages_msg])
 934
 935 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 936 PPRINT_PROP_BOOL_CUSTOM([HTML API documentation], $value, [To build documentation, use --enable-api-doc])
 937 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 938 PPRINT_PROP_BOOL_CUSTOM([Python bindings documentation], $value, [To build the Python bindings documentation, use --enable-python-bindings-doc])
 939
 940 AS_ECHO
 941 PPRINT_SUBTITLE([Logging])
 942 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 943
 944 AS_ECHO
 945 PPRINT_SUBTITLE([Special build modes])
 946 PPRINT_PROP_BOOL_CUSTOM([Debug mode], $BABELTRACE_DEBUG_MODE, [To enable, set the BABELTRACE_DEBUG_MODE environment variable to 1])
 947 PPRINT_PROP_BOOL_CUSTOM([Developer mode], $BABELTRACE_DEV_MODE, [To enable, set the BABELTRACE_DEV_MODE environment variable to 1])
 948
 949 report_bindir="`eval eval echo $bindir`"
 950 report_libdir="`eval eval echo $libdir`"
 951 report_sysconfdif="`eval eval echo $sysconfdir`"
 952 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 953 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 954
 955 # Print the bindir and libdir this `make install' will install into.
 956 AS_ECHO
 957 PPRINT_SUBTITLE([Install directories])
 958 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 959 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 960 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 961 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 962 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])