configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.2.4],[mathieu dot desnoyers at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 # Checks for C compiler
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_PROG_CC
  25 AC_PROG_CC_STDC
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34
  35 AX_C___ATTRIBUTE__
  36 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  37         [:],
  38         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  41 LIBS="$PTHREAD_LIBS $LIBS"
  42 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  43 CC="$PTHREAD_CC"
  44
  45 # Check linker option
  46 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  47 AC_SUBST([LD_NO_AS_NEEDED])
  48
  49 AC_CHECK_HEADERS([fcntl.h limits.h netdb.h netinet/in.h stddef.h sys/socket.h])
  50
  51 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  52         if test x"$YACC" != "xbison -y"; then
  53                 AC_MSG_ERROR([[bison not found and is required when building from git.
  54                 Please install bison]])
  55         fi
  56         AC_PATH_PROG([BISON],[bison])
  57         AX_PROG_BISON_VERSION([2.4], [],[
  58                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  59         ])
  60 fi
  61
  62 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  63         if test x"$LEX" != "xflex"; then
  64                 AC_MSG_ERROR([[flex not found and is required when building from git.
  65                 Please install flex]])
  66         fi
  67         AC_PATH_PROG([FLEX],[flex])
  68         AX_PROG_FLEX_VERSION([2.5.35], [],[
  69                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  70         ])
  71 fi
  72
  73
  74 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  75
  76 # Checks for typedefs, structures, and compiler characteristics.
  77 AC_C_INLINE
  78 AC_TYPE_PID_T
  79 AC_TYPE_SIZE_T
  80
  81 # Checks for library functions.
  82 AC_FUNC_MALLOC
  83 AC_FUNC_MMAP
  84 AC_CHECK_FUNCS([gettimeofday munmap strtoul strndup strnlen mkdtemp])
  85
  86 # Check for MinGW32.
  87 MINGW32=no
  88 case $host in
  89   *-*-mingw*)
  90         MINGW32=yes;;
  91 esac
  92
  93 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  94
  95 # Check what libraries are required on this platform to link sockets programs.
  96 AX_LIB_SOCKET_NSL
  97
  98 # Check for libuuid
  99 AC_CHECK_LIB([uuid], [uuid_generate],
 100 [
 101         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 102         have_libuuid=yes
 103 ],
 104 [
 105         # libuuid not found, check for uuid_create in libc.
 106         AC_CHECK_LIB([c], [uuid_create],
 107         [
 108                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 109                 have_libc_uuid=yes
 110         ],
 111         [
 112                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 113                 if test "x$MINGW32" = xno; then
 114                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 115                 fi
 116         ])
 117 ]
 118 )
 119 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 120 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 121
 122 # Check for fmemopen
 123 AC_CHECK_LIB([c], [fmemopen],
 124 [
 125         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 126 ]
 127 )
 128
 129 # Check for open_memstream
 130 AC_CHECK_LIB([c], [open_memstream],
 131 [
 132         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 133 ]
 134 )
 135
 136 # Check for posix_fallocate
 137 AC_CHECK_LIB([c], [posix_fallocate],
 138 [
 139         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 140 ]
 141 )
 142
 143 # Check for faccessat
 144 AC_CHECK_LIB([c], [faccessat],
 145 [
 146         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 147 ]
 148 )
 149
 150 AC_CHECK_LIB([popt], [poptGetContext], [],
 151         [AC_MSG_ERROR([Cannot find popt.])]
 152 )
 153
 154 # For Python
 155 # SWIG version needed or newer:
 156 swig_version=2.0.0
 157
 158 AC_ARG_ENABLE([python-bindings],
 159               [AC_HELP_STRING([--enable-python-bindings],
 160                               [generate Python bindings])],
 161               [enable_python=yes], [enable_python=no])
 162
 163 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 164
 165 if test "x${enable_python:-yes}" = xyes; then
 166   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 167   AM_PATH_PYTHON
 168
 169   AM_PATH_PYTHON_MODULES([PYTHON])
 170   # pythondir is the path where extra modules are to be installed
 171   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 172   # pyexecdir is the path that contains shared objects used by the extra modules
 173   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 174   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 175   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 176   AS_IF([test -z "$PYTHON_INCLUDE"], [
 177     AS_IF([test -z "$PYTHON_CONFIG"], [
 178       AC_PATH_PROGS([PYTHON_CONFIG],
 179                     [python$PYTHON_VERSION-config python-config],
 180                     [no],
 181                     [`dirname $PYTHON`])
 182       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 183     ])
 184     AC_MSG_CHECKING([python include flags])
 185     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 186     AC_MSG_RESULT([$PYTHON_INCLUDE])
 187   ])
 188
 189 else
 190     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 191 [if you want Python bindings.])
 192
 193 fi
 194
 195 pkg_modules="gmodule-2.0 >= 2.0.0"
 196 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 197 AC_SUBST(PACKAGE_LIBS)
 198
 199 LIBS="$LIBS $GMODULE_LIBS"
 200 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 201 AC_SUBST(PACKAGE_CFLAGS)
 202
 203 babeltraceincludedir="${includedir}/babeltrace"
 204 AC_SUBST(babeltraceincludedir)
 205
 206 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 207 AC_SUBST(babeltracectfincludedir)
 208
 209 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 210 AC_SUBST(babeltracectfwriterincludedir)
 211
 212 AC_CONFIG_FILES([
 213         Makefile
 214         types/Makefile
 215         compat/Makefile
 216         formats/Makefile
 217         formats/ctf/Makefile
 218         formats/ctf/types/Makefile
 219         formats/ctf-text/Makefile
 220         formats/ctf-text/types/Makefile
 221         formats/ctf-metadata/Makefile
 222         formats/bt-dummy/Makefile
 223         formats/lttng-live/Makefile
 224         formats/ctf/metadata/Makefile
 225         formats/ctf/writer/Makefile
 226         converter/Makefile
 227         doc/Makefile
 228         lib/Makefile
 229         lib/prio_heap/Makefile
 230         include/Makefile
 231         bindings/Makefile
 232         bindings/python/Makefile
 233         tests/Makefile
 234         tests/bin/Makefile
 235         tests/lib/Makefile
 236         tests/utils/Makefile
 237         tests/utils/tap/Makefile
 238         extras/Makefile
 239         extras/valgrind/Makefile
 240         babeltrace.pc
 241         babeltrace-ctf.pc
 242 ])
 243 AC_OUTPUT