configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([babeltrace],[1.1.1],[mathieu dot desnoyers at efficios dot com])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CANONICAL_TARGET
   7 AC_CANONICAL_HOST
   8 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_PROG_MKDIR_P
  14
  15 AC_CONFIG_HEADERS([config.h])
  16
  17 AC_SYS_LARGEFILE
  18
  19 # Checks for programs.
  20 AC_PROG_CC_STDC
  21 AC_PROG_MAKE_SET
  22 LT_INIT
  23 AC_PROG_YACC
  24 AC_PROG_LEX
  25
  26 AC_DEFUN([AC_PROG_BISON], [AC_CHECK_PROGS(BISON, bison, bison)])
  27
  28 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  29
  30 # Checks for typedefs, structures, and compiler characteristics.
  31 AC_C_INLINE
  32 AC_TYPE_PID_T
  33 AC_TYPE_SIZE_T
  34
  35 # Checks for library functions.
  36 AC_FUNC_MALLOC
  37 AC_FUNC_MMAP
  38 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  39
  40 # Check for MinGW32.
  41 MINGW32=no
  42 case $host in
  43   *-*-mingw*)
  44         MINGW32=yes;;
  45 esac
  46
  47 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  48
  49 # Check for libuuid
  50 AC_CHECK_LIB([uuid], [uuid_generate],
  51 [
  52         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  53         have_libuuid=yes
  54 ],
  55 [
  56         # libuuid not found, check for uuid_create in libc.
  57         AC_CHECK_LIB([c], [uuid_create],
  58         [
  59                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  60                 have_libc_uuid=yes
  61         ],
  62         [
  63                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  64                 if test "x$MINGW32" = xno; then
  65                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  66                 fi
  67         ])
  68 ]
  69 )
  70 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  71 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  72
  73 # Check for fmemopen
  74 AC_CHECK_LIB([c], [fmemopen],
  75 [
  76         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
  77 ]
  78 )
  79
  80 # Check for open_memstream
  81 AC_CHECK_LIB([c], [open_memstream],
  82 [
  83         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
  84 ]
  85 )
  86
  87 AC_CHECK_LIB([popt], [poptGetContext], [],
  88         [AC_MSG_ERROR([Cannot find popt.])]
  89 )
  90
  91 pkg_modules="gmodule-2.0 >= 2.0.0"
  92 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
  93 AC_SUBST(PACKAGE_LIBS)
  94
  95 LIBS="$LIBS $GMODULE_LIBS"
  96 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
  97 AC_SUBST(PACKAGE_CFLAGS)
  98
  99 babeltraceincludedir="${includedir}/babeltrace"
 100 AC_SUBST(babeltraceincludedir)
 101
 102 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 103 AC_SUBST(babeltracectfincludedir)
 104
 105 AC_CONFIG_FILES([
 106         Makefile
 107         types/Makefile
 108         compat/Makefile
 109         formats/Makefile
 110         formats/ctf/Makefile
 111         formats/ctf/types/Makefile
 112         formats/ctf-text/Makefile
 113         formats/ctf-text/types/Makefile
 114         formats/ctf-metadata/Makefile
 115         formats/bt-dummy/Makefile
 116         formats/ctf/metadata/Makefile
 117         converter/Makefile
 118         doc/Makefile
 119         lib/Makefile
 120         lib/prio_heap/Makefile
 121         include/Makefile
 122         tests/Makefile
 123         tests/lib/Makefile
 124         extras/Makefile
 125         extras/valgrind/Makefile
 126         babeltrace.pc
 127 ])
 128 AC_OUTPUT