configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([babeltrace],[1.0.2],[mathieu dot desnoyers at efficios dot com])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CANONICAL_TARGET
   7 AC_CANONICAL_HOST
   8 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AM_PROG_MKDIR_P
  14
  15 AC_CONFIG_HEADERS([config.h])
  16
  17 AC_SYS_LARGEFILE
  18
  19 # Checks for programs.
  20 AC_PROG_CC
  21 AC_PROG_MAKE_SET
  22 LT_INIT
  23 AC_PROG_YACC
  24 AC_PROG_LEX
  25
  26 AC_DEFUN([AC_PROG_BISON], [AC_CHECK_PROGS(BISON, bison, bison)])
  27
  28 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  29
  30 # Checks for typedefs, structures, and compiler characteristics.
  31 AC_C_INLINE
  32 AC_TYPE_PID_T
  33 AC_TYPE_SIZE_T
  34
  35 # Checks for library functions.
  36 AC_FUNC_MALLOC
  37 AC_FUNC_MMAP
  38 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  39
  40 # Check for libuuid
  41 AC_CHECK_LIB([uuid], [uuid_generate],
  42 [
  43         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  44         have_libuuid=yes
  45 ],
  46 [
  47         # libuuid not found, check for uuid_create in libc.
  48         AC_CHECK_LIB([c], [uuid_create],
  49         [
  50                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  51                 have_libc_uuid=yes
  52         ],
  53         [
  54                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  55         ])
  56 ]
  57 )
  58 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  59 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  60
  61 # Check for fmemopen
  62 AC_CHECK_LIB([c], [fmemopen],
  63 [
  64         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
  65 ]
  66 )
  67
  68 # Check for open_memstream
  69 AC_CHECK_LIB([c], [open_memstream],
  70 [
  71         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
  72 ]
  73 )
  74
  75 AC_CHECK_LIB([popt], [poptGetContext], [],
  76         [AC_MSG_ERROR([Cannot find popt.])]
  77 )
  78
  79
  80 # For Python
  81 # SWIG version needed or newer:
  82 swig_version=2.0.0
  83
  84 AC_ARG_ENABLE([python],
  85               [AC_HELP_STRING([--disable-python],
  86                               [do not compile Python bindings])],
  87               [], [enable_python=yes])
  88
  89 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
  90
  91 if test "x${enable_python:-yes}" = xyes; then
  92   AC_MSG_NOTICE([You may configure with --disable-python ]dnl
  93 [if you do not want Python bindings.])
  94
  95   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
  96   AM_PATH_PYTHON
  97
  98   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
  99   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 100   AS_IF([test -z "$PYTHON_INCLUDE"], [
 101     AS_IF([test -z "$PYTHON_CONFIG"], [
 102       AC_PATH_PROGS([PYTHON_CONFIG],
 103                     [python$PYTHON_VERSION-config python-config],
 104                     [no],
 105                     [`dirname $PYTHON`])
 106       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON.])])
 107     ])
 108     AC_MSG_CHECKING([python include flags])
 109     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 110     AC_MSG_RESULT([$PYTHON_INCLUDE])
 111   ])
 112 fi
 113
 114 pkg_modules="gmodule-2.0 >= 2.0.0"
 115 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 116 AC_SUBST(PACKAGE_LIBS)
 117
 118 LIBS="$LIBS $GMODULE_LIBS"
 119 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 120 AC_SUBST(PACKAGE_CFLAGS)
 121
 122 babeltraceincludedir="${includedir}/babeltrace"
 123 AC_SUBST(babeltraceincludedir)
 124
 125 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 126 AC_SUBST(babeltracectfincludedir)
 127
 128 AC_CONFIG_FILES([
 129         Makefile
 130         types/Makefile
 131         formats/Makefile
 132         formats/ctf/Makefile
 133         formats/ctf/types/Makefile
 134         formats/ctf-text/Makefile
 135         formats/ctf-text/types/Makefile
 136         formats/bt-dummy/Makefile
 137         formats/ctf/metadata/Makefile
 138         converter/Makefile
 139         doc/Makefile
 140         lib/Makefile
 141         lib/prio_heap/Makefile
 142         include/Makefile
 143         bindings/Makefile
 144         bindings/python/Makefile
 145         tests/Makefile
 146         tests/lib/Makefile
 147         extras/Makefile
 148         extras/valgrind/Makefile
 149         babeltrace.pc
 150 ])
 151 AC_OUTPUT