configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.5.8],[jeremie.galarneau@efficios.com],[],[https://diamon.org/babeltrace])
   3 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   4
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 AC_PROG_CC_STDC
  25
  26 # Checks for programs.
  27 AC_PROG_MAKE_SET
  28 LT_INIT
  29 AC_PROG_YACC
  30 AC_PROG_LEX
  31 AC_PROG_MKDIR_P
  32 AC_PROG_LN_S
  33
  34 AX_C___ATTRIBUTE__
  35 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  36         [:],
  37         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  38
  39 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  40 LIBS="$PTHREAD_LIBS $LIBS"
  41 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  42 CC="$PTHREAD_CC"
  43
  44 # Check linker option
  45 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  46 AC_SUBST([LD_NO_AS_NEEDED])
  47
  48 AC_HEADER_STDBOOL
  49 AC_CHECK_HEADERS([ \
  50         fcntl.h \
  51         float.h \
  52         libintl.h \
  53         limits.h \
  54         malloc.h \
  55         netdb.h \
  56         netinet/in.h \
  57         stddef.h \
  58         sys/socket.h \
  59 ])
  60
  61 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  62         if test x"$(basename "$YACC")" != "xbison -y"; then
  63                 AC_MSG_ERROR([[bison not found and is required when building from git.
  64                 Please install bison]])
  65         fi
  66         AC_PATH_PROG([BISON],[bison])
  67         AX_PROG_BISON_VERSION([2.4], [],[
  68                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  69         ])
  70 fi
  71
  72 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  73         if test x"$LEX" != "xflex"; then
  74                 AC_MSG_ERROR([[flex not found and is required when building from git.
  75                 Please install flex]])
  76         fi
  77         AC_PATH_PROG([FLEX],[flex])
  78         AX_PROG_FLEX_VERSION([2.5.35], [],[
  79                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  80         ])
  81 fi
  82
  83 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  84
  85 # Check what libraries are required on this platform to link sockets programs.
  86 AX_LIB_SOCKET_NSL
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_PID_T
  91 AC_TYPE_SIZE_T
  92
  93 # Checks for library functions.
  94 AC_FUNC_ALLOCA
  95 AC_FUNC_FORK
  96 AC_FUNC_MALLOC
  97 AC_FUNC_MKTIME
  98 AC_FUNC_MMAP
  99 AC_FUNC_REALLOC
 100 AC_CHECK_FUNCS([ \
 101         atexit \
 102         dirfd \
 103         dup2 \
 104         ftruncate \
 105         gethostbyname \
 106         gethostname \
 107         gettimeofday \
 108         localtime_r \
 109         memchr \
 110         memset \
 111         mkdir \
 112         mkdtemp \
 113         munmap \
 114         rmdir \
 115         setenv \
 116         socket \
 117         strchr \
 118         strdup \
 119         strerror \
 120         strndup \
 121         strnlen \
 122         strrchr \
 123         strtoul \
 124         strtoull \
 125         tzset \
 126         uname \
 127 ])
 128
 129 MINGW32=no
 130 DEFAULT_ENABLE_DEBUG_INFO=yes
 131 LT_NO_UNDEFINED=""
 132 AS_CASE([$host_os],
 133   [solaris*|darwin*],
 134     [
 135         DEFAULT_ENABLE_DEBUG_INFO=no
 136     ],
 137   [mingw*],
 138     [
 139         MINGW32=yes
 140         LT_NO_UNDEFINED="-no-undefined"
 141     ],
 142   [cygwin*],
 143     [
 144         LT_NO_UNDEFINED="-no-undefined"
 145         DEFAULT_ENABLE_DEBUG_INFO=no
 146     ]
 147 )
 148
 149 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 150 AC_SUBST(LT_NO_UNDEFINED)
 151
 152 # Check what libraries are required on this platform to link sockets programs.
 153 AX_LIB_SOCKET_NSL
 154
 155 # Check for uuid in system libs
 156 AC_CHECK_FUNCS([uuid_generate],
 157 [
 158   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 159   link_with_libuuid=no
 160 ],
 161 [
 162   # First, check the pkg-config module is available, otherwise explicitly check
 163   # for libuuid, or uuid support in the C-library.
 164   PKG_CHECK_MODULES([UUID], [uuid],
 165   [
 166     LIBS="${UUID_LIBS} ${LIBS}"
 167     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 168     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 169     link_with_libuuid=yes
 170   ],
 171   [
 172     # Check for libuuid
 173     AC_CHECK_LIB([uuid], [uuid_generate],
 174     [
 175       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 176       link_with_libuuid=yes
 177     ],
 178     [
 179       # libuuid not found, check for uuid_create in libc.
 180       AC_CHECK_LIB([c], [uuid_create],
 181       [
 182         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 183         link_with_libc_uuid=yes
 184       ],
 185       [
 186         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 187         if test "x$MINGW32" = xno; then
 188           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 189         fi
 190       ])
 191     ])
 192   ])
 193 ])
 194
 195 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 196 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 197
 198 # Check for fmemopen
 199 AC_CHECK_LIB([c], [fmemopen],
 200 [
 201         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 202 ]
 203 )
 204
 205 # Check for open_memstream
 206 AC_CHECK_LIB([c], [open_memstream],
 207 [
 208         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 209 ]
 210 )
 211
 212 # Check for posix_fallocate
 213 AC_CHECK_LIB([c], [posix_fallocate],
 214 [
 215         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 216 ]
 217 )
 218
 219 # Check for faccessat
 220 AC_CHECK_LIB([c], [faccessat],
 221 [
 222         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 223 ]
 224 )
 225
 226 AC_CHECK_LIB([popt], [poptGetContext], [],
 227         [AC_MSG_ERROR([Cannot find popt.])]
 228 )
 229
 230 # For Python
 231 # SWIG version needed or newer:
 232 swig_version=2.0.0
 233
 234 AC_ARG_ENABLE([python-bindings],
 235               [AC_HELP_STRING([--enable-python-bindings],
 236                               [generate Python bindings])],
 237               [enable_python=yes], [enable_python=no])
 238
 239 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 240
 241 if test "x${enable_python:-yes}" = xyes; then
 242   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 243   AM_PATH_PYTHON([3.0], [], [ AC_MSG_ERROR([Python 3.0 or newer is needed]) ])
 244
 245   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 246   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 247   AS_IF([test -z "$PYTHON_INCLUDE"], [
 248     AS_IF([test -z "$PYTHON_CONFIG"], [
 249       AC_PATH_PROGS([PYTHON_CONFIG],
 250                     [python$PYTHON_VERSION-config python-config],
 251                     [no],
 252                     [`dirname $PYTHON`])
 253       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 254     ])
 255     AC_MSG_CHECKING([python include flags])
 256     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 257     AC_MSG_RESULT([$PYTHON_INCLUDE])
 258   ])
 259
 260 else
 261     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 262 [if you want Python bindings.])
 263
 264 fi
 265
 266 # Set default enable state for debug info.
 267 # The _enable_debug_info variable is prepended with an underscore to
 268 # avoid clashing with the one generated by AC_ARG_ENABLE.
 269 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 270
 271 # Optional debug info feature
 272 # Do _not_ indent the help string below (appears in the configure --help
 273 # output).
 274 AC_ARG_ENABLE([debug-info],
 275 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 276 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 277         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 278
 279 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 280 AS_IF([test "x$_enable_debug_info" = xyes], [
 281             # Check if libelf and libdw are present
 282             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 283             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 284             BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 285             AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 286 ], [])
 287
 288 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 289 AC_SUBST(PACKAGE_LIBS)
 290
 291 LIBS="$LIBS $GMODULE_LIBS"
 292 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 293 AC_SUBST(PACKAGE_CFLAGS)
 294
 295 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 296 AC_SUBST(DEFAULT_INCLUDES)
 297
 298 babeltraceincludedir="${includedir}/babeltrace"
 299 AC_SUBST(babeltraceincludedir)
 300
 301 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 302 AC_SUBST(babeltracectfincludedir)
 303
 304 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 305 AC_SUBST(babeltracectfwriterincludedir)
 306
 307 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 308 AC_SUBST(babeltracectfirincludedir)
 309
 310 AC_CONFIG_FILES([
 311         Makefile
 312         types/Makefile
 313         compat/Makefile
 314         formats/Makefile
 315         formats/ctf/Makefile
 316         formats/ctf/types/Makefile
 317         formats/ctf-text/Makefile
 318         formats/ctf-text/types/Makefile
 319         formats/ctf-metadata/Makefile
 320         formats/bt-dummy/Makefile
 321         formats/lttng-live/Makefile
 322         formats/ctf/metadata/Makefile
 323         formats/ctf/writer/Makefile
 324         formats/ctf/ir/Makefile
 325         converter/Makefile
 326         doc/Makefile
 327         lib/Makefile
 328         lib/prio_heap/Makefile
 329         include/Makefile
 330         bindings/Makefile
 331         bindings/python/Makefile
 332         bindings/python/setup.py
 333         bindings/python/babeltrace/Makefile
 334         bindings/python/babeltrace/__init__.py
 335         tests/Makefile
 336         tests/bin/Makefile
 337         tests/bin/intersection/Makefile
 338         tests/lib/Makefile
 339         tests/utils/Makefile
 340         tests/utils/tap/Makefile
 341         extras/Makefile
 342         extras/valgrind/Makefile
 343         babeltrace.pc
 344         babeltrace-ctf.pc
 345 ])
 346
 347 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 348 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 349 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 350 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 351 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 352
 353 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 354 AC_CONFIG_FILES([tests/bin/intersection/test_intersection], [chmod +x tests/bin/intersection/test_intersection])
 355 AC_CONFIG_FILES([tests/bin/intersection/bt_python_helper.py])
 356 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 357
 358 # Create link for Babeltrace complements files for out-of-tree builds
 359 AC_CONFIG_LINKS([
 360         bindings/python/babeltrace/python-complements.c:bindings/python/babeltrace/python-complements.c
 361         bindings/python/babeltrace/python-complements.h:bindings/python/babeltrace/python-complements.h
 362         bindings/python/babeltrace/babeltrace.i.in:bindings/python/babeltrace/babeltrace.i.in
 363 ])
 364
 365 AC_OUTPUT
 366
 367 #
 368 # Mini-report on what will be built.
 369 #
 370
 371 PPRINT_INIT
 372 PPRINT_SET_INDENT(1)
 373 PPRINT_SET_TS(38)
 374
 375 AS_ECHO
 376 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 377 AS_ECHO
 378
 379 PPRINT_SUBTITLE([Features])
 380
 381 # Target architecture we're building for.
 382 target_arch=$host_cpu
 383 [
 384 for f in $CFLAGS; do
 385         if test $f = "-m32"; then
 386                 target_arch="32-bit"
 387         elif test $f = "-m64"; then
 388                 target_arch="64-bit"
 389         fi
 390 done
 391 ]
 392 PPRINT_PROP_STRING([Target architecture], $target_arch)
 393
 394 # python bindings enabled/disabled
 395 test "x$enable_python" = "xyes" && value=1 || value=0
 396 PPRINT_PROP_BOOL([Python bindings], $value)
 397
 398 # python bindings doc enabled/disabled
 399 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 400 PPRINT_PROP_BOOL([Python bindings doc], $value)
 401
 402 # debug info enabled/disabled
 403 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 404 PPRINT_PROP_BOOL([Debug information output], $value)
 405
 406
 407 report_bindir="`eval eval echo $bindir`"
 408 report_libdir="`eval eval echo $libdir`"
 409
 410 # Print the bindir and libdir this `make install' will install into.
 411 AS_ECHO
 412 PPRINT_SUBTITLE([Install directories])
 413 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 414 PPRINT_PROP_STRING([Libraries], [$report_libdir])