configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([babeltrace],[1.0.0-pre2],[mathieu dot desnoyers at efficios dot com])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CANONICAL_TARGET
   7 AC_CANONICAL_HOST
   8 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AM_PROG_MKDIR_P
  14
  15 AC_CONFIG_HEADERS([config.h])
  16
  17 # Checks for programs.
  18 AC_PROG_CC
  19 AC_PROG_MAKE_SET
  20 LT_INIT
  21 AC_PROG_YACC
  22 AC_PROG_LEX
  23
  24 AC_DEFUN([AC_PROG_BISON], [AC_CHECK_PROGS(BISON, bison, bison)])
  25
  26 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  27
  28 # Checks for typedefs, structures, and compiler characteristics.
  29 AC_C_INLINE
  30 AC_TYPE_PID_T
  31 AC_TYPE_SIZE_T
  32
  33 # Checks for library functions.
  34 AC_FUNC_MALLOC
  35 AC_FUNC_MMAP
  36 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  37
  38 # Check for libuuid
  39 AC_CHECK_LIB([uuid], [uuid_generate],
  40 [
  41         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  42         have_libuuid=yes
  43 ],
  44 [
  45         # libuuid not found, check for uuid_create in libc.
  46         AC_CHECK_LIB([c], [uuid_create],
  47         [
  48                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  49                 have_libc_uuid=yes
  50         ],
  51         [
  52                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  53         ])
  54 ]
  55 )
  56 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  57 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  58
  59 AC_CHECK_LIB([popt], [poptGetContext], [],
  60         [AC_MSG_ERROR([Cannot find popt.])]
  61 )
  62
  63 pkg_modules="gmodule-2.0 >= 2.0.0"
  64 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
  65 AC_SUBST(PACKAGE_LIBS)
  66
  67 LIBS="$LIBS $GMODULE_LIBS"
  68 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
  69 AC_SUBST(PACKAGE_CFLAGS)
  70
  71 babeltraceincludedir="${includedir}/babeltrace"
  72 AC_SUBST(babeltraceincludedir)
  73
  74 babeltracectfincludedir="${includedir}/babeltrace/ctf"
  75 AC_SUBST(babeltracectfincludedir)
  76
  77 AC_CONFIG_FILES([
  78         Makefile
  79         types/Makefile
  80         formats/Makefile
  81         formats/ctf/Makefile
  82         formats/ctf/types/Makefile
  83         formats/ctf-text/Makefile
  84         formats/ctf-text/types/Makefile
  85         formats/bt-dummy/Makefile
  86         formats/ctf/metadata/Makefile
  87         converter/Makefile
  88         doc/Makefile
  89         lib/Makefile
  90         lib/prio_heap/Makefile
  91         include/Makefile
  92         tests/Makefile
  93 ])
  94 AC_OUTPUT