configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.2.4],[mathieu dot desnoyers at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 # Checks for C compiler
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_PROG_CC
  25 AC_PROG_CC_STDC
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34
  35 AX_C___ATTRIBUTE__
  36 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  37         [:],
  38         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Check linker option
  41 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  42 AC_SUBST([LD_NO_AS_NEEDED])
  43
  44 AC_CHECK_HEADERS([fcntl.h limits.h netdb.h netinet/in.h stddef.h sys/socket.h])
  45
  46 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  47         if test x"$YACC" != "xbison -y"; then
  48                 AC_MSG_ERROR([[bison not found and is required when building from git.
  49                 Please install bison]])
  50         fi
  51         AC_PATH_PROG([BISON],[bison])
  52         AX_PROG_BISON_VERSION([2.4], [],[
  53                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  54         ])
  55 fi
  56
  57 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  58         if test x"$LEX" != "xflex"; then
  59                 AC_MSG_ERROR([[flex not found and is required when building from git.
  60                 Please install flex]])
  61         fi
  62         AC_PATH_PROG([FLEX],[flex])
  63         AX_PROG_FLEX_VERSION([2.5.35], [],[
  64                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  65         ])
  66 fi
  67
  68
  69 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  70
  71 # Checks for typedefs, structures, and compiler characteristics.
  72 AC_C_INLINE
  73 AC_TYPE_PID_T
  74 AC_TYPE_SIZE_T
  75
  76 # Checks for library functions.
  77 AC_FUNC_MALLOC
  78 AC_FUNC_MMAP
  79 AC_CHECK_FUNCS([gettimeofday munmap strtoul])
  80
  81 # Check for MinGW32.
  82 MINGW32=no
  83 case $host in
  84   *-*-mingw*)
  85         MINGW32=yes;;
  86 esac
  87
  88 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  89
  90 # Check what libraries are required on this platform to link sockets programs.
  91 AX_LIB_SOCKET_NSL
  92
  93 # Check for libuuid
  94 AC_CHECK_LIB([uuid], [uuid_generate],
  95 [
  96         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  97         have_libuuid=yes
  98 ],
  99 [
 100         # libuuid not found, check for uuid_create in libc.
 101         AC_CHECK_LIB([c], [uuid_create],
 102         [
 103                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 104                 have_libc_uuid=yes
 105         ],
 106         [
 107                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 108                 if test "x$MINGW32" = xno; then
 109                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 110                 fi
 111         ])
 112 ]
 113 )
 114 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 115 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 116
 117 # Check for fmemopen
 118 AC_CHECK_LIB([c], [fmemopen],
 119 [
 120         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 121 ]
 122 )
 123
 124 # Check for open_memstream
 125 AC_CHECK_LIB([c], [open_memstream],
 126 [
 127         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 128 ]
 129 )
 130
 131 AC_CHECK_LIB([popt], [poptGetContext], [],
 132         [AC_MSG_ERROR([Cannot find popt.])]
 133 )
 134
 135
 136 # For Python
 137 # SWIG version needed or newer:
 138 swig_version=2.0.0
 139
 140 AC_ARG_ENABLE([python-bindings],
 141               [AC_HELP_STRING([--enable-python-bindings],
 142                               [generate Python bindings])],
 143               [enable_python=yes], [enable_python=no])
 144
 145 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 146
 147 if test "x${enable_python:-yes}" = xyes; then
 148   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 149   AM_PATH_PYTHON
 150
 151   AM_PATH_PYTHON_MODULES([PYTHON])
 152   # pythondir is the path where extra modules are to be installed
 153   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 154   # pyexecdir is the path that contains shared objects used by the extra modules
 155   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 156   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 157   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 158   AS_IF([test -z "$PYTHON_INCLUDE"], [
 159     AS_IF([test -z "$PYTHON_CONFIG"], [
 160       AC_PATH_PROGS([PYTHON_CONFIG],
 161                     [python$PYTHON_VERSION-config python-config],
 162                     [no],
 163                     [`dirname $PYTHON`])
 164       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 165     ])
 166     AC_MSG_CHECKING([python include flags])
 167     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 168     AC_MSG_RESULT([$PYTHON_INCLUDE])
 169   ])
 170
 171 else
 172     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 173 [if you want Python bindings.])
 174
 175 fi
 176
 177 pkg_modules="gmodule-2.0 >= 2.0.0"
 178 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 179 AC_SUBST(PACKAGE_LIBS)
 180
 181 LIBS="$LIBS $GMODULE_LIBS"
 182 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 183 AC_SUBST(PACKAGE_CFLAGS)
 184
 185 babeltraceincludedir="${includedir}/babeltrace"
 186 AC_SUBST(babeltraceincludedir)
 187
 188 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 189 AC_SUBST(babeltracectfincludedir)
 190
 191 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 192 AC_SUBST(babeltracectfwriterincludedir)
 193
 194 AC_CONFIG_FILES([
 195         Makefile
 196         types/Makefile
 197         compat/Makefile
 198         formats/Makefile
 199         formats/ctf/Makefile
 200         formats/ctf/types/Makefile
 201         formats/ctf-text/Makefile
 202         formats/ctf-text/types/Makefile
 203         formats/ctf-metadata/Makefile
 204         formats/bt-dummy/Makefile
 205         formats/lttng-live/Makefile
 206         formats/ctf/metadata/Makefile
 207         formats/ctf/writer/Makefile
 208         converter/Makefile
 209         doc/Makefile
 210         lib/Makefile
 211         lib/prio_heap/Makefile
 212         include/Makefile
 213         bindings/Makefile
 214         bindings/python/Makefile
 215         tests/Makefile
 216         tests/bin/Makefile
 217         tests/lib/Makefile
 218         tests/utils/Makefile
 219         tests/utils/tap/Makefile
 220         extras/Makefile
 221         extras/valgrind/Makefile
 222         babeltrace.pc
 223         babeltrace-ctf.pc
 224 ])
 225 AC_OUTPUT