Build: add version check on flex
[babeltrace.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4 AC_PREREQ([2.50])
5 AC_INIT([babeltrace],[1.2.4],[mathieu dot desnoyers at efficios dot com])
6
7 # Following the numbering scheme proposed by libtool for the library version
8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
10
11 AC_CONFIG_AUX_DIR([config])
12 AC_CANONICAL_TARGET
13 AC_CANONICAL_HOST
14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_CONFIG_MACRO_DIR([m4])
18
19 AC_PROG_MKDIR_P
20
21 AC_CONFIG_HEADERS([config.h])
22
23 AC_SYS_LARGEFILE
24
25 # Checks for programs.
26 AC_PROG_CC_STDC
27 AC_PROG_MAKE_SET
28 LT_INIT
29 AC_PROG_YACC
30 AC_PROG_LEX
31
32 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
33 if test x"$YACC" != "xbison -y"; then
34 AC_MSG_ERROR([[bison not found and is required when building from git.
35 Please install bison]])
36 fi
37 AC_PATH_PROG([BISON],[bison])
38 AX_PROG_BISON_VERSION([2.4], [],[
39 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
40 ])
41 fi
42
43 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
44 if test x"$LEX" != "xflex"; then
45 AC_MSG_ERROR([[flex not found and is required when building from git.
46 Please install flex]])
47 fi
48 AC_PATH_PROG([FLEX],[flex])
49 AX_PROG_FLEX_VERSION([2.5.35], [],[
50 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
51 ])
52 fi
53
54
55 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
56
57 # Checks for typedefs, structures, and compiler characteristics.
58 AC_C_INLINE
59 AC_TYPE_PID_T
60 AC_TYPE_SIZE_T
61
62 # Checks for library functions.
63 AC_FUNC_MALLOC
64 AC_FUNC_MMAP
65 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
66
67 # Check for MinGW32.
68 MINGW32=no
69 case $host in
70 *-*-mingw*)
71 MINGW32=yes;;
72 esac
73
74 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
75
76 # Check for libuuid
77 AC_CHECK_LIB([uuid], [uuid_generate],
78 [
79 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
80 have_libuuid=yes
81 ],
82 [
83 # libuuid not found, check for uuid_create in libc.
84 AC_CHECK_LIB([c], [uuid_create],
85 [
86 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
87 have_libc_uuid=yes
88 ],
89 [
90 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
91 if test "x$MINGW32" = xno; then
92 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
93 fi
94 ])
95 ]
96 )
97 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
98 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
99
100 # Check for fmemopen
101 AC_CHECK_LIB([c], [fmemopen],
102 [
103 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
104 ]
105 )
106
107 # Check for open_memstream
108 AC_CHECK_LIB([c], [open_memstream],
109 [
110 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
111 ]
112 )
113
114 AC_CHECK_LIB([popt], [poptGetContext], [],
115 [AC_MSG_ERROR([Cannot find popt.])]
116 )
117
118
119 # For Python
120 # SWIG version needed or newer:
121 swig_version=2.0.0
122
123 AC_ARG_ENABLE([python-bindings],
124 [AC_HELP_STRING([--enable-python-bindings],
125 [generate Python bindings])],
126 [enable_python=yes], [enable_python=no])
127
128 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
129
130 if test "x${enable_python:-yes}" = xyes; then
131 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
132 AM_PATH_PYTHON
133
134 AM_PATH_PYTHON_MODULES([PYTHON])
135 # pythondir is the path where extra modules are to be installed
136 pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
137 # pyexecdir is the path that contains shared objects used by the extra modules
138 pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
139 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
140 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
141 AS_IF([test -z "$PYTHON_INCLUDE"], [
142 AS_IF([test -z "$PYTHON_CONFIG"], [
143 AC_PATH_PROGS([PYTHON_CONFIG],
144 [python$PYTHON_VERSION-config python-config],
145 [no],
146 [`dirname $PYTHON`])
147 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
148 ])
149 AC_MSG_CHECKING([python include flags])
150 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
151 AC_MSG_RESULT([$PYTHON_INCLUDE])
152 ])
153
154 else
155 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
156 [if you want Python bindings.])
157
158 fi
159
160 pkg_modules="gmodule-2.0 >= 2.0.0"
161 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
162 AC_SUBST(PACKAGE_LIBS)
163
164 LIBS="$LIBS $GMODULE_LIBS"
165 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
166 AC_SUBST(PACKAGE_CFLAGS)
167
168 babeltraceincludedir="${includedir}/babeltrace"
169 AC_SUBST(babeltraceincludedir)
170
171 babeltracectfincludedir="${includedir}/babeltrace/ctf"
172 AC_SUBST(babeltracectfincludedir)
173
174 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
175 AC_SUBST(babeltracectfwriterincludedir)
176
177 AC_CONFIG_FILES([
178 Makefile
179 types/Makefile
180 compat/Makefile
181 formats/Makefile
182 formats/ctf/Makefile
183 formats/ctf/types/Makefile
184 formats/ctf-text/Makefile
185 formats/ctf-text/types/Makefile
186 formats/ctf-metadata/Makefile
187 formats/bt-dummy/Makefile
188 formats/lttng-live/Makefile
189 formats/ctf/metadata/Makefile
190 formats/ctf/writer/Makefile
191 converter/Makefile
192 doc/Makefile
193 lib/Makefile
194 lib/prio_heap/Makefile
195 include/Makefile
196 bindings/Makefile
197 bindings/python/Makefile
198 tests/Makefile
199 tests/bin/Makefile
200 tests/lib/Makefile
201 tests/utils/Makefile
202 tests/utils/tap/Makefile
203 extras/Makefile
204 extras/valgrind/Makefile
205 babeltrace.pc
206 babeltrace-ctf.pc
207 ])
208 AC_OUTPUT
This page took 0.033231 seconds and 4 git commands to generate.