configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([babeltrace],[1.2.4],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   9
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CANONICAL_TARGET
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  14 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  15
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 AC_PROG_MKDIR_P
  19
  20 AC_CONFIG_HEADERS([config.h])
  21
  22 AC_SYS_LARGEFILE
  23
  24 # Checks for programs.
  25 AC_PROG_CC_STDC
  26 AC_PROG_MAKE_SET
  27 LT_INIT
  28 AC_PROG_YACC
  29 AC_PROG_LEX
  30
  31 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  32         if test x"$YACC" != "xbison -y"; then
  33                 AC_MSG_ERROR([[bison not found and is required when building from git.
  34                 Please install bison]])
  35         fi
  36 fi
  37
  38 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  39         if test x"$LEX" != "xflex"; then
  40                 AC_MSG_ERROR([[flex not found and is required when building from git.
  41                 Please install flex]])
  42         fi
  43 fi
  44
  45
  46 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  47
  48 # Checks for typedefs, structures, and compiler characteristics.
  49 AC_C_INLINE
  50 AC_TYPE_PID_T
  51 AC_TYPE_SIZE_T
  52
  53 # Checks for library functions.
  54 AC_FUNC_MALLOC
  55 AC_FUNC_MMAP
  56 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  57
  58 # Check for MinGW32.
  59 MINGW32=no
  60 case $host in
  61   *-*-mingw*)
  62         MINGW32=yes;;
  63 esac
  64
  65 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  66
  67 # Check for libuuid
  68 AC_CHECK_LIB([uuid], [uuid_generate],
  69 [
  70         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
  71         have_libuuid=yes
  72 ],
  73 [
  74         # libuuid not found, check for uuid_create in libc.
  75         AC_CHECK_LIB([c], [uuid_create],
  76         [
  77                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  78                 have_libc_uuid=yes
  79         ],
  80         [
  81                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
  82                 if test "x$MINGW32" = xno; then
  83                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  84                 fi
  85         ])
  86 ]
  87 )
  88 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  89 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  90
  91 # Check for fmemopen
  92 AC_CHECK_LIB([c], [fmemopen],
  93 [
  94         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
  95 ]
  96 )
  97
  98 # Check for open_memstream
  99 AC_CHECK_LIB([c], [open_memstream],
 100 [
 101         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 102 ]
 103 )
 104
 105 AC_CHECK_LIB([popt], [poptGetContext], [],
 106         [AC_MSG_ERROR([Cannot find popt.])]
 107 )
 108
 109
 110 # For Python
 111 # SWIG version needed or newer:
 112 swig_version=2.0.0
 113
 114 AC_ARG_ENABLE([python-bindings],
 115               [AC_HELP_STRING([--enable-python-bindings],
 116                               [generate Python bindings])],
 117               [enable_python=yes], [enable_python=no])
 118
 119 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 120
 121 if test "x${enable_python:-yes}" = xyes; then
 122   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 123   AM_PATH_PYTHON
 124
 125   AM_PATH_PYTHON_MODULES([PYTHON])
 126   # pythondir is the path where extra modules are to be installed
 127   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 128   # pyexecdir is the path that contains shared objects used by the extra modules
 129   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 130   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 131   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 132   AS_IF([test -z "$PYTHON_INCLUDE"], [
 133     AS_IF([test -z "$PYTHON_CONFIG"], [
 134       AC_PATH_PROGS([PYTHON_CONFIG],
 135                     [python$PYTHON_VERSION-config python-config],
 136                     [no],
 137                     [`dirname $PYTHON`])
 138       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 139     ])
 140     AC_MSG_CHECKING([python include flags])
 141     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 142     AC_MSG_RESULT([$PYTHON_INCLUDE])
 143   ])
 144
 145 else
 146     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 147 [if you want Python bindings.])
 148
 149 fi
 150
 151 pkg_modules="gmodule-2.0 >= 2.0.0"
 152 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 153 AC_SUBST(PACKAGE_LIBS)
 154
 155 LIBS="$LIBS $GMODULE_LIBS"
 156 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 157 AC_SUBST(PACKAGE_CFLAGS)
 158
 159 babeltraceincludedir="${includedir}/babeltrace"
 160 AC_SUBST(babeltraceincludedir)
 161
 162 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 163 AC_SUBST(babeltracectfincludedir)
 164
 165 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 166 AC_SUBST(babeltracectfwriterincludedir)
 167
 168 AC_CONFIG_FILES([
 169         Makefile
 170         types/Makefile
 171         compat/Makefile
 172         formats/Makefile
 173         formats/ctf/Makefile
 174         formats/ctf/types/Makefile
 175         formats/ctf-text/Makefile
 176         formats/ctf-text/types/Makefile
 177         formats/ctf-metadata/Makefile
 178         formats/bt-dummy/Makefile
 179         formats/lttng-live/Makefile
 180         formats/ctf/metadata/Makefile
 181         formats/ctf/writer/Makefile
 182         converter/Makefile
 183         doc/Makefile
 184         lib/Makefile
 185         lib/prio_heap/Makefile
 186         include/Makefile
 187         bindings/Makefile
 188         bindings/python/Makefile
 189         tests/Makefile
 190         tests/bin/Makefile
 191         tests/lib/Makefile
 192         tests/utils/Makefile
 193         tests/utils/tap/Makefile
 194         extras/Makefile
 195         extras/valgrind/Makefile
 196         babeltrace.pc
 197         babeltrace-ctf.pc
 198 ])
 199 AC_OUTPUT