configure.ac

   1 AC_PREREQ([2.50])
   2 m4_define([bt_version_major], [2])
   3 m4_define([bt_version_minor], [0])
   4 m4_define([bt_version_patch], [0])
   5 m4_define([bt_version_extra], [-pre3])
   6 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
   7 AC_INIT([babeltrace],bt_version,[jeremie dot galarneau at efficios dot com])
   8
   9 # Following the numbering scheme proposed by libtool for the library version
  10 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  11 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_version_major[:]bt_version_minor[:]bt_version_patch)
  12
  13 AC_CONFIG_HEADERS([include/config.h])
  14 AC_CONFIG_AUX_DIR([config])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace library major version])
  18 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace library minor version])
  19 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace library patch version])
  20 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace library extra version])
  21
  22 AC_CANONICAL_TARGET
  23 AC_CANONICAL_HOST
  24
  25 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  26 AM_MAINTAINER_MODE([enable])
  27
  28 # Enable silent rules if available (Introduced in AM 1.11)
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30
  31 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  32
  33 # Checks for C compiler
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PROG_CC
  37 AC_PROG_CC_STDC
  38
  39 # Checks for programs.
  40 AC_PROG_MAKE_SET
  41 LT_INIT(win32-dll)
  42 AC_PROG_YACC
  43 AC_PROG_LEX
  44 AC_PROG_MKDIR_P
  45 AC_PROG_LN_S
  46
  47 AX_C___ATTRIBUTE__
  48 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  49         [:],
  50         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  51
  52 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  53
  54 # Check linker option
  55 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  56 AC_SUBST([LD_NO_AS_NEEDED])
  57
  58 AC_HEADER_STDBOOL
  59 AC_CHECK_HEADERS([ \
  60         fcntl.h \
  61         float.h \
  62         ftw.h \
  63         libintl.h \
  64         limits.h \
  65         malloc.h \
  66         netdb.h \
  67         netinet/in.h \
  68         stddef.h \
  69         sys/socket.h \
  70 ])
  71
  72 if test ! -f "$srcdir/plugins/ctf/common/metadata/parser.h"; then
  73         if test x"$(basename "$YACC")" != "xbison -y"; then
  74                 AC_MSG_ERROR([[bison not found and is required when building from git.
  75                 Please install bison]])
  76         fi
  77         AC_PATH_PROG([BISON],[bison])
  78         AX_PROG_BISON_VERSION([2.4], [],[
  79                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  80         ])
  81 fi
  82
  83 if test ! -f "$srcdir/plugins/ctf/common/metadata/lexer.c"; then
  84         if test x"$LEX" != "xflex"; then
  85                 AC_MSG_ERROR([[flex not found and is required when building from git.
  86                 Please install flex]])
  87         fi
  88         AC_PATH_PROG([FLEX],[flex])
  89         AX_PROG_FLEX_VERSION([2.5.35], [],[
  90                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  91         ])
  92 fi
  93
  94
  95 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule-no-export)
  96
  97 # Check what libraries are required on this platform to link sockets programs.
  98 AX_LIB_SOCKET_NSL
  99
 100 # Checks for typedefs, structures, and compiler characteristics.
 101 AC_C_INLINE
 102 AC_TYPE_PID_T
 103 AC_TYPE_SIZE_T
 104 AC_TYPE_INT16_T
 105 AC_TYPE_INT32_T
 106 AC_TYPE_INT64_T
 107 AC_TYPE_INT8_T
 108 AC_TYPE_OFF_T
 109 AC_TYPE_SSIZE_T
 110 AC_TYPE_UINT16_T
 111 AC_TYPE_UINT32_T
 112 AC_TYPE_UINT64_T
 113 AC_TYPE_UINT8_T
 114
 115 # Checks for library functions.
 116 AC_FUNC_ALLOCA
 117 AC_FUNC_FORK
 118 AC_FUNC_MKTIME
 119 AC_FUNC_MMAP
 120 AC_FUNC_STRERROR_R
 121 AC_CHECK_FUNCS([ \
 122         atexit \
 123         dup2 \
 124         ftruncate \
 125         gethostbyname \
 126         gethostname \
 127         gettimeofday \
 128         localtime_r \
 129         memchr \
 130         memset \
 131         mkdir \
 132         mkdtemp \
 133         munmap \
 134         rmdir \
 135         setenv \
 136         socket \
 137         strchr \
 138         strdup \
 139         strerror \
 140         strndup \
 141         strnlen \
 142         strrchr \
 143         strtoul \
 144         strtoull \
 145         tzset \
 146         uname \
 147 ])
 148
 149 # AC_FUNC_MALLOC causes problems when cross-compiling.
 150 #AC_FUNC_MALLOC
 151 #AC_FUNC_REALLOC
 152
 153 MINGW32=no
 154 DEFAULT_ENABLE_DEBUG_INFO=yes
 155 LT_NO_UNDEFINED=""
 156 AS_CASE([$host_os],
 157   [solaris*|darwin*],
 158     [
 159         DEFAULT_ENABLE_DEBUG_INFO=no
 160     ],
 161   [cygwin*],
 162     [
 163         DEFAULT_ENABLE_DEBUG_INFO=no
 164         LT_NO_UNDEFINED="-no-undefined"
 165     ],
 166   [mingw*],
 167     [
 168         MINGW32=yes
 169         DEFAULT_ENABLE_DEBUG_INFO=no
 170         LT_NO_UNDEFINED="-no-undefined"
 171     ]
 172 )
 173
 174 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 175 AC_SUBST(LT_NO_UNDEFINED)
 176
 177 # Check for uuid in system libs
 178 AC_CHECK_FUNCS([uuid_generate],
 179 [
 180   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 181   link_with_libuuid=no
 182 ],
 183 [
 184   # First, check the pkg-config module is available, otherwise explicitly check
 185   # for libuuid, or uuid support in the C-library.
 186   PKG_CHECK_MODULES([UUID], [uuid],
 187   [
 188     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 189     link_with_libuuid=yes
 190   ],
 191   [
 192     # Check for libuuid
 193     AC_CHECK_LIB([uuid], [uuid_generate],
 194     [
 195       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 196       link_with_libuuid=yes
 197     ],
 198     [
 199       # libuuid not found, check for uuid_create in libc.
 200       AC_CHECK_LIB([c], [uuid_create],
 201       [
 202         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 203         link_with_libc_uuid=yes
 204       ],
 205       [
 206         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 207         if test "x$MINGW32" = xno; then
 208           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 209         fi
 210       ])
 211     ])
 212   ])
 213 ])
 214
 215 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 216 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 217
 218 # Check for fmemopen
 219 AC_CHECK_LIB([c], [fmemopen],
 220 [
 221         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 222 ]
 223 )
 224
 225 # Check for open_memstream
 226 AC_CHECK_LIB([c], [open_memstream],
 227 [
 228         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 229 ]
 230 )
 231
 232 # Check for posix_fallocate
 233 AC_CHECK_LIB([c], [posix_fallocate],
 234 [
 235         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 236 ]
 237 )
 238
 239 # Check libpopt
 240 PKG_CHECK_MODULES([POPT], [popt],
 241   [
 242     dnl PKG_CHECK_MODULES defines POPT_LIBS
 243   ],
 244   [
 245     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 246     AC_MSG_WARN([Finding libpopt without pkg-config.])
 247     AC_CHECK_LIB([popt],
 248       [poptGetContext],
 249       [POPT_LIBS="-lpopt"],
 250       [
 251         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 252       ]
 253     )
 254   ]
 255 )
 256 AC_SUBST(POPT_LIBS)
 257
 258 # Plugins
 259 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 260 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 261
 262 # For Python
 263 # SWIG version needed or newer:
 264 swig_version=2.0.0
 265
 266 AC_ARG_ENABLE([python-bindings],
 267               [AC_HELP_STRING([--enable-python-bindings],
 268                               [generate Python bindings])],
 269               [enable_python_bindings=$enableval], [enable_python_bindings=no])
 270
 271 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python_bindings:-yes}" = xyes])
 272
 273 AC_ARG_ENABLE(
 274         [python-plugins],
 275         [AC_HELP_STRING(
 276                 [--enable-python-plugins],
 277                 [add support for the Babeltrace library and converter to load Python plugins])
 278         ],
 279         [enable_python_plugins=$enableval],
 280         [enable_python_plugins=no]
 281 )
 282
 283 if test "x${enable_python_bindings:-yes}" = xyes; then
 284   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 285 else
 286     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 287 [if you want Python bindings.])
 288 fi
 289
 290 if test "x$enable_python_bindings" != xno || test "x$enable_python_plugins" != xno; then
 291   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python 3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 292
 293   AM_PATH_PYTHON_MODULES([PYTHON])
 294   # pythondir is the path where extra modules are to be installed
 295   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 296   # pyexecdir is the path that contains shared objects used by the extra modules
 297   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 298   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 299   AC_ARG_VAR([PYTHON_LIBS], [Library flags for Python, bypassing python-config])
 300   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 301   AS_IF([test -z "$PYTHON_INCLUDE"], [
 302     AS_IF([test -z "$PYTHON_CONFIG"], [
 303       AC_PATH_PROGS([PYTHON_CONFIG],
 304                     [python$PYTHON_VERSION-config python-config],
 305                     [no],
 306                     [`dirname $PYTHON`])
 307       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 308     ])
 309     AC_MSG_CHECKING([Python include flags])
 310     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 311     AC_MSG_RESULT([$PYTHON_INCLUDE])
 312   ])
 313   AS_IF([test -z "$PYTHON_LIBS"], [
 314     AS_IF([test -z "$PYTHON_CONFIG"], [
 315       AC_PATH_PROGS([PYTHON_CONFIG],
 316                     [python$PYTHON_VERSION-config python-config],
 317                     [no],
 318                     [`dirname $PYTHON`])
 319       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 320     ])
 321     AC_MSG_CHECKING([Python library flags])
 322     PYTHON_LIBS=`$PYTHON_CONFIG --libs`
 323     AC_MSG_RESULT([$PYTHON_LIBS])
 324   ])
 325 fi
 326
 327 AS_IF([test "x$BUILT_IN_PLUGINS" = ""])
 328
 329 AM_CONDITIONAL([WITH_PYTHON_PLUGINS], [test "x$enable_python_plugins" != xno])
 330 AS_IF(
 331   [test "x$enable_python_plugins" != xno],
 332   AC_DEFINE_UNQUOTED([WITH_PYTHON_PLUGINS], [1], [Python plugin support.])
 333 )
 334
 335 AC_ARG_ENABLE([python-bindings-doc],
 336               [AC_HELP_STRING([--enable-python-bindings-doc],
 337                               [generate Python bindings documentation])],
 338               [enable_python_bindings_doc=$enableval], [enable_python_bindings_doc=no])
 339
 340 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 341
 342 AC_ARG_ENABLE([python-bindings-tests],
 343               [AC_HELP_STRING([--enable-python-bindings-tests],
 344                               [test Python bindings])],
 345               [enable_python_bindings_tests=$enableval], [enable_python_bindings_tests=no])
 346
 347 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 348
 349 if test "x${enable_python_bindings:-no}" = xno; then
 350   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 351     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 352   fi
 353
 354   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 355     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 356   fi
 357 fi
 358
 359 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 360     AM_CHECK_PYTHON_SPHINX([PYTHON])
 361     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 362       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 363     )
 364 fi
 365
 366 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 367     AM_CHECK_PYTHON_TAPPY([PYTHON])
 368     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 369         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 370     )
 371 fi
 372
 373 # Set default enable state for debug info.
 374 # The _enable_debug_info variable is prepended with an underscore to
 375 # avoid clashing with the one generated by AC_ARG_ENABLE.
 376 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 377
 378 # Optional debug info feature
 379 # Do _not_ indent the help string below (appears in the configure --help
 380 # output).
 381 AC_ARG_ENABLE([debug-info],
 382 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 383 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 384         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 385
 386 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 387
 388 AS_IF([test "x$_enable_debug_info" = xyes], [
 389         # Check if libelf and libdw are present
 390         AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 391         AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 392         BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 393         AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 394 ], [])
 395
 396 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 397 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 398 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 399         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 400         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 401         built_in_plugins=yes
 402         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 403 ])
 404 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 405
 406 AC_ARG_VAR([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [Statically-link Python plugin support into the babeltrace library])
 407 AS_IF([test "x$BUILT_IN_PYTHON_PLUGIN_SUPPORT" != x], [
 408 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 409   AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace executable)])
 410   AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace executable)])
 411   AS_IF([test "x$enable_python_plugins" = "xno"], [
 412     AC_MSG_ERROR([You can't use BUILT_IN_PYTHON_PLUGIN_SUPPORT=1 without --enable-python-plugins.])
 413   ])
 414   built_in_python_plugin_support=yes
 415   AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])
 416 ])
 417 AM_CONDITIONAL([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$built_in_python_plugin_support" = "xyes"])
 418
 419 PKG_CHECK_MODULES(GMODULE, [gmodule-no-export-2.0 >= 2.0.0])
 420
 421 # Logging
 422 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (VERBOSE, DEBUG, INFO, WARN, ERROR (default), FATAL, or NONE)])
 423 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = "x"], [BABELTRACE_MINIMAL_LOG_LEVEL=VERBOSE])
 424 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "VERBOSE" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "WARN" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "ERROR" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "FATAL" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "NONE"], [
 425         AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use VERBOSE, DEBUG, INFO, WARN, ERROR, FATAL, or NONE.])
 426 ])
 427 AC_DEFINE_UNQUOTED([BT_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 428
 429 AM_CFLAGS="-Wall -Wformat $PTHREAD_CFLAGS $GLIB_CFLAGS"
 430 AC_SUBST(AM_CFLAGS)
 431
 432 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 433 AC_SUBST(AM_CPPFLAGS)
 434
 435 LIBS="$GLIB_LIBS"
 436
 437 babeltraceincludedir="${includedir}/babeltrace"
 438 AC_SUBST(babeltraceincludedir)
 439
 440 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 441 AC_SUBST(babeltracectfwriterincludedir)
 442
 443 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 444 AC_SUBST(babeltracectfincludedir)
 445
 446 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 447 AC_SUBST(babeltracectfirincludedir)
 448
 449 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 450 AC_SUBST(babeltracepluginincludedir)
 451
 452 babeltracegraphincludedir="${includedir}/babeltrace/graph"
 453 AC_SUBST(babeltracegraphincludedir)
 454
 455 program_transform_name="s&babeltrace\.bin&babeltrace&;s&babeltrace-log\.bin&babeltrace-log&;$program_transform_name"
 456 AC_SUBST(program_transform_name)
 457
 458 # check for Doxygen
 459 AC_ARG_ENABLE(
 460   [api-doc],
 461   [AC_HELP_STRING(
 462     [--enable-api-doc],
 463     [generate and install HTML API documentation]
 464   )],
 465   [enable_api_doc=$enableval],
 466   [enable_api_doc=no]
 467 )
 468 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 469
 470 AS_IF([test "x$enable_api_doc" = "xyes"], [
 471   DX_DOXYGEN_FEATURE(ON)
 472   DX_DOT_FEATURE(OFF)
 473   DX_HTML_FEATURE(ON)
 474   DX_CHM_FEATURE(OFF)
 475   DX_CHI_FEATURE(OFF)
 476   DX_MAN_FEATURE(OFF)
 477   DX_RTF_FEATURE(OFF)
 478   DX_XML_FEATURE(OFF)
 479   DX_PDF_FEATURE(OFF)
 480   DX_PS_FEATURE(OFF)
 481   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 482 ])
 483
 484         #TODO: removed, work in progress
 485         #bindings/python/Makefile
 486         #bindings/python/babeltrace/Makefile
 487         #bindings/python/bt2/Makefile
 488         #bindings/python/bt2/__init__.py
 489 AC_CONFIG_FILES([
 490         Makefile
 491         common/Makefile
 492         compat/Makefile
 493         cli/Makefile
 494         doc/Makefile
 495         doc/api/Makefile
 496         doc/api/Doxyfile
 497         doc/bindings/Makefile
 498         doc/bindings/python/Makefile
 499         doc/images/Makefile
 500         lib/Makefile
 501         lib/prio_heap/Makefile
 502         lib/plugin/Makefile
 503         lib/graph/Makefile
 504         lib/graph/notification/Makefile
 505         lib/ctf-ir/Makefile
 506         lib/ctf-writer/Makefile
 507         include/Makefile
 508         logging/Makefile
 509         bindings/Makefile
 510         tests/Makefile
 511         tests/cli/Makefile
 512         tests/cli/intersection/Makefile
 513         tests/lib/Makefile
 514         tests/lib/writer/Makefile
 515         tests/lib/test-plugin-plugins/Makefile
 516         tests/utils/Makefile
 517         tests/utils/tap/Makefile
 518         tests/bindings/Makefile
 519         tests/bindings/python/Makefile
 520         tests/bindings/python/bt2/Makefile
 521         tests/plugins/Makefile
 522         extras/Makefile
 523         extras/valgrind/Makefile
 524         plugins/Makefile
 525         plugins/ctf/Makefile
 526         plugins/ctf/common/Makefile
 527         plugins/ctf/common/btr/Makefile
 528         plugins/ctf/common/metadata/Makefile
 529         plugins/ctf/common/notif-iter/Makefile
 530         plugins/ctf/fs-src/Makefile
 531         plugins/ctf/fs-sink/Makefile
 532         plugins/ctf/lttng-live/Makefile
 533         plugins/text/Makefile
 534   plugins/text/dmesg/Makefile
 535         plugins/text/pretty/Makefile
 536         plugins/utils/Makefile
 537         plugins/utils/dummy/Makefile
 538         plugins/utils/counter/Makefile
 539         plugins/utils/trimmer/Makefile
 540         plugins/utils/muxer/Makefile
 541         python-plugin-provider/Makefile
 542         plugins/libctfcopytrace/Makefile
 543         plugins/lttng-utils/Makefile
 544         babeltrace.pc
 545         babeltrace-ctf.pc
 546 ])
 547
 548 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 549 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 550 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 551 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 552 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 553
 554 AC_CONFIG_FILES([tests/plugins/test-utils-muxer-complete], [chmod +x tests/plugins/test-utils-muxer-complete])
 555
 556 AC_CONFIG_FILES([tests/cli/test_trace_read], [chmod +x tests/cli/test_trace_read])
 557 AC_CONFIG_FILES([tests/cli/test_trace_copy], [chmod +x tests/cli/test_trace_copy])
 558 AC_CONFIG_FILES([tests/cli/test_debug_info], [chmod +x tests/cli/test_debug_info])
 559 AC_CONFIG_FILES([tests/cli/test_trimmer], [chmod +x tests/cli/test_trimmer])
 560 AC_CONFIG_FILES([tests/cli/intersection/test_intersection], [chmod +x tests/cli/intersection/test_intersection])
 561 AC_CONFIG_FILES([tests/cli/test_convert_args], [chmod +x tests/cli/test_convert_args])
 562 AC_CONFIG_FILES([tests/cli/intersection/bt_python_helper.py])
 563 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 564 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_empty_packet.py])
 565 AC_CONFIG_FILES([tests/lib/writer/test_ctf_writer_no_packet_context.py])
 566 AC_CONFIG_FILES([tests/cli/test_packet_seq_num], [chmod +x tests/cli/test_packet_seq_num])
 567
 568 AS_IF([test "x$enable_python" = "xyes"], [
 569         AC_CONFIG_FILES(
 570                 [tests/bindings/python/bt2/testall.sh],
 571                 [chmod +x tests/bindings/python/bt2/testall.sh]
 572         )
 573 ])
 574
 575 AC_OUTPUT
 576
 577 #
 578 # Mini-report on what will be built.
 579 #
 580
 581 PPRINT_INIT
 582 PPRINT_SET_INDENT(1)
 583 PPRINT_SET_TS(38)
 584
 585 AS_ECHO
 586 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 587 AS_ECHO
 588
 589 PPRINT_SUBTITLE([System])
 590
 591 # Target architecture we're building for.
 592 target_arch=$host_cpu
 593 [
 594 for f in $CFLAGS; do
 595         if test $f = "-m32"; then
 596                 target_arch="32-bit"
 597         elif test $f = "-m64"; then
 598                 target_arch="64-bit"
 599         fi
 600 done
 601 ]
 602
 603 PPRINT_PROP_STRING([Target architecture], $target_arch)
 604
 605 AS_ECHO
 606 PPRINT_SUBTITLE([Python 3 language support])
 607 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 608 PPRINT_PROP_BOOL([Python bindings], $value)
 609 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 610 PPRINT_PROP_BOOL([Python plugin support], $value)
 611 AS_IF([test "x$enable_python_bindings" = "xyes" || test "x$enable_python_plugins" = "xyes"], [
 612   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 613   PPRINT_PROP_STRING([Python libraries], [$PYTHON_LIBS])
 614 ])
 615
 616 AS_ECHO
 617 PPRINT_SUBTITLE([Plugins])
 618 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 619 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 620 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 621 PPRINT_PROP_BOOL(['text' plugin], 1)
 622 PPRINT_PROP_BOOL(['utils' plugin], 1)
 623
 624 AS_ECHO
 625 PPRINT_SUBTITLE([Built-in features])
 626 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 627 PPRINT_PROP_BOOL([Built-in plugins], $value)
 628 test "x$built_in_python_plugin_support" = "xyes" && value=1 || value=0
 629 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 630
 631 AS_ECHO
 632 PPRINT_SUBTITLE([Documentation])
 633 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 634 PPRINT_PROP_BOOL([HTML API documentation], $value)
 635 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 636 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 637
 638 AS_ECHO
 639 PPRINT_SUBTITLE([Logging])
 640 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 641
 642 AS_ECHO
 643 PPRINT_SUBTITLE([Testing])
 644 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 645 PPRINT_PROP_BOOL([Python bindings tests], $value)
 646
 647 report_bindir="`eval eval echo $bindir`"
 648 report_libdir="`eval eval echo $libdir`"
 649 report_sysconfdif="`eval eval echo $sysconfdir`"
 650
 651 # Print the bindir and libdir this `make install' will install into.
 652 AS_ECHO
 653 PPRINT_SUBTITLE([Install directories])
 654 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 655 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 656 PPRINT_PROP_STRING([Plugins], [$report_libdir/babeltrace/plugins])
 657 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])