configure.ac

   1 dnl SPDX-License-Identifier: MIT
   2 dnl
   3 dnl Copyright (C) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7 ##                     ##
   8 ## Autoconf base setup ##
   9 ##                     ##
  10
  11 AC_PREREQ([2.50])
  12
  13 m4_define([bt_version_major], [2])
  14 m4_define([bt_version_minor], [1])
  15 m4_define([bt_version_patch], [0])
  16 m4_define([bt_version_dev_stage], [-rc1])
  17 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
  18 m4_define([bt_version_name], [])
  19
  20 AC_INIT([babeltrace2], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  21 AC_PROG_SED
  22
  23 # Following the numbering scheme proposed by libtool for the library version
  24 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  25 m4_define([bt_lib_version_current], [0])
  26 m4_define([bt_lib_version_revision], [0])
  27 m4_define([bt_lib_version_age], [0])
  28 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  29
  30 bt_version_description=""
  31 bt_version_description_c_safe=$(echo $bt_version_description | $SED 's/"/\\"/g')
  32
  33 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  34
  35 AC_CONFIG_HEADERS([src/common/config.h])
  36 AC_CONFIG_AUX_DIR([config])
  37 AC_CONFIG_MACRO_DIR([m4])
  38
  39 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  40 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  41 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  42 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
  43 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
  44 AC_DEFINE_UNQUOTED([BT_VERSION_DESCRIPTION], ["$bt_version_description_c_safe"], [Babeltrace version description])
  45
  46 AC_CANONICAL_TARGET
  47 AC_CANONICAL_HOST
  48
  49
  50 ##                     ##
  51 ## Automake base setup ##
  52 ##                     ##
  53
  54 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  55 AM_MAINTAINER_MODE([enable])
  56
  57 # Enable silent rules if available (Introduced in AM 1.11)
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  59
  60
  61 ##                      ##
  62 ## OS specific defaults ##
  63 ##                      ##
  64
  65 MINGW32=no
  66 DEFAULT_ENABLE_DEBUG_INFO=yes
  67 LT_NO_UNDEFINED=""
  68 AS_CASE([$host_os],
  69   [solaris*|darwin*],
  70     [
  71         DEFAULT_ENABLE_DEBUG_INFO=no
  72     ],
  73   [cygwin*],
  74     [
  75         DEFAULT_ENABLE_DEBUG_INFO=no
  76         LT_NO_UNDEFINED="-no-undefined"
  77     ],
  78   [mingw*],
  79     [
  80         MINGW32=yes
  81         DEFAULT_ENABLE_DEBUG_INFO=no
  82         LT_NO_UNDEFINED="-no-undefined"
  83     ]
  84 )
  85
  86 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  87 AC_SUBST(LT_NO_UNDEFINED)
  88
  89
  90 ##                   ##
  91 ## C compiler checks ##
  92 ##                   ##
  93
  94 AC_USE_SYSTEM_EXTENSIONS
  95 AC_SYS_LARGEFILE
  96
  97 # Choose the c compiler
  98 AC_PROG_CC
  99
 100 # Make sure the c compiler supports C99
 101 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 102
 103 # Make sure the c compiler supports __attributes__
 104 AX_C___ATTRIBUTE__
 105 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 106   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 107
 108 # Make sur we have pthread support
 109 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 110
 111 # Checks for typedefs, structures, and compiler characteristics.
 112 AC_C_INLINE
 113 AC_C_TYPEOF
 114 AC_TYPE_PID_T
 115 AC_TYPE_SIZE_T
 116 AC_TYPE_INT16_T
 117 AC_TYPE_INT32_T
 118 AC_TYPE_INT64_T
 119 AC_TYPE_INT8_T
 120 AC_TYPE_OFF_T
 121 AC_TYPE_SSIZE_T
 122 AC_TYPE_UINT16_T
 123 AC_TYPE_UINT32_T
 124 AC_TYPE_UINT64_T
 125 AC_TYPE_UINT8_T
 126 AC_CHECK_TYPES([ptrdiff_t])
 127
 128
 129 ##               ##
 130 ## Header checks ##
 131 ##               ##
 132
 133 AC_HEADER_STDBOOL
 134 AC_CHECK_HEADERS([ \
 135         fcntl.h \
 136         float.h \
 137         ftw.h \
 138         libintl.h \
 139         limits.h \
 140         malloc.h \
 141         netdb.h \
 142         netinet/in.h \
 143         stddef.h \
 144         sys/socket.h \
 145         sys/time.h
 146 ])
 147
 148
 149 ##               ##
 150 ## Linker checks ##
 151 ##               ##
 152
 153 # Check if the linker supports no-as-needed
 154 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 155 AC_SUBST([LD_NO_AS_NEEDED])
 156
 157 # Check if the linker supports whole-archive
 158 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 159   [
 160     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 161     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 162   ],[
 163     # Fallback to force_load for the macOS linker
 164     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 165       [
 166         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 167         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 168       ],[
 169         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 170       ]
 171     )
 172   ]
 173 )
 174
 175 # Initialize and configure libtool
 176 LT_INIT([win32-dll])
 177
 178
 179 ##                 ##
 180 ## Programs checks ##
 181 ##                 ##
 182
 183 AC_PROG_MAKE_SET
 184 AC_PROG_MKDIR_P
 185 AC_PROG_LN_S
 186 AC_PATH_PROG([report_fold], [fold])
 187
 188 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 189 # is not distributed in tarballs
 190 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 191 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 192
 193 # check for bison
 194 AC_PROG_YACC
 195 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 196
 197 AS_IF([test "x$have_bison" != "xyes"], [
 198   AS_IF([test "x$in_git_repo" = "xyes"], [
 199     AC_MSG_FAILURE([dnl
 200 Bison >= 2.4 is required when building from the Git repository. You can
 201 set the YACC variable to override automatic detection.
 202     ])
 203   ], [
 204     AC_MSG_WARN([dnl
 205 Missing Bison >= 2.4. Note that the parser files are already built in
 206 this distribution tarball, so Bison is only needed if you intend to
 207 modify their sources. You can set the YACC variable to override automatic
 208 detection.
 209     ])
 210   ])
 211 ])
 212 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 213
 214 # check for flex
 215 AC_PROG_LEX
 216 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 217
 218 AS_IF([test "x$have_flex" != "xyes"], [
 219   AS_IF([test "x$in_git_repo" = "xyes"], [
 220     AC_MSG_FAILURE([dnl
 221 Flex >= 2.5.35 is required when building from the Git repository. You can
 222 set the LEX variable to override automatic detection.
 223     ])
 224   ], [
 225     AC_MSG_WARN([dnl
 226 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 227 this distribution tarball, so Flex is only needed if you intend to
 228 modify their sources. You can set the LEX variable to override automatic
 229 detection.
 230     ])
 231   ])
 232 ])
 233 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 234
 235
 236 ##                ##
 237 ## Library checks ##
 238 ##                ##
 239
 240 # Check what libraries are required on this platform to link sockets programs.
 241 AX_LIB_SOCKET_NSL
 242
 243 # Check for glib >= 2.28 with gmodule support
 244 AM_PATH_GLIB_2_0([2.28.0], [],
 245   AC_MSG_ERROR([glib >= 2.28 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 246   [gmodule-no-export]
 247 )
 248
 249 # Checks for library functions.
 250 AC_FUNC_ALLOCA
 251 AC_FUNC_FORK
 252 AC_FUNC_MKTIME
 253 AC_FUNC_MMAP
 254 AC_FUNC_STRERROR_R
 255 AC_FUNC_STRNLEN
 256 AC_CHECK_FUNCS([ \
 257         atexit \
 258         dup2 \
 259         ftruncate \
 260         gethostbyname \
 261         gettimeofday \
 262         localtime_r \
 263         memchr \
 264         memset \
 265         mkdir \
 266         mkdtemp \
 267         munmap \
 268         rmdir \
 269         setenv \
 270         socket \
 271         strchr \
 272         strdup \
 273         strerror \
 274         strndup \
 275         strnlen \
 276         strrchr \
 277         strstr \
 278         strtoul \
 279         strtoull \
 280         tzset \
 281 ])
 282
 283 # AC_FUNC_MALLOC causes problems when cross-compiling.
 284 #AC_FUNC_MALLOC
 285 #AC_FUNC_REALLOC
 286
 287 # Check for fmemopen
 288 AC_CHECK_LIB([c], [fmemopen],
 289   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 290 )
 291
 292 # Check for open_memstream
 293 AC_CHECK_LIB([c], [open_memstream],
 294   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 295 )
 296
 297 # Check for posix_fallocate
 298 AC_CHECK_LIB([c], [posix_fallocate],
 299   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 300 )
 301
 302 ##                 ##
 303 ## User variables  ##
 304 ##                 ##
 305
 306 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 307 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 308 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 309
 310 # BABELTRACE_PLUGINS_DIR: Plugins directory
 311 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 312 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 313
 314 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 315 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 316 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 317
 318 # BABELTRACE_MINIMAL_LOG_LEVEL:
 319 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 320 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 321 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 322        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 323        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 324   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 325 )
 326 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 327
 328 # BABELTRACE_DEV_MODE:
 329 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 330 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 331         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 332 ], [BABELTRACE_DEV_MODE=0])
 333
 334 # BABELTRACE_DEBUG_MODE:
 335 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 336 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 337         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 338 ], [BABELTRACE_DEBUG_MODE=0])
 339
 340
 341 ##                              ##
 342 ## Optionnal features selection ##
 343 ##                              ##
 344
 345 # Python bindings
 346 # Disabled by default
 347 AC_ARG_ENABLE([python-bindings],
 348   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 349   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 350   [enable_python_bindings=unspecified]
 351 )
 352
 353 # Python plugins
 354 # Disabled by default
 355 AC_ARG_ENABLE([python-plugins],
 356   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])]
 357   dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 358 )
 359
 360 # Debug info
 361 # Enabled by default, except on some platforms
 362 AC_ARG_ENABLE([debug-info],
 363   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 364   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 365   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 366 )
 367
 368 # API documentation
 369 # Disabled by default
 370 AC_ARG_ENABLE([api-doc],
 371   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 372   [enable_api_doc=$enableval]
 373 )
 374
 375 # Built-in plugins
 376 # Disabled by default
 377 AC_ARG_ENABLE([built-in-plugins],
 378   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])]
 379   dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 380 )
 381
 382 # Built-in python plugin support
 383 # Disabled by default
 384 AC_ARG_ENABLE([built-in-python-plugin-support],
 385   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])]
 386   dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 387 )
 388
 389 # Man pages
 390 # Enabled by default
 391 AC_ARG_ENABLE([man-pages],
 392   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 393   [], dnl AC_ARG_ENABLE will fill enable_man_pages with the user choice
 394   [enable_man_pages=yes]
 395 )
 396
 397
 398 # Set automake variables for optionnal feature conditionnals in Makefile.am
 399 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 400 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 401 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 402 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 403 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 404 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 405 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 406 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 407
 408 # Set defines for optionnal features conditionnals in the source code
 409
 410 ## jgalar: still used?
 411 AS_IF([test "x$enable_python_plugins" = xyes],
 412   [AC_DEFINE([PYTHON_PLUGINS], [1], [Python plugin support.])]
 413 )
 414
 415 AS_IF([test "x$enable_debug_info" = xyes],
 416   [AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])]
 417 )
 418
 419 AS_IF([test "x$enable_built_in_plugins" = xyes],
 420   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 421 )
 422
 423 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 424   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 425 )
 426
 427 AS_IF([test "x$enable_debug_info" = xyes],
 428   [ENABLE_DEBUG_INFO_VAL=1],
 429   [ENABLE_DEBUG_INFO_VAL=0]
 430 )
 431
 432 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 433
 434 # Check for conflicting Python related features user choices.
 435 AS_IF([test "x$enable_python_plugins" = xyes],
 436   [
 437     AS_IF([test "x$enable_python_bindings" = xunspecified],
 438       [
 439         # --enable-python-plugins was provided but --enable-python-bindings was
 440         # omitted. Turn the Python bindings ON anyway because it's needed to
 441         # use the Python plugins.
 442         enable_python_bindings=yes
 443       ],
 444       [
 445         AS_IF([test "x$enable_python_bindings" = xno],
 446           [
 447             # --enable-python-plugins _and_ --disable-python-bindings were
 448             # used. This is invalid because Python plugins need the Python
 449             # bindings to be useful.
 450             AC_MSG_ERROR(--enable-python-bindings must be used to support Python plugins)
 451           ]
 452         )
 453       ]
 454     )
 455   ]
 456 )
 457
 458 # Check for conflicting optional features user choices
 459
 460 AS_IF([test "x$enable_built_in_plugins" = xyes],
 461   [
 462     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 463     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 464     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 465   ]
 466 )
 467
 468 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 469   [
 470     AS_IF([test "x$enable_python_plugins" != xyes], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 471     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 472     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 473     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 474   ]
 475 )
 476
 477
 478 # Check for optionnal features dependencies
 479
 480 AS_IF([test "x$enable_python_bindings" = xyes],
 481   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 482 )
 483
 484 AM_PATH_PYTHON([3.0], [
 485   AM_PATH_PYTHON_MODULES([PYTHON])
 486
 487   # pythondir is the path where extra modules are to be installed
 488   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 489
 490   # pyexecdir is the path that contains shared objects used by the extra modules
 491   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 492
 493   AS_IF([test -z "$PYTHON_CONFIG"], [
 494     AC_PATH_PROGS([PYTHON_CONFIG],
 495                   [python$PYTHON_VERSION-config python-config],
 496                   [],
 497                   [`dirname $PYTHON`])
 498   ])
 499
 500   AS_IF([test -n "$PYTHON_CONFIG"], [
 501     AS_IF([test -z "$PYTHON_INCLUDE"], [
 502       AC_MSG_CHECKING([Python include flags])
 503       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 504       AC_MSG_RESULT([$PYTHON_INCLUDE])
 505     ])
 506
 507     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 508       AC_MSG_CHECKING([Python library flags])
 509       # Python 3.8+ requires that we pass --embed to get the -lpython3.x flag.
 510       AS_IF([! PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags --embed`], [
 511         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 512       ])
 513       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 514     ])
 515   ])
 516 ], [:])
 517
 518 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 519 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 520
 521 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 522 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 523
 524 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 525   AS_IF([test "x$have_python_dev" = xno], [
 526     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 527   ])
 528 ])
 529
 530 AS_IF([test "x$enable_debug_info" = xyes],
 531   [
 532     # Check if libelf and libdw are present
 533     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 534     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 535     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 536     ELFUTILS_LIBS="-lelf -ldw"
 537   ]
 538 )
 539 AC_SUBST([ELFUTILS_LIBS])
 540
 541 AS_IF([test "x$enable_api_doc" = "xyes"],
 542   [
 543     DX_DOXYGEN_FEATURE(ON)
 544     DX_DOT_FEATURE(OFF)
 545     DX_HTML_FEATURE(ON)
 546     DX_CHM_FEATURE(OFF)
 547     DX_CHI_FEATURE(OFF)
 548     DX_MAN_FEATURE(OFF)
 549     DX_RTF_FEATURE(OFF)
 550     DX_XML_FEATURE(OFF)
 551     DX_PDF_FEATURE(OFF)
 552     DX_PS_FEATURE(OFF)
 553     DX_INIT_DOXYGEN([Babeltrace 2], [$(builddir)/Doxyfile], [output])
 554     AS_IF([test -z "$DX_DOXYGEN"],
 555           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 556     )
 557   ]
 558 )
 559
 560 have_asciidoc_xmlto=no
 561 warn_prebuilt_man_pages=no
 562
 563 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 564 AC_PATH_PROG([XMLTO], [xmlto], [no])
 565
 566 AS_IF([test "x$enable_man_pages" = "xyes"], [
 567   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 568     AS_IF([test "x$in_git_repo" = "xyes"], [
 569       # this is an error because we're in the Git repo, which
 570       # means the man pages are not already generated for us,
 571       # thus asciixmlto are required because we were asked
 572       # to build the man pages
 573       AC_MSG_ERROR([
 574 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 575 --disable-man-pages to disable building the man pages, in which case
 576 they will not be installed.
 577       ])
 578     ], [
 579       # only warn here: since we're in the tarball, the man
 580       # pages should already be generated at this point, thus
 581       # asciidoc/xmlto are not strictly required
 582       warn_prebuilt_man_pages=yes
 583     ])
 584   ], [
 585     have_asciidoc_xmlto=yes
 586   ])
 587 ])
 588
 589 # export AsciiDoc and xmlto existence
 590 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 591
 592 # a wonderful hack that seems necessary because $libdir is
 593 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 594 # by autoconf when it's not specified by the user
 595 AS_IF([test "x$exec_prefix" = xNONE], [
 596   AS_IF([test "x$prefix" = xNONE], [
 597     PREFIX="$ac_default_prefix"
 598   ], [
 599     PREFIX="$prefix"
 600   ])
 601
 602   LIBDIR="$PREFIX/lib"
 603 ], [
 604   LIBDIR="$libdir"
 605 ])
 606
 607 AC_SUBST(LIBDIR)
 608
 609 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 610 # test).
 611 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 612
 613 # Check that the current size_t matches the size that glib thinks it should
 614 # be. This catches problems on multi-arch where people try to do a 32-bit
 615 # build while pointing at 64-bit glib headers. This is a common error because
 616 # glib.h is not platform specific but it includes glibconfig.h which is and
 617 # is usually installed in a non-standard path.
 618
 619 # Do this before enabling all the warning flags, as the
 620 # AC_LANG_PROGRAM-generated program may generate some warning, which makes this
 621 # test fail unnecessarily.
 622
 623 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 624 # output. Specifically allow pkg_config_libdir to be able to print the
 625 # error message.
 626 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 627
 628 save_CFLAGS=${CFLAGS}
 629 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 630 AC_COMPILE_IFELSE([
 631   AC_LANG_PROGRAM([dnl
 632 #include <glib.h>
 633 #include <unistd.h>
 634   ], [dnl
 635 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 636   ])
 637 ],[:],[
 638   AC_MSG_ERROR([dnl
 639 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 640 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 641 target.
 642   ])
 643 ])
 644 CFLAGS=${save_CFLAGS}
 645
 646 # Detect C and LD warning flags supported by the compiler.
 647
 648 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
 649 #
 650 # Pass -Werror as an extra flag during the test: this is needed to make the
 651 # -Wunknown-warning-option diagnostic fatal with clang.
 652 AX_APPEND_COMPILE_FLAGS([ dnl
 653                 -Wall dnl
 654                 -Wextra dnl
 655                 -Wstrict-prototypes dnl
 656                 -Wmissing-prototypes dnl
 657                 -Wmissing-declarations dnl
 658                 -Wnull-dereference dnl
 659                 -Wundef dnl
 660                 -Wredundant-decls dnl
 661                 -Wshadow dnl
 662                 -Wjump-misses-init dnl
 663                 -Wsuggest-attribute=format dnl
 664                 -Wtautological-constant-out-of-range-compare dnl
 665                 -Wnested-externs dnl
 666                 -Wwrite-strings dnl
 667                 -Wformat=2 dnl
 668                 -Wstrict-aliasing dnl
 669                 -Wmissing-noreturn dnl
 670                 -Winit-self dnl
 671                 -Wduplicated-cond dnl
 672                 -Wduplicated-branches dnl
 673                 -Wlogical-op dnl
 674                 -Wno-unused-parameter dnl
 675                 -Wno-sign-compare dnl
 676                 dnl
 677                 dnl Some versions of SWIG (like 3.0.12) generate code that produces
 678                 dnl -Wcast-function-type warnings.  This warning is present in gcc >= 8.  This
 679                 dnl combo happens on RHEL/Centos 8, for example.  Later versions of SWIG (like
 680                 dnl 4.0.1) have the correct function signatures to not produce this warning.
 681                 dnl It's simpler to just disable the warning globally.
 682                 dnl
 683                 dnl Note that the Debian/Ubuntu SWIG package 3.0.12-2 contains a local patch to
 684                 dnl fix this (python-fix-function-cast-warnings.patch), so you won't be able to
 685                 dnl reproduce the warning using that package.
 686                 dnl
 687                 dnl Ref: https://github.com/swig/swig/issues/1259
 688                 -Wno-cast-function-type dnl
 689                 -Wno-missing-field-initializers dnl
 690         ],
 691         [WARN_CFLAGS],
 692         [-Werror])
 693
 694 # When given, add -Werror to WARN_CFLAGS.
 695 AC_ARG_ENABLE([Werror],
 696         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
 697 )
 698 AS_IF([test "x$enable_Werror" = "xyes"],
 699         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
 700 )
 701
 702 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 703 # written in such a way that it triggers a -Wold-style-definition warning.  So
 704 # this warning always ends up disabled if we put it there, because the test
 705 # program does not build.
 706 #
 707 # Enable it here unconditionally.  It is supported by GCC >= 4.8 and by Clang
 708 # (it is accepted for compatibility although it has no effect), and there is
 709 # not reason to not want it.
 710
 711 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition"
 712
 713 # CFLAGS from AX_APPEND_COMPILE_FLAGS.
 714 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 715
 716 # Done for AM_CFLAGS.
 717 AC_SUBST(AM_CFLAGS)
 718
 719 # Set global CPPFLAGS in AM_CPPFLAGS
 720 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 721 AC_SUBST(AM_CPPFLAGS)
 722
 723 # Add glib to global link libs
 724 LIBS="$LIBS $GLIB_LIBS"
 725
 726 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 727 # to rename babeltrace2.bin to babeltrace2 at install time.
 728 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 729 AC_SUBST(program_transform_name)
 730
 731 AC_CONFIG_FILES([
 732         doc/api/Makefile
 733         doc/api/libbabeltrace2/Doxyfile
 734         doc/api/libbabeltrace2/Makefile
 735         doc/contributing-images/Makefile
 736         doc/Makefile
 737         doc/man/asciidoc-attrs.conf
 738         doc/man/Makefile
 739         include/Makefile
 740         Makefile
 741         src/argpar/Makefile
 742         src/autodisc/Makefile
 743         src/babeltrace2-ctf-writer.pc
 744         src/babeltrace2.pc
 745         src/bindings/Makefile
 746         src/bindings/python/bt2/bt2/version.py
 747         src/bindings/python/bt2/Makefile
 748         src/bindings/python/bt2/setup.py
 749         src/bindings/python/Makefile
 750         src/cli/Makefile
 751         src/common/Makefile
 752         src/compat/Makefile
 753         src/ctfser/Makefile
 754         src/ctf-writer/Makefile
 755         src/fd-cache/Makefile
 756         src/lib/graph/Makefile
 757         src/lib/graph/message/Makefile
 758         src/lib/Makefile
 759         src/lib/plugin/Makefile
 760         src/lib/prio-heap/Makefile
 761         src/lib/trace-ir/Makefile
 762         src/logging/Makefile
 763         src/Makefile
 764         src/plugins/common/Makefile
 765         src/plugins/common/muxing/Makefile
 766         src/plugins/common/param-validation/Makefile
 767         src/plugins/ctf/common/bfcr/Makefile
 768         src/plugins/ctf/common/Makefile
 769         src/plugins/ctf/common/metadata/Makefile
 770         src/plugins/ctf/common/msg-iter/Makefile
 771         src/plugins/ctf/fs-sink/Makefile
 772         src/plugins/ctf/fs-src/Makefile
 773         src/plugins/ctf/lttng-live/Makefile
 774         src/plugins/ctf/Makefile
 775         src/plugins/lttng-utils/debug-info/Makefile
 776         src/plugins/lttng-utils/Makefile
 777         src/plugins/Makefile
 778         src/plugins/text/dmesg/Makefile
 779         src/plugins/text/Makefile
 780         src/plugins/text/pretty/Makefile
 781         src/plugins/text/details/Makefile
 782         src/plugins/utils/counter/Makefile
 783         src/plugins/utils/dummy/Makefile
 784         src/plugins/utils/Makefile
 785         src/plugins/utils/muxer/Makefile
 786         src/plugins/utils/trimmer/Makefile
 787         src/py-common/Makefile
 788         src/python-plugin-provider/Makefile
 789         src/param-parse/Makefile
 790         src/string-format/Makefile
 791         tests/bitfield/Makefile
 792         tests/ctf-writer/Makefile
 793         tests/lib/Makefile
 794         tests/lib/test-plugin-plugins/Makefile
 795         tests/Makefile
 796         tests/param-validation/Makefile
 797         tests/plugins/Makefile
 798         tests/plugins/src.ctf.fs/Makefile
 799         tests/plugins/src.ctf.fs/succeed/Makefile
 800         tests/plugins/sink.ctf.fs/Makefile
 801         tests/plugins/sink.ctf.fs/succeed/Makefile
 802         tests/plugins/flt.lttng-utils.debug-info/Makefile
 803         tests/plugins/flt.utils.muxer/Makefile
 804         tests/plugins/flt.utils.muxer/succeed/Makefile
 805         tests/plugins/flt.utils.trimmer/Makefile
 806         tests/utils/Makefile
 807         tests/utils/tap/Makefile
 808 ])
 809
 810 AC_OUTPUT
 811
 812 #
 813 # Mini-report on what will be built.
 814 #
 815
 816 PPRINT_INIT
 817 PPRINT_SET_INDENT(1)
 818 PPRINT_SET_TS(38)
 819
 820 AS_ECHO
 821
 822 AS_IF([test -n "bt_version_name"], [
 823         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION \"bt_version_name\"$PPRINT_COLOR_RST")
 824 ], [
 825         AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION")
 826 ])
 827
 828 AS_ECHO
 829
 830 AS_IF([test -n "$bt_version_description"], [
 831         AS_IF([test -n "$report_fold"], [
 832                 AS_ECHO("`AS_ECHO("$bt_version_description") | $report_fold -s`")
 833         ], [
 834                 AS_ECHO("$bt_version_description")
 835         ])
 836
 837         AS_ECHO
 838 ])
 839
 840 PPRINT_SUBTITLE([System])
 841
 842 # Target architecture we're building for.
 843 target_arch=$host_cpu
 844 [
 845 for f in $CFLAGS; do
 846         if test $f = "-m32"; then
 847                 target_arch="32-bit"
 848         elif test $f = "-m64"; then
 849                 target_arch="64-bit"
 850         fi
 851 done
 852 ]
 853
 854 PPRINT_PROP_STRING([Target architecture], $target_arch)
 855
 856 AS_ECHO
 857 PPRINT_SUBTITLE([Python 3 language support])
 858 test "x$have_python" = "xyes" && value=1 || value=0
 859 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 860 test "x$have_python_dev" = "xyes" && value=1 || value=0
 861 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 862 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 863 PPRINT_PROP_BOOL_CUSTOM([Python bindings], $value, [To enable, use --enable-python-bindings])
 864 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 865 PPRINT_PROP_BOOL_CUSTOM([Python plugin support], $value, [To enable, use --enable-python-plugins])
 866 AS_IF([test "x$have_python" = "xyes"], [
 867   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 868 ])
 869 AS_IF([test "x$have_python_dev" = "xyes"], [
 870   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 871   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 872   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 873 ])
 874 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 875   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 876   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 877 ])
 878
 879 AS_ECHO
 880 PPRINT_SUBTITLE([Plugins])
 881 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 882 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 883 PPRINT_PROP_BOOL_CUSTOM(['lttng-utils' plugin], $value, [To enable, use --enable-debug-info])
 884 PPRINT_PROP_BOOL(['text' plugin], 1)
 885 PPRINT_PROP_BOOL(['utils' plugin], 1)
 886
 887 AS_ECHO
 888 PPRINT_SUBTITLE([Built-in features])
 889 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 890 PPRINT_PROP_BOOL_CUSTOM([Built-in plugins], $value, [To enable, use --enable-built-in-plugins])
 891 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 892 PPRINT_PROP_BOOL_CUSTOM([Built-in Python plugin support], $value, [To enable, use --enable-built-in-python-plugin-support])
 893
 894 AS_ECHO
 895 PPRINT_SUBTITLE([Documentation])
 896
 897 # man pages build enabled/disabled
 898 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 899
 900 AS_IF([test "x$enable_man_pages" != "xno"], [
 901   AS_IF([test "x$in_git_repo" = "xyes"], [
 902     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 903   ], [
 904     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 905       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 906     ], [
 907       PPRINT_PROP_STRING([build_man_pages_msg],
 908         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 909         $PPRINT_COLOR_SUBTITLE)
 910     ])
 911   ])
 912 ], [
 913   PPRINT_PROP_BOOL_CUSTOM([build_man_pages_msg], 0, [To build man pages, use --enable-man-pages])
 914 ])
 915
 916 m4_popdef([build_man_pages_msg])
 917
 918 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 919 PPRINT_PROP_BOOL_CUSTOM([HTML API documentation], $value, [To build documentation, use --enable-api-doc])
 920
 921 AS_ECHO
 922 PPRINT_SUBTITLE([Logging])
 923 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 924
 925 AS_ECHO
 926 PPRINT_SUBTITLE([Special build modes])
 927 PPRINT_PROP_BOOL_CUSTOM([Debug mode], $BABELTRACE_DEBUG_MODE, [To enable, set the BABELTRACE_DEBUG_MODE environment variable to 1])
 928 PPRINT_PROP_BOOL_CUSTOM([Developer mode], $BABELTRACE_DEV_MODE, [To enable, set the BABELTRACE_DEV_MODE environment variable to 1])
 929
 930 report_bindir="`eval eval echo $bindir`"
 931 report_libdir="`eval eval echo $libdir`"
 932 report_sysconfdif="`eval eval echo $sysconfdir`"
 933 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 934 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 935
 936 # Print the bindir and libdir this `make install' will install into.
 937 AS_ECHO
 938 PPRINT_SUBTITLE([Install directories])
 939 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 940 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 941 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 942 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 943 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])