formats/ctf/metadata/ctf-lexer.l

   1 %{
   2 /*
   3  * ctf-lexer.l
   4  *
   5  * Common Trace Formal Lexer
   6  *
   7  * Copyright 2010 - Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a copy
  10  * of this software and associated documentation files (the "Software"), to deal
  11  * in the Software without restriction, including without limitation the rights
  12  * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  13  * copies of the Software, and to permit persons to whom the Software is
  14  * furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included in
  17  * all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  20  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  22  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  23  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  24  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  25  * SOFTWARE.
  26  */
  27
  28 #include <stdio.h>
  29 #include <babeltrace/babeltrace-internal.h>
  30 #include "ctf-scanner.h"
  31 #include "ctf-parser.h"
  32 #include "ctf-ast.h"
  33
  34 BT_HIDDEN
  35 void setstring(struct ctf_scanner *scanner, YYSTYPE *lvalp, const char *src);
  36
  37 static void yyunput (int c, register char * yy_bp , yyscan_t yyscanner)
  38         __attribute__((unused));
  39 static int input (yyscan_t yyscanner) __attribute__((unused));
  40
  41 BT_HIDDEN
  42 int import_string(struct ctf_scanner *scanner, YYSTYPE *lvalp, const char *src, char delim);
  43
  44 %}
  45
  46 %x comment_ml comment_sl string_lit char_const
  47 %option reentrant yylineno noyywrap bison-bridge
  48 %option extra-type="struct ctf_scanner *"
  49         /* bison-locations */
  50 INTEGER_SUFFIX                  [ \n\t]*(U|UL|ULL|LU|LLU|Ul|Ull|lU|llU|u|uL|uLL|Lu|LLu|ul|ull|lu|llu)
  51 DIGIT                           [0-9]
  52 NONDIGIT                        [a-zA-Z_]
  53 HEXDIGIT                        [0-9A-Fa-f]
  54 OCTALDIGIT                      [0-7]
  55 UCHARLOWERCASE                  \\u{HEXDIGIT}{4}
  56 UCHARUPPERCASE                  \\U{HEXDIGIT}{8}
  57 ID_NONDIGIT                     {NONDIGIT}|{UCHARLOWERCASE}|{UCHARUPPERCASE}
  58 IDENTIFIER                      {ID_NONDIGIT}({ID_NONDIGIT}|{DIGIT})*
  59 %%
  60
  61                                 /*
  62                                  * Using start conditions to deal with comments
  63                                  * and strings.
  64                                  */
  65
  66 "/*"                            BEGIN(comment_ml);
  67 <comment_ml>[^*\n]*             /* eat anything that's not a '*' */
  68 <comment_ml>"*"+[^*/\n]*        /* eat up '*'s not followed by '/'s */
  69 <comment_ml>\n
  70 <comment_ml>"*"+"/"             BEGIN(INITIAL);
  71
  72 "//"                            BEGIN(comment_sl);
  73 <comment_sl>[^\n]*\n            BEGIN(INITIAL);
  74
  75 L?\"(\\.|[^\\"])*\"             { if (import_string(yyextra, yylval, yytext, '\"') < 0) return ERROR; else return STRING_LITERAL; }
  76 L?\'(\\.|[^\\'])*\'             { if (import_string(yyextra, yylval, yytext, '\'') < 0) return ERROR; else return CHARACTER_LITERAL; }
  77
  78 "["                             return LSBRAC;
  79 "]"                             return RSBRAC;
  80 "("                             return LPAREN;
  81 ")"                             return RPAREN;
  82 "{"                             return LBRAC;
  83 "}"                             return RBRAC;
  84 "->"                            return RARROW;
  85 "*"                             return STAR;
  86 "+"                             return PLUS;
  87 "-"                             return MINUS;
  88 "<"                             return LT;
  89 ">"                             return GT;
  90 :=                              return TYPEASSIGN;
  91 :                               return COLON;
  92 ;                               return SEMICOLON;
  93 "..."                           return DOTDOTDOT;
  94 "."                             return DOT;
  95 =                               return EQUAL;
  96 ","                             return COMMA;
  97 align                           setstring(yyextra, yylval, yytext); return TOK_ALIGN;
  98 const                           setstring(yyextra, yylval, yytext); return CONST;
  99 char                            setstring(yyextra, yylval, yytext); return CHAR;
 100 clock                           setstring(yyextra, yylval, yytext); return CLOCK;
 101 double                          setstring(yyextra, yylval, yytext); return DOUBLE;
 102 enum                            setstring(yyextra, yylval, yytext); return ENUM;
 103 env                             setstring(yyextra, yylval, yytext); return ENV;
 104 event                           setstring(yyextra, yylval, yytext); return EVENT;
 105 floating_point                  setstring(yyextra, yylval, yytext); return FLOATING_POINT;
 106 float                           setstring(yyextra, yylval, yytext); return FLOAT;
 107 integer                         setstring(yyextra, yylval, yytext); return INTEGER;
 108 int                             setstring(yyextra, yylval, yytext); return INT;
 109 long                            setstring(yyextra, yylval, yytext); return LONG;
 110 short                           setstring(yyextra, yylval, yytext); return SHORT;
 111 signed                          setstring(yyextra, yylval, yytext); return SIGNED;
 112 stream                          setstring(yyextra, yylval, yytext); return STREAM;
 113 string                          setstring(yyextra, yylval, yytext); return STRING;
 114 struct                          setstring(yyextra, yylval, yytext); return STRUCT;
 115 trace                           setstring(yyextra, yylval, yytext); return TRACE;
 116 callsite                        setstring(yyextra, yylval, yytext); return CALLSITE;
 117 typealias                       setstring(yyextra, yylval, yytext); return TYPEALIAS;
 118 typedef                         setstring(yyextra, yylval, yytext); return TYPEDEF;
 119 unsigned                        setstring(yyextra, yylval, yytext); return UNSIGNED;
 120 variant                         setstring(yyextra, yylval, yytext); return VARIANT;
 121 void                            setstring(yyextra, yylval, yytext); return VOID;
 122 _Bool                           setstring(yyextra, yylval, yytext); return _BOOL;
 123 _Complex                        setstring(yyextra, yylval, yytext); return _COMPLEX;
 124 _Imaginary                      setstring(yyextra, yylval, yytext); return _IMAGINARY;
 125 [1-9]{DIGIT}*{INTEGER_SUFFIX}?  setstring(yyextra, yylval, yytext); return DECIMAL_CONSTANT;
 126 0{OCTALDIGIT}*{INTEGER_SUFFIX}? setstring(yyextra, yylval, yytext); return OCTAL_CONSTANT;
 127 0[xX]{HEXDIGIT}+{INTEGER_SUFFIX}?       setstring(yyextra, yylval, yytext); return HEXADECIMAL_CONSTANT;
 128 {IDENTIFIER}                    printf_debug("<IDENTIFIER %s>\n", yytext); setstring(yyextra, yylval, yytext); if (is_type(yyextra, yytext)) return ID_TYPE; else return IDENTIFIER;
 129 [ \t\r\n]                       ; /* ignore */
 130 .                               printfl_error(yylineno, "invalid character '0x%02X'", yytext[0]);  return ERROR;
 131 %%