m4/ax_pkg_swig.m4

   1 # ===========================================================================
   2 #       https://www.gnu.org/software/autoconf-archive/ax_pkg_swig.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PKG_SWIG([major.minor.micro], [action-if-found], [action-if-not-found])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro searches for a SWIG installation on your system. If found,
  12 #   then SWIG is AC_SUBST'd; if not found, then $SWIG is empty.  If SWIG is
  13 #   found, then SWIG_LIB is set to the SWIG library path, and AC_SUBST'd.
  14 #
  15 #   You can use the optional first argument to check if the version of the
  16 #   available SWIG is greater than or equal to the value of the argument. It
  17 #   should have the format: N[.N[.N]] (N is a number between 0 and 999. Only
  18 #   the first N is mandatory.) If the version argument is given (e.g.
  19 #   1.3.17), AX_PKG_SWIG checks that the swig package is this version number
  20 #   or higher.
  21 #
  22 #   As usual, action-if-found is executed if SWIG is found, otherwise
  23 #   action-if-not-found is executed.
  24 #
  25 #   In configure.in, use as:
  26 #
  27 #     AX_PKG_SWIG(1.3.17, [], [ AC_MSG_ERROR([SWIG is required to build..]) ])
  28 #     AX_SWIG_ENABLE_CXX
  29 #     AX_SWIG_MULTI_MODULE_SUPPORT
  30 #     AX_SWIG_PYTHON
  31 #
  32 # LICENSE
  33 #
  34 #   Copyright (c) 2008 Sebastian Huber <sebastian-huber@web.de>
  35 #   Copyright (c) 2008 Alan W. Irwin
  36 #   Copyright (c) 2008 Rafael Laboissiere <rafael@laboissiere.net>
  37 #   Copyright (c) 2008 Andrew Collier
  38 #   Copyright (c) 2011 Murray Cumming <murrayc@openismus.com>
  39 #   Copyright (c) 2018 Reini Urban <rurban@cpan.org>
  40 #   Copyright (c) 2021 Vincent Danjean <Vincent.Danjean@ens-lyon.org>
  41 #
  42 #   This program is free software; you can redistribute it and/or modify it
  43 #   under the terms of the GNU General Public License as published by the
  44 #   Free Software Foundation; either version 2 of the License, or (at your
  45 #   option) any later version.
  46 #
  47 #   This program is distributed in the hope that it will be useful, but
  48 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  49 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  50 #   Public License for more details.
  51 #
  52 #   You should have received a copy of the GNU General Public License along
  53 #   with this program. If not, see <https://www.gnu.org/licenses/>.
  54 #
  55 #   As a special exception, the respective Autoconf Macro's copyright owner
  56 #   gives unlimited permission to copy, distribute and modify the configure
  57 #   scripts that are the output of Autoconf when processing the Macro. You
  58 #   need not follow the terms of the GNU General Public License when using
  59 #   or distributing such scripts, even though portions of the text of the
  60 #   Macro appear in them. The GNU General Public License (GPL) does govern
  61 #   all other use of the material that constitutes the Autoconf Macro.
  62 #
  63 #   This special exception to the GPL applies to versions of the Autoconf
  64 #   Macro released by the Autoconf Archive. When you make and distribute a
  65 #   modified version of the Autoconf Macro, you may extend this special
  66 #   exception to the GPL to apply to your modified version as well.
  67
  68 #serial 15
  69
  70 AC_DEFUN([AX_PKG_SWIG],[
  71         # Find path to the "swig" executable.
  72         AC_PATH_PROGS([SWIG],[swig swig3.0 swig2.0])
  73         if test -z "$SWIG" ; then
  74                 m4_ifval([$3],[$3],[:])
  75         elif test -z "$1" ; then
  76                 m4_ifval([$2],[$2],[:])
  77         else
  78                 AC_MSG_CHECKING([SWIG version])
  79                 [swig_version=`$SWIG -version 2>&1 | grep 'SWIG Version' | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`]
  80                 AC_MSG_RESULT([$swig_version])
  81                 if test -n "$swig_version" ; then
  82                         # Calculate the required version number components
  83                         [required=$1]
  84                         [required_major=`echo $required | sed 's/[^0-9].*//'`]
  85                         if test -z "$required_major" ; then
  86                                 [required_major=0]
  87                         fi
  88                         [required=`echo $required. | sed 's/[0-9]*[^0-9]//'`]
  89                         [required_minor=`echo $required | sed 's/[^0-9].*//'`]
  90                         if test -z "$required_minor" ; then
  91                                 [required_minor=0]
  92                         fi
  93                         [required=`echo $required. | sed 's/[0-9]*[^0-9]//'`]
  94                         [required_patch=`echo $required | sed 's/[^0-9].*//'`]
  95                         if test -z "$required_patch" ; then
  96                                 [required_patch=0]
  97                         fi
  98                         # Calculate the available version number components
  99                         [available=$swig_version]
 100                         [available_major=`echo $available | sed 's/[^0-9].*//'`]
 101                         if test -z "$available_major" ; then
 102                                 [available_major=0]
 103                         fi
 104                         [available=`echo $available | sed 's/[0-9]*[^0-9]//'`]
 105                         [available_minor=`echo $available | sed 's/[^0-9].*//'`]
 106                         if test -z "$available_minor" ; then
 107                                 [available_minor=0]
 108                         fi
 109                         [available=`echo $available | sed 's/[0-9]*[^0-9]//'`]
 110                         [available_patch=`echo $available | sed 's/[^0-9].*//'`]
 111                         if test -z "$available_patch" ; then
 112                                 [available_patch=0]
 113                         fi
 114                         # Convert the version tuple into a single number for easier comparison.
 115                         # Using base 100 should be safe since SWIG internally uses BCD values
 116                         # to encode its version number.
 117                         required_swig_vernum=`expr $required_major \* 10000 \
 118                             \+ $required_minor \* 100 \+ $required_patch`
 119                         available_swig_vernum=`expr $available_major \* 10000 \
 120                             \+ $available_minor \* 100 \+ $available_patch`
 121
 122                         if test $available_swig_vernum -lt $required_swig_vernum; then
 123                                 AC_MSG_WARN([SWIG version >= $1 is required.  You have $swig_version.])
 124                                 SWIG=''
 125                                 m4_ifval([$3],[$3],[])
 126                         else
 127                                 AC_MSG_CHECKING([for SWIG library])
 128                                 SWIG_LIB=`$SWIG -swiglib | tr '\r\n' '  '`
 129                                 AC_MSG_RESULT([$SWIG_LIB])
 130                                 m4_ifval([$2],[$2],[])
 131                         fi
 132                 else
 133                         AC_MSG_WARN([cannot determine SWIG version])
 134                         SWIG=''
 135                         m4_ifval([$3],[$3],[])
 136                 fi
 137         fi
 138         AC_SUBST([SWIG_LIB])
 139 ])