src/plugins/ctf/common/metadata/lexer.l

   1 %{
   2 /*
   3  * SPDX-License-Identifier: MIT
   4  *
   5  * Copyright 2010 Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
   6  *
   7  * Common Trace Formal Lexer
   8  */
   9
  10 #define BT_LOG_OUTPUT_LEVEL ctf_plugin_metadata_log_level
  11 #define BT_LOG_TAG "PLUGIN-CTF-METADATA-LEXER"
  12 #include "logging.h"
  13
  14 #include <stdio.h>
  15 #include <ctype.h>
  16 #include "scanner.h"
  17 #include "parser-wrap.h"
  18 #include "ast.h"
  19
  20 #define YY_FATAL_ERROR(_msg)    BT_LOGF_STR(_msg)
  21
  22 #define PARSE_INTEGER_LITERAL(base)                                     \
  23         do {                                                            \
  24                 errno = 0;                                              \
  25                 yylval->ull = strtoull(yytext, NULL, base);             \
  26                 if (errno) {                                            \
  27                         _BT_LOGE_LINENO(yylineno,                       \
  28                                 "Cannot parser constant integer: "      \
  29                                 "base=%d, text=\"%s\"", base, yytext);  \
  30                         return CTF_ERROR;                               \
  31                 }                                                       \
  32         } while (0)
  33 %}
  34
  35 %x comment_ml comment_sl string_lit char_const
  36 %option reentrant yylineno noyywrap bison-bridge
  37 %option extra-type="struct ctf_scanner *"
  38         /* bison-locations */
  39 INTEGER_SUFFIX                  (U|UL|ULL|LU|LLU|Ul|Ull|lU|llU|u|uL|uLL|Lu|LLu|ul|ull|lu|llu)
  40 DIGIT                           [0-9]
  41 NONDIGIT                        [a-zA-Z_]
  42 HEXDIGIT                        [0-9A-Fa-f]
  43 OCTALDIGIT                      [0-7]
  44 UCHARLOWERCASE                  \\u{HEXDIGIT}{4}
  45 UCHARUPPERCASE                  \\U{HEXDIGIT}{8}
  46 ID_NONDIGIT                     {NONDIGIT}|{UCHARLOWERCASE}|{UCHARUPPERCASE}
  47 IDENTIFIER                      {ID_NONDIGIT}({ID_NONDIGIT}|{DIGIT})*
  48 %%
  49
  50                                 /*
  51                                  * Using start conditions to deal with comments
  52                                  * and strings.
  53                                  */
  54
  55 "/*"                            BEGIN(comment_ml);
  56 <comment_ml>[^*\n]*             /* eat anything that's not a '*' */
  57 <comment_ml>"*"+[^*/\n]*        /* eat up '*'s not followed by '/'s */
  58 <comment_ml>\n
  59 <comment_ml>"*"+"/"             BEGIN(INITIAL);
  60
  61 "//"[^\n]*\n                    /* skip comment */
  62
  63 L?\"(\\.|[^\\"])*\"             { if (import_string(yyextra, yylval, yytext, '\"') < 0) return CTF_ERROR; else return CTF_STRING_LITERAL; }
  64 L?\'(\\.|[^\\'])*\'             { if (import_string(yyextra, yylval, yytext, '\'') < 0) return CTF_ERROR; else return CTF_CHARACTER_LITERAL; }
  65
  66 "["                             return CTF_LSBRAC;
  67 "]"                             return CTF_RSBRAC;
  68 "("                             return CTF_LPAREN;
  69 ")"                             return CTF_RPAREN;
  70 "{"                             return CTF_LBRAC;
  71 "}"                             return CTF_RBRAC;
  72 "->"                            return CTF_RARROW;
  73 "*"                             return CTF_STAR;
  74 "+"                             return CTF_PLUS;
  75 "-"                             return CTF_MINUS;
  76 "<"                             return CTF_LT;
  77 ">"                             return CTF_GT;
  78 :=                              return CTF_TYPEASSIGN;
  79 :                               return CTF_COLON;
  80 ;                               return CTF_SEMICOLON;
  81 "..."                           return CTF_DOTDOTDOT;
  82 "."                             return CTF_DOT;
  83 =                               return CTF_EQUAL;
  84 ","                             return CTF_COMMA;
  85 align                           setstring(yyextra, yylval, yytext); return CTF_TOK_ALIGN;
  86 const                           setstring(yyextra, yylval, yytext); return CTF_CONST;
  87 char                            setstring(yyextra, yylval, yytext); return CTF_CHAR;
  88 clock                           setstring(yyextra, yylval, yytext); return CTF_CLOCK;
  89 double                          setstring(yyextra, yylval, yytext); return CTF_DOUBLE;
  90 enum                            setstring(yyextra, yylval, yytext); return CTF_ENUM;
  91 env                             setstring(yyextra, yylval, yytext); return CTF_ENV;
  92 event                           setstring(yyextra, yylval, yytext); return CTF_EVENT;
  93 floating_point                  setstring(yyextra, yylval, yytext); return CTF_FLOATING_POINT;
  94 float                           setstring(yyextra, yylval, yytext); return CTF_FLOAT;
  95 integer                         setstring(yyextra, yylval, yytext); return CTF_INTEGER;
  96 int                             setstring(yyextra, yylval, yytext); return CTF_INT;
  97 long                            setstring(yyextra, yylval, yytext); return CTF_LONG;
  98 short                           setstring(yyextra, yylval, yytext); return CTF_SHORT;
  99 signed                          setstring(yyextra, yylval, yytext); return CTF_SIGNED;
 100 stream                          setstring(yyextra, yylval, yytext); return CTF_STREAM;
 101 string                          setstring(yyextra, yylval, yytext); return CTF_STRING;
 102 struct                          setstring(yyextra, yylval, yytext); return CTF_STRUCT;
 103 trace                           setstring(yyextra, yylval, yytext); return CTF_TRACE;
 104 callsite                        setstring(yyextra, yylval, yytext); return CTF_CALLSITE;
 105 typealias                       setstring(yyextra, yylval, yytext); return CTF_TYPEALIAS;
 106 typedef                         setstring(yyextra, yylval, yytext); return CTF_TYPEDEF;
 107 unsigned                        setstring(yyextra, yylval, yytext); return CTF_UNSIGNED;
 108 variant                         setstring(yyextra, yylval, yytext); return CTF_VARIANT;
 109 void                            setstring(yyextra, yylval, yytext); return CTF_VOID;
 110 _Bool                           setstring(yyextra, yylval, yytext); return CTF_BOOL;
 111 _Complex                        setstring(yyextra, yylval, yytext); return CTF_COMPLEX;
 112 _Imaginary                      setstring(yyextra, yylval, yytext); return CTF_IMAGINARY;
 113 [1-9]{DIGIT}*{INTEGER_SUFFIX}?  PARSE_INTEGER_LITERAL(10); return CTF_INTEGER_LITERAL;
 114 0{OCTALDIGIT}*{INTEGER_SUFFIX}? PARSE_INTEGER_LITERAL(8); return CTF_INTEGER_LITERAL;
 115 0[xX]{HEXDIGIT}+{INTEGER_SUFFIX}?       PARSE_INTEGER_LITERAL(16); return CTF_INTEGER_LITERAL;
 116
 117 {IDENTIFIER}                    BT_LOGT("Got identifier: id=\"%s\"", yytext); setstring(yyextra, yylval, yytext); if (is_type(yyextra, yytext)) return ID_TYPE; else return IDENTIFIER;
 118 [ \t\r\n]                       ; /* ignore */
 119 .                               _BT_LOGE_LINENO(yylineno, "Invalid character: char=\"%c\", val=0x%02x", isprint((unsigned char) yytext[0]) ? yytext[0] : '\0', yytext[0]); return CTF_ERROR;
 120 %%