X-Git-Url: http://git.efficios.com/?p=babeltrace.git;a=blobdiff_plain;f=configure.ac;h=673fd7209523d66785ce18eddc917d3d1307f4f3;hp=4e3a07a26ed4c17ea223af67762214c81bd063a3;hb=e46cbefe0605ab6e66e5c1d1487c823682d3ac10;hpb=dc13cd867d9c8504abc17d54a7539fa35bbfd8b4

diff --git a/configure.ac b/configure.ac
index 4e3a07a2..673fd720 100644
--- a/configure.ac
+++ b/configure.ac
@@ -8,7 +8,7 @@ dnl Process this file with autoconf to produce a configure script.
 ## Autoconf base setup ##
 ##                     ##
 
-AC_PREREQ([2.50])
+AC_PREREQ([2.69])
 
 m4_define([bt_version_major], [2])
 m4_define([bt_version_minor], [1])
@@ -17,8 +17,7 @@ m4_define([bt_version_dev_stage], [-rc1])
 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_dev_stage)
 m4_define([bt_version_name], [])
 
-AC_INIT([babeltrace2], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
-AC_PROG_SED
+AC_INIT([babeltrace2],[bt_version],[jeremie dot galarneau at efficios dot com],[],[https://efficios.com/babeltrace/])
 
 # Following the numbering scheme proposed by libtool for the library version
 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
@@ -26,9 +25,8 @@ m4_define([bt_lib_version_current], [0])
 m4_define([bt_lib_version_revision], [0])
 m4_define([bt_lib_version_age], [0])
 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
-
-bt_version_description=""
-bt_version_description_c_safe=$(echo $bt_version_description | $SED 's/"/\\"/g')
+m4_define([bt_version_description], [])
+m4_define([bt_version_description_c_safe], AS_ESCAPE(bt_version_description))
 
 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
 
@@ -41,7 +39,7 @@ AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
 AC_DEFINE([BT_VERSION_DEV_STAGE], ["]bt_version_dev_stage["], [Babeltrace version development stage (can be empty)])
 AC_DEFINE([BT_VERSION_NAME], ["]bt_version_name["], [Babeltrace version name])
-AC_DEFINE_UNQUOTED([BT_VERSION_DESCRIPTION], ["$bt_version_description_c_safe"], [Babeltrace version description])
+AC_DEFINE([BT_VERSION_DESCRIPTION], ["]bt_version_description_c_safe["], [Babeltrace version description])
 
 AC_CANONICAL_TARGET
 AC_CANONICAL_HOST
@@ -51,11 +49,11 @@ AC_CANONICAL_HOST
 ## Automake base setup ##
 ##                     ##
 
-AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
+AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
 AM_MAINTAINER_MODE([enable])
 
-# Enable silent rules if available (Introduced in AM 1.11)
-m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
+# Enable silent rules by default
+AM_SILENT_RULES([yes])
 
 
 ##                      ##
@@ -63,22 +61,25 @@ m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 ##                      ##
 
 MINGW32=no
-DEFAULT_ENABLE_DEBUG_INFO=yes
 LT_NO_UNDEFINED=""
 AS_CASE([$host_os],
   [solaris*|darwin*],
     [
-	DEFAULT_ENABLE_DEBUG_INFO=no
+	AE_FEATURE_DISABLE([debug-info])
+    ],
+  [freebsd*],
+    [
+	AE_FEATURE_DISABLE([debug-info])
     ],
   [cygwin*],
     [
-	DEFAULT_ENABLE_DEBUG_INFO=no
+	AE_FEATURE_DISABLE([debug-info])
 	LT_NO_UNDEFINED="-no-undefined"
     ],
   [mingw*],
     [
 	MINGW32=yes
-	DEFAULT_ENABLE_DEBUG_INFO=no
+	AE_FEATURE_DISABLE([debug-info])
 	LT_NO_UNDEFINED="-no-undefined"
     ]
 )
@@ -91,14 +92,16 @@ AC_SUBST(LT_NO_UNDEFINED)
 ## C compiler checks ##
 ##                   ##
 
-AC_USE_SYSTEM_EXTENSIONS
-AC_SYS_LARGEFILE
-
 # Choose the c compiler
 AC_PROG_CC
+m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
 
 # Make sure the c compiler supports C99
-AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
+AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
+
+# Enable available system extensions and LFS support
+AC_USE_SYSTEM_EXTENSIONS
+AC_SYS_LARGEFILE
 
 # Make sure the c compiler supports __attributes__
 AX_C___ATTRIBUTE__
@@ -126,6 +129,14 @@ AC_TYPE_UINT8_T
 AC_CHECK_TYPES([ptrdiff_t])
 
 
+##                     ##
+## C++ compiler checks ##
+##                     ##
+
+# Require a C++11 compiler without GNU extensions (-std=c++11)
+AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory])
+
+
 ##               ##
 ## Header checks ##
 ##               ##
@@ -172,17 +183,21 @@ AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
   ]
 )
 
-# Initialize and configure libtool
-LT_INIT([win32-dll])
+# Check if the linker supports the "notext" keyword
+AX_CHECK_LINK_FLAG([-Wl,-z,notext],[
+	AC_SUBST([LD_NOTEXT], [-Wl,-z,notext])
+])
 
 
 ##                 ##
 ## Programs checks ##
 ##                 ##
 
+AM_PROG_AR
 AC_PROG_MAKE_SET
 AC_PROG_MKDIR_P
 AC_PROG_LN_S
+AC_PROG_SED
 AC_PATH_PROG([report_fold], [fold])
 
 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
@@ -212,7 +227,9 @@ detection.
 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 
 # check for flex
-AC_PROG_LEX
+# Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
+# problem since the argument is silently ignored by older versions.
+AC_PROG_LEX([noyywrap])
 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 
 AS_IF([test "x$have_flex" != "xyes"], [
@@ -232,6 +249,9 @@ detection.
 ])
 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 
+# Initialize and configure libtool
+LT_INIT([win32-dll])
+
 
 ##                ##
 ## Library checks ##
@@ -299,6 +319,7 @@ AC_CHECK_LIB([c], [posix_fallocate],
   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 )
 
+
 ##                 ##
 ## User variables  ##
 ##                 ##
@@ -345,145 +366,130 @@ AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 
 # Python bindings
 # Disabled by default
-AC_ARG_ENABLE([python-bindings],
-  [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
-  [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
-  [enable_python_bindings=unspecified]
-)
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([python-bindings],[build the Python bindings])
 
 # Python bindings documentation
 # Disabled by default
-AC_ARG_ENABLE([python-bindings-doc],
-  [AC_HELP_STRING([--enable-python-bindings-doc], [build the Python bindings documentation])],
-  [], dnl AC_ARG_ENABLE will fill enable_python_bindings_doc with the user choice
-  [enable_python_bindings_doc=no]
-)
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([python-bindings-doc],[build the Python bindings documentation])
 
 # Python plugins
 # Disabled by default
-AC_ARG_ENABLE([python-plugins],
-  [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])]
-  dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
-)
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([python-plugins],[enable the Python plugins support for the library and converter])
 
 # Debug info
 # Enabled by default, except on some platforms
-AC_ARG_ENABLE([debug-info],
-  [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
-  [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
-  [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
-)
+AE_FEATURE_DEFAULT_ENABLE
+AE_FEATURE([debug-info],[disable the debug info support (default on macOS, Solaris and Windows)])
 
 # API documentation
 # Disabled by default
-AC_ARG_ENABLE([api-doc],
-  [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
-  [enable_api_doc=$enableval]
-)
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([api-doc],[build the HTML API documentation])
 
 # Built-in plugins
 # Disabled by default
-AC_ARG_ENABLE([built-in-plugins],
-  [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])]
-  dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
-)
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([built-in-plugins],[Statically-link in-tree plug-ins into the babeltrace2 executable])
 
 # Built-in python plugin support
 # Disabled by default
-AC_ARG_ENABLE([built-in-python-plugin-support],
-  [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])]
-  dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
-)
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([built-in-python-plugin-support],[Statically-link Python plugin support into the babeltrace library])
 
 # Man pages
 # Enabled by default
-AC_ARG_ENABLE([man-pages],
-  [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
-  [], dnl AC_ARG_ENABLE will fill enable_man_pages with the user choice
-  [enable_man_pages=yes]
-)
+AE_FEATURE_DEFAULT_ENABLE
+AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball])
 
+# When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
+# Disabled by default
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([Werror],[Treat compiler warnings as errors.])
 
-# Set automake variables for optionnal feature conditionnals in Makefile.am
-AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
-AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], [test "x$enable_python_bindings_doc" = xyes])
-AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
-AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
-AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
-AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
-AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
-AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
-AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 
-# Set defines for optionnal features conditionnals in the source code
+##                                          ##
+## Check for conflicting features selection ##
+##                                          ##
 
-AS_IF([test "x$enable_built_in_plugins" = xyes],
-  [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
-)
+# Check for conflicting Python related features user choices.
+AE_IF_FEATURE_ENABLED([python-plugins], [
+  AE_IF_FEATURE_UNDEF([python-bindings], [
+    # --enable-python-plugins was provided but --enable-python-bindings was
+    # omitted. Turn the Python bindings ON anyway because it's needed to
+    # use the Python plugins.
+    AE_FEATURE_ENABLE([python-bindings])
+  ], [
+    AE_IF_FEATURE_DISABLED([python-bindings], [
+      # --enable-python-plugins _and_ --disable-python-bindings were
+      # used. This is invalid because Python plugins need the Python
+      # bindings to be useful.
+      AC_MSG_ERROR(--enable-python-bindings must be used to support Python plugins)
+    ])
+  ])
+])
 
-AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
-  [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
-)
+# Check for conflicting optional features user choices
+AE_IF_FEATURE_ENABLED([built-in-plugins], [
+    # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
+    AE_IF_FEATURE_NOT_ENABLED([static], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
+    AE_IF_FEATURE_ENABLED([shared], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
+])
 
-AS_IF([test "x$enable_debug_info" = xyes],
-  [ENABLE_DEBUG_INFO_VAL=1],
-  [ENABLE_DEBUG_INFO_VAL=0]
-)
+AE_IF_FEATURE_ENABLED([built-in-python-plugin-support], [
+    AE_IF_FEATURE_NOT_ENABLED([python-plugins], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
+    # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
+    AE_IF_FEATURE_NOT_ENABLED([static], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
+    AE_IF_FEATURE_ENABLED([shared], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
+])
 
-AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 
-# Check for conflicting Python related features user choices.
-AS_IF([test "x$enable_python_plugins" = xyes],
-  [
-    AS_IF([test "x$enable_python_bindings" = xunspecified],
-      [
-        # --enable-python-plugins was provided but --enable-python-bindings was
-        # omitted. Turn the Python bindings ON anyway because it's needed to
-        # use the Python plugins.
-        enable_python_bindings=yes
-      ],
-      [
-        AS_IF([test "x$enable_python_bindings" = xno],
-          [
-            # --enable-python-plugins _and_ --disable-python-bindings were
-            # used. This is invalid because Python plugins need the Python
-            # bindings to be useful.
-            AC_MSG_ERROR(--enable-python-bindings must be used to support Python plugins)
-          ]
-        )
-      ]
-    )
-  ]
-)
+##                                                                           ##
+## Set automake variables for optionnal feature conditionnals in Makefile.am ##
+##                                                                           ##
 
-# Check for conflicting optional features user choices
+AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], AE_IS_FEATURE_ENABLED([python-bindings]))
+AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], AE_IS_FEATURE_ENABLED([python-bindings-doc]))
+AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], AE_IS_FEATURE_ENABLED([python-plugins]))
+AM_CONDITIONAL([ENABLE_DEBUG_INFO], AE_IS_FEATURE_ENABLED([debug-info]))
+AM_CONDITIONAL([ENABLE_API_DOC], AE_IS_FEATURE_ENABLED([api-doc]))
+AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], AE_IS_FEATURE_ENABLED([built-in-plugins]))
+AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], AE_IS_FEATURE_ENABLED([built-in-python-plugin-support]))
+AM_CONDITIONAL([ENABLE_MAN_PAGES], AE_IS_FEATURE_ENABLED([man-pages]))
+AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], AE_IS_FEATURE_ENABLED([python-bindings]) || AE_IS_FEATURE_ENABLED([python-plugins]))
 
-AS_IF([test "x$enable_built_in_plugins" = xyes],
-  [
-    # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
-    AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
-    AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
-  ]
+
+##                                                                     ##
+## Set defines for optionnal features conditionnals in the source code ##
+##                                                                     ##
+
+AE_IF_FEATURE_ENABLED([built-in-plugins],
+  [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 )
 
-AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
-  [
-    AS_IF([test "x$enable_python_plugins" != xyes], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
-    # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
-    AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
-    AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
-  ]
+AE_IF_FEATURE_ENABLED([built-in-python-plugin-support],
+  [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 )
 
+AE_IF_FEATURE_ENABLED([debug-info], [ENABLE_DEBUG_INFO_VAL=1], [ENABLE_DEBUG_INFO_VAL=0])
+AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 
-# Check for optionnal features dependencies
 
-AS_IF([test "x$enable_python_bindings" = xyes],
+##                                           ##
+## Check for optionnal features dependencies ##
+##                                           ##
+
+# The Python bindings require SWIG
+AE_IF_FEATURE_ENABLED([python-bindings],
   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 )
 
+# Always check for python, we will fail later if some features require it and
+# it's unavailable.
 AM_PATH_PYTHON([3.0], [
-  AM_PATH_PYTHON_MODULES([PYTHON])
+  AE_PATH_PYTHON_MODULES([PYTHON])
 
   # pythondir is the path where extra modules are to be installed
   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
@@ -522,37 +528,45 @@ AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 
-AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
+AS_IF([AE_IS_FEATURE_ENABLED([python-bindings]) || AE_IS_FEATURE_ENABLED([python-plugins])], [
   AS_IF([test "x$have_python_dev" = xno], [
     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
   ])
 ])
 
-AS_IF([test "x$enable_python_bindings_doc" = xyes],
+AE_IF_FEATURE_ENABLED([python-bindings-doc],
   [
-    AM_CHECK_PYTHON_SPHINX([PYTHON])
+    AE_CHECK_PYTHON_SPHINX([PYTHON])
     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno], [
       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])
     ])
 
-    AS_IF([test "x$enable_python_bindings" != xyes], [
+    AE_IF_FEATURE_NOT_ENABLED([python-bindings], [
       AC_MSG_ERROR([The Python bindings are required to build their documentation])
     ])
   ]
 )
 
-AS_IF([test "x$enable_debug_info" = xyes],
-  [
-    # Check if libelf and libdw are present
-    AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
-    AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
-    BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
-    ELFUTILS_LIBS="-lelf -ldw"
-  ]
-)
+AE_IF_FEATURE_ENABLED([debug-info], [
+  # Check if libelf and libdw are present
+  PKG_CHECK_MODULES([ELFUTILS], [libelf >= 0.154 libdw >= 0.154],
+    [
+      dnl PKG_CHECK_MODULES defines ELFUTILS_LIBS
+    ],
+    [
+      AC_MSG_WARN([pkg-config was unable to find a valid .pc for libelf/libdw. Set PKG_CONFIG_PATH to specify the pkg-config configuration file location.])
+
+      # Turns out SLES12 doesn't bother shipping .pc file for libelf
+      AC_MSG_WARN([Finding libelf without pkg-config.])
+      AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
+      AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
+      AE_LIB_ELFUTILS([0], [154], [], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
+      ELFUTILS_LIBS="-lelf -ldw"
+    ])
+])
 AC_SUBST([ELFUTILS_LIBS])
 
-AS_IF([test "x$enable_api_doc" = "xyes"],
+AE_IF_FEATURE_ENABLED([api-doc],
   [
     DX_DOXYGEN_FEATURE(ON)
     DX_DOT_FEATURE(OFF)
@@ -577,7 +591,7 @@ warn_prebuilt_man_pages=no
 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 AC_PATH_PROG([XMLTO], [xmlto], [no])
 
-AS_IF([test "x$enable_man_pages" = "xyes"], [
+AE_IF_FEATURE_ENABLED([man-pages], [
   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
     AS_IF([test "x$in_git_repo" = "xyes"], [
       # this is an error because we're in the Git repo, which
@@ -620,9 +634,13 @@ AS_IF([test "x$exec_prefix" = xNONE], [
 
 AC_SUBST(LIBDIR)
 
+
+
+
 # CFLAGS from libraries (the glib ones are needed for the following sizeof
 # test).
 AM_CFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
+AM_CXXFLAGS="${PTHREAD_CFLAGS} ${GLIB_CFLAGS}"
 
 # Check that the current size_t matches the size that glib thinks it should
 # be. This catches problems on multi-arch where people try to do a 32-bit
@@ -659,14 +677,12 @@ CFLAGS=${save_CFLAGS}
 
 # Detect C and LD warning flags supported by the compiler.
 
-# Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
+# Detect warning flags supported by the C and C++ compilers and append them to
+# WARN_CFLAGS and WARN_CXXFLAGS.
 #
-# Pass -Werror as an extra flag during the test: this is needed to make the
-# -Wunknown-warning-option diagnostic fatal with clang.
-AX_APPEND_COMPILE_FLAGS([ dnl
+m4_define([WARN_FLAGS_LIST], [ dnl
 		-Wall dnl
 		-Wextra dnl
-		-Wstrict-prototypes dnl
 		-Wmissing-prototypes dnl
 		-Wmissing-declarations dnl
 		-Wnull-dereference dnl
@@ -701,33 +717,33 @@ AX_APPEND_COMPILE_FLAGS([ dnl
 		dnl Ref: https://github.com/swig/swig/issues/1259
 		-Wno-cast-function-type dnl
 		-Wno-missing-field-initializers dnl
-	],
-	[WARN_CFLAGS],
-	[-Werror])
+	])
 
-# When given, add -Werror to WARN_CFLAGS.
-AC_ARG_ENABLE([Werror],
-	[AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
-)
-AS_IF([test "x$enable_Werror" = "xyes"],
-	[WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
-)
+# Pass -Werror as an extra flag during the test: this is needed to make the
+# -Wunknown-warning-option diagnostic fatal with clang.
+AC_LANG([C++])
+AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror])
+AC_LANG([C])
+AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
+
+AE_IF_FEATURE_ENABLED([Werror], [WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"])
+AE_IF_FEATURE_ENABLED([Werror], [WARN_CFLAGS="${WARN_CFLAGS} -Werror"])
 
 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
-# written in such a way that it triggers a -Wold-style-definition warning.  So
-# this warning always ends up disabled if we put it there, because the test
-# program does not build.
+# written in such a way that it triggers warnings with the following warning
+# flags.  So they would always end up disabled if we put them there, because
+# the test program would not build.
 #
-# Enable it here unconditionally.  It is supported by GCC >= 4.8 and by Clang
-# (it is accepted for compatibility although it has no effect), and there is
-# not reason to not want it.
-
-WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition"
+# Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
+# Clang >= 3.3 (required by the project) and are only valid for C code.
+WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 
 # CFLAGS from AX_APPEND_COMPILE_FLAGS.
+AM_CXXFLAGS="${AM_CXXFLAGS} ${WARN_CXXFLAGS}"
 AM_CFLAGS="${AM_CFLAGS} ${WARN_CFLAGS}"
 
-# Done for AM_CFLAGS.
+# Done for AM_CXXFLAGS and AM_CFLAGS.
+AC_SUBST(AM_CXXFLAGS)
 AC_SUBST(AM_CFLAGS)
 
 # Set global CPPFLAGS in AM_CPPFLAGS
@@ -820,10 +836,13 @@ AC_CONFIG_FILES([
 	tests/plugins/flt.utils.muxer/Makefile
 	tests/plugins/flt.utils.muxer/succeed/Makefile
 	tests/plugins/flt.utils.trimmer/Makefile
+	tests/plugins/sink.text.pretty/Makefile
 	tests/utils/Makefile
 	tests/utils/tap/Makefile
 ])
 
+AC_CONFIG_FILES([tests/utils/env.sh],[chmod +x tests/utils/env.sh])
+
 AC_OUTPUT
 
 #
@@ -844,11 +863,11 @@ AS_IF([test -n "bt_version_name"], [
 
 AS_ECHO
 
-AS_IF([test -n "$bt_version_description"], [
+AS_IF([test -n "bt_version_description"], [
 	AS_IF([test -n "$report_fold"], [
-		AS_ECHO("`AS_ECHO("$bt_version_description") | $report_fold -s`")
+		AS_ECHO("`AS_ECHO("bt_version_description") | $report_fold -s`")
 	], [
-		AS_ECHO("$bt_version_description")
+		AS_ECHO("bt_version_description")
 	])
 
 	AS_ECHO
@@ -888,7 +907,7 @@ AS_IF([test "x$have_python_dev" = "xyes"], [
   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 ])
-AS_IF([test "x$enable_python_bindings" = "xyes"], [
+AE_IF_FEATURE_ENABLED([python-bindings], [
   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 ])