configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_DISABLE_OPTION_CHECKING
  35
  36 if test x"${enable_gdb}" != x"no" -a x"${enable_src_release_build}" != x"yes"; then
  37   # For this branch, we do not support building GDB in-tree.
  38   # Try to detect whether we are in this situation or not by
  39   # searching for a couple of known files in the source directory.
  40   if test -f gnulib/update-gnulib.sh -a -f gdb/ChangeLog; then
  41     AC_MSG_ERROR([GDB must be configured and built in a directory separate from its sources.
  42
  43 To do so, create a dedicated directory for your GDB build and invoke
  44 the configure script from that directory:
  45
  46       $ mkdir build
  47       $ cd build
  48       $ <full path to your sources>/gdb-VERSION/configure [[etc...]]
  49       $ make])
  50   fi
  51 fi
  52
  53 progname=$0
  54 # if PWD already has a value, it is probably wrong.
  55 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  56
  57 # Export original configure arguments for use by sub-configures.
  58 # Quote arguments with shell meta charatcers.
  59 TOPLEVEL_CONFIGURE_ARGUMENTS=
  60 set -- "$progname" "$@"
  61 for ac_arg
  62 do
  63   case "$ac_arg" in
  64   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  65     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  66     # if the argument is of the form -foo=baz, quote the baz part only
  67     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  68   *) ;;
  69   esac
  70   # Add the quoted argument to the list.
  71   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  72 done
  73 if test "$silent" = yes; then
  74   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  75 fi
  76 # Remove the initial space we just introduced and, as these will be
  77 # expanded by make, quote '$'.
  78 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  79 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  80
  81 # Find the build, host, and target systems.
  82 ACX_NONCANONICAL_BUILD
  83 ACX_NONCANONICAL_HOST
  84 ACX_NONCANONICAL_TARGET
  85
  86 dnl Autoconf 2.5x and later will set a default program prefix if
  87 dnl --target was used, even if it was the same as --host.  Disable
  88 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  89 dnl to take effect.
  90 test "$host_noncanonical" = "$target_noncanonical" &&
  91   test "$program_prefix$program_suffix$program_transform_name" = \
  92     NONENONEs,x,x, &&
  93   program_transform_name=s,y,y,
  94
  95 AC_CANONICAL_SYSTEM
  96 AC_ARG_PROGRAM
  97
  98 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  99 m4_pattern_allow([^AS_FOR_BUILD$])dnl
 100
 101 # Get 'install' or 'install-sh' and its variants.
 102 AC_PROG_INSTALL
 103 ACX_PROG_LN
 104 AC_PROG_LN_S
 105 AC_PROG_SED
 106 AC_PROG_AWK
 107
 108 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
 109
 110 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
 111 # a relative path.
 112 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 113   INSTALL="${srcpwd}/install-sh -c"
 114 fi
 115
 116 # Set srcdir to "." if that's what it is.
 117 # This is important for multilib support.
 118 pwd=`${PWDCMD-pwd}`
 119 if test "${pwd}" = "${srcpwd}" ; then
 120   srcdir=.
 121 fi
 122
 123 topsrcdir=$srcpwd
 124
 125 extra_host_args=
 126
 127 ### To add a new directory to the tree, first choose whether it is a target
 128 ### or a host dependent tool.  Then put it into the appropriate list
 129 ### (library or tools, host or target), doing a dependency sort.
 130
 131 # Subdirs will be configured in the order listed in build_configdirs,
 132 # configdirs, or target_configdirs; see the serialization section below.
 133
 134 # Dependency sorting is only needed when *configuration* must be done in
 135 # a particular order.  In all cases a dependency should be specified in
 136 # the Makefile, whether or not it's implicitly specified here.
 137
 138 # Double entries in build_configdirs, configdirs, or target_configdirs may
 139 # cause circular dependencies and break everything horribly.
 140
 141 # these library is used by various programs built for the build
 142 # environment
 143 #
 144 build_libs="build-libiberty build-libcpp"
 145
 146 # these tools are built for the build environment
 147 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 148
 149 # these libraries are used by various programs built for the host environment
 150 #f
 151 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 152
 153 # these tools are built for the host environment
 154 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 155 # know that we are building the simulator.
 156 # binutils, gas and ld appear in that order because it makes sense to run
 157 # "make check" in that particular order.
 158 # If --enable-gold is used, "gold" may replace "ld".
 159 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 160
 161 # these libraries are built for the target environment, and are built after
 162 # the host libraries and the host tools (which may be a cross compiler)
 163 # Note that libiberty is not a target library.
 164 target_libraries="target-libgcc \
 165                 target-libbacktrace \
 166                 target-libgloss \
 167                 target-newlib \
 168                 target-libgomp \
 169                 target-liboffloadmic \
 170                 target-libhsail-rt \
 171                 target-libatomic \
 172                 target-libitm \
 173                 target-libstdc++-v3 \
 174                 target-libsanitizer \
 175                 target-libvtv \
 176                 target-libssp \
 177                 target-libquadmath \
 178                 target-libgfortran \
 179                 target-libffi \
 180                 target-libobjc \
 181                 target-libada \
 182                 target-libgo"
 183
 184 # these tools are built using the target libraries, and are intended to
 185 # run only in the target environment
 186 #
 187 # note: any program that *uses* libraries that are in the "target_libraries"
 188 # list belongs in this list.
 189 #
 190 target_tools="target-rda"
 191
 192 ################################################################################
 193
 194 ## All tools belong in one of the four categories, and are assigned above
 195 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 196 ## is important because configure will choke if they ever get through.
 197 ## ${configdirs} is directories we build using the host tools.
 198 ## ${target_configdirs} is directories we build using the target tools.
 199 configdirs=`echo ${host_libs} ${host_tools}`
 200 target_configdirs=`echo ${target_libraries} ${target_tools}`
 201 build_configdirs=`echo ${build_libs} ${build_tools}`
 202
 203 m4_divert_text([PARSE_ARGS],
 204 [case $srcdir in
 205   *" "*)
 206 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 207     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 208 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 209     ;;
 210 esac
 211 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 212 ])
 213
 214 ################################################################################
 215
 216 srcname="gnu development package"
 217
 218 # This gets set non-empty for some net releases of packages.
 219 appdirs=""
 220
 221 # Define is_cross_compiler to save on calls to 'test'.
 222 is_cross_compiler=
 223 if test x"${host}" = x"${target}" ; then
 224   is_cross_compiler=no
 225 else
 226   is_cross_compiler=yes
 227 fi
 228
 229 # Find the build and target subdir names.
 230 GCC_TOPLEV_SUBDIRS
 231 # Be sure to cover against remnants of an in-tree build.
 232 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 233   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 234 Use a pristine source tree when building in a separate tree])
 235 fi
 236
 237 # Skipdirs are removed silently.
 238 skipdirs=
 239 # Noconfigdirs are removed loudly.
 240 noconfigdirs=""
 241
 242 use_gnu_ld=
 243 # Make sure we don't let GNU ld be added if we didn't want it.
 244 if test x$with_gnu_ld = xno ; then
 245   use_gnu_ld=no
 246   noconfigdirs="$noconfigdirs ld gold"
 247 fi
 248
 249 use_gnu_as=
 250 # Make sure we don't let GNU as be added if we didn't want it.
 251 if test x$with_gnu_as = xno ; then
 252   use_gnu_as=no
 253   noconfigdirs="$noconfigdirs gas"
 254 fi
 255
 256 use_included_zlib=
 257 AC_ARG_WITH(system-zlib,
 258 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 259 # Make sure we don't let ZLIB be added if we didn't want it.
 260 if test x$with_system_zlib = xyes ; then
 261   use_included_zlib=no
 262   noconfigdirs="$noconfigdirs zlib"
 263 fi
 264
 265 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 266 # is provided.
 267 if test x$with_system_readline = xyes ; then
 268   noconfigdirs="$noconfigdirs readline"
 269 fi
 270
 271 # some tools are so dependent upon X11 that if we're not building with X,
 272 # it's not even worth trying to configure, much less build, that tool.
 273
 274 case ${with_x} in
 275   yes | "") ;; # the default value for this tree is that X11 is available
 276   no)
 277     skipdirs="${skipdirs} tk itcl libgui"
 278     # We won't be able to build gdbtk without X.
 279     enable_gdbtk=no
 280     ;;
 281   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 282 esac
 283
 284 # Some are only suitable for cross toolchains.
 285 # Remove these if host=target.
 286 cross_only="target-libgloss target-newlib target-opcodes"
 287
 288 case $is_cross_compiler in
 289   no) skipdirs="${skipdirs} ${cross_only}" ;;
 290 esac
 291
 292 # If both --with-headers and --with-libs are specified, default to
 293 # --without-newlib.
 294 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 295    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 296   if test x"${with_newlib}" = x ; then
 297     with_newlib=no
 298   fi
 299 fi
 300
 301 # Recognize --with-newlib/--without-newlib.
 302 case ${with_newlib} in
 303   no) skipdirs="${skipdirs} target-newlib" ;;
 304   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 305 esac
 306
 307 AC_ARG_ENABLE(as-accelerator-for,
 308 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 309                 [build as offload target compiler.
 310                 Specify offload host triple by ARG])])
 311
 312 AC_ARG_ENABLE(offload-targets,
 313 [AS_HELP_STRING([--enable-offload-targets=LIST],
 314                 [enable offloading to devices from comma-separated LIST of
 315                 TARGET[=DIR]. Use optional path to find offload target compiler
 316                 during the build])],
 317 [
 318   if test x"$enable_offload_targets" = x; then
 319     AC_MSG_ERROR([no offload targets specified])
 320   fi
 321 ], [enable_offload_targets=])
 322
 323 # Handle --enable-gold, --enable-ld.
 324 # --disable-gold [--enable-ld]
 325 #     Build only ld.  Default option.
 326 # --enable-gold [--enable-ld]
 327 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 328 #     as "ld.bfd" and "ld".
 329 # --enable-gold=default [--enable-ld]
 330 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 331 #     install ld as "ld.bfd".
 332 # --enable-gold[=default] --disable-ld
 333 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 334 # --enable-gold --enable-ld=default
 335 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 336 #     and ld.bfd).
 337 #     In other words, ld is default
 338 # --enable-gold=default --enable-ld=default
 339 #     Error.
 340
 341 default_ld=
 342 AC_ARG_ENABLE(gold,
 343 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 344                 [build gold @<:@ARG={default,yes,no}@:>@])],
 345 ENABLE_GOLD=$enableval,
 346 ENABLE_GOLD=no)
 347 case "${ENABLE_GOLD}" in
 348   yes|default)
 349     # Check for ELF target.
 350     is_elf=no
 351     case "${target}" in
 352       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 353       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 354       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 355       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 356         case "${target}" in
 357           *-*-linux*aout* | *-*-linux*oldld*)
 358             ;;
 359           *)
 360             is_elf=yes
 361             ;;
 362         esac
 363     esac
 364
 365     if test "$is_elf" = "yes"; then
 366       # Check for target supported by gold.
 367       case "${target}" in
 368         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 369         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 370           configdirs="$configdirs gold"
 371           if test x${ENABLE_GOLD} = xdefault; then
 372             default_ld=gold
 373           fi
 374           ENABLE_GOLD=yes
 375           ;;
 376       esac
 377     fi
 378     ;;
 379   no)
 380     ;;
 381   *)
 382     AC_MSG_ERROR([invalid --enable-gold argument])
 383     ;;
 384 esac
 385
 386 AC_ARG_ENABLE(ld,
 387 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 388                 [build ld @<:@ARG={default,yes,no}@:>@])],
 389 ENABLE_LD=$enableval,
 390 ENABLE_LD=yes)
 391
 392 case "${ENABLE_LD}" in
 393   default)
 394     if test x${default_ld} != x; then
 395       AC_MSG_ERROR([either gold or ld can be the default ld])
 396     fi
 397     ;;
 398   yes)
 399     ;;
 400   no)
 401     if test x${ENABLE_GOLD} != xyes; then
 402       AC_MSG_WARN([neither ld nor gold are enabled])
 403     fi
 404     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 405     ;;
 406   *)
 407     AC_MSG_ERROR([invalid --enable-ld argument])
 408     ;;
 409 esac
 410
 411 # PR gas/19109
 412 # Decide the default method for compressing debug sections.
 413 # Provide a configure time option to override our default.
 414 AC_ARG_ENABLE(compressed_debug_sections,
 415 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 416                 [Enable compressed debug sections for gas, gold or ld by
 417                  default])],
 418 [
 419   if test x"$enable_compressed_debug_sections" = xyes; then
 420     AC_MSG_ERROR([no program with compressed debug sections specified])
 421   fi
 422 ], [enable_compressed_debug_sections=])
 423
 424 # Configure extra directories which are host specific
 425
 426 case "${host}" in
 427   *-cygwin*)
 428     configdirs="$configdirs libtermcap" ;;
 429 esac
 430
 431 # A target can indicate whether a language isn't supported for some reason.
 432 # Only spaces may be used in this macro; not newlines or tabs.
 433 unsupported_languages=
 434
 435 # Remove more programs from consideration, based on the host or
 436 # target this usually means that a port of the program doesn't
 437 # exist yet.
 438
 439 case "${host}" in
 440   i[[3456789]]86-*-msdosdjgpp*)
 441     noconfigdirs="$noconfigdirs tcl tk itcl"
 442     ;;
 443 esac
 444
 445
 446 AC_ARG_ENABLE(libquadmath,
 447 AS_HELP_STRING([--disable-libquadmath],
 448   [do not build libquadmath directory]),
 449 ENABLE_LIBQUADMATH=$enableval,
 450 ENABLE_LIBQUADMATH=yes)
 451 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 452   noconfigdirs="$noconfigdirs target-libquadmath"
 453 fi
 454
 455
 456 AC_ARG_ENABLE(libquadmath-support,
 457 AS_HELP_STRING([--disable-libquadmath-support],
 458   [disable libquadmath support for Fortran]),
 459 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 460 ENABLE_LIBQUADMATH_SUPPORT=yes)
 461 enable_libquadmath_support=
 462 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 463   enable_libquadmath_support=no
 464 fi
 465
 466
 467 AC_ARG_ENABLE(libada,
 468 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 469 ENABLE_LIBADA=$enableval,
 470 ENABLE_LIBADA=yes)
 471 if test "${ENABLE_LIBADA}" != "yes" ; then
 472   noconfigdirs="$noconfigdirs gnattools"
 473 fi
 474
 475 AC_ARG_ENABLE(libssp,
 476 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 477 ENABLE_LIBSSP=$enableval,
 478 ENABLE_LIBSSP=yes)
 479
 480 AC_ARG_ENABLE(libstdcxx,
 481 AS_HELP_STRING([--disable-libstdcxx],
 482   [do not build libstdc++-v3 directory]),
 483 ENABLE_LIBSTDCXX=$enableval,
 484 ENABLE_LIBSTDCXX=default)
 485 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 486   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 487 fi]
 488
 489 # If this is accelerator compiler and its target is intelmic we enable
 490 # target liboffloadmic by default.  If this is compiler with offloading
 491 # for intelmic we enable host liboffloadmic by default.  Otherwise
 492 # liboffloadmic is disabled by default.
 493 AC_ARG_ENABLE([liboffloadmic],
 494 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 495                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 496 [case "$enableval" in
 497   no | host | target)
 498     enable_liboffloadmic=$enableval ;;
 499   *)
 500     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 501 esac],
 502 [if test x"$enable_as_accelerator_for" != x; then
 503   case "${target}" in
 504     *-intelmic-* | *-intelmicemul-*)
 505       enable_liboffloadmic=target
 506       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 507       ;;
 508     *)
 509       enable_liboffloadmic=no
 510       ;;
 511   esac
 512 else
 513   case "${enable_offload_targets}" in
 514     *-intelmic-* | *-intelmicemul-*)
 515       enable_liboffloadmic=host
 516       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 517       ;;
 518     *)
 519       enable_liboffloadmic=no
 520       ;;
 521     esac
 522 fi])
 523 AC_SUBST(extra_liboffloadmic_configure_flags)
 524
 525 # Enable libgomp by default on hosted POSIX systems, and a few others.
 526 if test x$enable_libgomp = x ; then
 527     case "${target}" in
 528     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 529         ;;
 530     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 531         ;;
 532     *-*-solaris2* | *-*-hpux11*)
 533         ;;
 534     *-*-darwin* | *-*-aix*)
 535         ;;
 536     nvptx*-*-*)
 537         ;;
 538     *)
 539         noconfigdirs="$noconfigdirs target-libgomp"
 540         ;;
 541     esac
 542 fi
 543
 544 # Disable libatomic on unsupported systems.
 545 if test -d ${srcdir}/libatomic; then
 546     if test x$enable_libatomic = x; then
 547         AC_MSG_CHECKING([for libatomic support])
 548         if (srcdir=${srcdir}/libatomic; \
 549                 . ${srcdir}/configure.tgt; \
 550                 test -n "$UNSUPPORTED")
 551         then
 552             AC_MSG_RESULT([no])
 553             noconfigdirs="$noconfigdirs target-libatomic"
 554         else
 555             AC_MSG_RESULT([yes])
 556         fi
 557     fi
 558 fi
 559
 560 # Disable liboffloadmic on unsupported systems.
 561 if test -d ${srcdir}/liboffloadmic; then
 562     if test x$enable_liboffloadmic != xno; then
 563         AC_MSG_CHECKING([for liboffloadmic support])
 564         if (srcdir=${srcdir}/liboffloadmic; \
 565                 . ${srcdir}/configure.tgt; \
 566                 test -n "$UNSUPPORTED")
 567         then
 568             AC_MSG_RESULT([no])
 569             noconfigdirs="$noconfigdirs target-liboffloadmic"
 570         else
 571             AC_MSG_RESULT([yes])
 572         fi
 573     fi
 574 fi
 575
 576 # Disable libitm on unsupported systems.
 577 if test -d ${srcdir}/libitm; then
 578     if test x$enable_libitm = x; then
 579         AC_MSG_CHECKING([for libitm support])
 580         if (srcdir=${srcdir}/libitm; \
 581                 . ${srcdir}/configure.tgt; \
 582                 test -n "$UNSUPPORTED")
 583         then
 584             AC_MSG_RESULT([no])
 585             noconfigdirs="$noconfigdirs target-libitm"
 586         else
 587             AC_MSG_RESULT([yes])
 588         fi
 589     fi
 590 fi
 591
 592 # Disable libsanitizer on unsupported systems.
 593 if test -d ${srcdir}/libsanitizer; then
 594     if test x$enable_libsanitizer = x; then
 595         AC_MSG_CHECKING([for libsanitizer support])
 596         if (srcdir=${srcdir}/libsanitizer; \
 597                 . ${srcdir}/configure.tgt; \
 598                 test -n "$UNSUPPORTED")
 599         then
 600             AC_MSG_RESULT([no])
 601             noconfigdirs="$noconfigdirs target-libsanitizer"
 602         else
 603             AC_MSG_RESULT([yes])
 604         fi
 605     fi
 606 fi
 607
 608 # Disable libvtv on unsupported systems.
 609 if test -d ${srcdir}/libvtv; then
 610     if test x$enable_libvtv = x; then
 611         AC_MSG_CHECKING([for libvtv support])
 612         if (srcdir=${srcdir}/libvtv; \
 613                 . ${srcdir}/configure.tgt; \
 614                 test "$VTV_SUPPORTED" != "yes")
 615         then
 616             AC_MSG_RESULT([no])
 617             noconfigdirs="$noconfigdirs target-libvtv"
 618         else
 619             AC_MSG_RESULT([yes])
 620         fi
 621     fi
 622 fi
 623
 624
 625 # Disable libhsail-rt on unsupported systems.
 626 if test -d ${srcdir}/libhsail-rt; then
 627     if test x$enable_libhsail_rt = x; then
 628         AC_MSG_CHECKING([for libhsail-rt support])
 629         if (srcdir=${srcdir}/libhsail-rt; \
 630                 . ${srcdir}/configure.tgt; \
 631                 test -n "$UNSUPPORTED")
 632         then
 633             AC_MSG_RESULT([no])
 634             unsupported_languages="$unsupported_languages brig"
 635             # This implicitly disables also target-libhsail-rt as it won't
 636             # get added to the build without BRIG FE.
 637         else
 638             AC_MSG_RESULT([yes])
 639         fi
 640     fi
 641 fi
 642
 643
 644 # Disable libquadmath for some systems.
 645 case "${target}" in
 646   avr-*-*)
 647     noconfigdirs="$noconfigdirs target-libquadmath"
 648     ;;
 649   # libquadmath is unused on AIX and libquadmath build process use of
 650   # LD_LIBRARY_PATH can break AIX bootstrap.
 651   powerpc-*-aix* | rs6000-*-aix*)
 652     noconfigdirs="$noconfigdirs target-libquadmath"
 653     ;;
 654 esac
 655
 656 # Disable libssp for some systems.
 657 case "${target}" in
 658   avr-*-*)
 659     # No hosted I/O support.
 660     noconfigdirs="$noconfigdirs target-libssp"
 661     ;;
 662   powerpc-*-aix* | rs6000-*-aix*)
 663     noconfigdirs="$noconfigdirs target-libssp"
 664     ;;
 665   rl78-*-*)
 666     # libssp uses a misaligned load to trigger a fault, but the RL78
 667     # doesn't fault for those - instead, it gives a build-time error
 668     # for explicit misaligned loads.
 669     noconfigdirs="$noconfigdirs target-libssp"
 670     ;;
 671   visium-*-*)
 672     # No hosted I/O support.
 673     noconfigdirs="$noconfigdirs target-libssp"
 674     ;;
 675 esac
 676
 677 # Disable libstdc++-v3 for some systems.
 678 # Allow user to override this if they pass --enable-libstdc++-v3
 679 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 680   case "${target}" in
 681     *-*-vxworks*)
 682       # VxWorks uses the Dinkumware C++ library.
 683       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 684       ;;
 685     arm*-wince-pe*)
 686       # the C++ libraries don't build on top of CE's C libraries
 687       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 688       ;;
 689     avr-*-*)
 690       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 691       ;;
 692     ft32-*-*)
 693       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 694       ;;
 695   esac
 696 fi
 697
 698 # Disable Fortran for some systems.
 699 case "${target}" in
 700   mmix-*-*)
 701     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 702     unsupported_languages="$unsupported_languages fortran"
 703     ;;
 704 esac
 705
 706 # Disable libffi for some systems.
 707 case "${target}" in
 708   powerpc-*-darwin*)
 709     ;;
 710   i[[3456789]]86-*-darwin*)
 711     ;;
 712   x86_64-*-darwin[[912]]*)
 713     ;;
 714   *-*-darwin*)
 715     noconfigdirs="$noconfigdirs target-libffi"
 716     ;;
 717   *-*-netware*)
 718     noconfigdirs="$noconfigdirs target-libffi"
 719     ;;
 720   *-*-phoenix*)
 721     noconfigdirs="$noconfigdirs target-libffi"
 722     ;;
 723   *-*-rtems*)
 724     noconfigdirs="$noconfigdirs target-libffi"
 725     ;;
 726   *-*-tpf*)
 727     noconfigdirs="$noconfigdirs target-libffi"
 728     ;;
 729   *-*-uclinux*)
 730     noconfigdirs="$noconfigdirs target-libffi"
 731     ;;
 732   *-*-vxworks*)
 733     noconfigdirs="$noconfigdirs target-libffi"
 734     ;;
 735   aarch64*-*-freebsd*)
 736     noconfigdirs="$noconfigdirs target-libffi"
 737     ;;
 738   alpha*-*-*vms*)
 739     noconfigdirs="$noconfigdirs target-libffi"
 740     ;;
 741   arm*-*-freebsd*)
 742     noconfigdirs="$noconfigdirs target-libffi"
 743     ;;
 744   arm-wince-pe)
 745     noconfigdirs="$noconfigdirs target-libffi"
 746     ;;
 747   arm*-*-symbianelf*)
 748     noconfigdirs="$noconfigdirs target-libffi"
 749     ;;
 750   cris-*-* | crisv32-*-*)
 751     case "${target}" in
 752       *-*-linux*)
 753         ;;
 754       *) # See PR46792 regarding target-libffi.
 755         noconfigdirs="$noconfigdirs target-libffi";;
 756     esac
 757     ;;
 758   hppa*64*-*-hpux*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   hppa*-hp-hpux11*)
 762     ;;
 763   hppa*-*-hpux*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   ia64*-*-*vms*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   i[[3456789]]86-w64-mingw*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   i[[3456789]]86-*-mingw*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   x86_64-*-mingw*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   mmix-*-*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   powerpc-*-aix*)
 782     ;;
 783   rs6000-*-aix*)
 784     ;;
 785   ft32-*-*)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   *-*-lynxos*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791 esac
 792
 793 # Disable the go frontend on systems where it is known to not work. Please keep
 794 # this in sync with contrib/config-list.mk.
 795 case "${target}" in
 796 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 797     unsupported_languages="$unsupported_languages go"
 798     ;;
 799 esac
 800
 801 # Disable libgo for some systems where it is known to not work.
 802 # For testing, you can easily override this with --enable-libgo.
 803 if test x$enable_libgo = x; then
 804     case "${target}" in
 805     *-*-darwin*)
 806         # PR 46986
 807         noconfigdirs="$noconfigdirs target-libgo"
 808         ;;
 809     *-*-cygwin* | *-*-mingw*)
 810         noconfigdirs="$noconfigdirs target-libgo"
 811         ;;
 812     esac
 813 fi
 814
 815 # Default libgloss CPU subdirectory.
 816 libgloss_dir="$target_cpu"
 817
 818 case "${target}" in
 819   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 820     libgloss_dir=wince
 821     ;;
 822   aarch64*-*-* )
 823     libgloss_dir=aarch64
 824     ;;
 825   arm*-*-*)
 826     libgloss_dir=arm
 827     ;;
 828   cris-*-* | crisv32-*-*)
 829     libgloss_dir=cris
 830     ;;
 831   hppa*-*-*)
 832     libgloss_dir=pa
 833     ;;
 834   i[[3456789]]86-*-*)
 835     libgloss_dir=i386
 836     ;;
 837   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 838     libgloss_dir=m68hc11
 839     ;;
 840   m68*-*-* | fido-*-*)
 841     libgloss_dir=m68k
 842     ;;
 843   mips*-*-*)
 844     libgloss_dir=mips
 845     ;;
 846   powerpc*-*-*)
 847     libgloss_dir=rs6000
 848     ;;
 849   sparc*-*-*)
 850     libgloss_dir=sparc
 851     ;;
 852 esac
 853
 854 # Disable newlib and libgloss for various target OSes.
 855 case "${target}" in
 856   alpha*-dec-osf*)
 857     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 858     ;;
 859   i[[3456789]]86-*-linux*)
 860     # This section makes it possible to build newlib natively on linux.
 861     # If we are using a cross compiler then don't configure newlib.
 862     if test x${is_cross_compiler} != xno ; then
 863       noconfigdirs="$noconfigdirs target-newlib"
 864     fi
 865     noconfigdirs="$noconfigdirs target-libgloss"
 866     # If we are not using a cross compiler, do configure newlib.
 867     # Note however, that newlib will only be configured in this situation
 868     # if the --with-newlib option has been given, because otherwise
 869     # 'target-newlib' will appear in skipdirs.
 870     ;;
 871   i[[3456789]]86-*-rdos*)
 872     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 873     ;;
 874   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 875     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 876     ;;
 877   sparc-*-sunos4*)
 878     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 879     ;;
 880   *-*-aix*)
 881     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 882     ;;
 883   *-*-beos*)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   *-*-chorusos)
 887     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 888     ;;
 889   *-*-dragonfly*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   *-*-freebsd*)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 896     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 897     ;;
 898   *-*-lynxos*)
 899     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 900     ;;
 901   *-*-mingw*)
 902     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 903     ;;
 904   *-*-netbsd*)
 905     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 906     ;;
 907   *-*-netware*)
 908     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     ;;
 910   *-*-tpf*)
 911     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 912     ;;
 913   *-*-uclinux*)
 914     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 915     ;;
 916   *-*-vxworks*)
 917     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 918     ;;
 919 esac
 920
 921 case "${target}" in
 922   *-*-chorusos)
 923     ;;
 924   aarch64-*-darwin*)
 925     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 926     noconfigdirs="$noconfigdirs sim target-rda"
 927     ;;
 928   arm-*-darwin*)
 929     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 930     noconfigdirs="$noconfigdirs sim target-rda"
 931     ;;
 932   powerpc-*-darwin*)
 933     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 934     noconfigdirs="$noconfigdirs sim target-rda"
 935     ;;
 936   i[[3456789]]86-*-darwin*)
 937     noconfigdirs="$noconfigdirs ld gprof"
 938     noconfigdirs="$noconfigdirs sim target-rda"
 939     ;;
 940   x86_64-*-darwin[[912]]*)
 941     noconfigdirs="$noconfigdirs ld gas gprof"
 942     noconfigdirs="$noconfigdirs sim target-rda"
 943     ;;
 944   *-*-darwin*)
 945     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 946     noconfigdirs="$noconfigdirs sim target-rda"
 947     ;;
 948   *-*-dragonfly*)
 949     ;;
 950   *-*-freebsd*)
 951     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 952         && test -f /usr/local/include/gmp.h; then
 953       with_gmp=/usr/local
 954     fi
 955     ;;
 956   *-*-kaos*)
 957     # Remove unsupported stuff on all kaOS configurations.
 958     noconfigdirs="$noconfigdirs target-libgloss"
 959     ;;
 960   *-*-netbsd*)
 961     ;;
 962   *-*-netware*)
 963     ;;
 964   *-*-phoenix*)
 965     noconfigdirs="$noconfigdirs target-libgloss"
 966     ;;
 967   *-*-rtems*)
 968     noconfigdirs="$noconfigdirs target-libgloss"
 969     ;;
 970     # The tpf target doesn't support gdb yet.
 971   *-*-tpf*)
 972     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 973     ;;
 974   *-*-uclinux*)
 975     noconfigdirs="$noconfigdirs target-rda"
 976     ;;
 977   *-*-vxworks*)
 978     ;;
 979   alpha*-dec-osf*)
 980     # ld works, but does not support shared libraries.
 981     # gas doesn't generate exception information.
 982     noconfigdirs="$noconfigdirs gas ld"
 983     ;;
 984   alpha*-*-*vms*)
 985     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 986     ;;
 987   alpha*-*-*)
 988     # newlib is not 64 bit ready
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 992     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 993     ;;
 994   arc*-*-*)
 995     noconfigdirs="$noconfigdirs sim"
 996     ;;
 997   arm-*-pe*)
 998     noconfigdirs="$noconfigdirs target-libgloss"
 999     ;;
1000   arm-*-riscix*)
1001     noconfigdirs="$noconfigdirs ld target-libgloss"
1002     ;;
1003   avr-*-*)
1004     if test x${with_avrlibc} != xno; then
1005       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1006     fi
1007     ;;
1008   c4x-*-* | tic4x-*-*)
1009     noconfigdirs="$noconfigdirs target-libgloss"
1010     ;;
1011   tic54x-*-*)
1012     noconfigdirs="$noconfigdirs target-libgloss gdb"
1013     ;;
1014   d10v-*-*)
1015     noconfigdirs="$noconfigdirs target-libgloss"
1016     ;;
1017   d30v-*-*)
1018     noconfigdirs="$noconfigdirs gdb"
1019     ;;
1020   fr30-*-elf*)
1021     noconfigdirs="$noconfigdirs gdb"
1022     ;;
1023   ft32-*-*)
1024     noconfigdirs="$noconfigdirs target-rda gprof"
1025     ;;
1026   moxie-*-*)
1027     noconfigdirs="$noconfigdirs"
1028     ;;
1029   h8300*-*-*)
1030     noconfigdirs="$noconfigdirs target-libgloss"
1031     ;;
1032   h8500-*-*)
1033     noconfigdirs="$noconfigdirs target-libgloss"
1034     ;;
1035   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1036     ;;
1037   hppa*64*-*-hpux*)
1038     noconfigdirs="$noconfigdirs gdb"
1039     ;;
1040   hppa*-*-hpux11*)
1041     noconfigdirs="$noconfigdirs gdb ld"
1042     ;;
1043   hppa*64*-*-linux*)
1044     ;;
1045   hppa*-*-linux*)
1046     ;;
1047   hppa*-*-*elf* | \
1048   hppa*-*-lites* | \
1049   hppa*-*-openbsd* | \
1050   hppa*64*-*-*)
1051     ;;
1052   hppa*-*-pro*)
1053     ;;
1054   hppa*-*-*)
1055     noconfigdirs="$noconfigdirs ld"
1056     ;;
1057   i960-*-*)
1058     noconfigdirs="$noconfigdirs gdb"
1059     ;;
1060   ia64*-*-elf*)
1061     # No gdb support yet.
1062     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1063     ;;
1064   ia64*-**-hpux*)
1065     # No ld support yet.
1066     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1067     ;;
1068   ia64*-*-*vms*)
1069     # No ld support yet.
1070     noconfigdirs="$noconfigdirs libgui itcl ld"
1071     ;;
1072   i[[3456789]]86-w64-mingw*)
1073     ;;
1074   i[[3456789]]86-*-mingw*)
1075     target_configdirs="$target_configdirs target-winsup"
1076     ;;
1077   *-*-cygwin*)
1078     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1079     noconfigdirs="$noconfigdirs target-libgloss"
1080     # always build newlib if winsup directory is present.
1081     if test -d "$srcdir/winsup/cygwin"; then
1082       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1083     elif test -d "$srcdir/newlib"; then
1084       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1085     fi
1086     ;;
1087   i[[3456789]]86-*-pe)
1088     noconfigdirs="$noconfigdirs target-libgloss"
1089     ;;
1090   i[[3456789]]86-*-sco3.2v5*)
1091     # The linker does not yet know about weak symbols in COFF,
1092     # and is not configured to handle mixed ELF and COFF.
1093     noconfigdirs="$noconfigdirs ld target-libgloss"
1094     ;;
1095   i[[3456789]]86-*-sco*)
1096     noconfigdirs="$noconfigdirs gprof target-libgloss"
1097     ;;
1098   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1099     noconfigdirs="$noconfigdirs target-libgloss"
1100     ;;
1101   i[[3456789]]86-*-sysv4*)
1102     noconfigdirs="$noconfigdirs target-libgloss"
1103     ;;
1104   i[[3456789]]86-*-beos*)
1105     noconfigdirs="$noconfigdirs gdb"
1106     ;;
1107   i[[3456789]]86-*-rdos*)
1108     noconfigdirs="$noconfigdirs gdb"
1109     ;;
1110   mmix-*-*)
1111     noconfigdirs="$noconfigdirs gdb"
1112     ;;
1113   mt-*-*)
1114     noconfigdirs="$noconfigdirs sim"
1115     ;;
1116   nfp-*-*)
1117     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1118     noconfigdirs="$noconfigdirs $target_libraries"
1119     ;;
1120   powerpc-*-aix*)
1121     # copied from rs6000-*-* entry
1122     noconfigdirs="$noconfigdirs gprof"
1123     ;;
1124   powerpc*-*-winnt* | powerpc*-*-pe*)
1125     target_configdirs="$target_configdirs target-winsup"
1126     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1127     # always build newlib.
1128     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1129     ;;
1130     # This is temporary until we can link against shared libraries
1131   powerpcle-*-solaris*)
1132     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1133     ;;
1134   powerpc-*-beos*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   rs6000-*-lynxos*)
1138     noconfigdirs="$noconfigdirs gprof"
1139     ;;
1140   rs6000-*-aix*)
1141     noconfigdirs="$noconfigdirs gprof"
1142     ;;
1143   rs6000-*-*)
1144     noconfigdirs="$noconfigdirs gprof"
1145     ;;
1146   m68k-apollo-*)
1147     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1148     ;;
1149   microblaze*)
1150     noconfigdirs="$noconfigdirs gprof"
1151     ;;
1152   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1153     if test x$with_newlib = xyes; then
1154       noconfigdirs="$noconfigdirs gprof"
1155     fi
1156     ;;
1157   mips*-*-irix5*)
1158     noconfigdirs="$noconfigdirs gprof target-libgloss"
1159     ;;
1160   mips*-*-irix6*)
1161     noconfigdirs="$noconfigdirs gprof target-libgloss"
1162     ;;
1163   mips*-*-bsd*)
1164     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1165     ;;
1166   mips*-*-linux*)
1167     ;;
1168   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1169   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1170     noconfigdirs="$noconfigdirs ld gas gprof"
1171     ;;
1172   mips*-*-*)
1173     noconfigdirs="$noconfigdirs gprof"
1174     ;;
1175   nvptx*-*-*)
1176     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1177     ;;
1178   sh-*-*)
1179     case "${target}" in
1180       sh*-*-elf)
1181          ;;
1182       *)
1183          noconfigdirs="$noconfigdirs target-libgloss" ;;
1184     esac
1185     ;;
1186   sparc-*-sunos4*)
1187     if test x${is_cross_compiler} = xno ; then
1188            use_gnu_ld=no
1189     fi
1190     ;;
1191   tic6x-*-*)
1192     noconfigdirs="$noconfigdirs sim"
1193     ;;
1194   tilepro*-*-* | tilegx*-*-*)
1195     noconfigdirs="$noconfigdirs sim"
1196     ;;
1197   v810-*-*)
1198     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1199     ;;
1200   vax-*-*)
1201     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1202     ;;
1203   wasm32-*-*)
1204     noconfigdirs="$noconfigdirs ld"
1205     ;;
1206 esac
1207
1208 # If we aren't building newlib, then don't build libgloss, since libgloss
1209 # depends upon some newlib header files.
1210 case "${noconfigdirs}" in
1211   *target-libgloss*) ;;
1212   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1213 esac
1214
1215 # Work in distributions that contain no compiler tools, like Autoconf.
1216 host_makefile_frag=/dev/null
1217 if test -d ${srcdir}/config ; then
1218 case "${host}" in
1219   i[[3456789]]86-*-msdosdjgpp*)
1220     host_makefile_frag="config/mh-djgpp"
1221     ;;
1222   *-cygwin*)
1223     ACX_CHECK_CYGWIN_CAT_WORKS
1224     host_makefile_frag="config/mh-cygwin"
1225     ;;
1226   *-mingw*)
1227     host_makefile_frag="config/mh-mingw"
1228     ;;
1229   alpha*-linux*)
1230     host_makefile_frag="config/mh-alpha-linux"
1231     ;;
1232   hppa*-hp-hpux10*)
1233     host_makefile_frag="config/mh-pa-hpux10"
1234     ;;
1235   hppa*-hp-hpux*)
1236     host_makefile_frag="config/mh-pa"
1237     ;;
1238   hppa*-*)
1239     host_makefile_frag="config/mh-pa"
1240     ;;
1241   *-*-darwin*)
1242     host_makefile_frag="config/mh-darwin"
1243     ;;
1244   powerpc-*-aix*)
1245     host_makefile_frag="config/mh-ppc-aix"
1246     ;;
1247   rs6000-*-aix*)
1248     host_makefile_frag="config/mh-ppc-aix"
1249     ;;
1250 esac
1251 fi
1252
1253 if test "${build}" != "${host}" ; then
1254   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1255   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1256   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1257   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1258   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1259   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1260   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1261   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1262   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1263   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1264   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1265   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1266 else
1267   AR_FOR_BUILD="\$(AR)"
1268   AS_FOR_BUILD="\$(AS)"
1269   CC_FOR_BUILD="\$(CC)"
1270   CXX_FOR_BUILD="\$(CXX)"
1271   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1272   GOC_FOR_BUILD="\$(GOC)"
1273   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1274   LD_FOR_BUILD="\$(LD)"
1275   NM_FOR_BUILD="\$(NM)"
1276   RANLIB_FOR_BUILD="\$(RANLIB)"
1277   WINDRES_FOR_BUILD="\$(WINDRES)"
1278   WINDMC_FOR_BUILD="\$(WINDMC)"
1279 fi
1280
1281 AC_PROG_CC
1282 AC_PROG_CXX
1283
1284 # We must set the default linker to the linker used by gcc for the correct
1285 # operation of libtool.  If LD is not defined and we are using gcc, try to
1286 # set the LD default to the ld used by gcc.
1287 if test -z "$LD"; then
1288   if test "$GCC" = yes; then
1289     case $build in
1290     *-*-mingw*)
1291       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1292     *)
1293       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1294     esac
1295     case $gcc_prog_ld in
1296     # Accept absolute paths.
1297     [[\\/]* | [A-Za-z]:[\\/]*)]
1298       LD="$gcc_prog_ld" ;;
1299     esac
1300   fi
1301 fi
1302
1303 # Check whether -static-libstdc++ -static-libgcc is supported.
1304 have_static_libs=no
1305 if test "$GCC" = yes; then
1306   saved_LDFLAGS="$LDFLAGS"
1307
1308   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1309   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1310   AC_LANG_PUSH(C++)
1311   AC_LINK_IFELSE([AC_LANG_SOURCE([
1312 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1313 #error -static-libstdc++ not implemented
1314 #endif
1315 int main() {}])],
1316     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1317     [AC_MSG_RESULT([no])])
1318   AC_LANG_POP(C++)
1319
1320   LDFLAGS="$saved_LDFLAGS"
1321 fi
1322
1323 ACX_PROG_GNAT
1324 ACX_PROG_CMP_IGNORE_INITIAL
1325
1326 AC_ARG_ENABLE([bootstrap],
1327 [AS_HELP_STRING([--enable-bootstrap],
1328                 [enable bootstrapping @<:@yes if native build@:>@])],,
1329 enable_bootstrap=default)
1330
1331 # Issue errors and warnings for invalid/strange bootstrap combinations.
1332 if test -r $srcdir/gcc/configure; then
1333   have_compiler=yes
1334 else
1335   have_compiler=no
1336 fi
1337
1338 case "$have_compiler:$host:$target:$enable_bootstrap" in
1339   *:*:*:no) ;;
1340
1341   # Default behavior.  Enable bootstrap if we have a compiler
1342   # and we are in a native configuration.
1343   yes:$build:$build:default)
1344     enable_bootstrap=yes ;;
1345
1346   *:*:*:default)
1347     enable_bootstrap=no ;;
1348
1349   # We have a compiler and we are in a native configuration, bootstrap is ok
1350   yes:$build:$build:yes)
1351     ;;
1352
1353   # Other configurations, but we have a compiler.  Assume the user knows
1354   # what he's doing.
1355   yes:*:*:yes)
1356     AC_MSG_WARN([trying to bootstrap a cross compiler])
1357     ;;
1358
1359   # No compiler: if they passed --enable-bootstrap explicitly, fail
1360   no:*:*:yes)
1361     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1362
1363   # Fail if wrong command line
1364   *)
1365     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1366     ;;
1367 esac
1368
1369 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1370 # C++98 compiler can still start the bootstrap.
1371 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1372   CXX="$CXX -std=gnu++98"
1373 fi
1374
1375 # Used for setting $lt_cv_objdir
1376 _LT_CHECK_OBJDIR
1377
1378 # Check for GMP, MPFR and MPC
1379 gmplibs="-lmpc -lmpfr -lgmp"
1380 gmpinc=
1381 have_gmp=no
1382
1383 # Specify a location for mpc
1384 # check for this first so it ends up on the link line before mpfr.
1385 AC_ARG_WITH(mpc,
1386 [AS_HELP_STRING([--with-mpc=PATH],
1387                 [specify prefix directory for installed MPC package.
1388                  Equivalent to --with-mpc-include=PATH/include
1389                  plus --with-mpc-lib=PATH/lib])])
1390 AC_ARG_WITH(mpc-include,
1391 [AS_HELP_STRING([--with-mpc-include=PATH],
1392                 [specify directory for installed MPC include files])])
1393 AC_ARG_WITH(mpc-lib,
1394 [AS_HELP_STRING([--with-mpc-lib=PATH],
1395                 [specify directory for the installed MPC library])])
1396
1397 if test "x$with_mpc" != x; then
1398   gmplibs="-L$with_mpc/lib $gmplibs"
1399   gmpinc="-I$with_mpc/include $gmpinc"
1400 fi
1401 if test "x$with_mpc_include" != x; then
1402   gmpinc="-I$with_mpc_include $gmpinc"
1403 fi
1404 if test "x$with_mpc_lib" != x; then
1405   gmplibs="-L$with_mpc_lib $gmplibs"
1406 fi
1407 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1408   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1409   gmpinc='-I$$s/mpc/src '"$gmpinc"
1410   # Do not test the mpc version.  Assume that it is sufficient, since
1411   # it is in the source tree, and the library has not been built yet
1412   # but it would be included on the link line in the version check below
1413   # hence making the test fail.
1414   have_gmp=yes
1415 fi
1416
1417 # Specify a location for mpfr
1418 # check for this first so it ends up on the link line before gmp.
1419 AC_ARG_WITH(mpfr-dir,
1420 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1421 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1422 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1423
1424 AC_ARG_WITH(mpfr,
1425 [AS_HELP_STRING([--with-mpfr=PATH],
1426                 [specify prefix directory for installed MPFR package.
1427                  Equivalent to --with-mpfr-include=PATH/include
1428                  plus --with-mpfr-lib=PATH/lib])])
1429 AC_ARG_WITH(mpfr-include,
1430 [AS_HELP_STRING([--with-mpfr-include=PATH],
1431                 [specify directory for installed MPFR include files])])
1432 AC_ARG_WITH(mpfr-lib,
1433 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1434                 [specify directory for the installed MPFR library])])
1435
1436 if test "x$with_mpfr" != x; then
1437   gmplibs="-L$with_mpfr/lib $gmplibs"
1438   gmpinc="-I$with_mpfr/include $gmpinc"
1439 fi
1440 if test "x$with_mpfr_include" != x; then
1441   gmpinc="-I$with_mpfr_include $gmpinc"
1442 fi
1443 if test "x$with_mpfr_lib" != x; then
1444   gmplibs="-L$with_mpfr_lib $gmplibs"
1445 fi
1446 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1447   # MPFR v3.1.0 moved the sources into a src sub-directory.
1448   if ! test -d ${srcdir}/mpfr/src; then
1449     AC_MSG_ERROR([dnl
1450 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1451   fi
1452   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1453   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1454   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1455   # Do not test the mpfr version.  Assume that it is sufficient, since
1456   # it is in the source tree, and the library has not been built yet
1457   # but it would be included on the link line in the version check below
1458   # hence making the test fail.
1459   have_gmp=yes
1460 fi
1461
1462 # Specify a location for gmp
1463 AC_ARG_WITH(gmp-dir,
1464 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1465 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1466 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1467
1468 AC_ARG_WITH(gmp,
1469 [AS_HELP_STRING([--with-gmp=PATH],
1470                 [specify prefix directory for the installed GMP package.
1471                  Equivalent to --with-gmp-include=PATH/include
1472                  plus --with-gmp-lib=PATH/lib])])
1473 AC_ARG_WITH(gmp-include,
1474 [AS_HELP_STRING([--with-gmp-include=PATH],
1475                 [specify directory for installed GMP include files])])
1476 AC_ARG_WITH(gmp-lib,
1477 [AS_HELP_STRING([--with-gmp-lib=PATH],
1478                 [specify directory for the installed GMP library])])
1479
1480
1481 if test "x$with_gmp" != x; then
1482   gmplibs="-L$with_gmp/lib $gmplibs"
1483   gmpinc="-I$with_gmp/include $gmpinc"
1484 fi
1485 if test "x$with_gmp_include" != x; then
1486   gmpinc="-I$with_gmp_include $gmpinc"
1487 fi
1488 if test "x$with_gmp_lib" != x; then
1489   gmplibs="-L$with_gmp_lib $gmplibs"
1490 fi
1491 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1492   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1493   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1494   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1495   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1496   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1497   # Do not test the gmp version.  Assume that it is sufficient, since
1498   # it is in the source tree, and the library has not been built yet
1499   # but it would be included on the link line in the version check below
1500   # hence making the test fail.
1501   have_gmp=yes
1502 fi
1503
1504 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1505   have_gmp=yes
1506   saved_CFLAGS="$CFLAGS"
1507   CFLAGS="$CFLAGS $gmpinc"
1508   # Check for the recommended and required versions of GMP.
1509   AC_MSG_CHECKING([for the correct version of gmp.h])
1510   AC_TRY_COMPILE([#include "gmp.h"],[
1511   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1512   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1513   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1514   choke me
1515   #endif
1516   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1517   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1518   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1519   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1520   choke me
1521   #endif
1522   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1523    [AC_MSG_RESULT([no]); have_gmp=no])
1524
1525   # If we have GMP, check the MPFR version.
1526   if test x"$have_gmp" = xyes; then
1527     # Check for the recommended and required versions of MPFR.
1528     AC_MSG_CHECKING([for the correct version of mpfr.h])
1529     AC_TRY_COMPILE([#include <gmp.h>
1530     #include <mpfr.h>],[
1531     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1532     choke me
1533     #endif
1534     ], [AC_TRY_COMPILE([#include <gmp.h>
1535     #include <mpfr.h>],[
1536     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1537     choke me
1538     #endif
1539     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1540      [AC_MSG_RESULT([no]); have_gmp=no])
1541   fi
1542
1543   # Check for the MPC header version.
1544   if test x"$have_gmp" = xyes ; then
1545     # Check for the recommended and required versions of MPC.
1546     AC_MSG_CHECKING([for the correct version of mpc.h])
1547     AC_TRY_COMPILE([#include <mpc.h>],[
1548     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1549     choke me
1550     #endif
1551     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1552     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1553     choke me
1554     #endif
1555     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1556      [AC_MSG_RESULT([no]); have_gmp=no])
1557   fi
1558
1559   # Now check the MPFR library.
1560   if test x"$have_gmp" = xyes; then
1561     saved_LIBS="$LIBS"
1562     LIBS="$LIBS $gmplibs"
1563     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1564     AC_TRY_LINK([#include <mpc.h>],[
1565     mpfr_t n;
1566     mpfr_t x;
1567     mpc_t c;
1568     int t;
1569     mpfr_init (n);
1570     mpfr_init (x);
1571     mpfr_atan2 (n, n, x, GMP_RNDN);
1572     mpfr_erfc (n, x, GMP_RNDN);
1573     mpfr_subnormalize (x, t, GMP_RNDN);
1574     mpfr_clear(n);
1575     mpfr_clear(x);
1576     mpc_init2 (c, 53);
1577     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1578     mpc_cosh (c, c, MPC_RNDNN);
1579     mpc_pow (c, c, c, MPC_RNDNN);
1580     mpc_acosh (c, c, MPC_RNDNN);
1581     mpc_clear (c);
1582     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1583     LIBS="$saved_LIBS"
1584   fi
1585
1586   CFLAGS="$saved_CFLAGS"
1587
1588 # The library versions listed in the error message below should match
1589 # the HARD-minimums enforced above.
1590   if test x$have_gmp != xyes; then
1591     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1592 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1593 their locations.  Source code for these libraries can be found at
1594 their respective hosting sites as well as at
1595 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1596 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1597 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1598 make sure that you have installed both the libraries and the header
1599 files.  They may be located in separate packages.])
1600   fi
1601 fi
1602
1603 # Flags needed for both GMP, MPFR and/or MPC.
1604 AC_SUBST(gmplibs)
1605 AC_SUBST(gmpinc)
1606 AC_SUBST(extra_mpfr_configure_flags)
1607 AC_SUBST(extra_mpc_gmp_configure_flags)
1608 AC_SUBST(extra_mpc_mpfr_configure_flags)
1609 AC_SUBST(extra_isl_gmp_configure_flags)
1610
1611 # Libraries to use for stage1 or when not bootstrapping.
1612 AC_ARG_WITH(stage1-libs,
1613 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1614 [if test "$withval" = "no" -o "$withval" = "yes"; then
1615    stage1_libs=
1616  else
1617    stage1_libs=$withval
1618  fi],
1619 [stage1_libs=])
1620 AC_SUBST(stage1_libs)
1621
1622 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1623 # default is yes if gcc is being built; no otherwise.  The reason for
1624 # this default is that gdb is sometimes linked against GNU Source
1625 # Highlight, which is a shared library that uses C++ exceptions.  In
1626 # this case, -static-libstdc++ will cause crashes.
1627 AC_ARG_WITH(static-standard-libraries,
1628 [AS_HELP_STRING([--with-static-standard-libraries],
1629                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1630 [], [with_static_standard_libraries=auto])
1631 if test "$with_static_standard_libraries" = auto; then
1632   with_static_standard_libraries=$have_compiler
1633 fi
1634
1635 # Linker flags to use for stage1 or when not bootstrapping.
1636 AC_ARG_WITH(stage1-ldflags,
1637 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1638 [if test "$withval" = "no" -o "$withval" = "yes"; then
1639    stage1_ldflags=
1640  else
1641    stage1_ldflags=$withval
1642  fi],
1643 [stage1_ldflags=
1644  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1645  # if supported.  But if the user explicitly specified the libraries to use,
1646  # trust that they are doing what they want.
1647  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1648      -a "$have_static_libs" = yes; then
1649    stage1_ldflags="-static-libstdc++ -static-libgcc"
1650  fi])
1651 AC_SUBST(stage1_ldflags)
1652
1653 # Libraries to use for stage2 and later builds.
1654 AC_ARG_WITH(boot-libs,
1655 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1656 [if test "$withval" = "no" -o "$withval" = "yes"; then
1657    poststage1_libs=
1658  else
1659    poststage1_libs=$withval
1660  fi],
1661 [poststage1_libs=])
1662 AC_SUBST(poststage1_libs)
1663
1664 # Linker flags to use for stage2 and later builds.
1665 AC_ARG_WITH(boot-ldflags,
1666 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1667                 [linker flags for stage2 and later])],
1668 [if test "$withval" = "no" -o "$withval" = "yes"; then
1669    poststage1_ldflags=
1670  else
1671    poststage1_ldflags=$withval
1672  fi],
1673 [poststage1_ldflags=
1674  # In stages 2 and 3, default to linking libstdc++ and libgcc
1675  # statically.  But if the user explicitly specified the libraries to
1676  # use, trust that they are doing what they want.
1677  if test "$poststage1_libs" = ""; then
1678    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1679  fi])
1680 AC_SUBST(poststage1_ldflags)
1681
1682 # GCC GRAPHITE dependency isl.
1683 # Basic setup is inlined here, actual checks are in config/isl.m4
1684
1685 AC_ARG_WITH(isl,
1686   [AS_HELP_STRING(
1687    [--with-isl=PATH],
1688    [Specify prefix directory for the installed isl package.
1689     Equivalent to --with-isl-include=PATH/include
1690     plus --with-isl-lib=PATH/lib])])
1691
1692 # Treat --without-isl as a request to disable
1693 # GRAPHITE support and skip all following checks.
1694 if test "x$with_isl" != "xno"; then
1695   # Check for isl
1696   dnl Provide configure switches and initialize islinc & isllibs
1697   dnl with user input.
1698   ISL_INIT_FLAGS
1699   dnl The versions of isl that work for Graphite
1700   ISL_CHECK_VERSION()
1701   dnl Only execute fail-action, if isl has been requested.
1702   ISL_IF_FAILED([
1703     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1704 fi
1705
1706 # If the isl check failed, disable builds of in-tree variant of isl
1707 if test "x$with_isl" = xno ||
1708    test "x$gcc_cv_isl" = xno; then
1709   noconfigdirs="$noconfigdirs isl"
1710   islinc=
1711 fi
1712
1713 AC_SUBST(isllibs)
1714 AC_SUBST(islinc)
1715
1716 # Check for LTO support.
1717 AC_ARG_ENABLE(lto,
1718 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1719 enable_lto=$enableval,
1720 enable_lto=yes; default_enable_lto=yes)
1721
1722 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1723   build_lto_plugin=yes
1724 ],[if test x"$default_enable_lto" = x"yes" ; then
1725     case $target in
1726       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1727       # On other non-ELF platforms, LTO has yet to be validated.
1728       *) enable_lto=no ;;
1729     esac
1730   else
1731   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1732   # It would also be nice to check the binutils support, but we don't
1733   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1734   # warn during gcc/ subconfigure; unless you're bootstrapping with
1735   # -flto it won't be needed until after installation anyway.
1736     case $target in
1737       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1738       *) if test x"$enable_lto" = x"yes"; then
1739         AC_MSG_ERROR([LTO support is not enabled for this target.])
1740         fi
1741       ;;
1742     esac
1743   fi
1744   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1745   # Build it unless LTO was explicitly disabled.
1746   case $target in
1747     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1748     *) ;;
1749   esac
1750 ])
1751
1752 AC_ARG_ENABLE(linker-plugin-configure-flags,
1753   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1754     [additional flags for configuring linker plugins @<:@none@:>@])],
1755   extra_linker_plugin_configure_flags=$enableval,
1756   extra_linker_plugin_configure_flags=)
1757 AC_SUBST(extra_linker_plugin_configure_flags)
1758 AC_ARG_ENABLE(linker-plugin-flags,
1759   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1760     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1761   extra_linker_plugin_flags=$enableval,
1762   extra_linker_plugin_flags=)
1763 AC_SUBST(extra_linker_plugin_flags)
1764
1765 # Enable --enable-host-shared.
1766 # Checked early to determine whether jit is an 'all' language
1767 AC_ARG_ENABLE(host-shared,
1768 [AS_HELP_STRING([--enable-host-shared],
1769                 [build host code as shared libraries])],
1770 [host_shared=$enableval], [host_shared=no])
1771 AC_SUBST(host_shared)
1772
1773 # By default, C and C++ are the only stage 1 languages.
1774 stage1_languages=,c,
1775
1776 # Target libraries that we bootstrap.
1777 bootstrap_target_libs=,target-libgcc,
1778
1779 # Figure out what language subdirectories are present.
1780 # Look if the user specified --enable-languages="..."; if not, use
1781 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1782 # go away some day.
1783 # NB:  embedded tabs in this IF block -- do not untabify
1784 if test -d ${srcdir}/gcc; then
1785   if test x"${enable_languages+set}" != xset; then
1786     if test x"${LANGUAGES+set}" = xset; then
1787       enable_languages="${LANGUAGES}"
1788         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1789     else
1790       enable_languages=default
1791     fi
1792   else
1793     if test x"${enable_languages}" = x ||
1794        test x"${enable_languages}" = xyes;
1795        then
1796       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1797       exit 1
1798     fi
1799   fi
1800   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1801
1802   # 'f95' is the old name for the 'fortran' language. We issue a warning
1803   # and make the substitution.
1804   case ,${enable_languages}, in
1805     *,f95,*)
1806       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1807       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1808       ;;
1809   esac
1810
1811   # If bootstrapping, C++ must be enabled.
1812   case ",$enable_languages,:$enable_bootstrap" in
1813     *,c++,*:*) ;;
1814     *:yes)
1815       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1816         enable_languages="${enable_languages},c++"
1817       else
1818         AC_MSG_ERROR([bootstrapping requires c++ sources])
1819       fi
1820       ;;
1821   esac
1822
1823   # First scan to see if an enabled language requires some other language.
1824   # We assume that a given config-lang.in will list all the language
1825   # front ends it requires, even if some are required indirectly.
1826   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1827     case ${lang_frag} in
1828       ..) ;;
1829       # The odd quoting in the next line works around
1830       # an apparent bug in bash 1.12 on linux.
1831       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1832       *)
1833         # From the config-lang.in, get $language, $lang_requires, and
1834         # $lang_requires_boot_languages.
1835         language=
1836         lang_requires=
1837         lang_requires_boot_languages=
1838         # set srcdir during sourcing lang_frag to the gcc dir.
1839         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1840         # polutes this shell
1841         saved_srcdir=${srcdir}
1842         srcdir=${srcdir}/gcc . ${lang_frag}
1843         srcdir=${saved_srcdir}
1844         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1845           case ,${enable_languages}, in
1846             *,$other,*) ;;
1847             *,default,*) ;;
1848             *,all,*) ;;
1849             *,$language,*)
1850               echo " \`$other' language required by \`$language'; enabling" 1>&2
1851               enable_languages="${enable_languages},${other}"
1852               ;;
1853           esac
1854         done
1855         for other in ${lang_requires_boot_languages} ; do
1856           if test "$other" != "c"; then
1857             case ,${enable_stage1_languages}, in
1858               *,$other,*) ;;
1859               *,default,*) ;;
1860               *,all,*) ;;
1861               *)
1862                 case ,${enable_languages}, in
1863                   *,$language,*)
1864                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1865                     enable_stage1_languages="$enable_stage1_languages,${other}"
1866                     ;;
1867                 esac
1868                 ;;
1869             esac
1870           fi
1871         done
1872         ;;
1873     esac
1874   done
1875
1876   new_enable_languages=,c,
1877
1878   # If LTO is enabled, add the LTO front end.
1879   if test "$enable_lto" = "yes" ; then
1880     case ,${enable_languages}, in
1881       *,lto,*) ;;
1882       *) enable_languages="${enable_languages},lto" ;;
1883     esac
1884     if test "${build_lto_plugin}" = "yes" ; then
1885       configdirs="$configdirs lto-plugin"
1886     fi
1887   fi
1888
1889   # If we're building an offloading compiler, add the LTO front end.
1890   if test x"$enable_as_accelerator_for" != x ; then
1891     case ,${enable_languages}, in
1892       *,lto,*) ;;
1893       *) enable_languages="${enable_languages},lto" ;;
1894     esac
1895   fi
1896
1897   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1898   potential_languages=,c,
1899
1900   enabled_target_libs=
1901   disabled_target_libs=
1902
1903   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1904     case ${lang_frag} in
1905       ..) ;;
1906       # The odd quoting in the next line works around
1907       # an apparent bug in bash 1.12 on linux.
1908       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1909       *)
1910         # From the config-lang.in, get $language, $target_libs,
1911         # $lang_dirs, $boot_language, and $build_by_default
1912         language=
1913         target_libs=
1914         lang_dirs=
1915         subdir_requires=
1916         boot_language=no
1917         build_by_default=yes
1918         # set srcdir during sourcing.  See above about save & restore
1919         saved_srcdir=${srcdir}
1920         srcdir=${srcdir}/gcc . ${lang_frag}
1921         srcdir=${saved_srcdir}
1922         if test x${language} = x; then
1923           echo "${lang_frag} doesn't set \$language." 1>&2
1924           exit 1
1925         fi
1926
1927         if test "$language" = "c++"; then
1928           boot_language=yes
1929         fi
1930
1931         add_this_lang=no
1932         # C is always enabled, so no need to add it again
1933         if test "$language" != "c"; then
1934           case ,${enable_languages}, in
1935             *,${language},*)
1936               # Language was explicitly selected; include it
1937               add_this_lang=yes
1938               ;;
1939             *,all,*)
1940               # All languages are enabled
1941               add_this_lang=all
1942               ;;
1943             *,default,*)
1944               # 'default' was selected, select it if it is a default language
1945               add_this_lang=${build_by_default}
1946               ;;
1947           esac
1948         fi
1949
1950         # Disable languages that need other directories if these aren't available.
1951         for i in $subdir_requires; do
1952           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1953           case ${add_this_lang} in
1954             yes)
1955               # Specifically requested language; tell them.
1956               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1957               ;;
1958             all)
1959               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1960               add_this_lang=unsupported
1961               ;;
1962             *)
1963               # Silently disable.
1964               add_this_lang=unsupported
1965               ;;
1966           esac
1967         done
1968
1969         # Disable Ada if no preexisting GNAT is available.
1970         case ${add_this_lang}:${language}:${have_gnat} in
1971           yes:ada:no)
1972             # Specifically requested language; tell them.
1973             AC_MSG_ERROR([GNAT is required to build $language])
1974             ;;
1975           all:ada:no)
1976             AC_MSG_WARN([GNAT is required to build $language])
1977             add_this_lang=unsupported
1978             ;;
1979           *:ada:no)
1980             # Silently disable.
1981             add_this_lang=unsupported
1982             ;;
1983         esac
1984
1985         # Disable jit if -enable-host-shared not specified
1986         case ${add_this_lang}:${language}:${host_shared} in
1987           yes:jit:no)
1988             # PR jit/64780: explicitly specify --enable-host-shared
1989             AC_MSG_ERROR([
1990 Enabling language "jit" requires --enable-host-shared.
1991
1992 --enable-host-shared typically slows the rest of the compiler down by
1993 a few %, so you must explicitly enable it.
1994
1995 If you want to build both the jit and the regular compiler, it is often
1996 best to do this via two separate configure/builds, in separate
1997 directories, to avoid imposing the performance cost of
1998 --enable-host-shared on the regular compiler.])
1999             ;;
2000           all:jit:no)
2001             AC_MSG_WARN([--enable-host-shared required to build $language])
2002             add_this_lang=unsupported
2003             ;;
2004           *:jit:no)
2005             # Silently disable.
2006             add_this_lang=unsupported
2007             ;;
2008         esac
2009
2010         # Disable a language that is unsupported by the target.
2011         case "${add_this_lang}: $unsupported_languages " in
2012           no:*) ;;
2013           unsupported:*) ;;
2014           *:*" $language "*)
2015             AC_MSG_WARN([${language} not supported for this target])
2016             add_this_lang=unsupported
2017             ;;
2018         esac
2019
2020         case $add_this_lang in
2021           unsupported)
2022             # Remove language-dependent dirs.
2023             disabled_target_libs="$disabled_target_libs $target_libs"
2024             noconfigdirs="$noconfigdirs $lang_dirs"
2025             ;;
2026           no)
2027             # Remove language-dependent dirs; still show language as supported.
2028             disabled_target_libs="$disabled_target_libs $target_libs"
2029             noconfigdirs="$noconfigdirs $lang_dirs"
2030             potential_languages="${potential_languages}${language},"
2031             ;;
2032           all|yes)
2033             new_enable_languages="${new_enable_languages}${language},"
2034             potential_languages="${potential_languages}${language},"
2035             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2036             enabled_target_libs="$enabled_target_libs $target_libs"
2037             case "${boot_language}:,$enable_stage1_languages," in
2038               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2039                 # Add to (comma-separated) list of stage 1 languages.
2040                 case ",$stage1_languages," in
2041                   *,$language,* | ,yes, | ,all,) ;;
2042                   *) stage1_languages="${stage1_languages}${language}," ;;
2043                 esac
2044                 # We need to bootstrap any supporting libraries.
2045                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2046                 ;;
2047             esac
2048             ;;
2049         esac
2050         ;;
2051     esac
2052   done
2053
2054   # Add target libraries which are only needed for disabled languages
2055   # to noconfigdirs.
2056   if test -n "$disabled_target_libs"; then
2057     for dir in $disabled_target_libs; do
2058       case " $enabled_target_libs " in
2059       *" ${dir} "*) ;;
2060       *) noconfigdirs="$noconfigdirs $dir" ;;
2061       esac
2062     done
2063   fi
2064
2065   AC_ARG_ENABLE(stage1-languages,
2066   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2067                   [choose additional languages to build during
2068                   stage1.  Mostly useful for compiler development])],
2069   [case ,${enable_stage1_languages}, in
2070     ,no,|,,)
2071       # Set it to something that will have no effect in the loop below
2072       enable_stage1_languages=c ;;
2073     ,yes,)
2074       enable_stage1_languages=`echo $new_enable_languages | \
2075         sed -e "s/^,//" -e "s/,$//" ` ;;
2076     *,all,*)
2077       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2078         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2079   esac
2080
2081   # Add "good" languages from enable_stage1_languages to stage1_languages,
2082   # while "bad" languages go in missing_languages.  Leave no duplicates.
2083   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2084     case $potential_languages in
2085       *,$i,*)
2086         case $stage1_languages in
2087           *,$i,*) ;;
2088           *) stage1_languages="$stage1_languages$i," ;;
2089         esac ;;
2090       *)
2091         case $missing_languages in
2092           *,$i,*) ;;
2093           *) missing_languages="$missing_languages$i," ;;
2094         esac ;;
2095      esac
2096   done])
2097
2098   # Remove leading/trailing commas that were added for simplicity
2099   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2100   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2101   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2102   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2103
2104   if test "x$missing_languages" != x; then
2105     AC_MSG_ERROR([
2106 The following requested languages could not be built: ${missing_languages}
2107 Supported languages are: ${potential_languages}])
2108   fi
2109   if test "x$new_enable_languages" != "x$enable_languages"; then
2110     echo The following languages will be built: ${new_enable_languages}
2111     enable_languages="$new_enable_languages"
2112   fi
2113
2114   AC_SUBST(stage1_languages)
2115   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2116 fi
2117
2118 # Handle --disable-<component> generically.
2119 for dir in $configdirs $build_configdirs $target_configdirs ; do
2120   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2121   varname=`echo $dirname | sed -e s/+/_/g`
2122   if eval test x\${enable_${varname}} "=" xno ; then
2123     noconfigdirs="$noconfigdirs $dir"
2124   fi
2125 done
2126
2127 # Check for Boehm's garbage collector
2128 AC_ARG_ENABLE(objc-gc,
2129 [AS_HELP_STRING([--enable-objc-gc],
2130                 [enable use of Boehm's garbage collector with the
2131                  GNU Objective-C runtime])])
2132 AC_ARG_WITH([target-bdw-gc],
2133 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2134                 [specify prefix directory for installed bdw-gc package.
2135                  Equivalent to --with-target-bdw-gc-include=PATH/include
2136                  plus --with-target-bdw-gc-lib=PATH/lib])])
2137 AC_ARG_WITH([target-bdw-gc-include],
2138 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2139                 [specify directories for installed bdw-gc include files])])
2140 AC_ARG_WITH([target-bdw-gc-lib],
2141 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2142                 [specify directories for installed bdw-gc library])])
2143
2144 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2145   AC_MSG_CHECKING([for bdw garbage collector])
2146   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2147     dnl no bdw-gw options, assume default locations
2148     AC_MSG_RESULT([using bdw-gc in default locations])
2149   else
2150     dnl bdw-gw options, first error checking, complete checking in libobjc
2151     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2152       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2153     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2154       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2155     else
2156       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2157     fi
2158   fi
2159 esac
2160
2161 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2162 case ,${enable_languages}, in
2163   *,c++,*)
2164     # Disable libitm, libsanitizer if we're not building libstdc++
2165     case "${noconfigdirs}" in
2166       *target-libstdc++-v3*)
2167         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2168         ;;
2169       *) ;;
2170     esac
2171     ;;
2172   *)
2173     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2174     ;;
2175 esac
2176
2177 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2178 # $build_configdirs and $target_configdirs.
2179 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2180
2181 notsupp=""
2182 for dir in . $skipdirs $noconfigdirs ; do
2183   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2184   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2185     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2186     if test -r $srcdir/$dirname/configure ; then
2187       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2188         true
2189       else
2190         notsupp="$notsupp $dir"
2191       fi
2192     fi
2193   fi
2194   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2195     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2196     if test -r $srcdir/$dirname/configure ; then
2197       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2198         true
2199       else
2200         notsupp="$notsupp $dir"
2201       fi
2202     fi
2203   fi
2204   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2205     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2206     if test -r $srcdir/$dirname/configure ; then
2207       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2208         true
2209       else
2210         notsupp="$notsupp $dir"
2211       fi
2212     fi
2213   fi
2214 done
2215
2216 # Quietly strip out all directories which aren't configurable in this tree.
2217 # This relies on all configurable subdirectories being autoconfiscated, which
2218 # is now the case.
2219 build_configdirs_all="$build_configdirs"
2220 build_configdirs=
2221 for i in ${build_configdirs_all} ; do
2222   j=`echo $i | sed -e s/build-//g`
2223   if test -f ${srcdir}/$j/configure ; then
2224     build_configdirs="${build_configdirs} $i"
2225   fi
2226 done
2227
2228 configdirs_all="$configdirs"
2229 configdirs=
2230 for i in ${configdirs_all} ; do
2231   if test -f ${srcdir}/$i/configure ; then
2232     configdirs="${configdirs} $i"
2233   fi
2234 done
2235
2236 target_configdirs_all="$target_configdirs"
2237 target_configdirs=
2238 for i in ${target_configdirs_all} ; do
2239   j=`echo $i | sed -e s/target-//g`
2240   if test -f ${srcdir}/$j/configure ; then
2241     target_configdirs="${target_configdirs} $i"
2242   fi
2243 done
2244
2245 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2246 # so we have to add it after the preceding checks.
2247 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2248 then
2249   case " $configdirs " in
2250     *" libiberty "*)
2251       # If we can build libiberty, we can also build libiberty-linker-plugin.
2252       configdirs="$configdirs libiberty-linker-plugin"
2253       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2254         --with-libiberty=../libiberty-linker-plugin";;
2255     *)
2256       AC_MSG_ERROR([libiberty missing]);;
2257   esac
2258 fi
2259
2260 # Sometimes we have special requirements for the host libiberty.
2261 extra_host_libiberty_configure_flags=
2262 extra_host_zlib_configure_flags=
2263 case " $configdirs " in
2264   *" lto-plugin "* | *" libcc1 "*)
2265     # When these are to be built as shared libraries, the same applies to
2266     # libiberty.
2267     extra_host_libiberty_configure_flags=--enable-shared
2268     ;;
2269   *" bfd "*)
2270     # When bfd is to be built as a shared library, the same applies to
2271     # zlib.
2272     if test "$enable_shared" = "yes"; then
2273       extra_host_zlib_configure_flags=--enable-host-shared
2274     fi
2275     ;;
2276 esac
2277 AC_SUBST(extra_host_libiberty_configure_flags)
2278 AC_SUBST(extra_host_zlib_configure_flags)
2279
2280 # Produce a warning message for the subdirs we can't configure.
2281 # This isn't especially interesting in the Cygnus tree, but in the individual
2282 # FSF releases, it's important to let people know when their machine isn't
2283 # supported by the one or two programs in a package.
2284
2285 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2286   # If $appdirs is non-empty, at least one of those directories must still
2287   # be configured, or we error out.  (E.g., if the gas release supports a
2288   # specified target in some subdirs but not the gas subdir, we shouldn't
2289   # pretend that all is well.)
2290   if test -n "$appdirs" ; then
2291     for dir in $appdirs ; do
2292       if test -r $dir/Makefile.in ; then
2293         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2294           appdirs=""
2295           break
2296         fi
2297         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2298           appdirs=""
2299           break
2300         fi
2301       fi
2302     done
2303     if test -n "$appdirs" ; then
2304       echo "*** This configuration is not supported by this package." 1>&2
2305       exit 1
2306     fi
2307   fi
2308   # Okay, some application will build, or we don't care to check.  Still
2309   # notify of subdirs not getting built.
2310   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2311   echo "    ${notsupp}" 1>&2
2312   echo "    (Any other directories should still work fine.)" 1>&2
2313 fi
2314
2315 case "$host" in
2316   *msdosdjgpp*)
2317     enable_gdbtk=no ;;
2318 esac
2319
2320 # To find our prefix, in gcc_cv_tool_prefix.
2321 ACX_TOOL_DIRS
2322
2323 copy_dirs=
2324
2325 AC_ARG_WITH([build-sysroot],
2326   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2327                   [use sysroot as the system root during the build])],
2328   [if test x"$withval" != x ; then
2329      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2330    fi],
2331   [SYSROOT_CFLAGS_FOR_TARGET=])
2332 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2333
2334 AC_ARG_WITH([debug-prefix-map],
2335   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2336                   [map A to B, C to D ... in debug information])],
2337   [if test x"$withval" != x; then
2338      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2339      for debug_map in $withval; do
2340        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2341      done
2342    fi],
2343   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2344 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2345
2346 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2347 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2348 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2349 # We want to ensure that TARGET libraries (which we know are built with
2350 # gcc) are built with "-O2 -g", so include those options when setting
2351 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2352 if test "x$CFLAGS_FOR_TARGET" = x; then
2353   if test "x${is_cross_compiler}" = xyes; then
2354     CFLAGS_FOR_TARGET="-g -O2"
2355   else
2356     CFLAGS_FOR_TARGET=$CFLAGS
2357     case " $CFLAGS " in
2358       *" -O2 "*) ;;
2359       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2360     esac
2361     case " $CFLAGS " in
2362       *" -g "* | *" -g3 "*) ;;
2363       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2364     esac
2365   fi
2366 fi
2367 AC_SUBST(CFLAGS_FOR_TARGET)
2368
2369 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2370   if test "x${is_cross_compiler}" = xyes; then
2371     CXXFLAGS_FOR_TARGET="-g -O2"
2372   else
2373     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2374     case " $CXXFLAGS " in
2375       *" -O2 "*) ;;
2376       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2377     esac
2378     case " $CXXFLAGS " in
2379       *" -g "* | *" -g3 "*) ;;
2380       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2381     esac
2382   fi
2383 fi
2384 AC_SUBST(CXXFLAGS_FOR_TARGET)
2385
2386 AC_SUBST(LDFLAGS_FOR_TARGET)
2387
2388 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2389 # the named directory are copied to $(tooldir)/sys-include.
2390 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2391   if test x${is_cross_compiler} = xno ; then
2392     echo 1>&2 '***' --with-headers is only supported when cross compiling
2393     exit 1
2394   fi
2395   if test x"${with_headers}" != xyes ; then
2396     x=${gcc_cv_tool_prefix}
2397     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2398   fi
2399 fi
2400
2401 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2402 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2403 # are permitted.
2404 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2405   if test x${is_cross_compiler} = xno ; then
2406     echo 1>&2 '***' --with-libs is only supported when cross compiling
2407     exit 1
2408   fi
2409   if test x"${with_libs}" != xyes ; then
2410     # Copy the libraries in reverse order, so that files in the first named
2411     # library override files in subsequent libraries.
2412     x=${gcc_cv_tool_prefix}
2413     for l in ${with_libs}; do
2414       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2415     done
2416   fi
2417 fi
2418
2419 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2420 #
2421 # This is done by determining whether or not the appropriate directory
2422 # is available, and by checking whether or not specific configurations
2423 # have requested that this magic not happen.
2424 #
2425 # The command line options always override the explicit settings in
2426 # configure.ac, and the settings in configure.ac override this magic.
2427 #
2428 # If the default for a toolchain is to use GNU as and ld, and you don't
2429 # want to do that, then you should use the --without-gnu-as and
2430 # --without-gnu-ld options for the configure script.  Similarly, if
2431 # the default is to use the included zlib and you don't want to do that,
2432 # you should use the --with-system-zlib option for the configure script.
2433
2434 if test x${use_gnu_as} = x &&
2435    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2436   with_gnu_as=yes
2437   extra_host_args="$extra_host_args --with-gnu-as"
2438 fi
2439
2440 if test x${use_gnu_ld} = x &&
2441    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2442   with_gnu_ld=yes
2443   extra_host_args="$extra_host_args --with-gnu-ld"
2444 fi
2445
2446 if test x${use_included_zlib} = x &&
2447    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2448   :
2449 else
2450   with_system_zlib=yes
2451   extra_host_args="$extra_host_args --with-system-zlib"
2452 fi
2453
2454 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2455 # can detect this case.
2456
2457 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2458   with_newlib=yes
2459   extra_host_args="$extra_host_args --with-newlib"
2460 fi
2461
2462 # Handle ${copy_dirs}
2463 set fnord ${copy_dirs}
2464 shift
2465 while test $# != 0 ; do
2466   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2467     :
2468   else
2469     echo Copying $1 to $2
2470
2471     # Use the install script to create the directory and all required
2472     # parent directories.
2473     if test -d $2 ; then
2474       :
2475     else
2476       echo >config.temp
2477       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2478     fi
2479
2480     # Copy the directory, assuming we have tar.
2481     # FIXME: Should we use B in the second tar?  Not all systems support it.
2482     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2483
2484     # It is the responsibility of the user to correctly adjust all
2485     # symlinks.  If somebody can figure out how to handle them correctly
2486     # here, feel free to add the code.
2487
2488     echo $1 > $2/COPIED
2489   fi
2490   shift; shift
2491 done
2492
2493 # Determine a target-dependent exec_prefix that the installed
2494 # gcc will search in.  Keep this list sorted by triplet, with
2495 # the *-*-osname triplets last.
2496 md_exec_prefix=
2497 case "${target}" in
2498   i[[34567]]86-pc-msdosdjgpp*)
2499     md_exec_prefix=/dev/env/DJDIR/bin
2500     ;;
2501   *-*-hpux* | \
2502   *-*-nto-qnx* | \
2503   *-*-solaris2*)
2504     md_exec_prefix=/usr/ccs/bin
2505     ;;
2506 esac
2507
2508 extra_arflags_for_target=
2509 extra_nmflags_for_target=
2510 extra_ranlibflags_for_target=
2511 target_makefile_frag=/dev/null
2512 case "${target}" in
2513   spu-*-*)
2514     target_makefile_frag="config/mt-spu"
2515     ;;
2516   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2517     target_makefile_frag="config/mt-sde"
2518     ;;
2519   mipsisa*-*-elfoabi*)
2520     target_makefile_frag="config/mt-mips-elfoabi"
2521     ;;
2522   mips*-*-*linux* | mips*-*-gnu*)
2523     target_makefile_frag="config/mt-mips-gnu"
2524     ;;
2525   nios2-*-elf*)
2526     target_makefile_frag="config/mt-nios2-elf"
2527     ;;
2528   *-*-linux-android*)
2529     target_makefile_frag="config/mt-android"
2530     ;;
2531   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2532     target_makefile_frag="config/mt-gnu"
2533     ;;
2534   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2535     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2536     # commands to handle both 32-bit and 64-bit objects.  These flags are
2537     # harmless if we're using GNU nm or ar.
2538     extra_arflags_for_target=" -X32_64"
2539     extra_nmflags_for_target=" -B -X32_64"
2540     ;;
2541 esac
2542
2543 alphaieee_frag=/dev/null
2544 case $target in
2545   alpha*-*-*)
2546     # This just makes sure to use the -mieee option to build target libs.
2547     # This should probably be set individually by each library.
2548     alphaieee_frag="config/mt-alphaieee"
2549     ;;
2550 esac
2551
2552 # If --enable-target-optspace always use -Os instead of -O2 to build
2553 # the target libraries, similarly if it is not specified, use -Os
2554 # on selected platforms.
2555 ospace_frag=/dev/null
2556 case "${enable_target_optspace}:${target}" in
2557   yes:*)
2558     ospace_frag="config/mt-ospace"
2559     ;;
2560   :d30v-*)
2561     ospace_frag="config/mt-d30v"
2562     ;;
2563   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2564     ospace_frag="config/mt-ospace"
2565     ;;
2566   no:* | :*)
2567     ;;
2568   *)
2569     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2570     ;;
2571 esac
2572
2573 # Some systems (e.g., one of the i386-aix systems the gas testers are
2574 # using) don't handle "\$" correctly, so don't use it here.
2575 tooldir='${exec_prefix}'/${target_noncanonical}
2576 build_tooldir=${tooldir}
2577
2578 # Create a .gdbinit file which runs the one in srcdir
2579 # and tells GDB to look there for source files.
2580
2581 if test -r ${srcdir}/.gdbinit ; then
2582   case ${srcdir} in
2583     .) ;;
2584     *) cat > ./.gdbinit <<EOF
2585 # ${NO_EDIT}
2586 dir ${srcdir}
2587 dir .
2588 source ${srcdir}/.gdbinit
2589 EOF
2590     ;;
2591   esac
2592 fi
2593
2594 # Make sure that the compiler is able to generate an executable.  If it
2595 # can't, we are probably in trouble.  We don't care whether we can run the
2596 # executable--we might be using a cross compiler--we only care whether it
2597 # can be created.  At this point the main configure script has set CC.
2598 we_are_ok=no
2599 echo "int main () { return 0; }" > conftest.c
2600 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2601 if test $? = 0 ; then
2602   if test -s conftest || test -s conftest.exe ; then
2603     we_are_ok=yes
2604   fi
2605 fi
2606 case $we_are_ok in
2607   no)
2608     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2609     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2610     rm -f conftest*
2611     exit 1
2612     ;;
2613 esac
2614 rm -f conftest*
2615
2616 # Decide which environment variable is used to find dynamic libraries.
2617 case "${host}" in
2618   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2619   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2620   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2621   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2622 esac
2623
2624 # On systems where the dynamic library environment variable is PATH,
2625 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2626 # built executables to PATH.
2627 if test "$RPATH_ENVVAR" = PATH; then
2628   GCC_SHLIB_SUBDIR=/shlib
2629 else
2630   GCC_SHLIB_SUBDIR=
2631 fi
2632
2633 # Adjust the toplevel makefile according to whether bootstrap was selected.
2634 case $enable_bootstrap in
2635   yes)
2636     bootstrap_suffix=bootstrap
2637     BUILD_CONFIG=bootstrap-debug
2638     ;;
2639   no)
2640     bootstrap_suffix=no-bootstrap
2641     BUILD_CONFIG=
2642     ;;
2643 esac
2644
2645 AC_MSG_CHECKING(for default BUILD_CONFIG)
2646
2647 AC_ARG_WITH([build-config],
2648   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2649                   [use config/NAME.mk build configuration])],
2650   [case $with_build_config in
2651    yes) with_build_config= ;;
2652    no) with_build_config= BUILD_CONFIG= ;;
2653    esac])
2654
2655 if test "x${with_build_config}" != x; then
2656   BUILD_CONFIG=$with_build_config
2657 else
2658   case $BUILD_CONFIG in
2659   bootstrap-debug)
2660     if echo "int f (void) { return 0; }" > conftest.c &&
2661        ${CC} -c conftest.c &&
2662        mv conftest.o conftest.o.g0 &&
2663        ${CC} -c -g conftest.c &&
2664        mv conftest.o conftest.o.g &&
2665        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2666       :
2667     else
2668       BUILD_CONFIG=
2669     fi
2670     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2671     ;;
2672   esac
2673 fi
2674 AC_MSG_RESULT($BUILD_CONFIG)
2675 AC_SUBST(BUILD_CONFIG)
2676
2677 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2678 AC_MSG_CHECKING([for --enable-vtable-verify])
2679 AC_ARG_ENABLE(vtable-verify,
2680 [AS_HELP_STRING([--enable-vtable-verify],
2681                 [Enable vtable verification feature])],
2682 [case "$enableval" in
2683  yes) enable_vtable_verify=yes ;;
2684  no)  enable_vtable_verify=no ;;
2685  *)   enable_vtable_verify=no;;
2686  esac],
2687 [enable_vtable_verify=no])
2688 AC_MSG_RESULT($enable_vtable_verify)
2689
2690 # Record target_configdirs and the configure arguments for target and
2691 # build configuration in Makefile.
2692 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2693 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2694 bootstrap_fixincludes=no
2695
2696 # If we are building libgomp, bootstrap it.
2697 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2698   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2699 fi
2700
2701 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2702 # or bootstrap-ubsan, bootstrap it.
2703 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2704   case "$BUILD_CONFIG" in
2705     *bootstrap-asan* | *bootstrap-ubsan* )
2706       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2707       bootstrap_fixincludes=yes
2708       ;;
2709   esac
2710 fi
2711
2712 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2713 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2714    test "$enable_vtable_verify" != no; then
2715   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2716 fi
2717
2718 # Determine whether gdb needs tk/tcl or not.
2719 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2720 # and in that case we want gdb to be built without tk.  Ugh!
2721 # In fact I believe gdb is the *only* package directly dependent on tk,
2722 # so we should be able to put the 'maybe's in unconditionally and
2723 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2724 # 100% sure that that's safe though.
2725
2726 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2727 case "$enable_gdbtk" in
2728   no)
2729     GDB_TK="" ;;
2730   yes)
2731     GDB_TK="${gdb_tk}" ;;
2732   *)
2733     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2734     # distro.  Eventually someone will fix this and move Insight, nee
2735     # gdbtk to a separate directory.
2736     if test -d ${srcdir}/gdb/gdbtk ; then
2737       GDB_TK="${gdb_tk}"
2738     else
2739       GDB_TK=""
2740     fi
2741     ;;
2742 esac
2743 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2744 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2745
2746 # gdb depends on gnulib, but as nothing else does, only include it if
2747 # gdb is built.
2748 if echo " ${configdirs} " | grep " gdb " > /dev/null 2>&1 ; then
2749   # The Makefile provides the ordering, so it's enough here to add
2750   # gnulib to the list.
2751   configdirs="${configdirs} gnulib"
2752 fi
2753
2754 # Strip out unwanted targets.
2755
2756 # While at that, we remove Makefiles if we were started for recursive
2757 # configuration, so that the top-level Makefile reconfigures them,
2758 # like we used to do when configure itself was recursive.
2759
2760 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2761 # but now we're fixing up the Makefile ourselves with the additional
2762 # commands passed to AC_CONFIG_FILES.  Use separate variables
2763 # extrasub-{build,host,target} not because there is any reason to split
2764 # the substitutions up that way, but only to remain below the limit of
2765 # 99 commands in a script, for HP-UX sed.
2766
2767 # Do not nest @if/@endif or @unless/@endunless pairs, because
2768 # configure will not warn you at all.
2769
2770 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2771   yes:yes:*\ gold\ *:*,c++,*) ;;
2772   yes:yes:*\ gold\ *:*)
2773     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2774     ;;
2775 esac
2776
2777 extrasub_build=
2778 for module in ${build_configdirs} ; do
2779   if test -z "${no_recursion}" \
2780      && test -f ${build_subdir}/${module}/Makefile; then
2781     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2782     rm -f ${build_subdir}/${module}/Makefile
2783   fi
2784   extrasub_build="$extrasub_build
2785 /^@if build-$module\$/d
2786 /^@endif build-$module\$/d
2787 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2788 /^@if build-$module-$bootstrap_suffix\$/d
2789 /^@endif build-$module-$bootstrap_suffix\$/d
2790 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2791 done
2792 extrasub_host=
2793 for module in ${configdirs} ; do
2794   if test -z "${no_recursion}"; then
2795     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2796       if test -f ${file}; then
2797         echo 1>&2 "*** removing ${file} to force reconfigure"
2798         rm -f ${file}
2799       fi
2800     done
2801   fi
2802   case ${module},${bootstrap_fixincludes} in
2803     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2804     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2805   esac
2806   extrasub_host="$extrasub_host
2807 /^@if $module\$/d
2808 /^@endif $module\$/d
2809 /^@unless $module\$/,/^@endunless $module\$/d
2810 /^@if $module-$host_bootstrap_suffix\$/d
2811 /^@endif $module-$host_bootstrap_suffix\$/d
2812 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2813 done
2814 extrasub_target=
2815 for module in ${target_configdirs} ; do
2816   if test -z "${no_recursion}" \
2817      && test -f ${target_subdir}/${module}/Makefile; then
2818     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2819     rm -f ${target_subdir}/${module}/Makefile
2820   fi
2821
2822   # We only bootstrap target libraries listed in bootstrap_target_libs.
2823   case $bootstrap_target_libs in
2824     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2825     *) target_bootstrap_suffix=no-bootstrap ;;
2826   esac
2827
2828   extrasub_target="$extrasub_target
2829 /^@if target-$module\$/d
2830 /^@endif target-$module\$/d
2831 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2832 /^@if target-$module-$target_bootstrap_suffix\$/d
2833 /^@endif target-$module-$target_bootstrap_suffix\$/d
2834 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2835 done
2836
2837 # Do the final fixup along with target modules.
2838 extrasub_target="$extrasub_target
2839 /^@if /,/^@endif /d
2840 /^@unless /d
2841 /^@endunless /d"
2842
2843 # Create the serialization dependencies.  This uses a temporary file.
2844
2845 AC_ARG_ENABLE([serial-configure],
2846 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2847                 [force sequential configuration of
2848                  sub-packages for the host, target or build
2849                  machine, or all sub-packages])])
2850
2851 case ${enable_serial_configure} in
2852   yes)
2853     enable_serial_build_configure=yes
2854     enable_serial_host_configure=yes
2855     enable_serial_target_configure=yes
2856     ;;
2857 esac
2858
2859 # These force 'configure's to be done one at a time, to avoid problems
2860 # with contention over a shared config.cache.
2861 rm -f serdep.tmp
2862 echo '# serdep.tmp' > serdep.tmp
2863 olditem=
2864 test "x${enable_serial_build_configure}" = xyes &&
2865 for item in ${build_configdirs} ; do
2866   case ${olditem} in
2867     "") ;;
2868     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2869   esac
2870   olditem=${item}
2871 done
2872 olditem=
2873 test "x${enable_serial_host_configure}" = xyes &&
2874 for item in ${configdirs} ; do
2875   case ${olditem} in
2876     "") ;;
2877     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2878   esac
2879   olditem=${item}
2880 done
2881 olditem=
2882 test "x${enable_serial_target_configure}" = xyes &&
2883 for item in ${target_configdirs} ; do
2884   case ${olditem} in
2885     "") ;;
2886     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2887   esac
2888   olditem=${item}
2889 done
2890 serialization_dependencies=serdep.tmp
2891 AC_SUBST_FILE(serialization_dependencies)
2892
2893 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2894 # target, nonopt, and variable assignments.  These are the ones we
2895 # might not want to pass down to subconfigures.  The exception being
2896 # --cache-file=/dev/null, which is used to turn off the use of cache
2897 # files altogether, and which should be passed on to subconfigures.
2898 # Also strip program-prefix, program-suffix, and program-transform-name,
2899 # so that we can pass down a consistent program-transform-name.
2900 baseargs=
2901 tbaseargs=
2902 keep_next=no
2903 skip_next=no
2904 eval "set -- $ac_configure_args"
2905 for ac_arg
2906 do
2907   if test X"$skip_next" = X"yes"; then
2908     skip_next=no
2909     continue
2910   fi
2911   if test X"$keep_next" = X"yes"; then
2912     case $ac_arg in
2913       *\'*)
2914         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2915     esac
2916     baseargs="$baseargs '$ac_arg'"
2917     tbaseargs="$tbaseargs '$ac_arg'"
2918     keep_next=no
2919     continue
2920   fi
2921
2922   # Handle separated arguments.  Based on the logic generated by
2923   # autoconf 2.59.
2924   case $ac_arg in
2925     *=* | --config-cache | -C | -disable-* | --disable-* \
2926       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2927       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2928       | -with-* | --with-* | -without-* | --without-* | --x)
2929       separate_arg=no
2930       ;;
2931     -*)
2932       separate_arg=yes
2933       ;;
2934     *)
2935       separate_arg=no
2936       ;;
2937   esac
2938
2939   skip_targ=no
2940   case $ac_arg in
2941 changequote(,)
2942   --with-* | --without-*)
2943     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2944
2945     case $libopt in
2946     *[-_]include)
2947       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2948       ;;
2949     *[-_]lib)
2950       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2951       ;;
2952     *)
2953       lib=$libopt
2954       ;;
2955     esac
2956 changequote([,])
2957
2958     case $lib in
2959     mpc | mpfr | gmp | isl)
2960       # If we're processing --with-$lib, --with-$lib-include or
2961       # --with-$lib-lib, for one of the libs above, and target is
2962       # different from host, don't pass the current argument to any
2963       # target library's configure.
2964       if test x$is_cross_compiler = xyes; then
2965         skip_targ=yes
2966       fi
2967       ;;
2968     esac
2969     ;;
2970   esac
2971
2972   case "$ac_arg" in
2973     --cache-file=/dev/null | \
2974     -cache-file=/dev/null )
2975       # Handled here to avoid the test to skip args below.
2976       baseargs="$baseargs '$ac_arg'"
2977       tbaseargs="$tbaseargs '$ac_arg'"
2978       # Assert: $separate_arg should always be no.
2979       keep_next=$separate_arg
2980       ;;
2981     --no*)
2982       continue
2983       ;;
2984     --c* | \
2985     --sr* | \
2986     --ho* | \
2987     --bu* | \
2988     --t* | \
2989     --program-* | \
2990     -cache_file* | \
2991     -srcdir* | \
2992     -host* | \
2993     -build* | \
2994     -target* | \
2995     -program-prefix* | \
2996     -program-suffix* | \
2997     -program-transform-name* )
2998       skip_next=$separate_arg
2999       continue
3000       ;;
3001     -*)
3002       # An option.  Add it.
3003       case $ac_arg in
3004         *\'*)
3005           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3006       esac
3007       baseargs="$baseargs '$ac_arg'"
3008       if test X"$skip_targ" = Xno; then
3009         tbaseargs="$tbaseargs '$ac_arg'"
3010       fi
3011       keep_next=$separate_arg
3012       ;;
3013     *)
3014       # Either a variable assignment, or a nonopt (triplet).  Don't
3015       # pass it down; let the Makefile handle this.
3016       continue
3017       ;;
3018   esac
3019 done
3020 # Remove the initial space we just introduced and, as these will be
3021 # expanded by make, quote '$'.
3022 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3023
3024 # Add in --program-transform-name, after --program-prefix and
3025 # --program-suffix have been applied to it.  Autoconf has already
3026 # doubled dollar signs and backslashes in program_transform_name; we want
3027 # the backslashes un-doubled, and then the entire thing wrapped in single
3028 # quotes, because this will be expanded first by make and then by the shell.
3029 # Also, because we want to override the logic in subdir configure scripts to
3030 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3031 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3032 ${program_transform_name}
3033 EOF_SED
3034 gcc_transform_name=`cat conftestsed.out`
3035 rm -f conftestsed.out
3036 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3037 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3038 if test "$silent" = yes; then
3039   baseargs="$baseargs --silent"
3040   tbaseargs="$tbaseargs --silent"
3041 fi
3042 baseargs="$baseargs --disable-option-checking"
3043 tbaseargs="$tbaseargs --disable-option-checking"
3044
3045 # Record and document user additions to sub configure arguments.
3046 AC_ARG_VAR([build_configargs],
3047            [additional configure arguments for build directories])
3048 AC_ARG_VAR([host_configargs],
3049            [additional configure arguments for host directories])
3050 AC_ARG_VAR([target_configargs],
3051            [additional configure arguments for target directories])
3052
3053 # For the build-side libraries, we just need to pretend we're native,
3054 # and not use the same cache file.  Multilibs are neither needed nor
3055 # desired.  We can't even use the same cache file for all build-side
3056 # libraries, as they're compiled differently; some with C, some with
3057 # C++ or with different feature-enabling options.
3058 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3059
3060 # For host modules, accept cache file option, or specification as blank.
3061 case "${cache_file}" in
3062 "") # empty
3063   cache_file_option="" ;;
3064 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3065   cache_file_option="--cache-file=${cache_file}" ;;
3066 *) # relative path
3067   cache_file_option="--cache-file=../${cache_file}" ;;
3068 esac
3069
3070 # Host dirs don't like to share a cache file either, horribly enough.
3071 # This seems to be due to autoconf 2.5x stupidity.
3072 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3073
3074 target_configargs="$target_configargs ${tbaseargs}"
3075
3076 # Passing a --with-cross-host argument lets the target libraries know
3077 # whether they are being built with a cross-compiler or being built
3078 # native.  However, it would be better to use other mechanisms to make the
3079 # sorts of decisions they want to make on this basis.  Please consider
3080 # this option to be deprecated.  FIXME.
3081 if test x${is_cross_compiler} = xyes ; then
3082   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3083 fi
3084
3085 # Special user-friendly check for native x86_64-linux build, if
3086 # multilib is not explicitly enabled.
3087 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3088   x86_64-*linux*:yes:$build:$build:)
3089     # Make sure we have a development environment that handles 32-bit
3090     dev64=no
3091     echo "int main () { return 0; }" > conftest.c
3092     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3093     if test $? = 0 ; then
3094       if test -s conftest || test -s conftest.exe ; then
3095         dev64=yes
3096       fi
3097     fi
3098     rm -f conftest*
3099     if test x${dev64} != xyes ; then
3100       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3101     fi
3102     ;;
3103 esac
3104
3105 # Default to --enable-multilib.
3106 if test x${enable_multilib} = x ; then
3107   target_configargs="--enable-multilib ${target_configargs}"
3108 fi
3109
3110 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3111 # changed from the earlier setting of with_newlib.
3112 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3113   target_configargs="--with-newlib ${target_configargs}"
3114 fi
3115
3116 # Different target subdirs use different values of certain variables
3117 # (notably CXX).  Worse, multilibs use *lots* of different values.
3118 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3119 # it doesn't automatically accept command-line overrides of them.
3120 # This means it's not safe for target subdirs to share a cache file,
3121 # which is disgusting, but there you have it.  Hopefully this can be
3122 # fixed in future.  It's still worthwhile to use a cache file for each
3123 # directory.  I think.
3124
3125 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3126 # We need to pass --target, as newer autoconf's requires consistency
3127 # for target_alias and gcc doesn't manage it consistently.
3128 target_configargs="--cache-file=./config.cache ${target_configargs}"
3129
3130 FLAGS_FOR_TARGET=
3131 case " $target_configdirs " in
3132  *" newlib "*)
3133   case " $target_configargs " in
3134   *" --with-newlib "*)
3135    case "$target" in
3136     *-cygwin*)
3137       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3138       ;;
3139    esac
3140
3141    # If we're not building GCC, don't discard standard headers.
3142    if test -d ${srcdir}/gcc; then
3143      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3144
3145      if test "${build}" != "${host}"; then
3146        # On Canadian crosses, CC_FOR_TARGET will have already been set
3147        # by `configure', so we won't have an opportunity to add -Bgcc/
3148        # to it.  This is right: we don't want to search that directory
3149        # for binaries, but we want the header files in there, so add
3150        # them explicitly.
3151        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3152
3153        # Someone might think of using the pre-installed headers on
3154        # Canadian crosses, in case the installed compiler is not fully
3155        # compatible with the compiler being built.  In this case, it
3156        # would be better to flag an error than risking having
3157        # incompatible object files being constructed.  We can't
3158        # guarantee that an error will be flagged, but let's hope the
3159        # compiler will do it, when presented with incompatible header
3160        # files.
3161      fi
3162    fi
3163
3164    case "${target}-${is_cross_compiler}" in
3165    i[[3456789]]86-*-linux*-no)
3166       # Here host == target, so we don't need to build gcc,
3167       # so we don't want to discard standard headers.
3168       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3169       ;;
3170    *)
3171       # If we're building newlib, use its generic headers last, but search
3172       # for any libc-related directories first (so make it the last -B
3173       # switch).
3174       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3175
3176       # If we're building libgloss, find the startup file, simulator library
3177       # and linker script.
3178       case " $target_configdirs " in
3179         *" libgloss "*)
3180         # Look for startup file, simulator library and maybe linker script.
3181         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3182         # Look for libnosys.a in case the target needs it.
3183         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3184         # Most targets have the linker script in the source directory.
3185         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3186         ;;
3187       esac
3188       ;;
3189    esac
3190    ;;
3191   esac
3192   ;;
3193 esac
3194
3195 case "$target" in
3196   x86_64-*mingw* | *-w64-mingw*)
3197   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3198   # however, use a symlink named 'mingw' in ${prefix} .
3199     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3200     ;;
3201   *-mingw*)
3202   # MinGW can't be handled as Cygwin above since it does not use newlib.
3203     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3204     ;;
3205 esac
3206
3207 # Allow the user to override the flags for
3208 # our build compiler if desired.
3209 if test x"${build}" = x"${host}" ; then
3210   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3211   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3212   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3213 fi
3214
3215 # On Canadian crosses, we'll be searching the right directories for
3216 # the previously-installed cross compiler, so don't bother to add
3217 # flags for directories within the install tree of the compiler
3218 # being built; programs in there won't even run.
3219 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3220   # Search for pre-installed headers if nothing else fits.
3221   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3222 fi
3223
3224 if test "x${use_gnu_ld}" = x &&
3225    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3226   # Arrange for us to find uninstalled linker scripts.
3227   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3228 fi
3229
3230 # Search for other target-specific linker scripts and such.
3231 case "${target}" in
3232   mep*)
3233     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3234     ;;
3235 esac
3236
3237 # Makefile fragments.
3238 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3239 do
3240   eval fragval=\$$frag
3241   if test $fragval != /dev/null; then
3242     eval $frag=${srcdir}/$fragval
3243   fi
3244 done
3245 AC_SUBST_FILE(host_makefile_frag)
3246 AC_SUBST_FILE(target_makefile_frag)
3247 AC_SUBST_FILE(alphaieee_frag)
3248 AC_SUBST_FILE(ospace_frag)
3249
3250 # Miscellanea: directories, flags, etc.
3251 AC_SUBST(RPATH_ENVVAR)
3252 AC_SUBST(GCC_SHLIB_SUBDIR)
3253 AC_SUBST(tooldir)
3254 AC_SUBST(build_tooldir)
3255 AC_SUBST(CONFIGURE_GDB_TK)
3256 AC_SUBST(GDB_TK)
3257 AC_SUBST(INSTALL_GDB_TK)
3258
3259 # Build module lists & subconfigure args.
3260 AC_SUBST(build_configargs)
3261 AC_SUBST(build_configdirs)
3262
3263 # Host module lists & subconfigure args.
3264 AC_SUBST(host_configargs)
3265 AC_SUBST(configdirs)
3266 AC_SUBST(target_configdirs)
3267
3268 # Target module lists & subconfigure args.
3269 AC_SUBST(target_configargs)
3270
3271
3272 # Build tools.
3273 AC_SUBST(AR_FOR_BUILD)
3274 AC_SUBST(AS_FOR_BUILD)
3275 AC_SUBST(CC_FOR_BUILD)
3276 AC_SUBST(CFLAGS_FOR_BUILD)
3277 AC_SUBST(CXXFLAGS_FOR_BUILD)
3278 AC_SUBST(CXX_FOR_BUILD)
3279 AC_SUBST(DLLTOOL_FOR_BUILD)
3280 AC_SUBST(GFORTRAN_FOR_BUILD)
3281 AC_SUBST(GOC_FOR_BUILD)
3282 AC_SUBST(LDFLAGS_FOR_BUILD)
3283 AC_SUBST(LD_FOR_BUILD)
3284 AC_SUBST(NM_FOR_BUILD)
3285 AC_SUBST(RANLIB_FOR_BUILD)
3286 AC_SUBST(WINDMC_FOR_BUILD)
3287 AC_SUBST(WINDRES_FOR_BUILD)
3288
3289 # Generate default definitions for YACC, M4, LEX and other programs that run
3290 # on the build machine.  These are used if the Makefile can't locate these
3291 # programs in objdir.
3292 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3293
3294 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3295 case " $build_configdirs " in
3296   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3297 esac
3298
3299 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3300 case " $build_configdirs " in
3301   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3302 esac
3303
3304 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3305 case " $build_configdirs " in
3306   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3307 esac
3308
3309 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3310 case " $build_configdirs " in
3311   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3312   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3313 esac
3314
3315 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3316 case " $build_configdirs " in
3317   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3318 esac
3319
3320 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3321 case " $build_configdirs " in
3322   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3323   *)
3324 changequote(,)
3325     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3326     # higher, else we use the "missing" dummy.
3327     if ${MAKEINFO} --version \
3328        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3329       :
3330     else
3331       MAKEINFO="$MISSING makeinfo"
3332     fi
3333     ;;
3334 changequote([,])
3335 esac
3336
3337 # FIXME: expect and dejagnu may become build tools?
3338
3339 AC_CHECK_PROGS(EXPECT, expect, expect)
3340 case " $configdirs " in
3341   *" expect "*)
3342     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3343     ;;
3344 esac
3345
3346 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3347 case " $configdirs " in
3348   *" dejagnu "*)
3349     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3350     ;;
3351 esac
3352
3353
3354 # Host tools.
3355 NCN_STRICT_CHECK_TOOLS(AR, ar)
3356 NCN_STRICT_CHECK_TOOLS(AS, as)
3357 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3358 NCN_STRICT_CHECK_TOOLS(LD, ld)
3359 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3360 NCN_STRICT_CHECK_TOOLS(NM, nm)
3361 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3362 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3363 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3364 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3365 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3366 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3367 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3368 AC_SUBST(CC)
3369 AC_SUBST(CXX)
3370 AC_SUBST(CFLAGS)
3371 AC_SUBST(CXXFLAGS)
3372
3373 # Target tools.
3374 AC_ARG_WITH([build-time-tools],
3375   [AS_HELP_STRING([--with-build-time-tools=PATH],
3376                   [use given path to find target tools during the build])],
3377   [case x"$withval" in
3378      x/*) ;;
3379      *)
3380        with_build_time_tools=
3381        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3382        ;;
3383    esac],
3384   [with_build_time_tools=])
3385
3386 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3387 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3388 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3389 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3390 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3391
3392 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3393 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3394 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3395 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3396 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3397 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3398 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3399 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3400 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3401 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3402 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3403 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3404 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3405
3406 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3407
3408 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3409 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3410 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3411 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3412 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3413                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3414                 c++)
3415 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3416                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3417                 c++)
3418 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3419 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3420 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3421                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3422 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3423                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3424 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3425 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3426 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3427 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3428 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3429 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3430 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3431 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3432 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3433 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3434
3435 AC_SUBST(FLAGS_FOR_TARGET)
3436 AC_SUBST(RAW_CXX_FOR_TARGET)
3437
3438 # Certain tools may need extra flags.
3439 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3440 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3441 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3442
3443 # When building target libraries, except in a Canadian cross, we use
3444 # the same toolchain as the compiler we just built.
3445 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3446 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3447 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3448 if test $host = $build; then
3449   case " $configdirs " in
3450     *" gcc "*)
3451       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3452       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3453       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3454       ;;
3455   esac
3456 fi
3457
3458 AC_SUBST(COMPILER_AS_FOR_TARGET)
3459 AC_SUBST(COMPILER_LD_FOR_TARGET)
3460 AC_SUBST(COMPILER_NM_FOR_TARGET)
3461
3462 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3463 AC_ARG_ENABLE(maintainer-mode,
3464 [AS_HELP_STRING([--enable-maintainer-mode],
3465                 [enable make rules and dependencies not useful
3466                  (and sometimes confusing) to the casual installer])],
3467       USE_MAINTAINER_MODE=$enableval,
3468       USE_MAINTAINER_MODE=no)
3469 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3470 AC_SUBST(MAINTAINER_MODE_TRUE)
3471 AC_SUBST(MAINTAINER_MODE_FALSE)
3472 if test "$USE_MAINTAINER_MODE" = yes; then
3473   MAINTAINER_MODE_TRUE=
3474   MAINTAINER_MODE_FALSE='#'
3475 else
3476   MAINTAINER_MODE_TRUE='#'
3477   MAINTAINER_MODE_FALSE=
3478 fi
3479 MAINT=$MAINTAINER_MODE_TRUE
3480 AC_SUBST(MAINT)dnl
3481
3482 # ---------------------
3483 # GCC bootstrap support
3484 # ---------------------
3485
3486 # Stage specific cflags for build.
3487 stage1_cflags="-g"
3488 case $build in
3489   vax-*-*)
3490     case ${GCC} in
3491       yes) stage1_cflags="-g -Wa,-J" ;;
3492       *) stage1_cflags="-g -J" ;;
3493     esac ;;
3494 esac
3495
3496 AC_SUBST(stage1_cflags)
3497
3498 # Enable --enable-checking in stage1 of the compiler.
3499 AC_ARG_ENABLE(stage1-checking,
3500 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3501                 [choose additional checking for stage1 of the compiler])],
3502 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3503 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3504   # For --disable-checking or implicit --enable-checking=release, avoid
3505   # setting --enable-checking=gc in the default stage1 checking for LTO
3506   # bootstraps.  See PR62077.
3507   case $BUILD_CONFIG in
3508     *lto*)
3509       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3510     *)
3511       stage1_checking=--enable-checking=yes,types;;
3512   esac
3513   if test "x$enable_checking" = x && \
3514      test -d ${srcdir}/gcc && \
3515      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3516     stage1_checking=--enable-checking=yes,types,extra
3517   fi
3518 else
3519   stage1_checking=--enable-checking=$enable_checking,types
3520 fi])
3521 AC_SUBST(stage1_checking)
3522
3523 # Enable -Werror in bootstrap stage2 and later.
3524 AC_ARG_ENABLE(werror,
3525 [AS_HELP_STRING([--enable-werror],
3526                 [enable -Werror in bootstrap stage2 and later])],
3527 [
3528 case ${enable_werror} in
3529   yes) stage2_werror_flag="--enable-werror-always" ;;
3530   *) stage2_werror_flag="" ;;
3531 esac
3532 ],
3533 [
3534 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3535   case $BUILD_CONFIG in
3536   bootstrap-debug)
3537       stage2_werror_flag="--enable-werror-always" ;;
3538   "")
3539       stage2_werror_flag="--enable-werror-always" ;;
3540   esac
3541 fi
3542 ])
3543
3544 AC_SUBST(stage2_werror_flag)
3545
3546 # Specify what files to not compare during bootstrap.
3547
3548 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3549 case "$target" in
3550   hppa*64*-*-hpux*) ;;
3551   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3552   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3553 esac
3554 AC_SUBST(compare_exclusions)
3555
3556 AC_CONFIG_FILES([Makefile],
3557   [sed "$extrasub_build" Makefile |
3558    sed "$extrasub_host" |
3559    sed "$extrasub_target" > mf$$
3560    mv -f mf$$ Makefile],
3561   [extrasub_build="$extrasub_build"
3562    extrasub_host="$extrasub_host"
3563    extrasub_target="$extrasub_target"])
3564 AC_OUTPUT