gdb/ptrace.m4

   1 dnl Copyright (C) 2012-2020 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GDB.
   4 dnl
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl Check the return and argument types of ptrace.
  19
  20 AC_DEFUN([GDB_AC_PTRACE],
  21 [
  22
  23 AC_CHECK_HEADERS([sys/ptrace.h ptrace.h])
  24
  25 gdb_ptrace_headers='
  26 #include <sys/types.h>
  27 #if HAVE_SYS_PTRACE_H
  28 # include <sys/ptrace.h>
  29 #endif
  30 #if HAVE_UNISTD_H
  31 # include <unistd.h>
  32 #endif
  33 '
  34
  35 # Check return type.  Varargs (used on GNU/Linux) conflict with the
  36 # empty argument list, so check for that explicitly.
  37 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
  38   AC_TRY_COMPILE($gdb_ptrace_headers,
  39     [extern long ptrace (enum __ptrace_request, ...);],
  40     gdb_cv_func_ptrace_ret='long',
  41     AC_TRY_COMPILE($gdb_ptrace_headers,
  42       [extern int ptrace ();],
  43       gdb_cv_func_ptrace_ret='int',
  44       gdb_cv_func_ptrace_ret='long')))
  45 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
  46   [Define as the return type of ptrace.])
  47 # Check argument types.
  48 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
  49   AC_TRY_COMPILE($gdb_ptrace_headers,
  50     [extern long ptrace (enum __ptrace_request, ...);],
  51     [gdb_cv_func_ptrace_args='enum __ptrace_request,int,long,long'],[
  52 for gdb_arg1 in 'int' 'long'; do
  53  for gdb_arg2 in 'pid_t' 'int' 'long'; do
  54   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
  55    for gdb_arg4 in 'int' 'long' 'void *'; do
  56      AC_TRY_COMPILE($gdb_ptrace_headers, [
  57 extern $gdb_cv_func_ptrace_ret
  58   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
  59 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
  60     break 4;])
  61     for gdb_arg5 in 'int *' 'int' 'long'; do
  62      AC_TRY_COMPILE($gdb_ptrace_headers, [
  63 extern $gdb_cv_func_ptrace_ret
  64   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
  65 ], [
  66 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
  67     break 5;])
  68     done
  69    done
  70   done
  71  done
  72 done
  73 # Provide a safe default value.
  74 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
  75 ])])
  76 ac_save_IFS=$IFS; IFS=','
  77 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
  78 IFS=$ac_save_IFS
  79 shift
  80 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG1, $[1],
  81   [Define to the type of arg 1 for ptrace.])
  82 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
  83   [Define to the type of arg 3 for ptrace.])
  84 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
  85   [Define to the type of arg 4 for ptrace.])
  86 if test -n "$[5]"; then
  87   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
  88     [Define to the type of arg 5 for ptrace.])
  89 fi
  90 ])