ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2020 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29 AM_MAINTAINER_MODE
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_GREP
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37
  38 LT_INIT
  39 ACX_LARGEFILE
  40
  41 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  42 AC_ARG_ENABLE(targets,
  43 [  --enable-targets        alternative target configurations],
  44 [case "${enableval}" in
  45   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  46             ;;
  47   no)       enable_targets= ;;
  48   *)        enable_targets=$enableval ;;
  49 esac])dnl
  50 AC_ARG_ENABLE(64-bit-bfd,
  51 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  52 [case "${enableval}" in
  53   yes)  want64=true  ;;
  54   no)   want64=false ;;
  55   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  56 esac],[want64=false])dnl
  57
  58 AC_ARG_WITH(sysroot,
  59 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  60 [
  61  case ${with_sysroot} in
  62  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  63  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  64  esac
  65
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  67  use_sysroot=yes
  68
  69  if test "x$prefix" = xNONE; then
  70   test_prefix=/usr/local
  71  else
  72   test_prefix=$prefix
  73  fi
  74  if test "x$exec_prefix" = xNONE; then
  75   test_exec_prefix=$test_prefix
  76  else
  77   test_exec_prefix=$exec_prefix
  78  fi
  79  case ${TARGET_SYSTEM_ROOT} in
  80  "${test_prefix}"|"${test_prefix}/"*|\
  81  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  82  '${prefix}'|'${prefix}/'*|\
  83  '${exec_prefix}'|'${exec_prefix}/'*)
  84    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  85    TARGET_SYSTEM_ROOT_DEFINE="$t"
  86    ;;
  87  esac
  88 ], [
  89  use_sysroot=no
  90  TARGET_SYSTEM_ROOT=
  91  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  92 ])
  93 AC_SUBST(use_sysroot)
  94 AC_SUBST(TARGET_SYSTEM_ROOT)
  95 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  96
  97 dnl Use --enable-gold to decide if this linker should be the default.
  98 dnl "install_as_default" is set to false if gold is the default linker.
  99 dnl "installed_linker" is the installed BFD linker name.
 100 AC_ARG_ENABLE(gold,
 101 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 102 [case "${enableval}" in
 103  default)
 104    install_as_default=no
 105    installed_linker=ld.bfd
 106    ;;
 107  yes|no)
 108    install_as_default=yes
 109    installed_linker=ld.bfd
 110    ;;
 111  *)
 112    AC_MSG_ERROR([invalid --enable-gold argument])
 113    ;;
 114  esac],
 115 [install_as_default=yes
 116  installed_linker=ld.bfd])
 117 AC_SUBST(install_as_default)
 118 AC_SUBST(installed_linker)
 119
 120 AC_ARG_ENABLE([got],
 121 AS_HELP_STRING([--enable-got=<type>],
 122                [GOT handling scheme (target, single, negative, multigot)]),
 123 [case "${enableval}" in
 124   target | single | negative | multigot)  got_handling=$enableval ;;
 125   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 126 esac],
 127 [got_handling=target])
 128
 129 case "${got_handling}" in
 130   target)
 131     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 132               [Define to choose default GOT handling scheme]) ;;
 133   single)
 134     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 135               [Define to choose default GOT handling scheme]) ;;
 136   negative)
 137     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 138               [Define to choose default GOT handling scheme]) ;;
 139   multigot)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 143 esac
 144
 145 # PR gas/19109
 146 # Decide the default method for compressing debug sections.
 147 ac_default_compressed_debug_sections=unset
 148 # Provide a configure time option to override our default.
 149 AC_ARG_ENABLE(compressed_debug_sections,
 150               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 151               [compress debug sections by default])],
 152 [case ,"${enableval}", in
 153   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 154   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 155 esac])dnl
 156
 157 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 158 ac_default_new_dtags=unset
 159 # Provide a configure time option to override our default.
 160 AC_ARG_ENABLE(new_dtags,
 161               AS_HELP_STRING([--enable-new-dtags],
 162               [set DT_RUNPATH instead of DT_RPATH by default])],
 163 [case "${enableval}" in
 164   yes) ac_default_new_dtags=1 ;;
 165   no) ac_default_new_dtags=0 ;;
 166 esac])dnl
 167
 168 # Decide if -z relro should be enabled in ELF linker by default.
 169 ac_default_ld_z_relro=unset
 170 # Provide a configure time option to override our default.
 171 AC_ARG_ENABLE(relro,
 172               AS_HELP_STRING([--enable-relro],
 173               [enable -z relro in ELF linker by default]),
 174 [case "${enableval}" in
 175   yes)  ac_default_ld_z_relro=1 ;;
 176   no)  ac_default_ld_z_relro=0 ;;
 177 esac])dnl
 178
 179 # Decide if DT_TEXTREL check should be enabled in ELF linker.
 180 ac_default_ld_textrel_check=unset
 181 AC_ARG_ENABLE([textrel-check],
 182               AC_HELP_STRING([--enable-textrel-check=@<:@yes|no|warning|error@:>@],
 183                              [enable DT_TEXTREL check in ELF linker]),
 184 [case "${enableval}" in
 185   yes|no|warning|error) ac_default_ld_textrel_check=${enableval} ;;
 186 esac])
 187
 188 # Decide if -z separate-code should be enabled in ELF linker by default.
 189 ac_default_ld_z_separate_code=unset
 190 AC_ARG_ENABLE(separate-code,
 191               AS_HELP_STRING([--enable-separate-code],
 192               [enable -z separate-code in ELF linker by default]),
 193 [case "${enableval}" in
 194   yes) ac_default_ld_z_separate_code=1 ;;
 195   no) ac_default_ld_z_separate_code=0 ;;
 196 esac])
 197
 198 # Decide which "--hash-style" to use by default
 199 # Provide a configure time option to override our default.
 200 AC_ARG_ENABLE([default-hash-style],
 201 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 202                [use this default hash style]),
 203 [case "${enable_default_hash_style}" in
 204   sysv | gnu | both) ;;
 205   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 206 esac],
 207 [case "${target}" in
 208   # Enable gnu hash only on GNU targets, but not mips
 209   mips*-*-*) enable_default_hash_style=sysv ;;
 210   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 211   *) enable_default_hash_style=sysv ;;
 212 esac])
 213
 214 case "${enable_default_hash_style}" in
 215   sysv | both) ac_default_emit_sysv_hash=1 ;;
 216   *) ac_default_emit_sysv_hash=0 ;;
 217 esac
 218
 219 case "${enable_default_hash_style}" in
 220   gnu | both) ac_default_emit_gnu_hash=1 ;;
 221   *) ac_default_emit_gnu_hash=0 ;;
 222 esac
 223
 224 AM_BINUTILS_WARNINGS
 225
 226 AM_LC_MESSAGES
 227
 228 AC_CONFIG_HEADERS([config.h:config.in])
 229
 230 # PR 14072
 231 AH_VERBATIM([00_CONFIG_H_CHECK],
 232 [/* Check that config.h is #included before system headers
 233    (this works only for glibc, but that should be enough).  */
 234 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 235 #  error config.h must be #included before system headers
 236 #endif
 237 #define __CONFIG_H__ 1])
 238
 239 if test -z "$target" ; then
 240     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 241 fi
 242 if test -z "$host" ; then
 243     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 244 fi
 245
 246 # host-specific stuff:
 247
 248 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 249 ZW_GNU_GETTEXT_SISTER_DIR
 250 AM_PO_SUBDIRS
 251
 252 AC_EXEEXT
 253
 254 AC_PROG_YACC
 255 AM_PROG_LEX
 256
 257 AM_MAINTAINER_MODE
 258 AM_CONDITIONAL(GENINSRC_NEVER, false)
 259 ACX_PROG_CMP_IGNORE_INITIAL
 260
 261 . ${srcdir}/configure.host
 262
 263 AC_SUBST(HDEFINES)
 264 AC_SUBST(NATIVE_LIB_DIRS)
 265
 266 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 267 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 268 ACX_HEADER_STRING
 269 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 270 AC_CHECK_FUNCS(open lseek close)
 271 AC_HEADER_DIRENT
 272
 273 dnl AC_CHECK_HEADERS(sys/mman.h)
 274 AC_FUNC_MMAP
 275
 276 AC_SEARCH_LIBS([dlopen], [dl])
 277 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$plugins = xyes])
 278
 279 AC_ARG_ENABLE(initfini-array,
 280 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 281 [case "${enableval}" in
 282  yes|no) ;;
 283  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 284  esac], [enable_initfini_array=yes])
 285 AC_SUBST(enable_initfini_array)
 286 if test $enable_initfini_array = yes; then
 287   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 288     [Define .init_array/.fini_array sections are available and working.])
 289 fi
 290
 291 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 292 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 293 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 294 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 295 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 296 if test $ld_cv_decl_getopt_unistd_h = yes; then
 297   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 298             [Is the prototype for getopt in <unistd.h> in the expected format?])
 299 fi
 300
 301 BFD_BINARY_FOPEN
 302
 303 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 304
 305 # Link in zlib if we can.  This allows us to read and write
 306 # compressed CTF sections.
 307 AM_ZLIB
 308
 309 # When converting linker scripts into strings for use in emulation
 310 # files, use astring.sed if the compiler supports ANSI string
 311 # concatenation, or ostring.sed otherwise.  This is to support the
 312 # broken Microsoft MSVC compiler, which limits the length of string
 313 # constants, while still supporting pre-ANSI compilers which do not
 314 # support string concatenation.
 315 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 316 AC_CACHE_VAL(ld_cv_string_concatenation,
 317 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 318   ld_cv_string_concatenation=yes,
 319   ld_cv_string_concatenation=no)])
 320 AC_MSG_RESULT($ld_cv_string_concatenation)
 321 if test "$ld_cv_string_concatenation" = "yes"; then
 322   STRINGIFY=astring.sed
 323 else
 324   STRINGIFY=ostring.sed
 325 fi
 326 AC_SUBST(STRINGIFY)
 327
 328 # target-specific stuff:
 329
 330 all_targets=
 331 EMUL=
 332 all_emuls=
 333 all_emul_extras=
 334 all_libpath=
 335 TDIRS=
 336
 337 # If the host is 64-bit, then we enable 64-bit targets by default.
 338 # This is consistent with what ../bfd/configure.ac does.
 339 if test x${want64} = xfalse; then
 340   AC_CHECK_SIZEOF(void *)
 341   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 342     want64=true
 343   fi
 344 fi
 345
 346 elf_list_options=FALSE
 347 elf_shlib_list_options=FALSE
 348 elf_plt_unwind_list_options=FALSE
 349 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 350 do
 351   if test "$targ_alias" = "all"; then
 352     all_targets=true
 353     elf_list_options=TRUE
 354     elf_shlib_list_options=TRUE
 355     elf_plt_unwind_list_options=TRUE
 356   else
 357     # Canonicalize the secondary target names.
 358     result=`$ac_config_sub $targ_alias 2>/dev/null`
 359     if test -n "$result"; then
 360         targ=$result
 361     else
 362         targ=$targ_alias
 363     fi
 364
 365     . ${srcdir}/configure.tgt
 366
 367     if test "$targ" = "$target"; then
 368       EMUL=$targ_emul
 369     fi
 370
 371     if test x${want64} = xfalse; then
 372       . ${srcdir}/../bfd/config.bfd
 373     fi
 374
 375     if test x${want64} = xtrue; then
 376       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 377       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 378     fi
 379
 380     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 381         case " $all_emuls " in
 382         *" e${i}.o "*) ;;
 383         *)
 384           all_emuls="$all_emuls e${i}.o"
 385           eval result=\$tdir_$i
 386           test -z "$result" && result=$targ_alias
 387           TDIRS="$TDIRS
 388 tdir_$i=$result"
 389           case "${i}" in
 390           *elf*)
 391             elf_list_options=TRUE
 392             ;;
 393           *)
 394             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 395               elf_list_options=TRUE
 396             fi
 397             ;;
 398           esac
 399           if test "$elf_list_options" = "TRUE"; then
 400             source_sh()
 401             {
 402               . $1
 403             }
 404             source_sh ${srcdir}/emulparams/${i}.sh
 405             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 406               elf_shlib_list_options=TRUE
 407             fi
 408             if test x${PLT_UNWIND} = xyes; then
 409               elf_plt_unwind_list_options=TRUE
 410             fi
 411           fi
 412           ;;
 413         esac
 414     done
 415
 416     for i in $targ_emul $targ_extra_libpath; do
 417         case " $all_libpath " in
 418         *" ${i} "*) ;;
 419         *)
 420           if test -z "$all_libpath"; then
 421             all_libpath=${i}
 422           else
 423             all_libpath="$all_libpath ${i}"
 424           fi
 425           ;;
 426         esac
 427     done
 428
 429     for i in $targ_extra_ofiles; do
 430         case " $all_emul_extras " in
 431         *" ${i} "*) ;;
 432         *)
 433           all_emul_extras="$all_emul_extras ${i}"
 434           ;;
 435         esac
 436     done
 437
 438   fi
 439 done
 440
 441 if test x$ac_default_compressed_debug_sections = xyes ; then
 442   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 443 fi
 444
 445 if test "${ac_default_new_dtags}" = unset; then
 446   ac_default_new_dtags=0
 447 fi
 448 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 449   $ac_default_new_dtags,
 450   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 451
 452 if test "${ac_default_ld_z_relro}" = unset; then
 453   ac_default_ld_z_relro=0
 454 fi
 455 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 456   $ac_default_ld_z_relro,
 457   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 458
 459 ac_default_ld_textrel_check_warning=0
 460 case "${ac_default_ld_textrel_check}" in
 461   unset|no)
 462     ac_default_ld_textrel_check=textrel_check_none
 463     ;;
 464   yes|warning)
 465     ac_default_ld_textrel_check=textrel_check_warning
 466     ac_default_ld_textrel_check_warning=1
 467     ;;
 468   error)
 469     ac_default_ld_textrel_check=textrel_check_error
 470     ;;
 471 esac
 472 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK,
 473   $ac_default_ld_textrel_check,
 474   [The default method for DT_TEXTREL check in ELF linker.])
 475 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK_WARNING,
 476   $ac_default_ld_textrel_check_warning,
 477   [Define to 1 if DT_TEXTREL check is warning in ELF linker by default.])
 478
 479 if test "${ac_default_ld_z_separate_code}" = unset; then
 480   ac_default_ld_z_separate_code=0
 481 fi
 482 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 483   $ac_default_ld_z_separate_code,
 484   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 485
 486 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 487   [$ac_default_emit_sysv_hash],
 488   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 489
 490 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 491   [$ac_default_emit_gnu_hash],
 492   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 493
 494 AC_SUBST(elf_list_options)
 495 AC_SUBST(elf_shlib_list_options)
 496 AC_SUBST(elf_plt_unwind_list_options)
 497 AC_SUBST(EMUL)
 498
 499 AC_SUBST(TDIRS)
 500 AM_SUBST_NOTMAKE(TDIRS)
 501
 502 if test x${all_targets} = xtrue; then
 503   if test x${want64} = xtrue; then
 504     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 505     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 506   else
 507     EMULATION_OFILES='$(ALL_EMULATIONS)'
 508     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 509   fi
 510 else
 511   EMULATION_OFILES=$all_emuls
 512   EMUL_EXTRA_OFILES=$all_emul_extras
 513 fi
 514 AC_SUBST(EMULATION_OFILES)
 515 AC_SUBST(EMUL_EXTRA_OFILES)
 516 AC_SUBST(LIB_PATH)
 517
 518 EMULATION_LIBPATH=$all_libpath
 519 AC_SUBST(EMULATION_LIBPATH)
 520
 521 if test x${enable_static} = xno; then
 522   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 523   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 524 else
 525   TESTBFDLIB="../bfd/.libs/libbfd.a"
 526   TESTCTFLIB="../libctf/.libs/libctf.a"
 527 fi
 528 AC_SUBST(TESTBFDLIB)
 529 AC_SUBST(TESTCTFLIB)
 530
 531 target_vendor=${target_vendor=$host_vendor}
 532 case "$target_vendor" in
 533   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 534   *)  EXTRA_SHLIB_EXTENSION= ;;
 535 esac
 536
 537 case "$target_os" in
 538   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 539 esac
 540
 541 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 542   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 543    [Additional extension a shared object might have.])
 544 fi
 545
 546 AC_CONFIG_COMMANDS([default],
 547 [[
 548 case "$srcdir" in
 549   .) srcdirpre= ;;
 550   *) srcdirpre='$(srcdir)/' ;;
 551 esac
 552 POFILES=
 553 GMOFILES=
 554 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 555   if test $lang != dummy; then
 556     POFILES="$POFILES $srcdirpre$lang.po"
 557     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 558   fi
 559 done
 560 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 561     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 562     -e "s,@POFILES@,$POFILES," \
 563     -e "s,@GMOFILES@,$GMOFILES," \
 564     po/Makefile.in > po/Makefile]],[[]])
 565
 566 dnl Required by html, pdf, install-pdf and install-html
 567 AC_SUBST(datarootdir)
 568 AC_SUBST(docdir)
 569 AC_SUBST(htmldir)
 570 AC_SUBST(pdfdir)
 571
 572 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 573 AC_OUTPUT