[deliverable/lttng-ust.git] / configure.ac

dnl -*- Autoconf -*-
dnl Process this file with autoconf to produce a configure script.

dnl Version infos
m4_define([V_MAJOR], [2])
m4_define([V_MINOR], [10])
m4_define([V_PATCH], [0])
m4_define([V_EXTRA], [rc1])
m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
m4_define([V_NAME], [[KeKriek]])
m4_define([V_DESC], [[From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.]])

AC_PREREQ(2.59)
AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
# This is the library version of liblttng-ust.
AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
# note: remember to update tracepoint.h dlopen() to match this version
# number. TODO: eventually automate by exporting the major number.

# This is the library version of liblttng-ust-ctl, used internally by
# liblttng-ust, lttng-sessiond, and lttng-consumerd.
AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [3:0:1])

AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
AM_MAINTAINER_MODE([enable])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

AC_REQUIRE_AUX_FILE([tap-driver.sh])

# Configuration options, which will be installed in the config.h
AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])

dnl Substitute minor/major/patchlevel version numbers
AC_SUBST([MAJOR_VERSION], [V_MAJOR])
AC_SUBST([MINOR_VERSION], [V_MINOR])
AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])

AC_PROG_SED
AC_PROG_GREP
AC_PROG_LN_S
AC_PROG_MKDIR_P

# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
AC_ARG_ENABLE([libtool-linkdep-fixup], [
	AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
], [
	libtool_fixup=$enableval
], [
	libtool_fixup=yes
])

AS_IF([test "x$libtool_fixup" = "xyes"], [
	libtool_m4="$srcdir/m4/libtool.m4"
	libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)

	AS_IF([test $libtool_flag_pattern_count -ne 0], [
	AC_MSG_RESULT([$libtool_flag_pattern_count])
	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
		sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
	], [
		AC_MSG_RESULT([none])
	])
])

AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
AC_PROG_MAKE_SET
LT_INIT

# rw_PROG_CXX_WORKS
# Check whether the C++ compiler works.
AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
	AC_LANG_PUSH([C++])

	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
		check_cxx_designated_initializers=yes
	], [
		rw_cv_prog_cxx_works=no
	])

	AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
			struct foo { int a; int b; };
			void fct(void)
			{
				struct foo f = { .a = 0, .b = 1 };
			}
		]])], [
			rw_cv_prog_cxx_works=yes
		], [
			rw_cv_prog_cxx_works=no
		])
	])

	AC_LANG_POP([C++])
])

AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])

# Check if the compiler support weak symbols
AX_SYS_WEAK_ALIAS

AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
])

# Checks for libraries.
AC_CHECK_LIB([dl], [dlopen], [
	have_libdl=yes
	libdl_name=dl
], [
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen], [
		have_libc_dl=yes
		libdl_name=c
	], [
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])

# Check if libdl has dlmopen support.
AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
AC_CHECK_LIB([$libdl_name], [dlmopen],
	[AC_DEFINE([HAVE_DLMOPEN], [1])]
)

AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])

AC_CHECK_LIB([pthread], [pthread_create])
AC_CHECK_LIB([pthread], [pthread_setname_np],
	AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
	AC_CHECK_LIB([pthread], [pthread_set_name_np],
		AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
		AC_MSG_RESULT([pthread setname/set_name not found.])))

# Check for dlfcn.h
AC_CHECK_HEADER([dlfcn.h])
AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
	AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
		#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
		#include <dlfcn.h>
	])
], [
	ac_cv_have_decl_RTLD_DI_LINKMAP="no"
])

AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])

# Checks for header files.
dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
dnl AC_TYPE_INT16_T
dnl AC_TYPE_INT32_T
dnl AC_TYPE_INT64_T
dnl AC_TYPE_INT8_T
dnl AC_TYPE_PID_T
dnl AC_TYPE_SIZE_T
dnl AC_TYPE_SSIZE_T
dnl AC_TYPE_UINT16_T
dnl AC_TYPE_UINT32_T
dnl AC_TYPE_UINT64_T
dnl AC_TYPE_UINT8_T
dnl AC_CHECK_TYPES([ptrdiff_t])

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])

# URCU

# urcu - check if we just find the headers it out of the box.
AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
This error can also occur when the liburcu package's configure script has not been run.])])

# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
# Part of Userspace RCU library 0.7.2 or better.
AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])

AC_MSG_CHECKING([caa_likely()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	#include <urcu/compiler.h>
	void fct(void)
	{
		if (caa_likely(1)) {
		}
	}
]])], [
	AC_MSG_RESULT([yes])
], [
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
])

# urcu - check that URCU lib is available to compilation
AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])

# urcu - check that URCU lib is at least version 0.6
AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])

# optional linux/perf_event.h
AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])

# Perf event counters are supported on all architectures supported by
# perf, using the read system call as fallback.
AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])

AS_IF([test "x$have_perf_event" = "xyes"], [
	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
])

AC_MSG_CHECKING([host system alignment requirements])
AS_CASE([$host_cpu],
	[i[[3456]]86], [],
	[x86_64], [],
	[amd64], [],
	[powerpc], [],
	[ppc64], [],
	[ppc64le], [],
	[powerpc64], [],
	[powerpc64le], [],
	[s390], [NO_UNALIGNED_ACCESS=1],
	[s390x], [NO_UNALIGNED_ACCESS=1],
	[arm*], [NO_UNALIGNED_ACCESS=1],
	[aarch64*], [NO_UNALIGNED_ACCESS=1],
	[mips*], [NO_UNALIGNED_ACCESS=1],
	[tile*], [NO_UNALIGNED_ACCESS=1],
	[
		UNSUPPORTED_ARCH=1
		NO_UNALIGNED_ACCESS=1
	])
AC_MSG_RESULT([$host_cpu])

AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
])

# Check for JNI header files if requested
AC_ARG_ENABLE([jni-interface], [
	AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
], [
	jni_interface=$enableval
], [
	jni_interface=no
])

AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])


AC_ARG_ENABLE([java-agent-jul], [
	AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
], [
	java_agent_jul=$enableval
], [
	java_agent_jul=no
])

AC_ARG_ENABLE([java-agent-log4j], [
	AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
], [
	java_agent_log4j=$enableval
], [
	java_agent_log4j=no
])

AC_ARG_ENABLE([java-agent-all], [
	AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
], [
	java_agent_jul=$enableval
	java_agent_log4j=$enableval
], [:])

AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])

AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
	AX_JAVA_OPTIONS
	AX_PROG_JAVAC
	AX_PROG_JAVA
	AX_PROG_JAR

	AX_JNI_INCLUDE_DIR
	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	do
		JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
	done

	saved_CPPFLAGS="$CPPFLAGS"
	CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
	AX_PROG_JAVAH
	CPPFLAGS="$saved_CPPFLAGS"
])

AS_IF([test "x$java_agent_log4j" = "xyes"], [
	AX_CHECK_CLASSPATH
	AX_CHECK_CLASS([org.apache.log4j.Logger])
	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
		AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	])
])

# Option to build the python agent
AC_ARG_ENABLE([python-agent], [
	AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
], [
	python_agent=$enableval
], [:])
AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
AS_IF([test "x$python_agent" = "xyes"], [
	AM_PATH_PYTHON([2.7])
])

# sdt.h integration
AC_ARG_WITH([sdt], [
	AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
], [
	with_sdt=$withval
], [
	with_sdt="no"
])

AS_IF([test "x$with_sdt" = "xyes"], [
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define SDT_USE_VARIADIC
		#include <sys/sdt.h>
		void fct(void)
		{
			STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
		}
	]])], [
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	], [
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

AC_MSG_CHECKING([whether shared libraries are enabled])
AS_IF([test "x$enable_shared" = "xyes"], [
	AC_MSG_RESULT([yes])
], [
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
])

AC_ARG_WITH([lttng-system-rundir], [
	AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
], [
	lttng_system_rundir="$withval"
], [
	lttng_system_rundir="/var/run/lttng"
])
AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
		[LTTng system runtime directory])

AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])

# Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
# is not distributed in tarballs.
AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])

# Enable building man pages (user's intention).
AC_ARG_ENABLE(
	man-pages,
	AS_HELP_STRING(
		[--disable-man-pages],
		[Do not build and install man pages (already built in a distributed tarball)]
	),
	[man_pages_opt=$enableval],
	[man_pages_opt=yes]
)

# Check for asciidoc and xmlto if we enabled building the man pages.
have_asciidoc_xmlto=no

AS_IF([test "x$man_pages_opt" = "xyes"], [
	AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
	AC_PATH_PROG([XMLTO], [xmlto], [no])

	AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
		AS_IF([test "x$in_git_repo" = "xyes"], [
			# This is an error because we're in the Git repo, which
			# means the man pages are not already generated for us,
			# thus asciidoc/xmlto are required because we were asked
			# to build the man pages.
			AC_MSG_ERROR([
Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
--disable-man-pages to disable building the man pages, in which case
they will not be installed.
			])
		], [
			# Only warn here: since we're in the tarball, the man
			# pages should already be generated at this point, thus
			# asciidoc/xmlto are not strictly required.
			AC_MSG_WARN([
Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
Note that the man pages are already built in this distribution tarball,
so asciidoc and xmlto are only needed if you intend to modify their
sources. Use --disable-man-pages to completely disable building
and installing the man pages.
			])
		])
	], [
		have_asciidoc_xmlto=yes
	])
])

# Export man page build condition: build the man pages if the user
# asked for it, and if the tools are available.
AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])

# Default values
AC_DEFUN([_AC_DEFINE_AND_SUBST], [
	AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
	$1="$2"
	AC_SUBST([$1])
])

_AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
# By default, do not retry on buffer full condition.
_AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_BLOCKING_RETRY_TIMEOUT_MS], [0])

AM_CFLAGS="-Wall"
AC_SUBST(AM_CFLAGS)
AC_SUBST(JNI_CPPFLAGS)

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	doc/man/Makefile
	include/Makefile
	include/lttng/ust-version.h
	snprintf/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-dl/Makefile
	liblttng-ust-fd/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-java-agent/Makefile
	liblttng-ust-java-agent/java/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	liblttng-ust-java-agent/jni/Makefile
	liblttng-ust-java-agent/jni/common/Makefile
	liblttng-ust-java-agent/jni/jul/Makefile
	liblttng-ust-java-agent/jni/log4j/Makefile
	liblttng-ust-libc-wrapper/Makefile
	liblttng-ust-cyg-profile/Makefile
	liblttng-ust-python-agent/Makefile
	python-lttngust/Makefile
	python-lttngust/setup.py
	python-lttngust/lttngust/__init__.py
	tools/Makefile
	tests/Makefile
	tests/ctf-types/Makefile
	tests/hello/Makefile
	tests/hello.cxx/Makefile
	tests/same_line_tracepoint/Makefile
	tests/snprintf/Makefile
	tests/ust-elf/Makefile
	tests/benchmark/Makefile
	tests/utils/Makefile
	tests/test-app-ctx/Makefile
	tests/gcc-weak-hidden/Makefile
	lttng-ust.pc
])

# Create link for python agent for the VPATH guru.
AC_CONFIG_LINKS([
	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
])

AC_OUTPUT

AS_ECHO
AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
AS_ECHO
AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])

# Report on the configuration options
AS_ECHO
AS_ECHO(["LTTng-UST will be built with the following options:"])

AS_ECHO

AS_ECHO_N(["Java agent (JUL support): "])
AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-jul)"])])

AS_ECHO_N(["Java agent (Log4j support): "])
AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-log4j)"])])

AS_ECHO_N(["JNI interface (JNI): "])
AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-jni-interface)"])])

AS_ECHO_N(["Python ($PYTHON) agent: "])
AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-python-agent)"])])

AS_ECHO_N(["sdt.h integration: "])
AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO(["Architecture: $host_cpu"])
AS_ECHO_N(["Efficient unaligned memory access: "])
AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
AS_ECHO

AS_ECHO(["Type 'make' to compile."])
Commit	Line	Data
	1	dnl -- Autoconf --
	2	dnl Process this file with autoconf to produce a configure script.
	3
	4	dnl Version infos
	5	m4_define([V_MAJOR], [2])
	6	m4_define([V_MINOR], [10])
	7	m4_define([V_PATCH], [0])
	8	m4_define([V_EXTRA], [rc1])
	9	m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
	10	m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
	11	m4_define([V_NAME], [[KeKriek]])
	12	m4_define([V_DESC], [[From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.]])
	13
	14	AC_PREREQ(2.59)
	15	AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
	16
	17	# Following the numbering scheme proposed by libtool for the library version
	18	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	19	# This is the library version of liblttng-ust.
	20	AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
	21	# note: remember to update tracepoint.h dlopen() to match this version
	22	# number. TODO: eventually automate by exporting the major number.
	23
	24	# This is the library version of liblttng-ust-ctl, used internally by
	25	# liblttng-ust, lttng-sessiond, and lttng-consumerd.
	26	AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [3:0:1])
	27
	28	AC_CONFIG_AUX_DIR([config])
	29	AC_CANONICAL_TARGET
	30	AC_CANONICAL_HOST
	31	AC_CONFIG_MACRO_DIR([m4])
	32	AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
	33	AM_MAINTAINER_MODE([enable])
	34	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	35	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
	36
	37	AC_REQUIRE_AUX_FILE([tap-driver.sh])
	38
	39	# Configuration options, which will be installed in the config.h
	40	AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
	41	AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
	42	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
	43	AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
	44
	45	dnl Substitute minor/major/patchlevel version numbers
	46	AC_SUBST([MAJOR_VERSION], [V_MAJOR])
	47	AC_SUBST([MINOR_VERSION], [V_MINOR])
	48	AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
	49
	50	AC_PROG_SED
	51	AC_PROG_GREP
	52	AC_PROG_LN_S
	53	AC_PROG_MKDIR_P
	54
	55	# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
	56	AC_ARG_ENABLE([libtool-linkdep-fixup], [
	57	AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
	58	], [
	59	libtool_fixup=$enableval
	60	], [
	61	libtool_fixup=yes
	62	])
	63
	64	AS_IF([test "x$libtool_fixup" = "xyes"], [
	65	libtool_m4="$srcdir/m4/libtool.m4"
	66	libtool_flag_pattern=".link_all_deplibs\s,\s\$1\s)"
	67	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	68	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s=\sno" $libtool_m4)
	69
	70	AS_IF([test $libtool_flag_pattern_count -ne 0], [
	71	AC_MSG_RESULT([$libtool_flag_pattern_count])
	72	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
	73	sed -i "s/\($libtool_flag_pattern\)\s=\sno/\1=unknown/g" $libtool_m4
	74	], [
	75	AC_MSG_RESULT([none])
	76	])
	77	])
	78
	79	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
	80
	81	# Checks for programs.
	82	AC_PROG_CC
	83	AC_PROG_CXX
	84	AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
	85	AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
	86	AC_PROG_MAKE_SET
	87	LT_INIT
	88
	89	# rw_PROG_CXX_WORKS
	90	# Check whether the C++ compiler works.
	91	AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
	92	AC_LANG_PUSH([C++])
	93
	94	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
	95	check_cxx_designated_initializers=yes
	96	], [
	97	rw_cv_prog_cxx_works=no
	98	])
	99
	100	AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
	101	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	102	struct foo { int a; int b; };
	103	void fct(void)
	104	{
	105	struct foo f = { .a = 0, .b = 1 };
	106	}
	107	]])], [
	108	rw_cv_prog_cxx_works=yes
	109	], [
	110	rw_cv_prog_cxx_works=no
	111	])
	112	])
	113
	114	AC_LANG_POP([C++])
	115	])
	116
	117	AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
	118
	119	# Check if the compiler support weak symbols
	120	AX_SYS_WEAK_ALIAS
	121
	122	AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	123	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
	124	])
	125
	126	# Checks for libraries.
	127	AC_CHECK_LIB([dl], [dlopen], [
	128	have_libdl=yes
	129	libdl_name=dl
	130	], [
	131	#libdl not found, check for dlopen in libc.
	132	AC_CHECK_LIB([c], [dlopen], [
	133	have_libc_dl=yes
	134	libdl_name=c
	135	], [
	136	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	137	])
	138	])
	139
	140	# Check if libdl has dlmopen support.
	141	AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
	142	AC_CHECK_LIB([$libdl_name], [dlmopen],
	143	[AC_DEFINE([HAVE_DLMOPEN], [1])]
	144	)
	145
	146	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
	147	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
	148
	149	AC_CHECK_LIB([pthread], [pthread_create])
	150	AC_CHECK_LIB([pthread], [pthread_setname_np],
	151	AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
	152	AC_CHECK_LIB([pthread], [pthread_set_name_np],
	153	AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
	154	AC_MSG_RESULT([pthread setname/set_name not found.])))
	155
	156	# Check for dlfcn.h
	157	AC_CHECK_HEADER([dlfcn.h])
	158	AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
	159	AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
	160	#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
	161	#include <dlfcn.h>
	162	])
	163	], [
	164	ac_cv_have_decl_RTLD_DI_LINKMAP="no"
	165	])
	166
	167	AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
	168
	169	# Checks for header files.
	170	dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
	171
	172	# Checks for typedefs, structures, and compiler characteristics.
	173	AC_C_INLINE
	174	dnl AC_TYPE_INT16_T
	175	dnl AC_TYPE_INT32_T
	176	dnl AC_TYPE_INT64_T
	177	dnl AC_TYPE_INT8_T
	178	dnl AC_TYPE_PID_T
	179	dnl AC_TYPE_SIZE_T
	180	dnl AC_TYPE_SSIZE_T
	181	dnl AC_TYPE_UINT16_T
	182	dnl AC_TYPE_UINT32_T
	183	dnl AC_TYPE_UINT64_T
	184	dnl AC_TYPE_UINT8_T
	185	dnl AC_CHECK_TYPES([ptrdiff_t])
	186
	187	# Checks for library functions.
	188	AC_FUNC_MALLOC
	189	AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
	190
	191	# URCU
	192
	193	# urcu - check if we just find the headers it out of the box.
	194	AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
	195	This error can also occur when the liburcu package's configure script has not been run.])])
	196
	197	# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
	198	# Part of Userspace RCU library 0.7.2 or better.
	199	AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
	200	liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
	201
	202	AC_MSG_CHECKING([caa_likely()])
	203	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	204	#include <urcu/compiler.h>
	205	void fct(void)
	206	{
	207	if (caa_likely(1)) {
	208	}
	209	}
	210	]])], [
	211	AC_MSG_RESULT([yes])
	212	], [
	213	AC_MSG_RESULT([no])
	214	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
	215	])
	216
	217	# urcu - check that URCU lib is available to compilation
	218	AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
	219
	220	# urcu - check that URCU lib is at least version 0.6
	221	AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
	222
	223	# optional linux/perf_event.h
	224	AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
	225
	226	# Perf event counters are supported on all architectures supported by
	227	# perf, using the read system call as fallback.
	228	AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
	229
	230	AS_IF([test "x$have_perf_event" = "xyes"], [
	231	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
	232	])
	233
	234	AC_MSG_CHECKING([host system alignment requirements])
	235	AS_CASE([$host_cpu],
	236	[i[[3456]]86], [],
	237	[x86_64], [],
	238	[amd64], [],
	239	[powerpc], [],
	240	[ppc64], [],
	241	[ppc64le], [],
	242	[powerpc64], [],
	243	[powerpc64le], [],
	244	[s390], [NO_UNALIGNED_ACCESS=1],
	245	[s390x], [NO_UNALIGNED_ACCESS=1],
	246	[arm*], [NO_UNALIGNED_ACCESS=1],
	247	[aarch64*], [NO_UNALIGNED_ACCESS=1],
	248	[mips*], [NO_UNALIGNED_ACCESS=1],
	249	[tile*], [NO_UNALIGNED_ACCESS=1],
	250	[
	251	UNSUPPORTED_ARCH=1
	252	NO_UNALIGNED_ACCESS=1
	253	])
	254	AC_MSG_RESULT([$host_cpu])
	255
	256	AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	257	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
	258	])
	259
	260	# Check for JNI header files if requested
	261	AC_ARG_ENABLE([jni-interface], [
	262	AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
	263	], [
	264	jni_interface=$enableval
	265	], [
	266	jni_interface=no
	267	])
	268
	269	AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
	270
	271
	272	AC_ARG_ENABLE([java-agent-jul], [
	273	AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
	274	], [
	275	java_agent_jul=$enableval
	276	], [
	277	java_agent_jul=no
	278	])
	279
	280	AC_ARG_ENABLE([java-agent-log4j], [
	281	AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
	282	], [
	283	java_agent_log4j=$enableval
	284	], [
	285	java_agent_log4j=no
	286	])
	287
	288	AC_ARG_ENABLE([java-agent-all], [
	289	AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
	290	], [
	291	java_agent_jul=$enableval
	292	java_agent_log4j=$enableval
	293	], [:])
	294
	295	AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"])
	296	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
	297	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
	298
	299	AS_IF([test "x$jni_interface" = "xyes" \|\| test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"], [
	300	AX_JAVA_OPTIONS
	301	AX_PROG_JAVAC
	302	AX_PROG_JAVA
	303	AX_PROG_JAR
	304
	305	AX_JNI_INCLUDE_DIR
	306	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	307	do
	308	JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
	309	done
	310
	311	saved_CPPFLAGS="$CPPFLAGS"
	312	CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
	313	AX_PROG_JAVAH
	314	CPPFLAGS="$saved_CPPFLAGS"
	315	])
	316
	317	AS_IF([test "x$java_agent_log4j" = "xyes"], [
	318	AX_CHECK_CLASSPATH
	319	AX_CHECK_CLASS([org.apache.log4j.Logger])
	320	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
	321	AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	322	])
	323	])
	324
	325	# Option to build the python agent
	326	AC_ARG_ENABLE([python-agent], [
	327	AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
	328	], [
	329	python_agent=$enableval
	330	], [:])
	331	AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
	332	AS_IF([test "x$python_agent" = "xyes"], [
	333	AM_PATH_PYTHON([2.7])
	334	])
	335
	336	# sdt.h integration
	337	AC_ARG_WITH([sdt], [
	338	AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
	339	], [
	340	with_sdt=$withval
	341	], [
	342	with_sdt="no"
	343	])
	344
	345	AS_IF([test "x$with_sdt" = "xyes"], [
	346	AC_MSG_CHECKING([STAP_PROBEV()])
	347	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	348	#define SDT_USE_VARIADIC
	349	#include <sys/sdt.h>
	350	void fct(void)
	351	{
	352	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	353	}
	354	]])], [
	355	AC_MSG_RESULT([yes])
	356	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	357	], [
	358	AC_MSG_RESULT([no])
	359	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	360	])
	361	])
	362
	363	AC_MSG_CHECKING([whether shared libraries are enabled])
	364	AS_IF([test "x$enable_shared" = "xyes"], [
	365	AC_MSG_RESULT([yes])
	366	], [
	367	AC_MSG_RESULT([no])
	368	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	369	])
	370
	371	AC_ARG_WITH([lttng-system-rundir], [
	372	AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	373	], [
	374	lttng_system_rundir="$withval"
	375	], [
	376	lttng_system_rundir="/var/run/lttng"
	377	])
	378	AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	379	[LTTng system runtime directory])
	380
	381	AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
	382	AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
	383
	384	# Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
	385	# is not distributed in tarballs.
	386	AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
	387	AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
	388
	389	# Enable building man pages (user's intention).
	390	AC_ARG_ENABLE(
	391	man-pages,
	392	AS_HELP_STRING(
	393	[--disable-man-pages],
	394	[Do not build and install man pages (already built in a distributed tarball)]
	395	),
	396	[man_pages_opt=$enableval],
	397	[man_pages_opt=yes]
	398	)
	399
	400	# Check for asciidoc and xmlto if we enabled building the man pages.
	401	have_asciidoc_xmlto=no
	402
	403	AS_IF([test "x$man_pages_opt" = "xyes"], [
	404	AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
	405	AC_PATH_PROG([XMLTO], [xmlto], [no])
	406
	407	AS_IF([test "x$ASCIIDOC" = "xno" \|\| test "x$XMLTO" = "xno"], [
	408	AS_IF([test "x$in_git_repo" = "xyes"], [
	409	# This is an error because we're in the Git repo, which
	410	# means the man pages are not already generated for us,
	411	# thus asciidoc/xmlto are required because we were asked
	412	# to build the man pages.
	413	AC_MSG_ERROR([
	414	Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
	415	--disable-man-pages to disable building the man pages, in which case
	416	they will not be installed.
	417	])
	418	], [
	419	# Only warn here: since we're in the tarball, the man
	420	# pages should already be generated at this point, thus
	421	# asciidoc/xmlto are not strictly required.
	422	AC_MSG_WARN([
	423	Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
	424	Note that the man pages are already built in this distribution tarball,
	425	so asciidoc and xmlto are only needed if you intend to modify their
	426	sources. Use --disable-man-pages to completely disable building
	427	and installing the man pages.
	428	])
	429	])
	430	], [
	431	have_asciidoc_xmlto=yes
	432	])
	433	])
	434
	435	# Export man page build condition: build the man pages if the user
	436	# asked for it, and if the tools are available.
	437	AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
	438	AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
	439
	440	# Default values
	441	AC_DEFUN([_AC_DEFINE_AND_SUBST], [
	442	AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
	443	$1="$2"
	444	AC_SUBST([$1])
	445	])
	446
	447	_AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
	448	# By default, do not retry on buffer full condition.
	449	_AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_BLOCKING_RETRY_TIMEOUT_MS], [0])
	450
	451	AM_CFLAGS="-Wall"
	452	AC_SUBST(AM_CFLAGS)
	453	AC_SUBST(JNI_CPPFLAGS)
	454
	455	AC_CONFIG_FILES([
	456	Makefile
	457	doc/Makefile
	458	doc/examples/Makefile
	459	doc/man/Makefile
	460	include/Makefile
	461	include/lttng/ust-version.h
	462	snprintf/Makefile
	463	libringbuffer/Makefile
	464	liblttng-ust-comm/Makefile
	465	liblttng-ust/Makefile
	466	liblttng-ust-ctl/Makefile
	467	liblttng-ust-fork/Makefile
	468	liblttng-ust-dl/Makefile
	469	liblttng-ust-fd/Makefile
	470	liblttng-ust-java/Makefile
	471	liblttng-ust-java-agent/Makefile
	472	liblttng-ust-java-agent/java/Makefile
	473	liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
	474	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	475	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	476	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	477	liblttng-ust-java-agent/jni/Makefile
	478	liblttng-ust-java-agent/jni/common/Makefile
	479	liblttng-ust-java-agent/jni/jul/Makefile
	480	liblttng-ust-java-agent/jni/log4j/Makefile
	481	liblttng-ust-libc-wrapper/Makefile
	482	liblttng-ust-cyg-profile/Makefile
	483	liblttng-ust-python-agent/Makefile
	484	python-lttngust/Makefile
	485	python-lttngust/setup.py
	486	python-lttngust/lttngust/__init__.py
	487	tools/Makefile
	488	tests/Makefile
	489	tests/ctf-types/Makefile
	490	tests/hello/Makefile
	491	tests/hello.cxx/Makefile
	492	tests/same_line_tracepoint/Makefile
	493	tests/snprintf/Makefile
	494	tests/ust-elf/Makefile
	495	tests/benchmark/Makefile
	496	tests/utils/Makefile
	497	tests/test-app-ctx/Makefile
	498	tests/gcc-weak-hidden/Makefile
	499	lttng-ust.pc
	500	])
	501
	502	# Create link for python agent for the VPATH guru.
	503	AC_CONFIG_LINKS([
	504	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	505	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	506	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	507	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
	508	])
	509
	510	AC_OUTPUT
	511
	512	AS_ECHO
	513	AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
	514	AS_ECHO
	515	AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])
	516
	517	# Report on the configuration options
	518	AS_ECHO
	519	AS_ECHO(["LTTng-UST will be built with the following options:"])
	520
	521	AS_ECHO
	522
	523	AS_ECHO_N(["Java agent (JUL support): "])
	524	AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-jul)"])])
	525
	526	AS_ECHO_N(["Java agent (Log4j support): "])
	527	AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-log4j)"])])
	528
	529	AS_ECHO_N(["JNI interface (JNI): "])
	530	AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-jni-interface)"])])
	531
	532	AS_ECHO_N(["Python ($PYTHON) agent: "])
	533	AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-python-agent)"])])
	534
	535	AS_ECHO_N(["sdt.h integration: "])
	536	AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	537
	538	AS_ECHO(["Architecture: $host_cpu"])
	539	AS_ECHO_N(["Efficient unaligned memory access: "])
	540	AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
	541	AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
	542	AS_ECHO
	543
	544	AS_ECHO(["Type 'make' to compile."])
	545