| | 1 | dnl SPDX-License-Identifier: GPL-2.0-only |
| | 2 | AC_PREREQ([2.64]) |
| | 3 | AC_INIT([lttng-tools],[2.12.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| | 4 | |
| | 5 | AC_CONFIG_HEADERS([include/config.h]) |
| | 6 | AC_CONFIG_AUX_DIR([config]) |
| | 7 | AC_CONFIG_MACRO_DIR([m4]) |
| | 8 | |
| | 9 | AC_CANONICAL_TARGET |
| | 10 | AC_CANONICAL_HOST |
| | 11 | |
| | 12 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc]) |
| | 13 | AM_MAINTAINER_MODE([enable]) |
| | 14 | |
| | 15 | # Enable silent rules if available (Introduced in AM 1.11) |
| | 16 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| | 17 | |
| | 18 | AC_REQUIRE_AUX_FILE([tap-driver.sh]) |
| | 19 | |
| | 20 | # Checks for C compiler |
| | 21 | AC_USE_SYSTEM_EXTENSIONS |
| | 22 | AC_SYS_LARGEFILE |
| | 23 | AC_PROG_CC |
| | 24 | AC_PROG_CC_STDC |
| | 25 | AC_PROG_CXX |
| | 26 | RW_PROG_CXX_WORKS |
| | 27 | AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"]) |
| | 28 | |
| | 29 | # Detect warning flags supported by the compiler, append them to WARN_CFLAGS. |
| | 30 | # |
| | 31 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 32 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 33 | AX_APPEND_COMPILE_FLAGS([ dnl |
| | 34 | -Wall dnl |
| | 35 | dnl We currently get this warning when building with Clang: |
| | 36 | dnl |
| | 37 | dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration] |
| | 38 | dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL; |
| | 39 | dnl ^ |
| | 40 | -Wno-incomplete-setjmp-declaration dnl |
| | 41 | -Wdiscarded-qualifiers dnl |
| | 42 | -Wmissing-declarations dnl |
| | 43 | -Wmissing-prototypes dnl |
| | 44 | -Wmissing-parameter-type dnl |
| | 45 | -Wold-style-definition dnl |
| | 46 | -Wstrict-prototypes dnl |
| | 47 | ], |
| | 48 | [WARN_CFLAGS], |
| | 49 | [-Werror]) |
| | 50 | |
| | 51 | # When given, add -Werror to WARN_CFLAGS. |
| | 52 | AC_ARG_ENABLE([Werror], |
| | 53 | [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])] |
| | 54 | ) |
| | 55 | AS_IF([test "x$enable_Werror" = "xyes"], |
| | 56 | [WARN_CFLAGS="${WARN_CFLAGS} -Werror"] |
| | 57 | ) |
| | 58 | |
| | 59 | # Checks for programs. |
| | 60 | AC_PROG_GREP |
| | 61 | AC_PROG_MAKE_SET |
| | 62 | AC_PROG_SED |
| | 63 | AC_PATH_PROG([report_fold], [fold]) |
| | 64 | LT_INIT |
| | 65 | |
| | 66 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| | 67 | AC_CHECK_TOOL([OBJCOPY], [objcopy], [no]) |
| | 68 | AS_IF([test "x$OBJCOPY" = "xno"], |
| | 69 | [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| | 70 | ) |
| | 71 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno]) |
| | 72 | |
| | 73 | # check for pgrep |
| | 74 | AC_PATH_PROG([PGREP], [pgrep], [no]) |
| | 75 | AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"]) |
| | 76 | |
| | 77 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| | 78 | # is not distributed in tarballs |
| | 79 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| | 80 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| | 81 | |
| | 82 | # check for bison |
| | 83 | AC_PROG_YACC |
| | 84 | BISON=$YACC |
| | 85 | AX_PROG_BISON_VERSION([2.4], [have_bison=yes]) |
| | 86 | |
| | 87 | AS_IF([test "x$have_bison" != "xyes"], [ |
| | 88 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 89 | AC_MSG_FAILURE([ |
| | 90 | Bison >= 2.4 is required when building from the Git repository. You can |
| | 91 | set the YACC variable to override automatic detection. |
| | 92 | ]) |
| | 93 | ], [ |
| | 94 | AC_MSG_WARN([ |
| | 95 | Missing Bison >= 2.4. Note that the parser files are already built in |
| | 96 | this distribution tarball, so Bison is only needed if you intend to |
| | 97 | modify their sources. You can set the YACC variable to override automatic |
| | 98 | detection. |
| | 99 | ]) |
| | 100 | ]) |
| | 101 | ]) |
| | 102 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| | 103 | |
| | 104 | # check for flex |
| | 105 | AC_PROG_LEX |
| | 106 | FLEX=$LEX |
| | 107 | AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes]) |
| | 108 | |
| | 109 | AS_IF([test "x$have_flex" != "xyes"], [ |
| | 110 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 111 | AC_MSG_FAILURE([ |
| | 112 | Flex >= 2.5.35 is required when building from the Git repository. You can |
| | 113 | set the LEX variable to override automatic detection. |
| | 114 | ]) |
| | 115 | ], [ |
| | 116 | AC_MSG_WARN([ |
| | 117 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| | 118 | this distribution tarball, so Flex is only needed if you intend to |
| | 119 | modify their sources. You can set the LEX variable to override automatic |
| | 120 | detection. |
| | 121 | ]) |
| | 122 | ]) |
| | 123 | ]) |
| | 124 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| | 125 | |
| | 126 | |
| | 127 | # Checks for typedefs, structures, and compiler characteristics. |
| | 128 | AC_C_INLINE |
| | 129 | AC_TYPE_INT32_T |
| | 130 | AC_TYPE_INT64_T |
| | 131 | AC_TYPE_MODE_T |
| | 132 | AC_TYPE_OFF_T |
| | 133 | AC_TYPE_PID_T |
| | 134 | AC_TYPE_SIZE_T |
| | 135 | AC_TYPE_SSIZE_T |
| | 136 | AC_TYPE_UID_T |
| | 137 | AC_TYPE_UINT16_T |
| | 138 | AC_TYPE_UINT32_T |
| | 139 | AC_TYPE_UINT64_T |
| | 140 | AC_TYPE_UINT8_T |
| | 141 | |
| | 142 | AX_C___ATTRIBUTE__ |
| | 143 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], |
| | 144 | [:], |
| | 145 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| | 146 | |
| | 147 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) |
| | 148 | |
| | 149 | # Check if linker has the -no-pie option. |
| | 150 | AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes]) |
| | 151 | AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"]) |
| | 152 | |
| | 153 | AX_LIB_SOCKET_NSL |
| | 154 | |
| | 155 | LT_NO_UNDEFINED="" |
| | 156 | AS_CASE([$host_os], |
| | 157 | [cygwin*], |
| | 158 | [ |
| | 159 | LT_NO_UNDEFINED="-no-undefined" |
| | 160 | ], |
| | 161 | [cygwin*|darwin*|mingw*|solaris*], |
| | 162 | [ |
| | 163 | # On platforms where we only support the relayd, disable the other binaries by default |
| | 164 | AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no]) |
| | 165 | AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no]) |
| | 166 | AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no]) |
| | 167 | AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no]) |
| | 168 | AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no]) |
| | 169 | AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no]) |
| | 170 | ] |
| | 171 | ) |
| | 172 | |
| | 173 | AC_SUBST(LT_NO_UNDEFINED) |
| | 174 | |
| | 175 | # Compute minor/major/patchlevel version numbers |
| | 176 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| | 177 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| | 178 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| | 179 | |
| | 180 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| | 181 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| | 182 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| | 183 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| | 184 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| | 185 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| | 186 | |
| | 187 | version_name="(Ta) Meilleure" |
| | 188 | version_description="Ta Meilleure is a Northeast IPA beer brewed by Lagabière. Translating to \"Your best one\", this beer gives out strong aromas of passion fruit, lemon, and peaches. Tastewise, expect a lot of fruit, a creamy texture, and a smooth lingering hop bitterness." |
| | 189 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| | 190 | |
| | 191 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| | 192 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| | 193 | |
| | 194 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| | 195 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| | 196 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| | 197 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| | 198 | libtool_fixup=$enableval, |
| | 199 | libtool_fixup=yes) |
| | 200 | |
| | 201 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| | 202 | [ |
| | 203 | libtool_m4="$srcdir/m4/libtool.m4" |
| | 204 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| | 205 | AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4]) |
| | 206 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| | 207 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| | 208 | [ |
| | 209 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| | 210 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| | 211 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| | 212 | ], |
| | 213 | [ |
| | 214 | AC_MSG_RESULT([none]) |
| | 215 | ]) |
| | 216 | ]) |
| | 217 | |
| | 218 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| | 219 | |
| | 220 | AC_CHECK_HEADERS([ \ |
| | 221 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| | 222 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| | 223 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| | 224 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| | 225 | sys/mount.h sys/param.h sys/time.h elf.h |
| | 226 | ]) |
| | 227 | |
| | 228 | AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes]) |
| | 229 | |
| | 230 | # Basic functions check |
| | 231 | AC_CHECK_FUNCS([ \ |
| | 232 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| | 233 | gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \ |
| | 234 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| | 235 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| | 236 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| | 237 | sched_getcpu sysconf sync_file_range |
| | 238 | ]) |
| | 239 | |
| | 240 | # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so, |
| | 241 | # add -lrt to LIBS |
| | 242 | AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete]) |
| | 243 | |
| | 244 | # Checks for dl. |
| | 245 | AC_CHECK_LIB([dl], [dlopen], [ |
| | 246 | have_libdl=yes |
| | 247 | libdl_name=dl |
| | 248 | DL_LIBS="-ldl" |
| | 249 | ], [ |
| | 250 | # libdl not found, check for dlopen in libc. |
| | 251 | AC_CHECK_LIB([c], [dlopen], [ |
| | 252 | have_libc_dl=yes |
| | 253 | libdl_name=c |
| | 254 | DL_LIBS="-lc" |
| | 255 | ], [ |
| | 256 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| | 257 | ]) |
| | 258 | ]) |
| | 259 | AC_SUBST(DL_LIBS) |
| | 260 | |
| | 261 | # Check if libdl has dlmopen support. |
| | 262 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) |
| | 263 | AC_CHECK_LIB([$libdl_name], [dlmopen], [ |
| | 264 | AC_DEFINE([HAVE_DLMOPEN], [1]) |
| | 265 | HAVE_DLMOPEN=1 |
| | 266 | ], [ |
| | 267 | HAVE_DLMOPEN=0 |
| | 268 | ]) |
| | 269 | AC_SUBST(HAVE_DLMOPEN) |
| | 270 | |
| | 271 | # Babeltrace viewer check |
| | 272 | AC_ARG_WITH([babeltrace-bin], |
| | 273 | AS_HELP_STRING([--with-babeltrace-bin], |
| | 274 | [Location of the babeltrace viewer executable (including the filename)]), |
| | 275 | [BABELTRACE_BIN="$withval"], |
| | 276 | [BABELTRACE_BIN='']) |
| | 277 | AC_SUBST([BABELTRACE_BIN]) |
| | 278 | |
| | 279 | AC_ARG_WITH([babeltrace2-bin], |
| | 280 | AS_HELP_STRING([--with-babeltrace2-bin], |
| | 281 | [Location of the babeltrace2 viewer executable (including the filename)]), |
| | 282 | [BABELTRACE2_BIN="$withval"], |
| | 283 | [BABELTRACE2_BIN='']) |
| | 284 | AC_SUBST([BABELTRACE2_BIN]) |
| | 285 | |
| | 286 | AC_ARG_WITH([consumerd32-bin], |
| | 287 | AS_HELP_STRING([--with-consumerd32-bin], |
| | 288 | [Location of the 32-bit consumerd executable (including the filename)]), |
| | 289 | [CONSUMERD32_BIN="$withval"], |
| | 290 | [CONSUMERD32_BIN='']) |
| | 291 | AC_SUBST([CONSUMERD32_BIN]) |
| | 292 | |
| | 293 | AC_ARG_WITH([consumerd64-bin], |
| | 294 | AS_HELP_STRING([--with-consumerd64-bin], |
| | 295 | [Location of the 64-bit consumerd executable (including the filename)]), |
| | 296 | [CONSUMERD64_BIN="$withval"], |
| | 297 | [CONSUMERD64_BIN='']) |
| | 298 | AC_SUBST([CONSUMERD64_BIN]) |
| | 299 | |
| | 300 | AC_ARG_WITH([consumerd32-libdir], |
| | 301 | AS_HELP_STRING([--with-consumerd32-libdir], |
| | 302 | [Directory containing the 32-bit consumerd libraries]), |
| | 303 | [CONSUMERD32_LIBDIR="$withval"], |
| | 304 | [CONSUMERD32_LIBDIR='']) |
| | 305 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| | 306 | |
| | 307 | AC_ARG_WITH([consumerd64-libdir], |
| | 308 | AS_HELP_STRING([--with-consumerd64-libdir], |
| | 309 | [Directory containing the 64-bit consumerd libraries]), |
| | 310 | [CONSUMERD64_LIBDIR="$withval"], |
| | 311 | [CONSUMERD64_LIBDIR='']) |
| | 312 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| | 313 | |
| | 314 | AC_ARG_WITH([sessiond-bin], |
| | 315 | AS_HELP_STRING([--with-sessiond-bin], |
| | 316 | [Location of the sessiond executable (including the filename)]), |
| | 317 | [SESSIOND_BIN="$withval"], |
| | 318 | [SESSIOND_BIN='']) |
| | 319 | AC_SUBST([SESSIOND_BIN]) |
| | 320 | |
| | 321 | AC_ARG_WITH([lttng-system-rundir], |
| | 322 | AS_HELP_STRING([--with-lttng-system-rundir], |
| | 323 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| | 324 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| | 325 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| | 326 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| | 327 | |
| | 328 | AC_ARG_ENABLE([test-java-agent-jul], |
| | 329 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| | 330 | [test_java_agent_jul=$enableval], |
| | 331 | [test_java_agent_jul=no] |
| | 332 | ) |
| | 333 | |
| | 334 | AC_ARG_ENABLE([test-java-agent-log4j], |
| | 335 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])], |
| | 336 | [test_java_agent_log4j=$enableval], |
| | 337 | [test_java_agent_log4j=no] |
| | 338 | ) |
| | 339 | |
| | 340 | AC_ARG_ENABLE([test-java-agent-all], |
| | 341 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| | 342 | [test_java_agent_jul=$enableval |
| | 343 | test_java_agent_log4j=$enableval], |
| | 344 | [:] |
| | 345 | ) |
| | 346 | |
| | 347 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| | 348 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| | 349 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| | 350 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| | 351 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| | 352 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.]) |
| | 353 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| | 354 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| | 355 | |
| | 356 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| | 357 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| | 358 | $1="$2" |
| | 359 | AC_SUBST([$1]) |
| | 360 | ]) |
| | 361 | |
| | 362 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| | 363 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| | 364 | $1="$2" |
| | 365 | AC_SUBST([$1]) |
| | 366 | ]) |
| | 367 | |
| | 368 | # Default values |
| | 369 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384]) |
| | 370 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| | 371 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| | 372 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| | 373 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| | 374 | m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000]) |
| | 375 | m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 376 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345]) |
| | 377 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354]) |
| | 378 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| | 379 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 380 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| | 381 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| | 382 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 383 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| | 384 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 385 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576]) |
| | 386 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 387 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 388 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT]) |
| | 389 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| | 390 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| | 391 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| | 392 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| | 393 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| | 394 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 395 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| | 396 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| | 397 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| | 398 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 399 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| | 400 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 401 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 402 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 403 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 404 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 405 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 406 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| | 407 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 408 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 409 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288]) |
| | 410 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 411 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 412 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| | 413 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| | 414 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| | 415 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| | 416 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728]) |
| | 417 | _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000]) |
| | 418 | |
| | 419 | # Command short descriptions |
| | 420 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel]) |
| | 421 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session]) |
| | 422 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session]) |
| | 423 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions]) |
| | 424 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels]) |
| | 425 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules]) |
| | 426 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule]) |
| | 427 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels]) |
| | 428 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules]) |
| | 429 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule]) |
| | 430 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command]) |
| | 431 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events]) |
| | 432 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations]) |
| | 433 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration]) |
| | 434 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk]) |
| | 435 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations]) |
| | 436 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session]) |
| | 437 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session]) |
| | 438 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing]) |
| | 439 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session]) |
| | 440 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing]) |
| | 441 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule]) |
| | 442 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule]) |
| | 443 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources]) |
| | 444 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources]) |
| | 445 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information]) |
| | 446 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer]) |
| | 447 | |
| | 448 | if test "x$prefix" = "xNONE"; then |
| | 449 | prefix=$ac_default_prefix |
| | 450 | fi |
| | 451 | CONFDIR=`eval echo $sysconfdir` |
| | 452 | AC_SUBST(CONFDIR) |
| | 453 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| | 454 | |
| | 455 | AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.]) |
| | 456 | |
| | 457 | # Check libpopt |
| | 458 | PKG_CHECK_MODULES([POPT], [popt], |
| | 459 | [ |
| | 460 | dnl PKG_CHECK_MODULES defines POPT_LIBS |
| | 461 | ], |
| | 462 | [ |
| | 463 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 464 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| | 465 | AC_CHECK_LIB([popt], |
| | 466 | [poptGetContext], |
| | 467 | [POPT_LIBS="-lpopt"], |
| | 468 | [ |
| | 469 | AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 470 | ] |
| | 471 | ) |
| | 472 | ] |
| | 473 | ) |
| | 474 | AC_SUBST(POPT_LIBS) |
| | 475 | |
| | 476 | PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6]) |
| | 477 | |
| | 478 | AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])]) |
| | 479 | |
| | 480 | # URCU library version needed or newer |
| | 481 | m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed]) |
| | 482 | |
| | 483 | # Check liburcu needed function calls |
| | 484 | AC_CHECK_DECL([cds_list_add], [], |
| | 485 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]]) |
| | 486 | AC_CHECK_DECL([cds_wfcq_init], [], |
| | 487 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| | 488 | AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [], |
| | 489 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| | 490 | AC_CHECK_DECL([futex_async], [], |
| | 491 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]]) |
| | 492 | AC_CHECK_DECL([rcu_thread_offline], [], |
| | 493 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 494 | AC_CHECK_DECL([rcu_thread_online], [], |
| | 495 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 496 | AC_CHECK_DECL([caa_likely], [], |
| | 497 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 498 | AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], |
| | 499 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])]) |
| | 500 | |
| | 501 | #Function added in urcu 0.7.0 |
| | 502 | AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [], |
| | 503 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]] |
| | 504 | ) |
| | 505 | |
| | 506 | #Function added in urcu 0.9.0 |
| | 507 | AC_CHECK_DECL([urcu_ref_get_unless_zero], [], |
| | 508 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]] |
| | 509 | ) |
| | 510 | |
| | 511 | # Check for libkmod, it will be auto-neabled if found but won't fail if it's not, |
| | 512 | # it can be explicitly disabled with --without-kmod |
| | 513 | AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support]) |
| | 514 | AC_ARG_WITH([kmod], |
| | 515 | [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])], |
| | 516 | [], |
| | 517 | [with_kmod=check] |
| | 518 | ) |
| | 519 | |
| | 520 | AS_IF([test "x$with_kmod" != "xno"], |
| | 521 | [ |
| | 522 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| | 523 | [ |
| | 524 | AC_DEFINE([HAVE_KMOD], [1]) |
| | 525 | KMOD_LIBS="-lkmod" |
| | 526 | ], |
| | 527 | [ |
| | 528 | if test "x$with_kmod" != xcheck; then |
| | 529 | AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.]) |
| | 530 | else |
| | 531 | with_kmod=no |
| | 532 | fi |
| | 533 | ] |
| | 534 | ) |
| | 535 | ] |
| | 536 | ) |
| | 537 | AC_SUBST(KMOD_LIBS) |
| | 538 | |
| | 539 | # Check for liblttng-ust-ctl, fail if it's not found, |
| | 540 | # it can be explicitly disabled with --without-lttng-ust |
| | 541 | AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support]) |
| | 542 | AC_ARG_WITH([lttng-ust], |
| | 543 | [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])], |
| | 544 | [], |
| | 545 | [with_lttng_ust=yes] |
| | 546 | ) |
| | 547 | |
| | 548 | AS_IF([test "x$with_lttng_ust" = "xyes"], [ |
| | 549 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1]) |
| | 550 | |
| | 551 | # Check for liblttng-ust |
| | 552 | PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version]) |
| | 553 | |
| | 554 | # Check for liblttng-ust-ctl |
| | 555 | PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version]) |
| | 556 | |
| | 557 | AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS" |
| | 558 | ]) |
| | 559 | |
| | 560 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"]) |
| | 561 | |
| | 562 | |
| | 563 | # Check for fmemopen |
| | 564 | AC_CHECK_LIB([c], [fmemopen], |
| | 565 | [ |
| | 566 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| | 567 | ] |
| | 568 | ) |
| | 569 | |
| | 570 | # check for libpfm |
| | 571 | AC_CHECK_LIB([pfm], [pfm_initialize], |
| | 572 | [ |
| | 573 | have_libpfm=yes |
| | 574 | ]) |
| | 575 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"]) |
| | 576 | |
| | 577 | # For Python |
| | 578 | # SWIG version needed or newer: |
| | 579 | swig_version=2.0.0 |
| | 580 | |
| | 581 | AC_ARG_ENABLE([python-bindings], |
| | 582 | [AC_HELP_STRING([--enable-python-bindings], |
| | 583 | [compile Python bindings])], |
| | 584 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| | 585 | |
| | 586 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| | 587 | |
| | 588 | if test "x$enable_python_binding" = xyes; then |
| | 589 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| | 590 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| | 591 | AM_PATH_PYTHON([3.0]) |
| | 592 | |
| | 593 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| | 594 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| | 595 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| | 596 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| | 597 | AC_PATH_PROGS([PYTHON_CONFIG], |
| | 598 | [python$PYTHON_VERSION-config python-config], |
| | 599 | [no], |
| | 600 | [`dirname $PYTHON`]) |
| | 601 | AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| | 602 | ]) |
| | 603 | AC_MSG_CHECKING([python include flags]) |
| | 604 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| | 605 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| | 606 | ]) |
| | 607 | |
| | 608 | else |
| | 609 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| | 610 | [if you want Python bindings.]) |
| | 611 | |
| | 612 | fi |
| | 613 | |
| | 614 | # Epoll check. If not present, the build will fallback on poll() API |
| | 615 | AX_HAVE_EPOLL( |
| | 616 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| | 617 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| | 618 | ) |
| | 619 | AX_CONFIG_FEATURE( |
| | 620 | [epoll], [This platform supports epoll(7)], |
| | 621 | [HAVE_EPOLL], [This platform supports epoll(7).], |
| | 622 | [enable_epoll="yes"], [enable_epoll="no"] |
| | 623 | ) |
| | 624 | AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ]) |
| | 625 | |
| | 626 | AS_IF([test "x$ac_cv_func_dirfd" = "xyes"], |
| | 627 | [AX_CONFIG_FEATURE_ENABLE(dirfd)], |
| | 628 | [AX_CONFIG_FEATURE_DISABLE(dirfd)] |
| | 629 | ) |
| | 630 | AX_CONFIG_FEATURE( |
| | 631 | [dirfd], [Use directory file descriptors], |
| | 632 | [COMPAT_DIRFD], [This platform supports directory file descriptors.], |
| | 633 | [enable_dirfd="yes"], [enable_dirfd="no"] |
| | 634 | ) |
| | 635 | AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ]) |
| | 636 | |
| | 637 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| | 638 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| | 639 | |
| | 640 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then |
| | 641 | AX_JAVA_OPTIONS |
| | 642 | AX_PROG_JAVAC |
| | 643 | AX_PROG_JAVA |
| | 644 | AX_PROG_JAR |
| | 645 | |
| | 646 | AX_CHECK_CLASSPATH |
| | 647 | |
| | 648 | # Check for Java UST agent common class first |
| | 649 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| | 650 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| | 651 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| | 652 | fi |
| | 653 | |
| | 654 | if test "x$test_java_agent_jul" = "xyes"; then |
| | 655 | # Check for JUL agent class |
| | 656 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| | 657 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| | 658 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| | 659 | fi |
| | 660 | fi |
| | 661 | |
| | 662 | if test "x$test_java_agent_log4j" = "xyes"; then |
| | 663 | # Check for Log4j agent class |
| | 664 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| | 665 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| | 666 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| | 667 | fi |
| | 668 | |
| | 669 | # Check for Log4j class |
| | 670 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| | 671 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| | 672 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| | 673 | fi |
| | 674 | fi |
| | 675 | fi |
| | 676 | |
| | 677 | # enable building man pages (user's intention) |
| | 678 | AC_ARG_ENABLE( |
| | 679 | man-pages, |
| | 680 | AS_HELP_STRING( |
| | 681 | [--disable-man-pages], |
| | 682 | [Do not build and install man pages (already built in a distributed tarball)] |
| | 683 | ), |
| | 684 | [man_pages_opt=$enableval], |
| | 685 | [man_pages_opt=yes] |
| | 686 | ) |
| | 687 | |
| | 688 | # check for asciidoc and xmlto if we enabled building the man pages |
| | 689 | have_asciidoc_xmlto=no |
| | 690 | warn_prebuilt_man_pages=no |
| | 691 | |
| | 692 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| | 693 | AC_PATH_PROG([ASCIIDOC], [asciidoc], [no]) |
| | 694 | AC_PATH_PROG([XMLTO], [xmlto], [no]) |
| | 695 | |
| | 696 | AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [ |
| | 697 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 698 | # this is an error because we're in the Git repo, which |
| | 699 | # means the man pages are not already generated for us, |
| | 700 | # thus asciidoc/xmlto are required because we were asked |
| | 701 | # to build the man pages |
| | 702 | AC_MSG_ERROR([ |
| | 703 | You need asciidoc and xmlto to build the LTTng-tools man pages. Use |
| | 704 | --disable-man-pages to disable building the man pages, in which case |
| | 705 | they will not be installed. |
| | 706 | ]) |
| | 707 | ], [ |
| | 708 | # only warn here: since we're in the tarball, the man |
| | 709 | # pages should already be generated at this point, thus |
| | 710 | # asciidoc/xmlto are not strictly required |
| | 711 | warn_prebuilt_man_pages=yes |
| | 712 | ]) |
| | 713 | ], [ |
| | 714 | have_asciidoc_xmlto=yes |
| | 715 | ]) |
| | 716 | ]) |
| | 717 | |
| | 718 | # export man page build condition: build the man pages if the user |
| | 719 | # asked for it, and if the tools are available |
| | 720 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| | 721 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| | 722 | |
| | 723 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| | 724 | |
| | 725 | # embedded --help message |
| | 726 | AC_ARG_ENABLE( |
| | 727 | [embedded-help], |
| | 728 | AS_HELP_STRING( |
| | 729 | [--enable-embedded-help], |
| | 730 | [Embed the --help messages in the executable files] |
| | 731 | ), |
| | 732 | [embedded_help=$enableval], |
| | 733 | [embedded_help=no] |
| | 734 | ) |
| | 735 | AS_IF([test "x$embedded_help" = "xyes"], [ |
| | 736 | AS_IF([test "x$man_pages_opt" = "xno"], [ |
| | 737 | AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.]) |
| | 738 | ]) |
| | 739 | AC_PATH_PROG([man_prog_path], [man], [no]) |
| | 740 | AS_IF([test "x$man_prog_path" = "xno"], [ |
| | 741 | AC_MSG_ERROR([You need man with the --enable-embedded-help option.]) |
| | 742 | ]) |
| | 743 | AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.]) |
| | 744 | AC_SUBST([MANPROG], [$man_prog_path]) |
| | 745 | ]) |
| | 746 | AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"]) |
| | 747 | |
| | 748 | # Python agent test |
| | 749 | UST_PYTHON_AGENT="lttngust" |
| | 750 | |
| | 751 | AC_ARG_ENABLE(test-python2-agent, |
| | 752 | AS_HELP_STRING([--enable-test-python2-agent], |
| | 753 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| | 754 | ),[:],[test_python2_agent_autodetect=yes] |
| | 755 | ) |
| | 756 | |
| | 757 | AC_ARG_ENABLE(test-python3-agent, |
| | 758 | AS_HELP_STRING([--enable-test-python3-agent], |
| | 759 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| | 760 | ),[:],[test_python3_agent_autodetect=yes] |
| | 761 | ) |
| | 762 | |
| | 763 | AC_ARG_ENABLE(test-python-agent-all, |
| | 764 | AS_HELP_STRING([--enable-test-python-agent-all], |
| | 765 | [enable test for all python{2/3} agent.] |
| | 766 | ), |
| | 767 | ) |
| | 768 | |
| | 769 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| | 770 | unset test_python2_agent_autodetect |
| | 771 | unset test_python3_agent_autodetect |
| | 772 | ]) |
| | 773 | |
| | 774 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| | 775 | enable_test_python2_agent=yes |
| | 776 | enable_test_python3_agent=yes |
| | 777 | ]) |
| | 778 | |
| | 779 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| | 780 | enable_test_python2_agent=no |
| | 781 | enable_test_python3_agent=no |
| | 782 | ]) |
| | 783 | |
| | 784 | |
| | 785 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| | 786 | AS_IF([test -z "$PYTHON2"], [ |
| | 787 | PYTHON2=python2 |
| | 788 | ], [ |
| | 789 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| | 790 | ]) |
| | 791 | |
| | 792 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| | 793 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| | 794 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 795 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| | 796 | ]) |
| | 797 | ], [ |
| | 798 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| | 799 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 800 | PYTHON2_AGENT=$PYTHON2_BIN |
| | 801 | AC_MSG_RESULT([yes]) |
| | 802 | RUN_PYTHON_AGENT_TEST=yes |
| | 803 | ], [ |
| | 804 | AC_MSG_RESULT([no]) |
| | 805 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 806 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 807 | ]) |
| | 808 | ]) |
| | 809 | |
| | 810 | ]) |
| | 811 | |
| | 812 | ]) |
| | 813 | |
| | 814 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| | 815 | AS_IF([test -z "$PYTHON3"], [ |
| | 816 | PYTHON3=python3 |
| | 817 | ], [ |
| | 818 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| | 819 | ]) |
| | 820 | |
| | 821 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| | 822 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| | 823 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 824 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| | 825 | ]) |
| | 826 | ], [ |
| | 827 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| | 828 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 829 | PYTHON3_AGENT=$PYTHON3_BIN |
| | 830 | AC_MSG_RESULT([yes]) |
| | 831 | RUN_PYTHON_AGENT_TEST=yes |
| | 832 | ], [ |
| | 833 | AC_MSG_RESULT([no]) |
| | 834 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 835 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 836 | ]) |
| | 837 | ]) |
| | 838 | |
| | 839 | ]) |
| | 840 | ]) |
| | 841 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| | 842 | AC_SUBST([PYTHON2_AGENT]) |
| | 843 | AC_SUBST([PYTHON3_AGENT]) |
| | 844 | |
| | 845 | AC_ARG_ENABLE([test-sdt-uprobe], |
| | 846 | [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])], |
| | 847 | [test_sdt_uprobe="$enableval"], |
| | 848 | [test_sdt_uprobe=autodetect] |
| | 849 | ) |
| | 850 | |
| | 851 | AS_IF([test "$test_sdt_uprobe" != "no"], [ |
| | 852 | LTTNG_CHECK_SDT_WORKS |
| | 853 | AC_PATH_PROG([DTRACE], [dtrace]) |
| | 854 | ]) |
| | 855 | |
| | 856 | AS_IF([test "$test_sdt_uprobe" = "yes"], [ |
| | 857 | AS_IF([test "$lttng_cv_sdt_works" = "no"], [ |
| | 858 | AC_MSG_ERROR([Cannot find 'sys/sdt.h'.]) |
| | 859 | ]) |
| | 860 | AS_IF([test "x$DTRACE" = "x"], [ |
| | 861 | AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.]) |
| | 862 | ]) |
| | 863 | ]) |
| | 864 | |
| | 865 | AS_IF([test "$test_sdt_uprobe" = "autodetect"], [ |
| | 866 | AS_IF([test "$lttng_cv_sdt_works" = "yes"], [ |
| | 867 | AS_IF([test "x$DTRACE" != "x"], [ |
| | 868 | test_sdt_uprobe=yes |
| | 869 | ]) |
| | 870 | ]) |
| | 871 | ]) |
| | 872 | |
| | 873 | AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"]) |
| | 874 | |
| | 875 | # Arguments for binaries build exclusion |
| | 876 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| | 877 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| | 878 | [Disable the build of lttng-consumerd binaries])) |
| | 879 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| | 880 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| | 881 | [Disable the build of lttng-relayd binaries])) |
| | 882 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| | 883 | [Disable the build of lttng-sessiond binaries])) |
| | 884 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| | 885 | [Disable the build of the extra components])) |
| | 886 | |
| | 887 | |
| | 888 | # Always build libconfig since it a dependency of libcommon |
| | 889 | build_lib_config=yes |
| | 890 | |
| | 891 | build_lib_compat=no |
| | 892 | build_lib_consumer=no |
| | 893 | build_lib_hashtable=no |
| | 894 | build_lib_health=no |
| | 895 | build_lib_index=no |
| | 896 | build_lib_kernel_consumer=no |
| | 897 | build_lib_kernel_ctl=no |
| | 898 | build_lib_lttng_ctl=no |
| | 899 | build_lib_relayd=no |
| | 900 | build_lib_fd_tracker=no |
| | 901 | build_lib_sessiond_comm=no |
| | 902 | build_lib_testpoint=no |
| | 903 | build_lib_ust_consumer=no |
| | 904 | |
| | 905 | # There is an overlap for enabled dependencies, but this makes everything |
| | 906 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| | 907 | # here. |
| | 908 | |
| | 909 | # Enable binary dependencies. |
| | 910 | AS_IF([test x$enable_bin_lttng != xno], |
| | 911 | [ |
| | 912 | build_lib_lttng_ctl=yes |
| | 913 | ] |
| | 914 | ) |
| | 915 | |
| | 916 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| | 917 | [ |
| | 918 | build_lib_consumer=yes |
| | 919 | build_lib_sessiond_comm=yes |
| | 920 | build_lib_index=yes |
| | 921 | build_lib_health=yes |
| | 922 | build_lib_testpoint=yes |
| | 923 | ] |
| | 924 | ) |
| | 925 | |
| | 926 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| | 927 | # Do nothing since libconfig and libcommon are built by default. |
| | 928 | [] |
| | 929 | ) |
| | 930 | |
| | 931 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| | 932 | [ |
| | 933 | build_lib_lttng_ctl=yes |
| | 934 | build_lib_sessiond_comm=yes |
| | 935 | build_lib_hashtable=yes |
| | 936 | build_lib_compat=yes |
| | 937 | build_lib_index=yes |
| | 938 | build_lib_health=yes |
| | 939 | build_lib_testpoint=yes |
| | 940 | build_lib_fd_tracker=yes |
| | 941 | ] |
| | 942 | ) |
| | 943 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| | 944 | [ |
| | 945 | build_lib_lttng_ctl=yes |
| | 946 | build_lib_sessiond_comm=yes |
| | 947 | build_lib_kernel_ctl=yes |
| | 948 | build_lib_hashtable=yes |
| | 949 | build_lib_compat=yes |
| | 950 | build_lib_relayd=yes |
| | 951 | build_lib_testpoint=yes |
| | 952 | build_lib_health=yes |
| | 953 | ] |
| | 954 | ) |
| | 955 | |
| | 956 | # Libraries dependencies enabling |
| | 957 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| | 958 | [ |
| | 959 | build_lib_sessiond_comm=yes |
| | 960 | build_lib_hashtable=yes |
| | 961 | ] |
| | 962 | ) |
| | 963 | |
| | 964 | AS_IF([test x$build_lib_consumer = xyes], |
| | 965 | [ |
| | 966 | build_lib_sessiond_comm=yes |
| | 967 | build_lib_kernel_consumer=yes |
| | 968 | build_lib_hashtable=yes |
| | 969 | build_lib_compat=yes |
| | 970 | build_lib_relayd=yes |
| | 971 | AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes]) |
| | 972 | ] |
| | 973 | ) |
| | 974 | |
| | 975 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| | 976 | [ |
| | 977 | build_lib_kernel_ctl=yes |
| | 978 | build_lib_relayd=yes |
| | 979 | ] |
| | 980 | ) |
| | 981 | |
| | 982 | AS_IF([test x$build_lib_relayd = xyes], |
| | 983 | [ |
| | 984 | build_lib_sessiond_comm=yes |
| | 985 | ] |
| | 986 | ) |
| | 987 | |
| | 988 | # Find arch type |
| | 989 | AS_CASE([$host_cpu], |
| | 990 | [k1om], [ARCHTYPE="x86"], |
| | 991 | [i386], [ARCHTYPE="x86"], |
| | 992 | [i486], [ARCHTYPE="x86"], |
| | 993 | [i586], [ARCHTYPE="x86"], |
| | 994 | [i686], [ARCHTYPE="x86"], |
| | 995 | [amd64], [ARCHTYPE="x86"], |
| | 996 | [x86_64], [ARCHTYPE="x86"], |
| | 997 | [powerpc], [ARCHTYPE="ppc"], |
| | 998 | [ppc64], [ARCHTYPE="ppc"], |
| | 999 | [powerpc64], [ARCHTYPE="ppc"], |
| | 1000 | [powerpc64le], [ARCHTYPE="ppc"], |
| | 1001 | [ppc], [ARCHTYPE="ppc"], |
| | 1002 | [s390], [ARCHTYPE="s390"], |
| | 1003 | [s390x], [ARCHTYPE="s390"], |
| | 1004 | [sparc], [ARCHTYPE="sparc64"], |
| | 1005 | [sparc64], [ARCHTYPE="sparc64"], |
| | 1006 | [alpha*], [ARCHTYPE="alpha"], |
| | 1007 | [ia64], [ARCHTYPE="ia64"], |
| | 1008 | [arm*], [ARCHTYPE="arm"], |
| | 1009 | [aarch64*], [ARCHTYPE="aarch64"], |
| | 1010 | [mips*], [ARCHTYPE="mips"], |
| | 1011 | [nios2*], [ARCHTYPE="nios2"], |
| | 1012 | [tile*], [ARCHTYPE="tile"], |
| | 1013 | [hppa*], [ARCHTYPE="hppa"], |
| | 1014 | [m68k], [ARCHTYPE="m68k"], |
| | 1015 | [riscv*], [ARCHTYPE="riscv"], |
| | 1016 | [ARCHTYPE="unknown"] |
| | 1017 | ) |
| | 1018 | |
| | 1019 | AC_SUBST(ARCHTYPE) |
| | 1020 | |
| | 1021 | AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support]) |
| | 1022 | AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel]) |
| | 1023 | AS_IF([test "x$ARCHTYPE" = "xx86"],[ |
| | 1024 | # Userspace callstack capture is only supported by the Linux kernel on x86. |
| | 1025 | AC_MSG_RESULT([yes]) |
| | 1026 | have_modules_userspace_callstack_context=yes |
| | 1027 | AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1]) |
| | 1028 | ], [ |
| | 1029 | AC_MSG_RESULT([no]) |
| | 1030 | have_modules_userspace_callstack_context=no |
| | 1031 | ]) |
| | 1032 | AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno]) |
| | 1033 | |
| | 1034 | # Export binaries build conditions. |
| | 1035 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| | 1036 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| | 1037 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| | 1038 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| | 1039 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| | 1040 | |
| | 1041 | # Export the tests and extras build conditions. |
| | 1042 | AS_IF([\ |
| | 1043 | test "x$enable_bin_lttng" != "xno" && \ |
| | 1044 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| | 1045 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| | 1046 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| | 1047 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| | 1048 | [build_tests=yes], |
| | 1049 | [build_tests=no] |
| | 1050 | ) |
| | 1051 | |
| | 1052 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| | 1053 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| | 1054 | |
| | 1055 | # Export libraries build conditions. |
| | 1056 | AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes]) |
| | 1057 | AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes]) |
| | 1058 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| | 1059 | AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes]) |
| | 1060 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| | 1061 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| | 1062 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| | 1063 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| | 1064 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| | 1065 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| | 1066 | AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes]) |
| | 1067 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| | 1068 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| | 1069 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| | 1070 | |
| | 1071 | AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS" |
| | 1072 | AC_SUBST(AM_CFLAGS) |
| | 1073 | |
| | 1074 | # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...". |
| | 1075 | AM_LDFLAGS="" |
| | 1076 | AC_SUBST(AM_LDFLAGS) |
| | 1077 | |
| | 1078 | # The order in which the include folders are searched is important. |
| | 1079 | # The top_builddir should always be searched first in the event that a build |
| | 1080 | # time generated file is included. An example of this is the "version.i" file. |
| | 1081 | # In a scenario where lttng-tools is built from a distribution tarball and in a |
| | 1082 | # out-of-tree manner, the generated "version.i" has priority on the one from |
| | 1083 | # the source (distribution tarball) and must be found first. |
| | 1084 | AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS" |
| | 1085 | AC_SUBST(AM_CPPFLAGS) |
| | 1086 | |
| | 1087 | lttngincludedir="${includedir}/lttng" |
| | 1088 | AC_SUBST(lttngincludedir) |
| | 1089 | |
| | 1090 | lttngactionincludedir="${includedir}/lttng/action" |
| | 1091 | AC_SUBST(lttngactionincludedir) |
| | 1092 | |
| | 1093 | lttngconditionincludedir="${includedir}/lttng/condition" |
| | 1094 | AC_SUBST(lttngconditionincludedir) |
| | 1095 | |
| | 1096 | lttngnotificationincludedir="${includedir}/lttng/notification" |
| | 1097 | AC_SUBST(lttngnotificationincludedir) |
| | 1098 | |
| | 1099 | lttngtriggerincludedir="${includedir}/lttng/trigger" |
| | 1100 | AC_SUBST(lttngtriggerincludedir) |
| | 1101 | |
| | 1102 | lttnglibexecdir="${libdir}/lttng/libexec" |
| | 1103 | AC_SUBST(lttnglibexecdir) |
| | 1104 | |
| | 1105 | AC_CONFIG_FILES([ |
| | 1106 | Makefile |
| | 1107 | doc/Makefile |
| | 1108 | doc/man/Makefile |
| | 1109 | doc/man/asciidoc-attrs.conf |
| | 1110 | include/Makefile |
| | 1111 | extras/Makefile |
| | 1112 | extras/bindings/Makefile |
| | 1113 | extras/bindings/swig/Makefile |
| | 1114 | extras/bindings/swig/python/Makefile |
| | 1115 | extras/core-handler/Makefile |
| | 1116 | src/Makefile |
| | 1117 | src/common/Makefile |
| | 1118 | src/common/kernel-ctl/Makefile |
| | 1119 | src/common/kernel-consumer/Makefile |
| | 1120 | src/common/consumer/Makefile |
| | 1121 | src/common/ust-consumer/Makefile |
| | 1122 | src/common/hashtable/Makefile |
| | 1123 | src/common/sessiond-comm/Makefile |
| | 1124 | src/common/compat/Makefile |
| | 1125 | src/common/relayd/Makefile |
| | 1126 | src/common/testpoint/Makefile |
| | 1127 | src/common/index/Makefile |
| | 1128 | src/common/health/Makefile |
| | 1129 | src/common/config/Makefile |
| | 1130 | src/common/string-utils/Makefile |
| | 1131 | src/common/fd-tracker/Makefile |
| | 1132 | src/lib/Makefile |
| | 1133 | src/lib/lttng-ctl/Makefile |
| | 1134 | src/lib/lttng-ctl/filter/Makefile |
| | 1135 | src/lib/lttng-ctl/lttng-ctl.pc |
| | 1136 | src/bin/Makefile |
| | 1137 | src/bin/lttng-consumerd/Makefile |
| | 1138 | src/bin/lttng-sessiond/Makefile |
| | 1139 | src/bin/lttng-relayd/Makefile |
| | 1140 | src/bin/lttng/Makefile |
| | 1141 | src/bin/lttng-crash/Makefile |
| | 1142 | tests/Makefile |
| | 1143 | tests/destructive/Makefile |
| | 1144 | tests/regression/Makefile |
| | 1145 | tests/regression/kernel/Makefile |
| | 1146 | tests/regression/tools/Makefile |
| | 1147 | tests/regression/tools/streaming/Makefile |
| | 1148 | tests/regression/tools/filtering/Makefile |
| | 1149 | tests/regression/tools/health/Makefile |
| | 1150 | tests/regression/tools/tracefile-limits/Makefile |
| | 1151 | tests/regression/tools/snapshots/Makefile |
| | 1152 | tests/regression/tools/live/Makefile |
| | 1153 | tests/regression/tools/exclusion/Makefile |
| | 1154 | tests/regression/tools/save-load/Makefile |
| | 1155 | tests/regression/tools/save-load/configuration/Makefile |
| | 1156 | tests/regression/tools/mi/Makefile |
| | 1157 | tests/regression/tools/wildcard/Makefile |
| | 1158 | tests/regression/tools/crash/Makefile |
| | 1159 | tests/regression/tools/regen-metadata/Makefile |
| | 1160 | tests/regression/tools/regen-statedump/Makefile |
| | 1161 | tests/regression/tools/notification/Makefile |
| | 1162 | tests/regression/tools/rotation/Makefile |
| | 1163 | tests/regression/tools/base-path/Makefile |
| | 1164 | tests/regression/tools/metadata/Makefile |
| | 1165 | tests/regression/tools/tracker/Makefile |
| | 1166 | tests/regression/tools/working-directory/Makefile |
| | 1167 | tests/regression/tools/relayd-grouping/Makefile |
| | 1168 | tests/regression/tools/clear/Makefile |
| | 1169 | tests/regression/ust/Makefile |
| | 1170 | tests/regression/ust/nprocesses/Makefile |
| | 1171 | tests/regression/ust/high-throughput/Makefile |
| | 1172 | tests/regression/ust/low-throughput/Makefile |
| | 1173 | tests/regression/ust/before-after/Makefile |
| | 1174 | tests/regression/ust/buffers-pid/Makefile |
| | 1175 | tests/regression/ust/periodical-metadata-flush/Makefile |
| | 1176 | tests/regression/ust/multi-session/Makefile |
| | 1177 | tests/regression/ust/multi-lib/Makefile |
| | 1178 | tests/regression/ust/overlap/Makefile |
| | 1179 | tests/regression/ust/overlap/demo/Makefile |
| | 1180 | tests/regression/ust/linking/Makefile |
| | 1181 | tests/regression/ust/daemon/Makefile |
| | 1182 | tests/regression/ust/exit-fast/Makefile |
| | 1183 | tests/regression/ust/fork/Makefile |
| | 1184 | tests/regression/ust/libc-wrapper/Makefile |
| | 1185 | tests/regression/ust/baddr-statedump/Makefile |
| | 1186 | tests/regression/ust/ust-dl/Makefile |
| | 1187 | tests/regression/ust/java-jul/Makefile |
| | 1188 | tests/regression/ust/java-log4j/Makefile |
| | 1189 | tests/regression/ust/python-logging/Makefile |
| | 1190 | tests/regression/ust/getcpu-override/Makefile |
| | 1191 | tests/regression/ust/clock-override/Makefile |
| | 1192 | tests/regression/ust/type-declarations/Makefile |
| | 1193 | tests/regression/ust/rotation-destroy-flush/Makefile |
| | 1194 | tests/regression/ust/blocking/Makefile |
| | 1195 | tests/regression/ust/namespaces/Makefile |
| | 1196 | tests/stress/Makefile |
| | 1197 | tests/unit/Makefile |
| | 1198 | tests/unit/ini_config/Makefile |
| | 1199 | tests/perf/Makefile |
| | 1200 | tests/utils/Makefile |
| | 1201 | tests/utils/tap/Makefile |
| | 1202 | tests/utils/testapp/Makefile |
| | 1203 | tests/utils/testapp/gen-ns-events/Makefile |
| | 1204 | tests/utils/testapp/gen-kernel-test-events/Makefile |
| | 1205 | tests/utils/testapp/gen-ust-events/Makefile |
| | 1206 | tests/utils/testapp/gen-ust-events-ns/Makefile |
| | 1207 | tests/utils/testapp/gen-syscall-events-callstack/Makefile |
| | 1208 | tests/utils/testapp/gen-ust-nevents/Makefile |
| | 1209 | tests/utils/testapp/gen-ust-nevents-str/Makefile |
| | 1210 | tests/utils/testapp/gen-syscall-events/Makefile |
| | 1211 | tests/utils/testapp/gen-ust-tracef/Makefile |
| | 1212 | tests/utils/testapp/userspace-probe-elf-binary/Makefile |
| | 1213 | tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile |
| | 1214 | tests/utils/testapp/userspace-probe-sdt-binary/Makefile |
| | 1215 | ]) |
| | 1216 | |
| | 1217 | # Inject variable into python test script. |
| | 1218 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| | 1219 | # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script. |
| | 1220 | AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw]) |
| | 1221 | AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl]) |
| | 1222 | |
| | 1223 | AC_OUTPUT |
| | 1224 | |
| | 1225 | # |
| | 1226 | # Mini-report on what will be built. |
| | 1227 | # |
| | 1228 | |
| | 1229 | PPRINT_INIT |
| | 1230 | PPRINT_SET_INDENT(1) |
| | 1231 | PPRINT_SET_TS(38) |
| | 1232 | |
| | 1233 | AS_ECHO |
| | 1234 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| | 1235 | AS_ECHO |
| | 1236 | |
| | 1237 | AS_IF([test -n "$report_fold"], [ |
| | 1238 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| | 1239 | ], [ |
| | 1240 | AS_ECHO("$version_description") |
| | 1241 | ]) |
| | 1242 | |
| | 1243 | AS_ECHO |
| | 1244 | PPRINT_SUBTITLE([Features]) |
| | 1245 | |
| | 1246 | # Target architecture we're building for. |
| | 1247 | target_arch=$host_cpu |
| | 1248 | [ |
| | 1249 | for f in $CFLAGS; do |
| | 1250 | if test $f = "-m32"; then |
| | 1251 | target_arch="32-bit" |
| | 1252 | elif test $f = "-m64"; then |
| | 1253 | target_arch="64-bit" |
| | 1254 | fi |
| | 1255 | done |
| | 1256 | ] |
| | 1257 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| | 1258 | |
| | 1259 | # kmod enabled/disabled |
| | 1260 | test "x$with_kmod" != "xno" && value=1 || value=0 |
| | 1261 | PPRINT_PROP_BOOL([libkmod support], $value) |
| | 1262 | |
| | 1263 | # LTTng-UST enabled/disabled |
| | 1264 | test "x$with_lttng_ust" = "xyes" && value=1 || value=0 |
| | 1265 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| | 1266 | |
| | 1267 | AS_ECHO |
| | 1268 | PPRINT_SUBTITLE([Binaries]) |
| | 1269 | |
| | 1270 | # List binaries to be built |
| | 1271 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| | 1272 | PPRINT_PROP_BOOL([lttng], $value) |
| | 1273 | |
| | 1274 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| | 1275 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| | 1276 | |
| | 1277 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| | 1278 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| | 1279 | |
| | 1280 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| | 1281 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| | 1282 | |
| | 1283 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| | 1284 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| | 1285 | |
| | 1286 | # Extras |
| | 1287 | test x$enable_extras != xno && value=1 || value=0 |
| | 1288 | AS_ECHO |
| | 1289 | PPRINT_SET_INDENT(0) |
| | 1290 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1291 | PPRINT_SET_INDENT(1) |
| | 1292 | |
| | 1293 | AS_ECHO |
| | 1294 | PPRINT_SUBTITLE([Tests]) |
| | 1295 | |
| | 1296 | # Print clear message that tests won't be built |
| | 1297 | AS_IF([test "x$build_tests" = "xno"],[ |
| | 1298 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| | 1299 | ]) |
| | 1300 | |
| | 1301 | # LTTng UST Java agent JUL tests enabled/disabled |
| | 1302 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| | 1303 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| | 1304 | |
| | 1305 | # LTTng UST Java agent Log4j tests enabled/disabled |
| | 1306 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| | 1307 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value) |
| | 1308 | |
| | 1309 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| | 1310 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| | 1311 | |
| | 1312 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| | 1313 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| | 1314 | |
| | 1315 | # LTTng UST Java agent Log4j tests enabled/disabled |
| | 1316 | test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0 |
| | 1317 | PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value) |
| | 1318 | |
| | 1319 | #Python binding enabled/disabled |
| | 1320 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| | 1321 | AS_ECHO |
| | 1322 | PPRINT_SET_INDENT(0) |
| | 1323 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1324 | |
| | 1325 | # man pages build enabled/disabled |
| | 1326 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| | 1327 | |
| | 1328 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| | 1329 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 1330 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1331 | ], [ |
| | 1332 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| | 1333 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1334 | ], [ |
| | 1335 | PPRINT_PROP_STRING([build_man_pages_msg], |
| | 1336 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| | 1337 | $PPRINT_COLOR_SUBTITLE) |
| | 1338 | ]) |
| | 1339 | ]) |
| | 1340 | ], [ |
| | 1341 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| | 1342 | ]) |
| | 1343 | |
| | 1344 | m4_popdef([build_man_pages_msg]) |
| | 1345 | |
| | 1346 | test "x$embedded_help" = xyes && value=1 || value=0 |
| | 1347 | PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1348 | |
| | 1349 | PPRINT_SET_INDENT(1) |
| | 1350 | |
| | 1351 | report_bindir="`eval eval echo $bindir`" |
| | 1352 | report_libdir="`eval eval echo $libdir`" |
| | 1353 | |
| | 1354 | # Print the bindir and libdir this `make install' will install into. |
| | 1355 | AS_ECHO |
| | 1356 | PPRINT_SUBTITLE([Install directories]) |
| | 1357 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| | 1358 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| | 1359 | |
| | 1360 | AS_ECHO |
| | 1361 | PPRINT_SUBTITLE([Search directories]) |
| | 1362 | |
| | 1363 | # If we build the sessiond, print the paths it will use |
| | 1364 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| | 1365 | path="$report_bindir/lttng-sessiond" |
| | 1366 | ],[ |
| | 1367 | path="$SESSIOND_BIN" |
| | 1368 | ]) |
| | 1369 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| | 1370 | |
| | 1371 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| | 1372 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1373 | ],[ |
| | 1374 | path="$CONSUMERD32_BIN" |
| | 1375 | ]) |
| | 1376 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| | 1377 | |
| | 1378 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| | 1379 | path="`eval eval echo $libdir`" |
| | 1380 | ],[ |
| | 1381 | path="$CONSUMERD32_LIBDIR" |
| | 1382 | ]) |
| | 1383 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| | 1384 | |
| | 1385 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| | 1386 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1387 | ],[ |
| | 1388 | path="$CONSUMERD64_BIN" |
| | 1389 | ]) |
| | 1390 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| | 1391 | |
| | 1392 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| | 1393 | path="`eval eval echo $libdir`" |
| | 1394 | ],[ |
| | 1395 | path="$CONSUMERD64_LIBDIR" |
| | 1396 | ]) |
| | 1397 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |
| | 1398 | PPRINT_SET_INDENT(0) |
| | 1399 | |
| | 1400 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ |
| | 1401 | AS_ECHO |
| | 1402 | PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages. |
| | 1403 | |
| | 1404 | Note that the man pages are already built in this distribution tarball, |
| | 1405 | therefore asciidoc and xmlto are only needed if you intend to modify |
| | 1406 | their sources. |
| | 1407 | |
| | 1408 | Also note that the installed man pages will contain the project's |
| | 1409 | default command-line option and environment variable values. |
| | 1410 | |
| | 1411 | Use --disable-man-pages to completely disable building and installing |
| | 1412 | the man pages.]) |
| | 1413 | ]) |
projects / lttng-tools.git / blame_incremental