| | 1 | AC_PREREQ([2.64]) |
| | 2 | AC_INIT([lttng-tools],[2.12.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| | 3 | |
| | 4 | AC_CONFIG_HEADERS([include/config.h]) |
| | 5 | AC_CONFIG_AUX_DIR([config]) |
| | 6 | AC_CONFIG_MACRO_DIR([m4]) |
| | 7 | |
| | 8 | AC_CANONICAL_TARGET |
| | 9 | AC_CANONICAL_HOST |
| | 10 | |
| | 11 | AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc]) |
| | 12 | AM_MAINTAINER_MODE([enable]) |
| | 13 | |
| | 14 | # Enable silent rules if available (Introduced in AM 1.11) |
| | 15 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| | 16 | |
| | 17 | AC_REQUIRE_AUX_FILE([tap-driver.sh]) |
| | 18 | |
| | 19 | # Checks for C compiler |
| | 20 | AC_USE_SYSTEM_EXTENSIONS |
| | 21 | AC_SYS_LARGEFILE |
| | 22 | AC_PROG_CC |
| | 23 | AC_PROG_CC_STDC |
| | 24 | AC_PROG_CXX |
| | 25 | rw_PROG_CXX_WORKS |
| | 26 | AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"]) |
| | 27 | |
| | 28 | ax_CHECK_SDT_WORKS |
| | 29 | AM_CONDITIONAL([SDT_WORKS], [test "x$ax_check_sdt_works" = "xyes"]) |
| | 30 | |
| | 31 | # Checks for programs. |
| | 32 | AC_PROG_GREP |
| | 33 | AC_PROG_MAKE_SET |
| | 34 | AC_PROG_SED |
| | 35 | AC_PATH_PROG([report_fold], [fold]) |
| | 36 | LT_INIT |
| | 37 | |
| | 38 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| | 39 | AC_CHECK_TOOL([OBJCOPY], [objcopy], [no]) |
| | 40 | AS_IF([test "x$OBJCOPY" = "xno"], |
| | 41 | [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| | 42 | ) |
| | 43 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno]) |
| | 44 | |
| | 45 | # check for pgrep |
| | 46 | AC_PATH_PROG([PGREP], [pgrep], [no]) |
| | 47 | AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"]) |
| | 48 | |
| | 49 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| | 50 | # is not distributed in tarballs |
| | 51 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| | 52 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| | 53 | |
| | 54 | # check for bison |
| | 55 | AC_PROG_YACC |
| | 56 | BISON=$YACC |
| | 57 | AX_PROG_BISON_VERSION([2.4], [have_bison=yes]) |
| | 58 | |
| | 59 | AS_IF([test "x$have_bison" != "xyes"], [ |
| | 60 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 61 | AC_MSG_FAILURE([ |
| | 62 | Bison >= 2.4 is required when building from the Git repository. You can |
| | 63 | set the YACC variable to override automatic detection. |
| | 64 | ]) |
| | 65 | ], [ |
| | 66 | AC_MSG_WARN([ |
| | 67 | Missing Bison >= 2.4. Note that the parser files are already built in |
| | 68 | this distribution tarball, so Bison is only needed if you intend to |
| | 69 | modify their sources. You can set the YACC variable to override automatic |
| | 70 | detection. |
| | 71 | ]) |
| | 72 | ]) |
| | 73 | ]) |
| | 74 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| | 75 | |
| | 76 | # check for flex |
| | 77 | AC_PROG_LEX |
| | 78 | FLEX=$LEX |
| | 79 | AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes]) |
| | 80 | |
| | 81 | AS_IF([test "x$have_flex" != "xyes"], [ |
| | 82 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 83 | AC_MSG_FAILURE([ |
| | 84 | Flex >= 2.5.35 is required when building from the Git repository. You can |
| | 85 | set the LEX variable to override automatic detection. |
| | 86 | ]) |
| | 87 | ], [ |
| | 88 | AC_MSG_WARN([ |
| | 89 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| | 90 | this distribution tarball, so Flex is only needed if you intend to |
| | 91 | modify their sources. You can set the LEX variable to override automatic |
| | 92 | detection. |
| | 93 | ]) |
| | 94 | ]) |
| | 95 | ]) |
| | 96 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| | 97 | |
| | 98 | |
| | 99 | # Checks for typedefs, structures, and compiler characteristics. |
| | 100 | AC_C_INLINE |
| | 101 | AC_TYPE_INT32_T |
| | 102 | AC_TYPE_INT64_T |
| | 103 | AC_TYPE_MODE_T |
| | 104 | AC_TYPE_OFF_T |
| | 105 | AC_TYPE_PID_T |
| | 106 | AC_TYPE_SIZE_T |
| | 107 | AC_TYPE_SSIZE_T |
| | 108 | AC_TYPE_UID_T |
| | 109 | AC_TYPE_UINT16_T |
| | 110 | AC_TYPE_UINT32_T |
| | 111 | AC_TYPE_UINT64_T |
| | 112 | AC_TYPE_UINT8_T |
| | 113 | |
| | 114 | AX_C___ATTRIBUTE__ |
| | 115 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], |
| | 116 | [:], |
| | 117 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| | 118 | |
| | 119 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) |
| | 120 | |
| | 121 | # Check if linker has the -no-pie option. |
| | 122 | AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes]) |
| | 123 | AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"]) |
| | 124 | |
| | 125 | AX_LIB_SOCKET_NSL |
| | 126 | |
| | 127 | LT_NO_UNDEFINED="" |
| | 128 | AS_CASE([$host_os], |
| | 129 | [cygwin*], |
| | 130 | [ |
| | 131 | LT_NO_UNDEFINED="-no-undefined" |
| | 132 | ], |
| | 133 | [cygwin*|darwin*|mingw*|solaris*], |
| | 134 | [ |
| | 135 | # On platforms where we only support the relayd, disable the other binaries by default |
| | 136 | AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no]) |
| | 137 | AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no]) |
| | 138 | AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no]) |
| | 139 | AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no]) |
| | 140 | AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no]) |
| | 141 | AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no]) |
| | 142 | ] |
| | 143 | ) |
| | 144 | |
| | 145 | AC_SUBST(LT_NO_UNDEFINED) |
| | 146 | |
| | 147 | # Compute minor/major/patchlevel version numbers |
| | 148 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| | 149 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| | 150 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| | 151 | |
| | 152 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| | 153 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| | 154 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| | 155 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| | 156 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| | 157 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| | 158 | |
| | 159 | version_name="Codename TBD" |
| | 160 | version_description="Description TBD" |
| | 161 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| | 162 | |
| | 163 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| | 164 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| | 165 | |
| | 166 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| | 167 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| | 168 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| | 169 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| | 170 | libtool_fixup=$enableval, |
| | 171 | libtool_fixup=yes) |
| | 172 | |
| | 173 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| | 174 | [ |
| | 175 | libtool_m4="$srcdir/m4/libtool.m4" |
| | 176 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| | 177 | AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4]) |
| | 178 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| | 179 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| | 180 | [ |
| | 181 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| | 182 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| | 183 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| | 184 | ], |
| | 185 | [ |
| | 186 | AC_MSG_RESULT([none]) |
| | 187 | ]) |
| | 188 | ]) |
| | 189 | |
| | 190 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| | 191 | |
| | 192 | AC_CHECK_HEADERS([ \ |
| | 193 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| | 194 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| | 195 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| | 196 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| | 197 | sys/mount.h sys/param.h sys/time.h elf.h |
| | 198 | ]) |
| | 199 | |
| | 200 | AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes]) |
| | 201 | |
| | 202 | # Basic functions check |
| | 203 | AC_CHECK_FUNCS([ \ |
| | 204 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| | 205 | gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \ |
| | 206 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| | 207 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| | 208 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| | 209 | sched_getcpu sysconf sync_file_range |
| | 210 | ]) |
| | 211 | |
| | 212 | # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so, |
| | 213 | # add -lrt to LIBS |
| | 214 | AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete]) |
| | 215 | |
| | 216 | # Checks for dl. |
| | 217 | AC_CHECK_LIB([dl], [dlopen], [ |
| | 218 | have_libdl=yes |
| | 219 | libdl_name=dl |
| | 220 | ], [ |
| | 221 | # libdl not found, check for dlopen in libc. |
| | 222 | AC_CHECK_LIB([c], [dlopen], [ |
| | 223 | have_libc_dl=yes |
| | 224 | libdl_name=c |
| | 225 | ], [ |
| | 226 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| | 227 | ]) |
| | 228 | ]) |
| | 229 | |
| | 230 | # Check if libdl has dlmopen support. |
| | 231 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) |
| | 232 | AC_CHECK_LIB([$libdl_name], [dlmopen], [ |
| | 233 | AC_DEFINE([HAVE_DLMOPEN], [1]) |
| | 234 | HAVE_DLMOPEN=1 |
| | 235 | ], [ |
| | 236 | HAVE_DLMOPEN=0 |
| | 237 | ]) |
| | 238 | AC_SUBST(HAVE_DLMOPEN) |
| | 239 | |
| | 240 | # Babeltrace viewer check |
| | 241 | AC_ARG_WITH([babeltrace-bin], |
| | 242 | AS_HELP_STRING([--with-babeltrace-bin], |
| | 243 | [Location of the babeltrace viewer executable (including the filename)]), |
| | 244 | [BABELTRACE_BIN="$withval"], |
| | 245 | [BABELTRACE_BIN='']) |
| | 246 | AC_SUBST([BABELTRACE_BIN]) |
| | 247 | |
| | 248 | # lttv-gui |
| | 249 | AC_ARG_WITH([lttv-gui-bin], |
| | 250 | AS_HELP_STRING([--with-lttv-gui-bin], |
| | 251 | [Location of the lttv GUI viewer executable (including the filename)]), |
| | 252 | [LTTV_GUI_BIN="$withval"], |
| | 253 | [LTTV_GUI_BIN='']) |
| | 254 | AC_SUBST([LTTV_GUI_BIN]) |
| | 255 | |
| | 256 | AC_ARG_WITH([consumerd32-bin], |
| | 257 | AS_HELP_STRING([--with-consumerd32-bin], |
| | 258 | [Location of the 32-bit consumerd executable (including the filename)]), |
| | 259 | [CONSUMERD32_BIN="$withval"], |
| | 260 | [CONSUMERD32_BIN='']) |
| | 261 | AC_SUBST([CONSUMERD32_BIN]) |
| | 262 | |
| | 263 | AC_ARG_WITH([consumerd64-bin], |
| | 264 | AS_HELP_STRING([--with-consumerd64-bin], |
| | 265 | [Location of the 64-bit consumerd executable (including the filename)]), |
| | 266 | [CONSUMERD64_BIN="$withval"], |
| | 267 | [CONSUMERD64_BIN='']) |
| | 268 | AC_SUBST([CONSUMERD64_BIN]) |
| | 269 | |
| | 270 | AC_ARG_WITH([consumerd32-libdir], |
| | 271 | AS_HELP_STRING([--with-consumerd32-libdir], |
| | 272 | [Directory containing the 32-bit consumerd libraries]), |
| | 273 | [CONSUMERD32_LIBDIR="$withval"], |
| | 274 | [CONSUMERD32_LIBDIR='']) |
| | 275 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| | 276 | |
| | 277 | AC_ARG_WITH([consumerd64-libdir], |
| | 278 | AS_HELP_STRING([--with-consumerd64-libdir], |
| | 279 | [Directory containing the 64-bit consumerd libraries]), |
| | 280 | [CONSUMERD64_LIBDIR="$withval"], |
| | 281 | [CONSUMERD64_LIBDIR='']) |
| | 282 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| | 283 | |
| | 284 | AC_ARG_WITH([sessiond-bin], |
| | 285 | AS_HELP_STRING([--with-sessiond-bin], |
| | 286 | [Location of the sessiond executable (including the filename)]), |
| | 287 | [SESSIOND_BIN="$withval"], |
| | 288 | [SESSIOND_BIN='']) |
| | 289 | AC_SUBST([SESSIOND_BIN]) |
| | 290 | |
| | 291 | AC_ARG_WITH([lttng-system-rundir], |
| | 292 | AS_HELP_STRING([--with-lttng-system-rundir], |
| | 293 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| | 294 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| | 295 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| | 296 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| | 297 | |
| | 298 | AC_ARG_ENABLE([test-java-agent-jul], |
| | 299 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| | 300 | [test_java_agent_jul=$enableval], |
| | 301 | [test_java_agent_jul=no] |
| | 302 | ) |
| | 303 | |
| | 304 | AC_ARG_ENABLE([test-java-agent-log4j], |
| | 305 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])], |
| | 306 | [test_java_agent_log4j=$enableval], |
| | 307 | [test_java_agent_log4j=no] |
| | 308 | ) |
| | 309 | |
| | 310 | AC_ARG_ENABLE([test-java-agent-all], |
| | 311 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| | 312 | [test_java_agent_jul=$enableval |
| | 313 | test_java_agent_log4j=$enableval], |
| | 314 | [:] |
| | 315 | ) |
| | 316 | |
| | 317 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| | 318 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| | 319 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| | 320 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| | 321 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| | 322 | AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.]) |
| | 323 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| | 324 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| | 325 | |
| | 326 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| | 327 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| | 328 | $1="$2" |
| | 329 | AC_SUBST([$1]) |
| | 330 | ]) |
| | 331 | |
| | 332 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| | 333 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| | 334 | $1="$2" |
| | 335 | AC_SUBST([$1]) |
| | 336 | ]) |
| | 337 | |
| | 338 | # Default values |
| | 339 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384]) |
| | 340 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| | 341 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| | 342 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| | 343 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| | 344 | m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000]) |
| | 345 | m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 346 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345]) |
| | 347 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354]) |
| | 348 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| | 349 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 350 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| | 351 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| | 352 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 353 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| | 354 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 355 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576]) |
| | 356 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 357 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 358 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT]) |
| | 359 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| | 360 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| | 361 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| | 362 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| | 363 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| | 364 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 365 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| | 366 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| | 367 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| | 368 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 369 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| | 370 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 371 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 372 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 373 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 374 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 375 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 376 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| | 377 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 378 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 379 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288]) |
| | 380 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 381 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 382 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| | 383 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| | 384 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| | 385 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| | 386 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728]) |
| | 387 | _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000]) |
| | 388 | |
| | 389 | # Command short descriptions |
| | 390 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel]) |
| | 391 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session]) |
| | 392 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions]) |
| | 393 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels]) |
| | 394 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules]) |
| | 395 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule]) |
| | 396 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels]) |
| | 397 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules]) |
| | 398 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule]) |
| | 399 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command]) |
| | 400 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events]) |
| | 401 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations]) |
| | 402 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration]) |
| | 403 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk]) |
| | 404 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations]) |
| | 405 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session]) |
| | 406 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session]) |
| | 407 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing]) |
| | 408 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session]) |
| | 409 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing]) |
| | 410 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources]) |
| | 411 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources]) |
| | 412 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information]) |
| | 413 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer]) |
| | 414 | |
| | 415 | if test "x$prefix" = "xNONE"; then |
| | 416 | prefix=$ac_default_prefix |
| | 417 | fi |
| | 418 | CONFDIR=`eval echo $sysconfdir` |
| | 419 | AC_SUBST(CONFDIR) |
| | 420 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| | 421 | |
| | 422 | AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.]) |
| | 423 | |
| | 424 | # Check libpopt |
| | 425 | PKG_CHECK_MODULES([POPT], [popt], |
| | 426 | [ |
| | 427 | dnl PKG_CHECK_MODULES defines POPT_LIBS |
| | 428 | ], |
| | 429 | [ |
| | 430 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 431 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| | 432 | AC_CHECK_LIB([popt], |
| | 433 | [poptGetContext], |
| | 434 | [POPT_LIBS="-lpopt"], |
| | 435 | [ |
| | 436 | AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 437 | ] |
| | 438 | ) |
| | 439 | ] |
| | 440 | ) |
| | 441 | AC_SUBST(POPT_LIBS) |
| | 442 | |
| | 443 | PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6]) |
| | 444 | |
| | 445 | # First, check for uuid in system libs |
| | 446 | AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support]) |
| | 447 | AC_CHECK_FUNCS([uuid_generate], |
| | 448 | [ |
| | 449 | AC_DEFINE([LTTNG_HAVE_LIBUUID], [1]) |
| | 450 | UUID_LIBS="" |
| | 451 | ], |
| | 452 | [ |
| | 453 | # Then, check if the pkg-config module is available, otherwise explicitly check |
| | 454 | # for libuuid, or uuid support in the C-library. |
| | 455 | PKG_CHECK_MODULES([UUID], [uuid], |
| | 456 | [ |
| | 457 | AC_DEFINE([LTTNG_HAVE_LIBUUID], [1]) |
| | 458 | dnl PKG_CHECK_MODULES defines UUID_LIBS |
| | 459 | ], |
| | 460 | [ |
| | 461 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 462 | AC_MSG_WARN([Finding libuuid without pkg-config.]) |
| | 463 | AC_CHECK_LIB([uuid], [uuid_generate], |
| | 464 | [ |
| | 465 | AC_DEFINE([LTTNG_HAVE_LIBUUID], [1]) |
| | 466 | UUID_LIBS="-luuid" |
| | 467 | ], |
| | 468 | [ |
| | 469 | # libuuid not found, check for uuid_create in libc. |
| | 470 | AC_CHECK_LIB([c], [uuid_create], |
| | 471 | [ |
| | 472 | AC_DEFINE([LTTNG_HAVE_LIBUUID], [1]) |
| | 473 | UUID_LIBS="-lc" |
| | 474 | ], |
| | 475 | [ |
| | 476 | AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 477 | ] |
| | 478 | ) |
| | 479 | ] |
| | 480 | ) |
| | 481 | ] |
| | 482 | ) |
| | 483 | ] |
| | 484 | ) |
| | 485 | AC_SUBST(UUID_LIBS) |
| | 486 | |
| | 487 | AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])]) |
| | 488 | |
| | 489 | # URCU library version needed or newer |
| | 490 | m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed]) |
| | 491 | |
| | 492 | # Check liburcu needed function calls |
| | 493 | AC_CHECK_DECL([cds_list_add], [], |
| | 494 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]]) |
| | 495 | AC_CHECK_DECL([cds_wfcq_init], [], |
| | 496 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| | 497 | AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [], |
| | 498 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| | 499 | AC_CHECK_DECL([futex_async], [], |
| | 500 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]]) |
| | 501 | AC_CHECK_DECL([rcu_thread_offline], [], |
| | 502 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 503 | AC_CHECK_DECL([rcu_thread_online], [], |
| | 504 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 505 | AC_CHECK_DECL([caa_likely], [], |
| | 506 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 507 | AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], |
| | 508 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])]) |
| | 509 | |
| | 510 | #Function added in urcu 0.7.0 |
| | 511 | AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [], |
| | 512 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]] |
| | 513 | ) |
| | 514 | |
| | 515 | #Function added in urcu 0.9.0 |
| | 516 | AC_CHECK_DECL([urcu_ref_get_unless_zero], [], |
| | 517 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]] |
| | 518 | ) |
| | 519 | |
| | 520 | # Check for libkmod, it will be auto-neabled if found but won't fail if it's not, |
| | 521 | # it can be explicitly disabled with --without-kmod |
| | 522 | AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support]) |
| | 523 | AC_ARG_WITH([kmod], |
| | 524 | [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])], |
| | 525 | [], |
| | 526 | [with_kmod=check] |
| | 527 | ) |
| | 528 | |
| | 529 | AS_IF([test "x$with_kmod" != "xno"], |
| | 530 | [ |
| | 531 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| | 532 | [ |
| | 533 | AC_DEFINE([HAVE_KMOD], [1]) |
| | 534 | KMOD_LIBS="-lkmod" |
| | 535 | ], |
| | 536 | [ |
| | 537 | if test "x$with_kmod" != xcheck; then |
| | 538 | AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.]) |
| | 539 | else |
| | 540 | with_kmod=no |
| | 541 | fi |
| | 542 | ] |
| | 543 | ) |
| | 544 | ] |
| | 545 | ) |
| | 546 | AC_SUBST(KMOD_LIBS) |
| | 547 | |
| | 548 | # Check for liblttng-ust-ctl, fail if it's not found, |
| | 549 | # it can be explicitly disabled with --without-lttng-ust |
| | 550 | AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support]) |
| | 551 | AC_ARG_WITH([lttng-ust], |
| | 552 | [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])], |
| | 553 | [], |
| | 554 | [with_lttng_ust=yes] |
| | 555 | ) |
| | 556 | |
| | 557 | AS_IF([test "x$with_lttng_ust" = "xyes"], |
| | 558 | [ |
| | 559 | AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer], |
| | 560 | [ |
| | 561 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1]) |
| | 562 | ], |
| | 563 | [ |
| | 564 | AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.]) |
| | 565 | ], |
| | 566 | [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl] |
| | 567 | ) |
| | 568 | ] |
| | 569 | ) |
| | 570 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"]) |
| | 571 | |
| | 572 | |
| | 573 | |
| | 574 | # check for dlopen |
| | 575 | AC_CHECK_LIB([dl], [dlopen], |
| | 576 | [DL_LIBS="-ldl"], |
| | 577 | [ |
| | 578 | #libdl not found, check for dlopen in libc. |
| | 579 | AC_CHECK_LIB([c], [dlopen], |
| | 580 | [DL_LIBS="-lc"], |
| | 581 | [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])] |
| | 582 | ) |
| | 583 | ] |
| | 584 | ) |
| | 585 | AC_SUBST(DL_LIBS) |
| | 586 | |
| | 587 | # Check for fmemopen |
| | 588 | AC_CHECK_LIB([c], [fmemopen], |
| | 589 | [ |
| | 590 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| | 591 | ] |
| | 592 | ) |
| | 593 | |
| | 594 | # check for libpfm |
| | 595 | AC_CHECK_LIB([pfm], [pfm_initialize], |
| | 596 | [ |
| | 597 | have_libpfm=yes |
| | 598 | ]) |
| | 599 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"]) |
| | 600 | |
| | 601 | # For Python |
| | 602 | # SWIG version needed or newer: |
| | 603 | swig_version=2.0.0 |
| | 604 | |
| | 605 | AC_ARG_ENABLE([python-bindings], |
| | 606 | [AC_HELP_STRING([--enable-python-bindings], |
| | 607 | [compile Python bindings])], |
| | 608 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| | 609 | |
| | 610 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| | 611 | |
| | 612 | if test "x$enable_python_binding" = xyes; then |
| | 613 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| | 614 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| | 615 | AM_PATH_PYTHON([3.0]) |
| | 616 | |
| | 617 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| | 618 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| | 619 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| | 620 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| | 621 | AC_PATH_PROGS([PYTHON_CONFIG], |
| | 622 | [python$PYTHON_VERSION-config python-config], |
| | 623 | [no], |
| | 624 | [`dirname $PYTHON`]) |
| | 625 | AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| | 626 | ]) |
| | 627 | AC_MSG_CHECKING([python include flags]) |
| | 628 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| | 629 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| | 630 | ]) |
| | 631 | |
| | 632 | else |
| | 633 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| | 634 | [if you want Python bindings.]) |
| | 635 | |
| | 636 | fi |
| | 637 | |
| | 638 | # Epoll check. If not present, the build will fallback on poll() API |
| | 639 | AX_HAVE_EPOLL( |
| | 640 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| | 641 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| | 642 | ) |
| | 643 | AX_CONFIG_FEATURE( |
| | 644 | [epoll], [This platform supports epoll(7)], |
| | 645 | [HAVE_EPOLL], [This platform supports epoll(7).], |
| | 646 | [enable_epoll="yes"], [enable_epoll="no"] |
| | 647 | ) |
| | 648 | AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ]) |
| | 649 | |
| | 650 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| | 651 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| | 652 | |
| | 653 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then |
| | 654 | AX_JAVA_OPTIONS |
| | 655 | AX_PROG_JAVAC |
| | 656 | AX_PROG_JAVA |
| | 657 | AX_PROG_JAR |
| | 658 | |
| | 659 | AX_CHECK_CLASSPATH |
| | 660 | |
| | 661 | # Check for Java UST agent common class first |
| | 662 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| | 663 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| | 664 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| | 665 | fi |
| | 666 | |
| | 667 | if test "x$test_java_agent_jul" = "xyes"; then |
| | 668 | # Check for JUL agent class |
| | 669 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| | 670 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| | 671 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| | 672 | fi |
| | 673 | fi |
| | 674 | |
| | 675 | if test "x$test_java_agent_log4j" = "xyes"; then |
| | 676 | # Check for Log4j agent class |
| | 677 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| | 678 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| | 679 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| | 680 | fi |
| | 681 | |
| | 682 | # Check for Log4j class |
| | 683 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| | 684 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| | 685 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| | 686 | fi |
| | 687 | fi |
| | 688 | fi |
| | 689 | |
| | 690 | # enable building man pages (user's intention) |
| | 691 | AC_ARG_ENABLE( |
| | 692 | man-pages, |
| | 693 | AS_HELP_STRING( |
| | 694 | [--disable-man-pages], |
| | 695 | [Do not build and install man pages (already built in a distributed tarball)] |
| | 696 | ), |
| | 697 | [man_pages_opt=$enableval], |
| | 698 | [man_pages_opt=yes] |
| | 699 | ) |
| | 700 | |
| | 701 | # check for asciidoc and xmlto if we enabled building the man pages |
| | 702 | have_asciidoc_xmlto=no |
| | 703 | warn_prebuilt_man_pages=no |
| | 704 | |
| | 705 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| | 706 | AC_PATH_PROG([ASCIIDOC], [asciidoc], [no]) |
| | 707 | AC_PATH_PROG([XMLTO], [xmlto], [no]) |
| | 708 | |
| | 709 | AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [ |
| | 710 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 711 | # this is an error because we're in the Git repo, which |
| | 712 | # means the man pages are not already generated for us, |
| | 713 | # thus asciidoc/xmlto are required because we were asked |
| | 714 | # to build the man pages |
| | 715 | AC_MSG_ERROR([ |
| | 716 | You need asciidoc and xmlto to build the LTTng-tools man pages. Use |
| | 717 | --disable-man-pages to disable building the man pages, in which case |
| | 718 | they will not be installed. |
| | 719 | ]) |
| | 720 | ], [ |
| | 721 | # only warn here: since we're in the tarball, the man |
| | 722 | # pages should already be generated at this point, thus |
| | 723 | # asciidoc/xmlto are not strictly required |
| | 724 | warn_prebuilt_man_pages=yes |
| | 725 | ]) |
| | 726 | ], [ |
| | 727 | have_asciidoc_xmlto=yes |
| | 728 | ]) |
| | 729 | ]) |
| | 730 | |
| | 731 | # export man page build condition: build the man pages if the user |
| | 732 | # asked for it, and if the tools are available |
| | 733 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| | 734 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| | 735 | |
| | 736 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| | 737 | |
| | 738 | # embedded --help message |
| | 739 | AC_ARG_ENABLE( |
| | 740 | [embedded-help], |
| | 741 | AS_HELP_STRING( |
| | 742 | [--enable-embedded-help], |
| | 743 | [Embed the --help messages in the executable files] |
| | 744 | ), |
| | 745 | [embedded_help=$enableval], |
| | 746 | [embedded_help=no] |
| | 747 | ) |
| | 748 | AS_IF([test "x$embedded_help" = "xyes"], [ |
| | 749 | AS_IF([test "x$man_pages_opt" = "xno"], [ |
| | 750 | AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.]) |
| | 751 | ]) |
| | 752 | AC_PATH_PROG([man_prog_path], [man], [no]) |
| | 753 | AS_IF([test "x$man_prog_path" = "xno"], [ |
| | 754 | AC_MSG_ERROR([You need man with the --enable-embedded-help option.]) |
| | 755 | ]) |
| | 756 | AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.]) |
| | 757 | AC_SUBST([MANPROG], [$man_prog_path]) |
| | 758 | ]) |
| | 759 | AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"]) |
| | 760 | |
| | 761 | # Python agent test |
| | 762 | UST_PYTHON_AGENT="lttngust" |
| | 763 | |
| | 764 | AC_ARG_ENABLE(test-python2-agent, |
| | 765 | AS_HELP_STRING([--enable-test-python2-agent], |
| | 766 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| | 767 | ),[:],[test_python2_agent_autodetect=yes] |
| | 768 | ) |
| | 769 | |
| | 770 | AC_ARG_ENABLE(test-python3-agent, |
| | 771 | AS_HELP_STRING([--enable-test-python3-agent], |
| | 772 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| | 773 | ),[:],[test_python3_agent_autodetect=yes] |
| | 774 | ) |
| | 775 | |
| | 776 | AC_ARG_ENABLE(test-python-agent-all, |
| | 777 | AS_HELP_STRING([--enable-test-python-agent-all], |
| | 778 | [enable test for all python{2/3} agent.] |
| | 779 | ), |
| | 780 | ) |
| | 781 | |
| | 782 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| | 783 | unset test_python2_agent_autodetect |
| | 784 | unset test_python3_agent_autodetect |
| | 785 | ]) |
| | 786 | |
| | 787 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| | 788 | enable_test_python2_agent=yes |
| | 789 | enable_test_python3_agent=yes |
| | 790 | ]) |
| | 791 | |
| | 792 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| | 793 | enable_test_python2_agent=no |
| | 794 | enable_test_python3_agent=no |
| | 795 | ]) |
| | 796 | |
| | 797 | |
| | 798 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| | 799 | AS_IF([test -z "$PYTHON2"], [ |
| | 800 | PYTHON2=python2 |
| | 801 | ], [ |
| | 802 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| | 803 | ]) |
| | 804 | |
| | 805 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| | 806 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| | 807 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 808 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| | 809 | ]) |
| | 810 | ], [ |
| | 811 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| | 812 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 813 | PYTHON2_AGENT=$PYTHON2_BIN |
| | 814 | AC_MSG_RESULT([yes]) |
| | 815 | RUN_PYTHON_AGENT_TEST=yes |
| | 816 | ], [ |
| | 817 | AC_MSG_RESULT([no]) |
| | 818 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 819 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 820 | ]) |
| | 821 | ]) |
| | 822 | |
| | 823 | ]) |
| | 824 | |
| | 825 | ]) |
| | 826 | |
| | 827 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| | 828 | AS_IF([test -z "$PYTHON3"], [ |
| | 829 | PYTHON3=python3 |
| | 830 | ], [ |
| | 831 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| | 832 | ]) |
| | 833 | |
| | 834 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| | 835 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| | 836 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 837 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| | 838 | ]) |
| | 839 | ], [ |
| | 840 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| | 841 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 842 | PYTHON3_AGENT=$PYTHON3_BIN |
| | 843 | AC_MSG_RESULT([yes]) |
| | 844 | RUN_PYTHON_AGENT_TEST=yes |
| | 845 | ], [ |
| | 846 | AC_MSG_RESULT([no]) |
| | 847 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 848 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 849 | ]) |
| | 850 | ]) |
| | 851 | |
| | 852 | ]) |
| | 853 | ]) |
| | 854 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| | 855 | AC_SUBST([PYTHON2_AGENT]) |
| | 856 | AC_SUBST([PYTHON3_AGENT]) |
| | 857 | |
| | 858 | # Arguments for binaries build exclusion |
| | 859 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| | 860 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| | 861 | [Disable the build of lttng-consumerd binaries])) |
| | 862 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| | 863 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| | 864 | [Disable the build of lttng-relayd binaries])) |
| | 865 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| | 866 | [Disable the build of lttng-sessiond binaries])) |
| | 867 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| | 868 | [Disable the build of the extra components])) |
| | 869 | |
| | 870 | |
| | 871 | # Always build libconfig since it a dependency of libcommon |
| | 872 | build_lib_config=yes |
| | 873 | |
| | 874 | build_lib_compat=no |
| | 875 | build_lib_consumer=no |
| | 876 | build_lib_hashtable=no |
| | 877 | build_lib_health=no |
| | 878 | build_lib_index=no |
| | 879 | build_lib_kernel_consumer=no |
| | 880 | build_lib_kernel_ctl=no |
| | 881 | build_lib_lttng_ctl=no |
| | 882 | build_lib_relayd=no |
| | 883 | build_lib_sessiond_comm=no |
| | 884 | build_lib_testpoint=no |
| | 885 | build_lib_ust_consumer=no |
| | 886 | |
| | 887 | # There is an overlap for enabled dependencies, but this makes everything |
| | 888 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| | 889 | # here. |
| | 890 | |
| | 891 | # Enable binary dependencies. |
| | 892 | AS_IF([test x$enable_bin_lttng != xno], |
| | 893 | [ |
| | 894 | build_lib_lttng_ctl=yes |
| | 895 | ] |
| | 896 | ) |
| | 897 | |
| | 898 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| | 899 | [ |
| | 900 | build_lib_consumer=yes |
| | 901 | build_lib_sessiond_comm=yes |
| | 902 | build_lib_index=yes |
| | 903 | build_lib_health=yes |
| | 904 | build_lib_testpoint=yes |
| | 905 | ] |
| | 906 | ) |
| | 907 | |
| | 908 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| | 909 | # Do nothing since libconfig and libcommon are built by default. |
| | 910 | [] |
| | 911 | ) |
| | 912 | |
| | 913 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| | 914 | [ |
| | 915 | build_lib_lttng_ctl=yes |
| | 916 | build_lib_sessiond_comm=yes |
| | 917 | build_lib_hashtable=yes |
| | 918 | build_lib_compat=yes |
| | 919 | build_lib_index=yes |
| | 920 | build_lib_health=yes |
| | 921 | build_lib_testpoint=yes |
| | 922 | ] |
| | 923 | ) |
| | 924 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| | 925 | [ |
| | 926 | build_lib_lttng_ctl=yes |
| | 927 | build_lib_sessiond_comm=yes |
| | 928 | build_lib_kernel_ctl=yes |
| | 929 | build_lib_hashtable=yes |
| | 930 | build_lib_compat=yes |
| | 931 | build_lib_relayd=yes |
| | 932 | build_lib_testpoint=yes |
| | 933 | build_lib_health=yes |
| | 934 | ] |
| | 935 | ) |
| | 936 | |
| | 937 | # Libraries dependencies enabling |
| | 938 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| | 939 | [ |
| | 940 | build_lib_sessiond_comm=yes |
| | 941 | build_lib_hashtable=yes |
| | 942 | ] |
| | 943 | ) |
| | 944 | |
| | 945 | AS_IF([test x$build_lib_consumer = xyes], |
| | 946 | [ |
| | 947 | build_lib_sessiond_comm=yes |
| | 948 | build_lib_kernel_consumer=yes |
| | 949 | build_lib_hashtable=yes |
| | 950 | build_lib_compat=yes |
| | 951 | build_lib_relayd=yes |
| | 952 | AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes]) |
| | 953 | ] |
| | 954 | ) |
| | 955 | |
| | 956 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| | 957 | [ |
| | 958 | build_lib_kernel_ctl=yes |
| | 959 | build_lib_relayd=yes |
| | 960 | ] |
| | 961 | ) |
| | 962 | |
| | 963 | AS_IF([test x$build_lib_relayd = xyes], |
| | 964 | [ |
| | 965 | build_lib_sessiond_comm=yes |
| | 966 | ] |
| | 967 | ) |
| | 968 | |
| | 969 | # Find arch type |
| | 970 | AS_CASE([$host_cpu], |
| | 971 | [k1om], [ARCHTYPE="x86"], |
| | 972 | [i386], [ARCHTYPE="x86"], |
| | 973 | [i486], [ARCHTYPE="x86"], |
| | 974 | [i586], [ARCHTYPE="x86"], |
| | 975 | [i686], [ARCHTYPE="x86"], |
| | 976 | [amd64], [ARCHTYPE="x86"], |
| | 977 | [x86_64], [ARCHTYPE="x86"], |
| | 978 | [powerpc], [ARCHTYPE="ppc"], |
| | 979 | [ppc64], [ARCHTYPE="ppc"], |
| | 980 | [powerpc64], [ARCHTYPE="ppc"], |
| | 981 | [powerpc64le], [ARCHTYPE="ppc"], |
| | 982 | [ppc], [ARCHTYPE="ppc"], |
| | 983 | [s390], [ARCHTYPE="s390"], |
| | 984 | [s390x], [ARCHTYPE="s390"], |
| | 985 | [sparc], [ARCHTYPE="sparc64"], |
| | 986 | [sparc64], [ARCHTYPE="sparc64"], |
| | 987 | [alpha*], [ARCHTYPE="alpha"], |
| | 988 | [ia64], [ARCHTYPE="ia64"], |
| | 989 | [arm*], [ARCHTYPE="arm"], |
| | 990 | [aarch64*], [ARCHTYPE="aarch64"], |
| | 991 | [mips*], [ARCHTYPE="mips"], |
| | 992 | [nios2*], [ARCHTYPE="nios2"], |
| | 993 | [tile*], [ARCHTYPE="tile"], |
| | 994 | [hppa*], [ARCHTYPE="hppa"], |
| | 995 | [m68k], [ARCHTYPE="m68k"], |
| | 996 | [riscv*], [ARCHTYPE="riscv"], |
| | 997 | [ARCHTYPE="unknown"] |
| | 998 | ) |
| | 999 | |
| | 1000 | AC_SUBST(ARCHTYPE) |
| | 1001 | |
| | 1002 | AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support]) |
| | 1003 | AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel]) |
| | 1004 | AS_IF([test "x$ARCHTYPE" = "xx86"],[ |
| | 1005 | # Userspace callstack capture is only supported by the Linux kernel on x86. |
| | 1006 | AC_MSG_RESULT([yes]) |
| | 1007 | have_modules_userspace_callstack_context=yes |
| | 1008 | AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1]) |
| | 1009 | ], [ |
| | 1010 | AC_MSG_RESULT([no]) |
| | 1011 | have_modules_userspace_callstack_context=no |
| | 1012 | ]) |
| | 1013 | AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno]) |
| | 1014 | |
| | 1015 | # Export binaries build conditions. |
| | 1016 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| | 1017 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| | 1018 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| | 1019 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| | 1020 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| | 1021 | |
| | 1022 | # Export the tests and extras build conditions. |
| | 1023 | AS_IF([\ |
| | 1024 | test "x$enable_bin_lttng" != "xno" && \ |
| | 1025 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| | 1026 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| | 1027 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| | 1028 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| | 1029 | [build_tests=yes], |
| | 1030 | [build_tests=no] |
| | 1031 | ) |
| | 1032 | |
| | 1033 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| | 1034 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| | 1035 | |
| | 1036 | # Export libraries build conditions. |
| | 1037 | AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes]) |
| | 1038 | AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes]) |
| | 1039 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| | 1040 | AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes]) |
| | 1041 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| | 1042 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| | 1043 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| | 1044 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| | 1045 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| | 1046 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| | 1047 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| | 1048 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| | 1049 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| | 1050 | |
| | 1051 | AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS" |
| | 1052 | AC_SUBST(AM_CFLAGS) |
| | 1053 | |
| | 1054 | AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS" |
| | 1055 | AC_SUBST(AM_CPPFLAGS) |
| | 1056 | |
| | 1057 | lttngincludedir="${includedir}/lttng" |
| | 1058 | AC_SUBST(lttngincludedir) |
| | 1059 | |
| | 1060 | lttngactionincludedir="${includedir}/lttng/action" |
| | 1061 | AC_SUBST(lttngactionincludedir) |
| | 1062 | |
| | 1063 | lttngconditionincludedir="${includedir}/lttng/condition" |
| | 1064 | AC_SUBST(lttngconditionincludedir) |
| | 1065 | |
| | 1066 | lttngnotificationincludedir="${includedir}/lttng/notification" |
| | 1067 | AC_SUBST(lttngnotificationincludedir) |
| | 1068 | |
| | 1069 | lttngtriggerincludedir="${includedir}/lttng/trigger" |
| | 1070 | AC_SUBST(lttngtriggerincludedir) |
| | 1071 | |
| | 1072 | lttnglibexecdir="${libdir}/lttng/libexec" |
| | 1073 | AC_SUBST(lttnglibexecdir) |
| | 1074 | |
| | 1075 | AC_CONFIG_FILES([ |
| | 1076 | Makefile |
| | 1077 | doc/Makefile |
| | 1078 | doc/man/Makefile |
| | 1079 | doc/man/asciidoc-attrs.conf |
| | 1080 | include/Makefile |
| | 1081 | extras/Makefile |
| | 1082 | extras/bindings/Makefile |
| | 1083 | extras/bindings/swig/Makefile |
| | 1084 | extras/bindings/swig/python/Makefile |
| | 1085 | extras/core-handler/Makefile |
| | 1086 | src/Makefile |
| | 1087 | src/common/Makefile |
| | 1088 | src/common/kernel-ctl/Makefile |
| | 1089 | src/common/kernel-consumer/Makefile |
| | 1090 | src/common/consumer/Makefile |
| | 1091 | src/common/ust-consumer/Makefile |
| | 1092 | src/common/hashtable/Makefile |
| | 1093 | src/common/sessiond-comm/Makefile |
| | 1094 | src/common/compat/Makefile |
| | 1095 | src/common/relayd/Makefile |
| | 1096 | src/common/testpoint/Makefile |
| | 1097 | src/common/index/Makefile |
| | 1098 | src/common/health/Makefile |
| | 1099 | src/common/config/Makefile |
| | 1100 | src/common/string-utils/Makefile |
| | 1101 | src/lib/Makefile |
| | 1102 | src/lib/lttng-ctl/Makefile |
| | 1103 | src/lib/lttng-ctl/filter/Makefile |
| | 1104 | src/lib/lttng-ctl/lttng-ctl.pc |
| | 1105 | src/bin/Makefile |
| | 1106 | src/bin/lttng-consumerd/Makefile |
| | 1107 | src/bin/lttng-sessiond/Makefile |
| | 1108 | src/bin/lttng-relayd/Makefile |
| | 1109 | src/bin/lttng/Makefile |
| | 1110 | src/bin/lttng-crash/Makefile |
| | 1111 | tests/Makefile |
| | 1112 | tests/destructive/Makefile |
| | 1113 | tests/regression/Makefile |
| | 1114 | tests/regression/kernel/Makefile |
| | 1115 | tests/regression/tools/Makefile |
| | 1116 | tests/regression/tools/streaming/Makefile |
| | 1117 | tests/regression/tools/filtering/Makefile |
| | 1118 | tests/regression/tools/health/Makefile |
| | 1119 | tests/regression/tools/tracefile-limits/Makefile |
| | 1120 | tests/regression/tools/snapshots/Makefile |
| | 1121 | tests/regression/tools/live/Makefile |
| | 1122 | tests/regression/tools/exclusion/Makefile |
| | 1123 | tests/regression/tools/save-load/Makefile |
| | 1124 | tests/regression/tools/save-load/configuration/Makefile |
| | 1125 | tests/regression/tools/mi/Makefile |
| | 1126 | tests/regression/tools/wildcard/Makefile |
| | 1127 | tests/regression/tools/crash/Makefile |
| | 1128 | tests/regression/tools/regen-metadata/Makefile |
| | 1129 | tests/regression/tools/regen-statedump/Makefile |
| | 1130 | tests/regression/tools/notification/Makefile |
| | 1131 | tests/regression/tools/rotation/Makefile |
| | 1132 | tests/regression/ust/Makefile |
| | 1133 | tests/regression/ust/nprocesses/Makefile |
| | 1134 | tests/regression/ust/high-throughput/Makefile |
| | 1135 | tests/regression/ust/low-throughput/Makefile |
| | 1136 | tests/regression/ust/before-after/Makefile |
| | 1137 | tests/regression/ust/buffers-pid/Makefile |
| | 1138 | tests/regression/ust/periodical-metadata-flush/Makefile |
| | 1139 | tests/regression/ust/multi-session/Makefile |
| | 1140 | tests/regression/ust/multi-lib/Makefile |
| | 1141 | tests/regression/ust/overlap/Makefile |
| | 1142 | tests/regression/ust/overlap/demo/Makefile |
| | 1143 | tests/regression/ust/linking/Makefile |
| | 1144 | tests/regression/ust/daemon/Makefile |
| | 1145 | tests/regression/ust/exit-fast/Makefile |
| | 1146 | tests/regression/ust/fork/Makefile |
| | 1147 | tests/regression/ust/libc-wrapper/Makefile |
| | 1148 | tests/regression/ust/baddr-statedump/Makefile |
| | 1149 | tests/regression/ust/ust-dl/Makefile |
| | 1150 | tests/regression/ust/java-jul/Makefile |
| | 1151 | tests/regression/ust/java-log4j/Makefile |
| | 1152 | tests/regression/ust/python-logging/Makefile |
| | 1153 | tests/regression/ust/getcpu-override/Makefile |
| | 1154 | tests/regression/ust/clock-override/Makefile |
| | 1155 | tests/regression/ust/type-declarations/Makefile |
| | 1156 | tests/regression/ust/rotation-destroy-flush/Makefile |
| | 1157 | tests/regression/ust/blocking/Makefile |
| | 1158 | tests/stress/Makefile |
| | 1159 | tests/unit/Makefile |
| | 1160 | tests/unit/ini_config/Makefile |
| | 1161 | tests/perf/Makefile |
| | 1162 | tests/utils/Makefile |
| | 1163 | tests/utils/tap/Makefile |
| | 1164 | tests/utils/testapp/Makefile |
| | 1165 | tests/utils/testapp/gen-ust-events/Makefile |
| | 1166 | tests/utils/testapp/gen-syscall-events-callstack/Makefile |
| | 1167 | tests/utils/testapp/gen-ust-nevents/Makefile |
| | 1168 | tests/utils/testapp/gen-ust-nevents-str/Makefile |
| | 1169 | tests/utils/testapp/gen-syscall-events/Makefile |
| | 1170 | tests/utils/testapp/gen-ust-tracef/Makefile |
| | 1171 | tests/utils/testapp/userspace-probe-elf-binary/Makefile |
| | 1172 | tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile |
| | 1173 | tests/utils/testapp/userspace-probe-sdt-binary/Makefile |
| | 1174 | ]) |
| | 1175 | |
| | 1176 | # Inject variable into python test script. |
| | 1177 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| | 1178 | # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script. |
| | 1179 | AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw]) |
| | 1180 | AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl]) |
| | 1181 | |
| | 1182 | AC_OUTPUT |
| | 1183 | |
| | 1184 | # |
| | 1185 | # Mini-report on what will be built. |
| | 1186 | # |
| | 1187 | |
| | 1188 | PPRINT_INIT |
| | 1189 | PPRINT_SET_INDENT(1) |
| | 1190 | PPRINT_SET_TS(38) |
| | 1191 | |
| | 1192 | AS_ECHO |
| | 1193 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| | 1194 | AS_ECHO |
| | 1195 | |
| | 1196 | AS_IF([test -n "$report_fold"], [ |
| | 1197 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| | 1198 | ], [ |
| | 1199 | AS_ECHO("$version_description") |
| | 1200 | ]) |
| | 1201 | |
| | 1202 | AS_ECHO |
| | 1203 | PPRINT_SUBTITLE([Features]) |
| | 1204 | |
| | 1205 | # Target architecture we're building for. |
| | 1206 | target_arch=$host_cpu |
| | 1207 | [ |
| | 1208 | for f in $CFLAGS; do |
| | 1209 | if test $f = "-m32"; then |
| | 1210 | target_arch="32-bit" |
| | 1211 | elif test $f = "-m64"; then |
| | 1212 | target_arch="64-bit" |
| | 1213 | fi |
| | 1214 | done |
| | 1215 | ] |
| | 1216 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| | 1217 | |
| | 1218 | # kmod enabled/disabled |
| | 1219 | test "x$with_kmod" != "xno" && value=1 || value=0 |
| | 1220 | PPRINT_PROP_BOOL([libkmod support], $value) |
| | 1221 | |
| | 1222 | # LTTng-UST enabled/disabled |
| | 1223 | test "x$with_lttng_ust" = "xyes" && value=1 || value=0 |
| | 1224 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| | 1225 | |
| | 1226 | AS_ECHO |
| | 1227 | PPRINT_SUBTITLE([Binaries]) |
| | 1228 | |
| | 1229 | # List binaries to be built |
| | 1230 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| | 1231 | PPRINT_PROP_BOOL([lttng], $value) |
| | 1232 | |
| | 1233 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| | 1234 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| | 1235 | |
| | 1236 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| | 1237 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| | 1238 | |
| | 1239 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| | 1240 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| | 1241 | |
| | 1242 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| | 1243 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| | 1244 | |
| | 1245 | # Extras |
| | 1246 | test x$enable_extras != xno && value=1 || value=0 |
| | 1247 | AS_ECHO |
| | 1248 | PPRINT_SET_INDENT(0) |
| | 1249 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1250 | PPRINT_SET_INDENT(1) |
| | 1251 | |
| | 1252 | AS_ECHO |
| | 1253 | PPRINT_SUBTITLE([Tests]) |
| | 1254 | |
| | 1255 | # Print clear message that tests won't be built |
| | 1256 | AS_IF([test "x$build_tests" = "xno"],[ |
| | 1257 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| | 1258 | ]) |
| | 1259 | |
| | 1260 | # LTTng UST Java agent JUL tests enabled/disabled |
| | 1261 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| | 1262 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| | 1263 | |
| | 1264 | # LTTng UST Java agent Log4j tests enabled/disabled |
| | 1265 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| | 1266 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value) |
| | 1267 | |
| | 1268 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| | 1269 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| | 1270 | |
| | 1271 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| | 1272 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| | 1273 | |
| | 1274 | #Python binding enabled/disabled |
| | 1275 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| | 1276 | AS_ECHO |
| | 1277 | PPRINT_SET_INDENT(0) |
| | 1278 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1279 | |
| | 1280 | # man pages build enabled/disabled |
| | 1281 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| | 1282 | |
| | 1283 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| | 1284 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 1285 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1286 | ], [ |
| | 1287 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| | 1288 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1289 | ], [ |
| | 1290 | PPRINT_PROP_STRING([build_man_pages_msg], |
| | 1291 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| | 1292 | $PPRINT_COLOR_SUBTITLE) |
| | 1293 | ]) |
| | 1294 | ]) |
| | 1295 | ], [ |
| | 1296 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| | 1297 | ]) |
| | 1298 | |
| | 1299 | m4_popdef([build_man_pages_msg]) |
| | 1300 | |
| | 1301 | test "x$embedded_help" = xyes && value=1 || value=0 |
| | 1302 | PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1303 | |
| | 1304 | PPRINT_SET_INDENT(1) |
| | 1305 | |
| | 1306 | report_bindir="`eval eval echo $bindir`" |
| | 1307 | report_libdir="`eval eval echo $libdir`" |
| | 1308 | |
| | 1309 | # Print the bindir and libdir this `make install' will install into. |
| | 1310 | AS_ECHO |
| | 1311 | PPRINT_SUBTITLE([Install directories]) |
| | 1312 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| | 1313 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| | 1314 | |
| | 1315 | AS_ECHO |
| | 1316 | PPRINT_SUBTITLE([Search directories]) |
| | 1317 | |
| | 1318 | # If we build the sessiond, print the paths it will use |
| | 1319 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| | 1320 | path="$report_bindir/lttng-sessiond" |
| | 1321 | ],[ |
| | 1322 | path="$SESSIOND_BIN" |
| | 1323 | ]) |
| | 1324 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| | 1325 | |
| | 1326 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| | 1327 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1328 | ],[ |
| | 1329 | path="$CONSUMERD32_BIN" |
| | 1330 | ]) |
| | 1331 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| | 1332 | |
| | 1333 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| | 1334 | path="`eval eval echo $libdir`" |
| | 1335 | ],[ |
| | 1336 | path="$CONSUMERD32_LIBDIR" |
| | 1337 | ]) |
| | 1338 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| | 1339 | |
| | 1340 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| | 1341 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1342 | ],[ |
| | 1343 | path="$CONSUMERD64_BIN" |
| | 1344 | ]) |
| | 1345 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| | 1346 | |
| | 1347 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| | 1348 | path="`eval eval echo $libdir`" |
| | 1349 | ],[ |
| | 1350 | path="$CONSUMERD64_LIBDIR" |
| | 1351 | ]) |
| | 1352 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |
| | 1353 | PPRINT_SET_INDENT(0) |
| | 1354 | |
| | 1355 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ |
| | 1356 | AS_ECHO |
| | 1357 | PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages. |
| | 1358 | |
| | 1359 | Note that the man pages are already built in this distribution tarball, |
| | 1360 | therefore asciidoc and xmlto are only needed if you intend to modify |
| | 1361 | their sources. |
| | 1362 | |
| | 1363 | Also note that the installed man pages will contain the project's |
| | 1364 | default command-line option and environment variable values. |
| | 1365 | |
| | 1366 | Use --disable-man-pages to completely disable building and installing |
| | 1367 | the man pages.]) |
| | 1368 | ]) |
projects / lttng-tools.git / blame_incremental