| | 1 | dnl SPDX-License-Identifier: GPL-2.0-only |
| | 2 | AC_PREREQ([2.64]) |
| | 3 | AC_INIT([lttng-tools],[2.12.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| | 4 | |
| | 5 | AC_CONFIG_HEADERS([include/config.h]) |
| | 6 | AC_CONFIG_AUX_DIR([config]) |
| | 7 | AC_CONFIG_MACRO_DIR([m4]) |
| | 8 | |
| | 9 | AC_CANONICAL_TARGET |
| | 10 | AC_CANONICAL_HOST |
| | 11 | |
| | 12 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc]) |
| | 13 | AM_MAINTAINER_MODE([enable]) |
| | 14 | |
| | 15 | # Enable silent rules if available (Introduced in AM 1.11) |
| | 16 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| | 17 | |
| | 18 | AC_REQUIRE_AUX_FILE([tap-driver.sh]) |
| | 19 | |
| | 20 | # Checks for C compiler |
| | 21 | AC_USE_SYSTEM_EXTENSIONS |
| | 22 | AC_SYS_LARGEFILE |
| | 23 | AC_PROG_CC |
| | 24 | AC_PROG_CC_STDC |
| | 25 | AC_PROG_CXX |
| | 26 | RW_PROG_CXX_WORKS |
| | 27 | AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"]) |
| | 28 | |
| | 29 | # Detect warning flags supported by the compiler, append them to WARN_CFLAGS. |
| | 30 | # |
| | 31 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 32 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 33 | AX_APPEND_COMPILE_FLAGS([ dnl |
| | 34 | -Wall dnl |
| | 35 | dnl We currently get this warning when building with Clang: |
| | 36 | dnl |
| | 37 | dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration] |
| | 38 | dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL; |
| | 39 | dnl ^ |
| | 40 | -Wno-incomplete-setjmp-declaration dnl |
| | 41 | -Wdiscarded-qualifiers dnl |
| | 42 | -Wmissing-declarations dnl |
| | 43 | -Wmissing-prototypes dnl |
| | 44 | -Wmissing-parameter-type dnl |
| | 45 | -Wold-style-definition dnl |
| | 46 | -Wstrict-prototypes dnl |
| | 47 | ], |
| | 48 | [WARN_CFLAGS], |
| | 49 | [-Werror]) |
| | 50 | |
| | 51 | # When given, add -Werror to WARN_CFLAGS. |
| | 52 | AC_ARG_ENABLE([Werror], |
| | 53 | [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])] |
| | 54 | ) |
| | 55 | AS_IF([test "x$enable_Werror" = "xyes"], |
| | 56 | [WARN_CFLAGS="${WARN_CFLAGS} -Werror"] |
| | 57 | ) |
| | 58 | |
| | 59 | # Checks for programs. |
| | 60 | AC_PROG_GREP |
| | 61 | AC_PROG_MAKE_SET |
| | 62 | AC_PROG_SED |
| | 63 | AC_PATH_PROG([report_fold], [fold]) |
| | 64 | LT_INIT |
| | 65 | |
| | 66 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| | 67 | AC_CHECK_TOOL([OBJCOPY], [objcopy], [no]) |
| | 68 | AS_IF([test "x$OBJCOPY" = "xno"], |
| | 69 | [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| | 70 | ) |
| | 71 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno]) |
| | 72 | |
| | 73 | # check for pgrep |
| | 74 | AC_PATH_PROG([PGREP], [pgrep], [no]) |
| | 75 | AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"]) |
| | 76 | |
| | 77 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| | 78 | # is not distributed in tarballs |
| | 79 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| | 80 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| | 81 | |
| | 82 | # check for bison |
| | 83 | AC_PROG_YACC |
| | 84 | BISON=$YACC |
| | 85 | AX_PROG_BISON_VERSION([2.4], [have_bison=yes]) |
| | 86 | |
| | 87 | AS_IF([test "x$have_bison" != "xyes"], [ |
| | 88 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 89 | AC_MSG_FAILURE([ |
| | 90 | Bison >= 2.4 is required when building from the Git repository. You can |
| | 91 | set the YACC variable to override automatic detection. |
| | 92 | ]) |
| | 93 | ], [ |
| | 94 | AC_MSG_WARN([ |
| | 95 | Missing Bison >= 2.4. Note that the parser files are already built in |
| | 96 | this distribution tarball, so Bison is only needed if you intend to |
| | 97 | modify their sources. You can set the YACC variable to override automatic |
| | 98 | detection. |
| | 99 | ]) |
| | 100 | ]) |
| | 101 | ]) |
| | 102 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| | 103 | |
| | 104 | # check for flex |
| | 105 | AC_PROG_LEX |
| | 106 | FLEX=$LEX |
| | 107 | AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes]) |
| | 108 | |
| | 109 | AS_IF([test "x$have_flex" != "xyes"], [ |
| | 110 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 111 | AC_MSG_FAILURE([ |
| | 112 | Flex >= 2.5.35 is required when building from the Git repository. You can |
| | 113 | set the LEX variable to override automatic detection. |
| | 114 | ]) |
| | 115 | ], [ |
| | 116 | AC_MSG_WARN([ |
| | 117 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| | 118 | this distribution tarball, so Flex is only needed if you intend to |
| | 119 | modify their sources. You can set the LEX variable to override automatic |
| | 120 | detection. |
| | 121 | ]) |
| | 122 | ]) |
| | 123 | ]) |
| | 124 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| | 125 | |
| | 126 | |
| | 127 | # Checks for typedefs, structures, and compiler characteristics. |
| | 128 | AC_C_INLINE |
| | 129 | AC_TYPE_INT32_T |
| | 130 | AC_TYPE_INT64_T |
| | 131 | AC_TYPE_MODE_T |
| | 132 | AC_TYPE_OFF_T |
| | 133 | AC_TYPE_PID_T |
| | 134 | AC_TYPE_SIZE_T |
| | 135 | AC_TYPE_SSIZE_T |
| | 136 | AC_TYPE_UID_T |
| | 137 | AC_TYPE_UINT16_T |
| | 138 | AC_TYPE_UINT32_T |
| | 139 | AC_TYPE_UINT64_T |
| | 140 | AC_TYPE_UINT8_T |
| | 141 | |
| | 142 | AX_C___ATTRIBUTE__ |
| | 143 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], |
| | 144 | [:], |
| | 145 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| | 146 | |
| | 147 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) |
| | 148 | |
| | 149 | # Check if linker has the -no-pie option. |
| | 150 | AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes]) |
| | 151 | AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"]) |
| | 152 | |
| | 153 | AX_LIB_SOCKET_NSL |
| | 154 | |
| | 155 | LT_NO_UNDEFINED="" |
| | 156 | AS_CASE([$host_os], |
| | 157 | [cygwin*], |
| | 158 | [ |
| | 159 | LT_NO_UNDEFINED="-no-undefined" |
| | 160 | ], |
| | 161 | [cygwin*|darwin*|mingw*|solaris*], |
| | 162 | [ |
| | 163 | # On platforms where we only support the relayd, disable the other binaries by default |
| | 164 | AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no]) |
| | 165 | AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no]) |
| | 166 | AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no]) |
| | 167 | AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no]) |
| | 168 | AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no]) |
| | 169 | AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no]) |
| | 170 | ] |
| | 171 | ) |
| | 172 | |
| | 173 | AC_SUBST(LT_NO_UNDEFINED) |
| | 174 | |
| | 175 | # Compute minor/major/patchlevel version numbers |
| | 176 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| | 177 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| | 178 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| | 179 | |
| | 180 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| | 181 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| | 182 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| | 183 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| | 184 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| | 185 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| | 186 | |
| | 187 | version_name="(Ta) Meilleure" |
| | 188 | version_description="Ta Meilleure is a Northeast IPA beer brewed by Lagabière. Translating to \"Your best one\", this beer gives out strong aromas of passion fruit, lemon, and peaches. Tastewise, expect a lot of fruit, a creamy texture, and a smooth lingering hop bitterness." |
| | 189 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| | 190 | |
| | 191 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| | 192 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| | 193 | |
| | 194 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| | 195 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| | 196 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| | 197 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| | 198 | libtool_fixup=$enableval, |
| | 199 | libtool_fixup=yes) |
| | 200 | |
| | 201 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| | 202 | [ |
| | 203 | libtool_m4="$srcdir/m4/libtool.m4" |
| | 204 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| | 205 | AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4]) |
| | 206 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| | 207 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| | 208 | [ |
| | 209 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| | 210 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| | 211 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| | 212 | ], |
| | 213 | [ |
| | 214 | AC_MSG_RESULT([none]) |
| | 215 | ]) |
| | 216 | ]) |
| | 217 | |
| | 218 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| | 219 | |
| | 220 | AC_CHECK_HEADERS([ \ |
| | 221 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| | 222 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| | 223 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| | 224 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| | 225 | sys/mount.h sys/param.h sys/time.h elf.h |
| | 226 | ]) |
| | 227 | |
| | 228 | AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes]) |
| | 229 | |
| | 230 | # Basic functions check |
| | 231 | AC_CHECK_FUNCS([ \ |
| | 232 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| | 233 | gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \ |
| | 234 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| | 235 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| | 236 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| | 237 | sched_getcpu sysconf sync_file_range |
| | 238 | ]) |
| | 239 | |
| | 240 | # Check for pthread_setname_np and its signature |
| | 241 | LTTNG_PTHREAD_SETNAME_NP |
| | 242 | |
| | 243 | # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so, |
| | 244 | # add -lrt to LIBS |
| | 245 | AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete]) |
| | 246 | |
| | 247 | # Checks for dl. |
| | 248 | AC_CHECK_LIB([dl], [dlopen], [ |
| | 249 | have_libdl=yes |
| | 250 | libdl_name=dl |
| | 251 | DL_LIBS="-ldl" |
| | 252 | ], [ |
| | 253 | # libdl not found, check for dlopen in libc. |
| | 254 | AC_CHECK_LIB([c], [dlopen], [ |
| | 255 | have_libc_dl=yes |
| | 256 | libdl_name=c |
| | 257 | DL_LIBS="-lc" |
| | 258 | ], [ |
| | 259 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| | 260 | ]) |
| | 261 | ]) |
| | 262 | AC_SUBST(DL_LIBS) |
| | 263 | |
| | 264 | # Check if libdl has dlmopen support. |
| | 265 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) |
| | 266 | AC_CHECK_LIB([$libdl_name], [dlmopen], [ |
| | 267 | AC_DEFINE([HAVE_DLMOPEN], [1]) |
| | 268 | HAVE_DLMOPEN=1 |
| | 269 | ], [ |
| | 270 | HAVE_DLMOPEN=0 |
| | 271 | ]) |
| | 272 | AC_SUBST(HAVE_DLMOPEN) |
| | 273 | |
| | 274 | # Babeltrace viewer check |
| | 275 | AC_ARG_WITH([babeltrace-bin], |
| | 276 | AS_HELP_STRING([--with-babeltrace-bin], |
| | 277 | [Location of the babeltrace viewer executable (including the filename)]), |
| | 278 | [BABELTRACE_BIN="$withval"], |
| | 279 | [BABELTRACE_BIN='']) |
| | 280 | AC_SUBST([BABELTRACE_BIN]) |
| | 281 | |
| | 282 | AC_ARG_WITH([babeltrace2-bin], |
| | 283 | AS_HELP_STRING([--with-babeltrace2-bin], |
| | 284 | [Location of the babeltrace2 viewer executable (including the filename)]), |
| | 285 | [BABELTRACE2_BIN="$withval"], |
| | 286 | [BABELTRACE2_BIN='']) |
| | 287 | AC_SUBST([BABELTRACE2_BIN]) |
| | 288 | |
| | 289 | AC_ARG_WITH([consumerd32-bin], |
| | 290 | AS_HELP_STRING([--with-consumerd32-bin], |
| | 291 | [Location of the 32-bit consumerd executable (including the filename)]), |
| | 292 | [CONSUMERD32_BIN="$withval"], |
| | 293 | [CONSUMERD32_BIN='']) |
| | 294 | AC_SUBST([CONSUMERD32_BIN]) |
| | 295 | |
| | 296 | AC_ARG_WITH([consumerd64-bin], |
| | 297 | AS_HELP_STRING([--with-consumerd64-bin], |
| | 298 | [Location of the 64-bit consumerd executable (including the filename)]), |
| | 299 | [CONSUMERD64_BIN="$withval"], |
| | 300 | [CONSUMERD64_BIN='']) |
| | 301 | AC_SUBST([CONSUMERD64_BIN]) |
| | 302 | |
| | 303 | AC_ARG_WITH([consumerd32-libdir], |
| | 304 | AS_HELP_STRING([--with-consumerd32-libdir], |
| | 305 | [Directory containing the 32-bit consumerd libraries]), |
| | 306 | [CONSUMERD32_LIBDIR="$withval"], |
| | 307 | [CONSUMERD32_LIBDIR='']) |
| | 308 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| | 309 | |
| | 310 | AC_ARG_WITH([consumerd64-libdir], |
| | 311 | AS_HELP_STRING([--with-consumerd64-libdir], |
| | 312 | [Directory containing the 64-bit consumerd libraries]), |
| | 313 | [CONSUMERD64_LIBDIR="$withval"], |
| | 314 | [CONSUMERD64_LIBDIR='']) |
| | 315 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| | 316 | |
| | 317 | AC_ARG_WITH([sessiond-bin], |
| | 318 | AS_HELP_STRING([--with-sessiond-bin], |
| | 319 | [Location of the sessiond executable (including the filename)]), |
| | 320 | [SESSIOND_BIN="$withval"], |
| | 321 | [SESSIOND_BIN='']) |
| | 322 | AC_SUBST([SESSIOND_BIN]) |
| | 323 | |
| | 324 | AC_ARG_WITH([lttng-system-rundir], |
| | 325 | AS_HELP_STRING([--with-lttng-system-rundir], |
| | 326 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| | 327 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| | 328 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| | 329 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| | 330 | |
| | 331 | AC_ARG_ENABLE([test-java-agent-jul], |
| | 332 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| | 333 | [test_java_agent_jul=$enableval], |
| | 334 | [test_java_agent_jul=no] |
| | 335 | ) |
| | 336 | |
| | 337 | AC_ARG_ENABLE([test-java-agent-log4j], |
| | 338 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])], |
| | 339 | [test_java_agent_log4j=$enableval], |
| | 340 | [test_java_agent_log4j=no] |
| | 341 | ) |
| | 342 | |
| | 343 | AC_ARG_ENABLE([test-java-agent-all], |
| | 344 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| | 345 | [test_java_agent_jul=$enableval |
| | 346 | test_java_agent_log4j=$enableval], |
| | 347 | [:] |
| | 348 | ) |
| | 349 | |
| | 350 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| | 351 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| | 352 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| | 353 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| | 354 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| | 355 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.]) |
| | 356 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| | 357 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| | 358 | |
| | 359 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| | 360 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| | 361 | $1="$2" |
| | 362 | AC_SUBST([$1]) |
| | 363 | ]) |
| | 364 | |
| | 365 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| | 366 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| | 367 | $1="$2" |
| | 368 | AC_SUBST([$1]) |
| | 369 | ]) |
| | 370 | |
| | 371 | # Default values |
| | 372 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384]) |
| | 373 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| | 374 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| | 375 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| | 376 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| | 377 | m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000]) |
| | 378 | m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 379 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345]) |
| | 380 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354]) |
| | 381 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| | 382 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 383 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| | 384 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| | 385 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 386 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| | 387 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 388 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576]) |
| | 389 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 390 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 391 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT]) |
| | 392 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| | 393 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| | 394 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| | 395 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| | 396 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| | 397 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 398 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| | 399 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| | 400 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| | 401 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 402 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| | 403 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 404 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 405 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 406 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 407 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 408 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 409 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| | 410 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 411 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 412 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288]) |
| | 413 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 414 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 415 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| | 416 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| | 417 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| | 418 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| | 419 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728]) |
| | 420 | _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000]) |
| | 421 | |
| | 422 | # Command short descriptions |
| | 423 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel]) |
| | 424 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session]) |
| | 425 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session]) |
| | 426 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions]) |
| | 427 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels]) |
| | 428 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules]) |
| | 429 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule]) |
| | 430 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels]) |
| | 431 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules]) |
| | 432 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule]) |
| | 433 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command]) |
| | 434 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events]) |
| | 435 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations]) |
| | 436 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration]) |
| | 437 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk]) |
| | 438 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations]) |
| | 439 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session]) |
| | 440 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session]) |
| | 441 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing]) |
| | 442 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session]) |
| | 443 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing]) |
| | 444 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule]) |
| | 445 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule]) |
| | 446 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources]) |
| | 447 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources]) |
| | 448 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information]) |
| | 449 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer]) |
| | 450 | |
| | 451 | if test "x$prefix" = "xNONE"; then |
| | 452 | prefix=$ac_default_prefix |
| | 453 | fi |
| | 454 | CONFDIR=`eval echo $sysconfdir` |
| | 455 | AC_SUBST(CONFDIR) |
| | 456 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| | 457 | |
| | 458 | AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.]) |
| | 459 | |
| | 460 | # Check libpopt |
| | 461 | PKG_CHECK_MODULES([POPT], [popt], |
| | 462 | [ |
| | 463 | dnl PKG_CHECK_MODULES defines POPT_LIBS |
| | 464 | ], |
| | 465 | [ |
| | 466 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 467 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| | 468 | AC_CHECK_LIB([popt], |
| | 469 | [poptGetContext], |
| | 470 | [POPT_LIBS="-lpopt"], |
| | 471 | [ |
| | 472 | AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 473 | ] |
| | 474 | ) |
| | 475 | ] |
| | 476 | ) |
| | 477 | AC_SUBST(POPT_LIBS) |
| | 478 | |
| | 479 | PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6]) |
| | 480 | |
| | 481 | AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])]) |
| | 482 | |
| | 483 | # URCU library version needed or newer |
| | 484 | m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed]) |
| | 485 | |
| | 486 | # Check liburcu needed function calls |
| | 487 | AC_CHECK_DECL([cds_list_add], [], |
| | 488 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]]) |
| | 489 | AC_CHECK_DECL([cds_wfcq_init], [], |
| | 490 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| | 491 | AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [], |
| | 492 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| | 493 | AC_CHECK_DECL([futex_async], [], |
| | 494 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]]) |
| | 495 | AC_CHECK_DECL([rcu_thread_offline], [], |
| | 496 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 497 | AC_CHECK_DECL([rcu_thread_online], [], |
| | 498 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 499 | AC_CHECK_DECL([caa_likely], [], |
| | 500 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 501 | AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], |
| | 502 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])]) |
| | 503 | |
| | 504 | #Function added in urcu 0.7.0 |
| | 505 | AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [], |
| | 506 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]] |
| | 507 | ) |
| | 508 | |
| | 509 | #Function added in urcu 0.9.0 |
| | 510 | AC_CHECK_DECL([urcu_ref_get_unless_zero], [], |
| | 511 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]] |
| | 512 | ) |
| | 513 | |
| | 514 | # Check for libkmod, it will be auto-neabled if found but won't fail if it's not, |
| | 515 | # it can be explicitly disabled with --without-kmod |
| | 516 | AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support]) |
| | 517 | AC_ARG_WITH([kmod], |
| | 518 | [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])], |
| | 519 | [], |
| | 520 | [with_kmod=check] |
| | 521 | ) |
| | 522 | |
| | 523 | AS_IF([test "x$with_kmod" != "xno"], |
| | 524 | [ |
| | 525 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| | 526 | [ |
| | 527 | AC_DEFINE([HAVE_KMOD], [1]) |
| | 528 | KMOD_LIBS="-lkmod" |
| | 529 | ], |
| | 530 | [ |
| | 531 | if test "x$with_kmod" != xcheck; then |
| | 532 | AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.]) |
| | 533 | else |
| | 534 | with_kmod=no |
| | 535 | fi |
| | 536 | ] |
| | 537 | ) |
| | 538 | ] |
| | 539 | ) |
| | 540 | AC_SUBST(KMOD_LIBS) |
| | 541 | |
| | 542 | # Check for liblttng-ust-ctl, fail if it's not found, |
| | 543 | # it can be explicitly disabled with --without-lttng-ust |
| | 544 | AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support]) |
| | 545 | AC_ARG_WITH([lttng-ust], |
| | 546 | [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])], |
| | 547 | [], |
| | 548 | [with_lttng_ust=yes] |
| | 549 | ) |
| | 550 | |
| | 551 | AS_IF([test "x$with_lttng_ust" = "xyes"], [ |
| | 552 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1]) |
| | 553 | |
| | 554 | # Check for liblttng-ust |
| | 555 | PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version]) |
| | 556 | |
| | 557 | # Check for liblttng-ust-ctl |
| | 558 | PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version]) |
| | 559 | |
| | 560 | AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS" |
| | 561 | ]) |
| | 562 | |
| | 563 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"]) |
| | 564 | |
| | 565 | |
| | 566 | # Check for fmemopen |
| | 567 | AC_CHECK_LIB([c], [fmemopen], |
| | 568 | [ |
| | 569 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| | 570 | ] |
| | 571 | ) |
| | 572 | |
| | 573 | # check for libpfm |
| | 574 | AC_CHECK_LIB([pfm], [pfm_initialize], |
| | 575 | [ |
| | 576 | have_libpfm=yes |
| | 577 | ]) |
| | 578 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"]) |
| | 579 | |
| | 580 | # For Python |
| | 581 | # SWIG version needed or newer: |
| | 582 | swig_version=2.0.0 |
| | 583 | |
| | 584 | AC_ARG_ENABLE([python-bindings], |
| | 585 | [AC_HELP_STRING([--enable-python-bindings], |
| | 586 | [compile Python bindings])], |
| | 587 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| | 588 | |
| | 589 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| | 590 | |
| | 591 | if test "x$enable_python_binding" = xyes; then |
| | 592 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| | 593 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| | 594 | AM_PATH_PYTHON([3.0]) |
| | 595 | |
| | 596 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| | 597 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| | 598 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| | 599 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| | 600 | AC_PATH_PROGS([PYTHON_CONFIG], |
| | 601 | [python$PYTHON_VERSION-config python-config], |
| | 602 | [no], |
| | 603 | [`dirname $PYTHON`]) |
| | 604 | AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| | 605 | ]) |
| | 606 | AC_MSG_CHECKING([python include flags]) |
| | 607 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| | 608 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| | 609 | ]) |
| | 610 | |
| | 611 | else |
| | 612 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| | 613 | [if you want Python bindings.]) |
| | 614 | |
| | 615 | fi |
| | 616 | |
| | 617 | # Epoll check. If not present, the build will fallback on poll() API |
| | 618 | AX_HAVE_EPOLL( |
| | 619 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| | 620 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| | 621 | ) |
| | 622 | AX_CONFIG_FEATURE( |
| | 623 | [epoll], [This platform supports epoll(7)], |
| | 624 | [HAVE_EPOLL], [This platform supports epoll(7).], |
| | 625 | [enable_epoll="yes"], [enable_epoll="no"] |
| | 626 | ) |
| | 627 | AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ]) |
| | 628 | |
| | 629 | AS_IF([test "x$ac_cv_func_dirfd" = "xyes"], |
| | 630 | [AX_CONFIG_FEATURE_ENABLE(dirfd)], |
| | 631 | [AX_CONFIG_FEATURE_DISABLE(dirfd)] |
| | 632 | ) |
| | 633 | AX_CONFIG_FEATURE( |
| | 634 | [dirfd], [Use directory file descriptors], |
| | 635 | [COMPAT_DIRFD], [This platform supports directory file descriptors.], |
| | 636 | [enable_dirfd="yes"], [enable_dirfd="no"] |
| | 637 | ) |
| | 638 | AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ]) |
| | 639 | |
| | 640 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| | 641 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| | 642 | |
| | 643 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then |
| | 644 | AX_JAVA_OPTIONS |
| | 645 | AX_PROG_JAVAC |
| | 646 | AX_PROG_JAVA |
| | 647 | AX_PROG_JAR |
| | 648 | |
| | 649 | AX_CHECK_CLASSPATH |
| | 650 | |
| | 651 | # Check for Java UST agent common class first |
| | 652 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| | 653 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| | 654 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| | 655 | fi |
| | 656 | |
| | 657 | if test "x$test_java_agent_jul" = "xyes"; then |
| | 658 | # Check for JUL agent class |
| | 659 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| | 660 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| | 661 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| | 662 | fi |
| | 663 | fi |
| | 664 | |
| | 665 | if test "x$test_java_agent_log4j" = "xyes"; then |
| | 666 | # Check for Log4j agent class |
| | 667 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| | 668 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| | 669 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| | 670 | fi |
| | 671 | |
| | 672 | # Check for Log4j class |
| | 673 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| | 674 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| | 675 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| | 676 | fi |
| | 677 | fi |
| | 678 | fi |
| | 679 | |
| | 680 | # enable building man pages (user's intention) |
| | 681 | AC_ARG_ENABLE( |
| | 682 | man-pages, |
| | 683 | AS_HELP_STRING( |
| | 684 | [--disable-man-pages], |
| | 685 | [Do not build and install man pages (already built in a distributed tarball)] |
| | 686 | ), |
| | 687 | [man_pages_opt=$enableval], |
| | 688 | [man_pages_opt=yes] |
| | 689 | ) |
| | 690 | |
| | 691 | # check for asciidoc and xmlto if we enabled building the man pages |
| | 692 | have_asciidoc_xmlto=no |
| | 693 | warn_prebuilt_man_pages=no |
| | 694 | |
| | 695 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| | 696 | AC_PATH_PROG([ASCIIDOC], [asciidoc], [no]) |
| | 697 | AC_PATH_PROG([XMLTO], [xmlto], [no]) |
| | 698 | |
| | 699 | AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [ |
| | 700 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 701 | # this is an error because we're in the Git repo, which |
| | 702 | # means the man pages are not already generated for us, |
| | 703 | # thus asciidoc/xmlto are required because we were asked |
| | 704 | # to build the man pages |
| | 705 | AC_MSG_ERROR([ |
| | 706 | You need asciidoc and xmlto to build the LTTng-tools man pages. Use |
| | 707 | --disable-man-pages to disable building the man pages, in which case |
| | 708 | they will not be installed. |
| | 709 | ]) |
| | 710 | ], [ |
| | 711 | # only warn here: since we're in the tarball, the man |
| | 712 | # pages should already be generated at this point, thus |
| | 713 | # asciidoc/xmlto are not strictly required |
| | 714 | warn_prebuilt_man_pages=yes |
| | 715 | ]) |
| | 716 | ], [ |
| | 717 | have_asciidoc_xmlto=yes |
| | 718 | ]) |
| | 719 | ]) |
| | 720 | |
| | 721 | # export man page build condition: build the man pages if the user |
| | 722 | # asked for it, and if the tools are available |
| | 723 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| | 724 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| | 725 | |
| | 726 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| | 727 | |
| | 728 | # embedded --help message |
| | 729 | AC_ARG_ENABLE( |
| | 730 | [embedded-help], |
| | 731 | AS_HELP_STRING( |
| | 732 | [--enable-embedded-help], |
| | 733 | [Embed the --help messages in the executable files] |
| | 734 | ), |
| | 735 | [embedded_help=$enableval], |
| | 736 | [embedded_help=no] |
| | 737 | ) |
| | 738 | AS_IF([test "x$embedded_help" = "xyes"], [ |
| | 739 | AS_IF([test "x$man_pages_opt" = "xno"], [ |
| | 740 | AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.]) |
| | 741 | ]) |
| | 742 | AC_PATH_PROG([man_prog_path], [man], [no]) |
| | 743 | AS_IF([test "x$man_prog_path" = "xno"], [ |
| | 744 | AC_MSG_ERROR([You need man with the --enable-embedded-help option.]) |
| | 745 | ]) |
| | 746 | AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.]) |
| | 747 | AC_SUBST([MANPROG], [$man_prog_path]) |
| | 748 | ]) |
| | 749 | AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"]) |
| | 750 | |
| | 751 | # Python agent test |
| | 752 | UST_PYTHON_AGENT="lttngust" |
| | 753 | |
| | 754 | AC_ARG_ENABLE(test-python2-agent, |
| | 755 | AS_HELP_STRING([--enable-test-python2-agent], |
| | 756 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| | 757 | ),[:],[test_python2_agent_autodetect=yes] |
| | 758 | ) |
| | 759 | |
| | 760 | AC_ARG_ENABLE(test-python3-agent, |
| | 761 | AS_HELP_STRING([--enable-test-python3-agent], |
| | 762 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| | 763 | ),[:],[test_python3_agent_autodetect=yes] |
| | 764 | ) |
| | 765 | |
| | 766 | AC_ARG_ENABLE(test-python-agent-all, |
| | 767 | AS_HELP_STRING([--enable-test-python-agent-all], |
| | 768 | [enable test for all python{2/3} agent.] |
| | 769 | ), |
| | 770 | ) |
| | 771 | |
| | 772 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| | 773 | unset test_python2_agent_autodetect |
| | 774 | unset test_python3_agent_autodetect |
| | 775 | ]) |
| | 776 | |
| | 777 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| | 778 | enable_test_python2_agent=yes |
| | 779 | enable_test_python3_agent=yes |
| | 780 | ]) |
| | 781 | |
| | 782 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| | 783 | enable_test_python2_agent=no |
| | 784 | enable_test_python3_agent=no |
| | 785 | ]) |
| | 786 | |
| | 787 | |
| | 788 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| | 789 | AS_IF([test -z "$PYTHON2"], [ |
| | 790 | PYTHON2=python2 |
| | 791 | ], [ |
| | 792 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| | 793 | ]) |
| | 794 | |
| | 795 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| | 796 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| | 797 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 798 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| | 799 | ]) |
| | 800 | ], [ |
| | 801 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| | 802 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 803 | PYTHON2_AGENT=$PYTHON2_BIN |
| | 804 | AC_MSG_RESULT([yes]) |
| | 805 | RUN_PYTHON_AGENT_TEST=yes |
| | 806 | ], [ |
| | 807 | AC_MSG_RESULT([no]) |
| | 808 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 809 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 810 | ]) |
| | 811 | ]) |
| | 812 | |
| | 813 | ]) |
| | 814 | |
| | 815 | ]) |
| | 816 | |
| | 817 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| | 818 | AS_IF([test -z "$PYTHON3"], [ |
| | 819 | PYTHON3=python3 |
| | 820 | ], [ |
| | 821 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| | 822 | ]) |
| | 823 | |
| | 824 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| | 825 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| | 826 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 827 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| | 828 | ]) |
| | 829 | ], [ |
| | 830 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| | 831 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 832 | PYTHON3_AGENT=$PYTHON3_BIN |
| | 833 | AC_MSG_RESULT([yes]) |
| | 834 | RUN_PYTHON_AGENT_TEST=yes |
| | 835 | ], [ |
| | 836 | AC_MSG_RESULT([no]) |
| | 837 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 838 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 839 | ]) |
| | 840 | ]) |
| | 841 | |
| | 842 | ]) |
| | 843 | ]) |
| | 844 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| | 845 | AC_SUBST([PYTHON2_AGENT]) |
| | 846 | AC_SUBST([PYTHON3_AGENT]) |
| | 847 | |
| | 848 | AC_ARG_ENABLE([test-sdt-uprobe], |
| | 849 | [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])], |
| | 850 | [test_sdt_uprobe="$enableval"], |
| | 851 | [test_sdt_uprobe=autodetect] |
| | 852 | ) |
| | 853 | |
| | 854 | AS_IF([test "$test_sdt_uprobe" != "no"], [ |
| | 855 | LTTNG_CHECK_SDT_WORKS |
| | 856 | AC_PATH_PROG([DTRACE], [dtrace]) |
| | 857 | ]) |
| | 858 | |
| | 859 | AS_IF([test "$test_sdt_uprobe" = "yes"], [ |
| | 860 | AS_IF([test "$lttng_cv_sdt_works" = "no"], [ |
| | 861 | AC_MSG_ERROR([Cannot find 'sys/sdt.h'.]) |
| | 862 | ]) |
| | 863 | AS_IF([test "x$DTRACE" = "x"], [ |
| | 864 | AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.]) |
| | 865 | ]) |
| | 866 | ]) |
| | 867 | |
| | 868 | AS_IF([test "$test_sdt_uprobe" = "autodetect"], [ |
| | 869 | AS_IF([test "$lttng_cv_sdt_works" = "yes"], [ |
| | 870 | AS_IF([test "x$DTRACE" != "x"], [ |
| | 871 | test_sdt_uprobe=yes |
| | 872 | ]) |
| | 873 | ]) |
| | 874 | ]) |
| | 875 | |
| | 876 | AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"]) |
| | 877 | |
| | 878 | # Arguments for binaries build exclusion |
| | 879 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| | 880 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| | 881 | [Disable the build of lttng-consumerd binaries])) |
| | 882 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| | 883 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| | 884 | [Disable the build of lttng-relayd binaries])) |
| | 885 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| | 886 | [Disable the build of lttng-sessiond binaries])) |
| | 887 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| | 888 | [Disable the build of the extra components])) |
| | 889 | |
| | 890 | |
| | 891 | # Always build libconfig since it a dependency of libcommon |
| | 892 | build_lib_config=yes |
| | 893 | |
| | 894 | build_lib_compat=no |
| | 895 | build_lib_consumer=no |
| | 896 | build_lib_hashtable=no |
| | 897 | build_lib_health=no |
| | 898 | build_lib_index=no |
| | 899 | build_lib_kernel_consumer=no |
| | 900 | build_lib_kernel_ctl=no |
| | 901 | build_lib_lttng_ctl=no |
| | 902 | build_lib_relayd=no |
| | 903 | build_lib_fd_tracker=no |
| | 904 | build_lib_sessiond_comm=no |
| | 905 | build_lib_testpoint=no |
| | 906 | build_lib_ust_consumer=no |
| | 907 | |
| | 908 | # There is an overlap for enabled dependencies, but this makes everything |
| | 909 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| | 910 | # here. |
| | 911 | |
| | 912 | # Enable binary dependencies. |
| | 913 | AS_IF([test x$enable_bin_lttng != xno], |
| | 914 | [ |
| | 915 | build_lib_lttng_ctl=yes |
| | 916 | ] |
| | 917 | ) |
| | 918 | |
| | 919 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| | 920 | [ |
| | 921 | build_lib_consumer=yes |
| | 922 | build_lib_sessiond_comm=yes |
| | 923 | build_lib_index=yes |
| | 924 | build_lib_health=yes |
| | 925 | build_lib_testpoint=yes |
| | 926 | ] |
| | 927 | ) |
| | 928 | |
| | 929 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| | 930 | # Do nothing since libconfig and libcommon are built by default. |
| | 931 | [] |
| | 932 | ) |
| | 933 | |
| | 934 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| | 935 | [ |
| | 936 | build_lib_lttng_ctl=yes |
| | 937 | build_lib_sessiond_comm=yes |
| | 938 | build_lib_hashtable=yes |
| | 939 | build_lib_compat=yes |
| | 940 | build_lib_index=yes |
| | 941 | build_lib_health=yes |
| | 942 | build_lib_testpoint=yes |
| | 943 | build_lib_fd_tracker=yes |
| | 944 | ] |
| | 945 | ) |
| | 946 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| | 947 | [ |
| | 948 | build_lib_lttng_ctl=yes |
| | 949 | build_lib_sessiond_comm=yes |
| | 950 | build_lib_kernel_ctl=yes |
| | 951 | build_lib_hashtable=yes |
| | 952 | build_lib_compat=yes |
| | 953 | build_lib_relayd=yes |
| | 954 | build_lib_testpoint=yes |
| | 955 | build_lib_health=yes |
| | 956 | ] |
| | 957 | ) |
| | 958 | |
| | 959 | # Libraries dependencies enabling |
| | 960 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| | 961 | [ |
| | 962 | build_lib_sessiond_comm=yes |
| | 963 | build_lib_hashtable=yes |
| | 964 | ] |
| | 965 | ) |
| | 966 | |
| | 967 | AS_IF([test x$build_lib_consumer = xyes], |
| | 968 | [ |
| | 969 | build_lib_sessiond_comm=yes |
| | 970 | build_lib_kernel_consumer=yes |
| | 971 | build_lib_hashtable=yes |
| | 972 | build_lib_compat=yes |
| | 973 | build_lib_relayd=yes |
| | 974 | AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes]) |
| | 975 | ] |
| | 976 | ) |
| | 977 | |
| | 978 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| | 979 | [ |
| | 980 | build_lib_kernel_ctl=yes |
| | 981 | build_lib_relayd=yes |
| | 982 | ] |
| | 983 | ) |
| | 984 | |
| | 985 | AS_IF([test x$build_lib_relayd = xyes], |
| | 986 | [ |
| | 987 | build_lib_sessiond_comm=yes |
| | 988 | ] |
| | 989 | ) |
| | 990 | |
| | 991 | # Find arch type |
| | 992 | AS_CASE([$host_cpu], |
| | 993 | [k1om], [ARCHTYPE="x86"], |
| | 994 | [i386], [ARCHTYPE="x86"], |
| | 995 | [i486], [ARCHTYPE="x86"], |
| | 996 | [i586], [ARCHTYPE="x86"], |
| | 997 | [i686], [ARCHTYPE="x86"], |
| | 998 | [amd64], [ARCHTYPE="x86"], |
| | 999 | [x86_64], [ARCHTYPE="x86"], |
| | 1000 | [powerpc], [ARCHTYPE="ppc"], |
| | 1001 | [ppc64], [ARCHTYPE="ppc"], |
| | 1002 | [powerpc64], [ARCHTYPE="ppc"], |
| | 1003 | [powerpc64le], [ARCHTYPE="ppc"], |
| | 1004 | [ppc], [ARCHTYPE="ppc"], |
| | 1005 | [s390], [ARCHTYPE="s390"], |
| | 1006 | [s390x], [ARCHTYPE="s390"], |
| | 1007 | [sparc], [ARCHTYPE="sparc64"], |
| | 1008 | [sparc64], [ARCHTYPE="sparc64"], |
| | 1009 | [alpha*], [ARCHTYPE="alpha"], |
| | 1010 | [ia64], [ARCHTYPE="ia64"], |
| | 1011 | [arm*], [ARCHTYPE="arm"], |
| | 1012 | [aarch64*], [ARCHTYPE="aarch64"], |
| | 1013 | [mips*], [ARCHTYPE="mips"], |
| | 1014 | [nios2*], [ARCHTYPE="nios2"], |
| | 1015 | [tile*], [ARCHTYPE="tile"], |
| | 1016 | [hppa*], [ARCHTYPE="hppa"], |
| | 1017 | [m68k], [ARCHTYPE="m68k"], |
| | 1018 | [riscv*], [ARCHTYPE="riscv"], |
| | 1019 | [ARCHTYPE="unknown"] |
| | 1020 | ) |
| | 1021 | |
| | 1022 | AC_SUBST(ARCHTYPE) |
| | 1023 | |
| | 1024 | AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support]) |
| | 1025 | AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel]) |
| | 1026 | AS_IF([test "x$ARCHTYPE" = "xx86"],[ |
| | 1027 | # Userspace callstack capture is only supported by the Linux kernel on x86. |
| | 1028 | AC_MSG_RESULT([yes]) |
| | 1029 | have_modules_userspace_callstack_context=yes |
| | 1030 | AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1]) |
| | 1031 | ], [ |
| | 1032 | AC_MSG_RESULT([no]) |
| | 1033 | have_modules_userspace_callstack_context=no |
| | 1034 | ]) |
| | 1035 | AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno]) |
| | 1036 | |
| | 1037 | # Export binaries build conditions. |
| | 1038 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| | 1039 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| | 1040 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| | 1041 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| | 1042 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| | 1043 | |
| | 1044 | # Export the tests and extras build conditions. |
| | 1045 | AS_IF([\ |
| | 1046 | test "x$enable_bin_lttng" != "xno" && \ |
| | 1047 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| | 1048 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| | 1049 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| | 1050 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| | 1051 | [build_tests=yes], |
| | 1052 | [build_tests=no] |
| | 1053 | ) |
| | 1054 | |
| | 1055 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| | 1056 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| | 1057 | |
| | 1058 | # Export libraries build conditions. |
| | 1059 | AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes]) |
| | 1060 | AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes]) |
| | 1061 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| | 1062 | AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes]) |
| | 1063 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| | 1064 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| | 1065 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| | 1066 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| | 1067 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| | 1068 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| | 1069 | AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes]) |
| | 1070 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| | 1071 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| | 1072 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| | 1073 | |
| | 1074 | AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS" |
| | 1075 | AC_SUBST(AM_CFLAGS) |
| | 1076 | |
| | 1077 | # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...". |
| | 1078 | AM_LDFLAGS="" |
| | 1079 | AC_SUBST(AM_LDFLAGS) |
| | 1080 | |
| | 1081 | # The order in which the include folders are searched is important. |
| | 1082 | # The top_builddir should always be searched first in the event that a build |
| | 1083 | # time generated file is included. An example of this is the "version.i" file. |
| | 1084 | # In a scenario where lttng-tools is built from a distribution tarball and in a |
| | 1085 | # out-of-tree manner, the generated "version.i" has priority on the one from |
| | 1086 | # the source (distribution tarball) and must be found first. |
| | 1087 | AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS" |
| | 1088 | AC_SUBST(AM_CPPFLAGS) |
| | 1089 | |
| | 1090 | lttngincludedir="${includedir}/lttng" |
| | 1091 | AC_SUBST(lttngincludedir) |
| | 1092 | |
| | 1093 | lttngactionincludedir="${includedir}/lttng/action" |
| | 1094 | AC_SUBST(lttngactionincludedir) |
| | 1095 | |
| | 1096 | lttngconditionincludedir="${includedir}/lttng/condition" |
| | 1097 | AC_SUBST(lttngconditionincludedir) |
| | 1098 | |
| | 1099 | lttngnotificationincludedir="${includedir}/lttng/notification" |
| | 1100 | AC_SUBST(lttngnotificationincludedir) |
| | 1101 | |
| | 1102 | lttngtriggerincludedir="${includedir}/lttng/trigger" |
| | 1103 | AC_SUBST(lttngtriggerincludedir) |
| | 1104 | |
| | 1105 | lttnglibexecdir="${libdir}/lttng/libexec" |
| | 1106 | AC_SUBST(lttnglibexecdir) |
| | 1107 | |
| | 1108 | AC_CONFIG_FILES([ |
| | 1109 | Makefile |
| | 1110 | doc/Makefile |
| | 1111 | doc/man/Makefile |
| | 1112 | doc/man/asciidoc-attrs.conf |
| | 1113 | include/Makefile |
| | 1114 | extras/Makefile |
| | 1115 | extras/bindings/Makefile |
| | 1116 | extras/bindings/swig/Makefile |
| | 1117 | extras/bindings/swig/python/Makefile |
| | 1118 | extras/core-handler/Makefile |
| | 1119 | src/Makefile |
| | 1120 | src/common/Makefile |
| | 1121 | src/common/kernel-ctl/Makefile |
| | 1122 | src/common/kernel-consumer/Makefile |
| | 1123 | src/common/consumer/Makefile |
| | 1124 | src/common/ust-consumer/Makefile |
| | 1125 | src/common/hashtable/Makefile |
| | 1126 | src/common/sessiond-comm/Makefile |
| | 1127 | src/common/compat/Makefile |
| | 1128 | src/common/relayd/Makefile |
| | 1129 | src/common/testpoint/Makefile |
| | 1130 | src/common/index/Makefile |
| | 1131 | src/common/health/Makefile |
| | 1132 | src/common/config/Makefile |
| | 1133 | src/common/string-utils/Makefile |
| | 1134 | src/common/fd-tracker/Makefile |
| | 1135 | src/common/filter/Makefile |
| | 1136 | src/lib/Makefile |
| | 1137 | src/lib/lttng-ctl/Makefile |
| | 1138 | src/lib/lttng-ctl/lttng-ctl.pc |
| | 1139 | src/bin/Makefile |
| | 1140 | src/bin/lttng-consumerd/Makefile |
| | 1141 | src/bin/lttng-sessiond/Makefile |
| | 1142 | src/bin/lttng-relayd/Makefile |
| | 1143 | src/bin/lttng/Makefile |
| | 1144 | src/bin/lttng-crash/Makefile |
| | 1145 | tests/Makefile |
| | 1146 | tests/destructive/Makefile |
| | 1147 | tests/regression/Makefile |
| | 1148 | tests/regression/kernel/Makefile |
| | 1149 | tests/regression/tools/Makefile |
| | 1150 | tests/regression/tools/streaming/Makefile |
| | 1151 | tests/regression/tools/filtering/Makefile |
| | 1152 | tests/regression/tools/health/Makefile |
| | 1153 | tests/regression/tools/tracefile-limits/Makefile |
| | 1154 | tests/regression/tools/snapshots/Makefile |
| | 1155 | tests/regression/tools/live/Makefile |
| | 1156 | tests/regression/tools/exclusion/Makefile |
| | 1157 | tests/regression/tools/save-load/Makefile |
| | 1158 | tests/regression/tools/save-load/configuration/Makefile |
| | 1159 | tests/regression/tools/mi/Makefile |
| | 1160 | tests/regression/tools/wildcard/Makefile |
| | 1161 | tests/regression/tools/crash/Makefile |
| | 1162 | tests/regression/tools/regen-metadata/Makefile |
| | 1163 | tests/regression/tools/regen-statedump/Makefile |
| | 1164 | tests/regression/tools/notification/Makefile |
| | 1165 | tests/regression/tools/rotation/Makefile |
| | 1166 | tests/regression/tools/base-path/Makefile |
| | 1167 | tests/regression/tools/metadata/Makefile |
| | 1168 | tests/regression/tools/tracker/Makefile |
| | 1169 | tests/regression/tools/working-directory/Makefile |
| | 1170 | tests/regression/tools/relayd-grouping/Makefile |
| | 1171 | tests/regression/tools/clear/Makefile |
| | 1172 | tests/regression/ust/Makefile |
| | 1173 | tests/regression/ust/nprocesses/Makefile |
| | 1174 | tests/regression/ust/high-throughput/Makefile |
| | 1175 | tests/regression/ust/low-throughput/Makefile |
| | 1176 | tests/regression/ust/before-after/Makefile |
| | 1177 | tests/regression/ust/buffers-pid/Makefile |
| | 1178 | tests/regression/ust/periodical-metadata-flush/Makefile |
| | 1179 | tests/regression/ust/multi-session/Makefile |
| | 1180 | tests/regression/ust/multi-lib/Makefile |
| | 1181 | tests/regression/ust/overlap/Makefile |
| | 1182 | tests/regression/ust/overlap/demo/Makefile |
| | 1183 | tests/regression/ust/linking/Makefile |
| | 1184 | tests/regression/ust/daemon/Makefile |
| | 1185 | tests/regression/ust/exit-fast/Makefile |
| | 1186 | tests/regression/ust/fork/Makefile |
| | 1187 | tests/regression/ust/libc-wrapper/Makefile |
| | 1188 | tests/regression/ust/baddr-statedump/Makefile |
| | 1189 | tests/regression/ust/ust-dl/Makefile |
| | 1190 | tests/regression/ust/java-jul/Makefile |
| | 1191 | tests/regression/ust/java-log4j/Makefile |
| | 1192 | tests/regression/ust/python-logging/Makefile |
| | 1193 | tests/regression/ust/getcpu-override/Makefile |
| | 1194 | tests/regression/ust/clock-override/Makefile |
| | 1195 | tests/regression/ust/type-declarations/Makefile |
| | 1196 | tests/regression/ust/rotation-destroy-flush/Makefile |
| | 1197 | tests/regression/ust/blocking/Makefile |
| | 1198 | tests/regression/ust/namespaces/Makefile |
| | 1199 | tests/stress/Makefile |
| | 1200 | tests/unit/Makefile |
| | 1201 | tests/unit/ini_config/Makefile |
| | 1202 | tests/perf/Makefile |
| | 1203 | tests/utils/Makefile |
| | 1204 | tests/utils/tap/Makefile |
| | 1205 | tests/utils/testapp/Makefile |
| | 1206 | tests/utils/testapp/gen-ns-events/Makefile |
| | 1207 | tests/utils/testapp/gen-kernel-test-events/Makefile |
| | 1208 | tests/utils/testapp/gen-ust-events/Makefile |
| | 1209 | tests/utils/testapp/gen-ust-events-ns/Makefile |
| | 1210 | tests/utils/testapp/gen-syscall-events-callstack/Makefile |
| | 1211 | tests/utils/testapp/gen-ust-nevents/Makefile |
| | 1212 | tests/utils/testapp/gen-ust-nevents-str/Makefile |
| | 1213 | tests/utils/testapp/gen-syscall-events/Makefile |
| | 1214 | tests/utils/testapp/gen-ust-tracef/Makefile |
| | 1215 | tests/utils/testapp/userspace-probe-elf-binary/Makefile |
| | 1216 | tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile |
| | 1217 | tests/utils/testapp/userspace-probe-sdt-binary/Makefile |
| | 1218 | ]) |
| | 1219 | |
| | 1220 | # Inject variable into python test script. |
| | 1221 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| | 1222 | # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script. |
| | 1223 | AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw]) |
| | 1224 | AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl]) |
| | 1225 | |
| | 1226 | AC_OUTPUT |
| | 1227 | |
| | 1228 | # |
| | 1229 | # Mini-report on what will be built. |
| | 1230 | # |
| | 1231 | |
| | 1232 | PPRINT_INIT |
| | 1233 | PPRINT_SET_INDENT(1) |
| | 1234 | PPRINT_SET_TS(38) |
| | 1235 | |
| | 1236 | AS_ECHO |
| | 1237 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| | 1238 | AS_ECHO |
| | 1239 | |
| | 1240 | AS_IF([test -n "$report_fold"], [ |
| | 1241 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| | 1242 | ], [ |
| | 1243 | AS_ECHO("$version_description") |
| | 1244 | ]) |
| | 1245 | |
| | 1246 | AS_ECHO |
| | 1247 | PPRINT_SUBTITLE([Features]) |
| | 1248 | |
| | 1249 | # Target architecture we're building for. |
| | 1250 | target_arch=$host_cpu |
| | 1251 | [ |
| | 1252 | for f in $CFLAGS; do |
| | 1253 | if test $f = "-m32"; then |
| | 1254 | target_arch="32-bit" |
| | 1255 | elif test $f = "-m64"; then |
| | 1256 | target_arch="64-bit" |
| | 1257 | fi |
| | 1258 | done |
| | 1259 | ] |
| | 1260 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| | 1261 | |
| | 1262 | # kmod enabled/disabled |
| | 1263 | test "x$with_kmod" != "xno" && value=1 || value=0 |
| | 1264 | PPRINT_PROP_BOOL([libkmod support], $value) |
| | 1265 | |
| | 1266 | # LTTng-UST enabled/disabled |
| | 1267 | test "x$with_lttng_ust" = "xyes" && value=1 || value=0 |
| | 1268 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| | 1269 | |
| | 1270 | AS_ECHO |
| | 1271 | PPRINT_SUBTITLE([Binaries]) |
| | 1272 | |
| | 1273 | # List binaries to be built |
| | 1274 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| | 1275 | PPRINT_PROP_BOOL([lttng], $value) |
| | 1276 | |
| | 1277 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| | 1278 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| | 1279 | |
| | 1280 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| | 1281 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| | 1282 | |
| | 1283 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| | 1284 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| | 1285 | |
| | 1286 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| | 1287 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| | 1288 | |
| | 1289 | # Extras |
| | 1290 | test x$enable_extras != xno && value=1 || value=0 |
| | 1291 | AS_ECHO |
| | 1292 | PPRINT_SET_INDENT(0) |
| | 1293 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1294 | PPRINT_SET_INDENT(1) |
| | 1295 | |
| | 1296 | AS_ECHO |
| | 1297 | PPRINT_SUBTITLE([Tests]) |
| | 1298 | |
| | 1299 | # Print clear message that tests won't be built |
| | 1300 | AS_IF([test "x$build_tests" = "xno"],[ |
| | 1301 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| | 1302 | ]) |
| | 1303 | |
| | 1304 | # LTTng UST Java agent JUL tests enabled/disabled |
| | 1305 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| | 1306 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| | 1307 | |
| | 1308 | # LTTng UST Java agent Log4j tests enabled/disabled |
| | 1309 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| | 1310 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value) |
| | 1311 | |
| | 1312 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| | 1313 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| | 1314 | |
| | 1315 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| | 1316 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| | 1317 | |
| | 1318 | # LTTng UST Java agent Log4j tests enabled/disabled |
| | 1319 | test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0 |
| | 1320 | PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value) |
| | 1321 | |
| | 1322 | #Python binding enabled/disabled |
| | 1323 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| | 1324 | AS_ECHO |
| | 1325 | PPRINT_SET_INDENT(0) |
| | 1326 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1327 | |
| | 1328 | # man pages build enabled/disabled |
| | 1329 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| | 1330 | |
| | 1331 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| | 1332 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 1333 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1334 | ], [ |
| | 1335 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| | 1336 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1337 | ], [ |
| | 1338 | PPRINT_PROP_STRING([build_man_pages_msg], |
| | 1339 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| | 1340 | $PPRINT_COLOR_SUBTITLE) |
| | 1341 | ]) |
| | 1342 | ]) |
| | 1343 | ], [ |
| | 1344 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| | 1345 | ]) |
| | 1346 | |
| | 1347 | m4_popdef([build_man_pages_msg]) |
| | 1348 | |
| | 1349 | test "x$embedded_help" = xyes && value=1 || value=0 |
| | 1350 | PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1351 | |
| | 1352 | PPRINT_SET_INDENT(1) |
| | 1353 | |
| | 1354 | report_bindir="`eval eval echo $bindir`" |
| | 1355 | report_libdir="`eval eval echo $libdir`" |
| | 1356 | |
| | 1357 | # Print the bindir and libdir this `make install' will install into. |
| | 1358 | AS_ECHO |
| | 1359 | PPRINT_SUBTITLE([Install directories]) |
| | 1360 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| | 1361 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| | 1362 | |
| | 1363 | AS_ECHO |
| | 1364 | PPRINT_SUBTITLE([Search directories]) |
| | 1365 | |
| | 1366 | # If we build the sessiond, print the paths it will use |
| | 1367 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| | 1368 | path="$report_bindir/lttng-sessiond" |
| | 1369 | ],[ |
| | 1370 | path="$SESSIOND_BIN" |
| | 1371 | ]) |
| | 1372 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| | 1373 | |
| | 1374 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| | 1375 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1376 | ],[ |
| | 1377 | path="$CONSUMERD32_BIN" |
| | 1378 | ]) |
| | 1379 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| | 1380 | |
| | 1381 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| | 1382 | path="`eval eval echo $libdir`" |
| | 1383 | ],[ |
| | 1384 | path="$CONSUMERD32_LIBDIR" |
| | 1385 | ]) |
| | 1386 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| | 1387 | |
| | 1388 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| | 1389 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1390 | ],[ |
| | 1391 | path="$CONSUMERD64_BIN" |
| | 1392 | ]) |
| | 1393 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| | 1394 | |
| | 1395 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| | 1396 | path="`eval eval echo $libdir`" |
| | 1397 | ],[ |
| | 1398 | path="$CONSUMERD64_LIBDIR" |
| | 1399 | ]) |
| | 1400 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |
| | 1401 | PPRINT_SET_INDENT(0) |
| | 1402 | |
| | 1403 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ |
| | 1404 | AS_ECHO |
| | 1405 | PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages. |
| | 1406 | |
| | 1407 | Note that the man pages are already built in this distribution tarball, |
| | 1408 | therefore asciidoc and xmlto are only needed if you intend to modify |
| | 1409 | their sources. |
| | 1410 | |
| | 1411 | Also note that the installed man pages will contain the project's |
| | 1412 | default command-line option and environment variable values. |
| | 1413 | |
| | 1414 | Use --disable-man-pages to completely disable building and installing |
| | 1415 | the man pages.]) |
| | 1416 | ]) |
projects / lttng-tools.git / blame_incremental