projects / lttng-tools.git / blame_incremental
? search:
summary | shortlog | log | commit | commitdiff | tree
blob | blame (non-incremental) | history | HEAD
Fix: Don't override user variables within the build system
[lttng-tools.git] / configure.ac
... / ...
CommitLineData
1AC_PREREQ([2.64])
2AC_INIT([lttng-tools],[2.10.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4AC_CONFIG_HEADERS([include/config.h])
5AC_CONFIG_AUX_DIR([config])
6AC_CONFIG_MACRO_DIR([m4])
7
8AC_CANONICAL_TARGET
9AC_CANONICAL_HOST
10
11AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
12AM_MAINTAINER_MODE([enable])
13
14# Enable silent rules if available (Introduced in AM 1.11)
15m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19# Checks for C compiler
20AC_USE_SYSTEM_EXTENSIONS
21AC_SYS_LARGEFILE
22AC_PROG_CC
23AC_PROG_CC_STDC
24
25# Checks for programs.
26AC_PROG_GREP
27AC_PROG_LEX
28AC_PROG_MAKE_SET
29AC_PROG_SED
30AC_PROG_YACC
31AC_PATH_PROG(report_fold, fold)
32LT_INIT
33
34# Check for objcopy, required by the base address statedump and dynamic linker tests
35AC_CHECK_TOOL([OBJCOPY], objcopy, no)
36AS_IF([test "x$OBJCOPY" = xno],
37 [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
38)
39AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
40
41# Checks for typedefs, structures, and compiler characteristics.
42AC_C_INLINE
43AC_TYPE_INT32_T
44AC_TYPE_INT64_T
45AC_TYPE_MODE_T
46AC_TYPE_OFF_T
47AC_TYPE_PID_T
48AC_TYPE_SIZE_T
49AC_TYPE_SSIZE_T
50AC_TYPE_UID_T
51AC_TYPE_UINT16_T
52AC_TYPE_UINT32_T
53AC_TYPE_UINT64_T
54AC_TYPE_UINT8_T
55
56AX_C___ATTRIBUTE__
57AS_IF([test "x$ax_cv___attribute__" = "xyes"],
58 [:],
59 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
60
61AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
62
63AX_LIB_SOCKET_NSL
64
65LT_NO_UNDEFINED=""
66AS_CASE([$host_os],
67 [cygwin*],
68 [
69 LT_NO_UNDEFINED="-no-undefined"
70 ]
71)
72
73AC_SUBST(LT_NO_UNDEFINED)
74
75# Compute minor/major/patchlevel version numbers
76major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
77minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
78patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
79
80AC_SUBST([MAJOR_VERSION], [$major_version])
81AC_SUBST([MINOR_VERSION], [$minor_version])
82AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
83AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
84AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
85AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
86
87version_name="KeKriek"
88version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
89version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
90
91AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
92AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
93
94# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
95AC_ARG_ENABLE(libtool-linkdep-fixup,
96 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
97 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
98 libtool_fixup=$enableval,
99 libtool_fixup=yes)
100
101AS_IF([test "x$libtool_fixup" = "xyes"],
102 [
103 libtool_m4="$srcdir/m4/libtool.m4"
104 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
105 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
106 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
107 AS_IF([test $libtool_flag_pattern_count -ne 0],
108 [
109 AC_MSG_RESULT([$libtool_flag_pattern_count])
110 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
111 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
112 ],
113 [
114 AC_MSG_RESULT([none])
115 ])
116 ])
117
118AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
119
120AC_CHECK_HEADERS([ \
121 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
122 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
123 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
124 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
125 sys/mount.h sys/param.h sys/time.h
126])
127
128# Basic functions check
129AC_CHECK_FUNCS([ \
130 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
131 gethostbyname gethostname getpagesize localtime_r memchr memset \
132 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
133 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
134 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
135])
136
137# Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
138# add -lrt to LIBS
139AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
140
141# Babeltrace viewer check
142AC_ARG_WITH([babeltrace-bin],
143 AS_HELP_STRING([--with-babeltrace-bin],
144 [Location of the babeltrace viewer executable (including the filename)]),
145 [BABELTRACE_BIN="$withval"],
146 [BABELTRACE_BIN=''])
147AC_SUBST([BABELTRACE_BIN])
148
149# lttv-gui
150AC_ARG_WITH([lttv-gui-bin],
151 AS_HELP_STRING([--with-lttv-gui-bin],
152 [Location of the lttv GUI viewer executable (including the filename)]),
153 [LTTV_GUI_BIN="$withval"],
154 [LTTV_GUI_BIN=''])
155AC_SUBST([LTTV_GUI_BIN])
156
157AC_ARG_WITH([consumerd32-bin],
158 AS_HELP_STRING([--with-consumerd32-bin],
159 [Location of the 32-bit consumerd executable (including the filename)]),
160 [CONSUMERD32_BIN="$withval"],
161 [CONSUMERD32_BIN=''])
162AC_SUBST([CONSUMERD32_BIN])
163
164AC_ARG_WITH([consumerd64-bin],
165 AS_HELP_STRING([--with-consumerd64-bin],
166 [Location of the 64-bit consumerd executable (including the filename)]),
167 [CONSUMERD64_BIN="$withval"],
168 [CONSUMERD64_BIN=''])
169AC_SUBST([CONSUMERD64_BIN])
170
171AC_ARG_WITH([consumerd32-libdir],
172 AS_HELP_STRING([--with-consumerd32-libdir],
173 [Directory containing the 32-bit consumerd libraries]),
174 [CONSUMERD32_LIBDIR="$withval"],
175 [CONSUMERD32_LIBDIR=''])
176AC_SUBST([CONSUMERD32_LIBDIR])
177
178AC_ARG_WITH([consumerd64-libdir],
179 AS_HELP_STRING([--with-consumerd64-libdir],
180 [Directory containing the 64-bit consumerd libraries]),
181 [CONSUMERD64_LIBDIR="$withval"],
182 [CONSUMERD64_LIBDIR=''])
183AC_SUBST([CONSUMERD64_LIBDIR])
184
185AC_ARG_WITH([sessiond-bin],
186 AS_HELP_STRING([--with-sessiond-bin],
187 [Location of the sessiond executable (including the filename)]),
188 [SESSIOND_BIN="$withval"],
189 [SESSIOND_BIN=''])
190AC_SUBST([SESSIOND_BIN])
191
192AC_ARG_WITH([lttng-system-rundir],
193 AS_HELP_STRING([--with-lttng-system-rundir],
194 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
195 [LTTNG_SYSTEM_RUNDIR="$withval"],
196 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
197AC_SUBST([LTTNG_SYSTEM_RUNDIR])
198
199AC_ARG_ENABLE([test-java-agent-jul],
200 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
201 [test_java_agent_jul=$enableval],
202 [test_java_agent_jul=no]
203)
204
205AC_ARG_ENABLE([test-java-agent-log4j],
206 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
207 [test_java_agent_log4j=$enableval],
208 [test_java_agent_log4j=no]
209)
210
211AC_ARG_ENABLE([test-java-agent-all],
212 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
213 [test_java_agent_jul=$enableval
214 test_java_agent_log4j=$enableval],
215 [:]
216)
217
218AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
219AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
220AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
221AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
222AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
223AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
224AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
225AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
226
227AC_DEFUN([_AC_DEFINE_AND_SUBST], [
228 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
229 $1="$2"
230 AC_SUBST([$1])
231])
232
233AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
234 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
235 $1="$2"
236 AC_SUBST([$1])
237])
238
239# Default values
240m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
241m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
242m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
243m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
244m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
245m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
246_AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
247_AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
248_AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
249_AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
250_AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
251_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
252_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
253_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
254_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
255_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
256_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
257_AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
258_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
259_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
260_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
261_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
262_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
263_AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
264_AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
265_AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
266_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
267_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
268_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
269_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
270_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
271_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
272_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
273_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
274_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
275_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
276_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
277_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
278_AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
279_AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
280_AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
281_AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
282
283# Command short descriptions
284_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
285_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
286_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
287_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
288_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
289_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
290_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
291_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
292_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
293_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
294_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
295_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
296_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
297_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
298_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
299_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
300_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
301_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
302_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
303_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
304_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
305
306if test "x$prefix" = "xNONE"; then
307 prefix=$ac_default_prefix
308fi
309CONFDIR=`eval echo $sysconfdir`
310AC_SUBST(CONFDIR)
311AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
312
313AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
314
315#
316# Check for pthread
317AC_CHECK_LIB([pthread], [pthread_create], [],
318 [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
319)
320
321# Check libpopt
322PKG_CHECK_MODULES([POPT], [popt],
323 [LIBS="$LIBS $POPT_LIBS"],
324 [
325 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
326 AC_MSG_WARN([Finding libpopt without pkg-config.])
327 AC_CHECK_LIB([popt],
328 [poptGetContext],
329 [],
330 [
331 AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
332 ]
333 )
334 ]
335)
336
337PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
338
339# Check for uuid in system libs
340AC_CHECK_FUNCS([uuid_generate],
341[
342 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
343 link_with_libuuid=no
344],
345[
346# First, check the pkg-config module is available, otherwise explicitly check
347# for libuuid, or uuid support in the C-library.
348PKG_CHECK_MODULES([UUID], [uuid],
349[
350 LIBS="$LIBS $UUID_LIBS"
351 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
352 link_with_libuuid=yes
353],
354[
355 # Check for libuuid
356 AC_CHECK_LIB([uuid],
357 [uuid_generate],
358 [
359 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
360 link_with_libuuid=yes
361 ],
362 [
363 # libuuid not found, check for uuid_create in libc.
364 AC_CHECK_LIB([c],
365 [uuid_create],
366 [
367 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
368 link_with_libc_uuid=yes
369 ],
370 [
371 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
372 ]
373 )
374 ]
375 )
376])
377])
378
379AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
380AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
381
382AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
383
384# URCU library version needed or newer
385m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
386
387# Check liburcu needed function calls
388AC_CHECK_DECL([cds_list_add], [],
389 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
390AC_CHECK_DECL([cds_wfcq_init], [],
391 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
392AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
393 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
394AC_CHECK_DECL([futex_async], [],
395 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
396AC_CHECK_DECL([rcu_thread_offline], [],
397 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
398AC_CHECK_DECL([rcu_thread_online], [],
399 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
400AC_CHECK_DECL([caa_likely], [],
401 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
402AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
403 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
404
405#Function added in urcu 0.7.0
406AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
407 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
408)
409
410# Check kmod library
411AC_ARG_WITH(kmod-prefix,
412 AS_HELP_STRING([--with-kmod-prefix=PATH],
413 [Specify the installation prefix of the kmod library.
414 Headers must be in PATH/include; libraries in PATH/lib.]),
415 [
416 AM_CPPFLAGS="$AM_CPPFLAGS -I${withval}/include"
417 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
418 ])
419
420AC_ARG_ENABLE(kmod,
421 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
422 kmod_support=$enableval, kmod_support=yes)
423
424AS_IF([test "x$kmod_support" = "xyes"], [
425 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
426 [
427 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
428 LIBS="$LIBS -lkmod"
429 kmod_found=yes
430 ],
431 kmod_found=no
432 )
433])
434AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
435
436AC_ARG_WITH(lttng-ust-prefix,
437 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
438 [Specify the installation prefix of the lttng-ust library.
439 Headers must be in PATH/include; libraries in PATH/lib.]),
440 [
441 AM_CPPFLAGS="$AM_CPPFLAGS -I${withval}/include"
442 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
443 ])
444
445# Check liblttng-ust-ctl library
446AC_ARG_WITH(lttng-ust,
447 AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
448 lttng_ust_support=$withval, lttng_ust_support=yes)
449
450AS_IF([test "x$lttng_ust_support" = "xyes"], [
451 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
452 [
453 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
454 lttng_ust_ctl_found=yes
455 ],
456 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
457 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
458 )
459])
460AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
461AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
462
463# check for dlopen
464AC_CHECK_LIB([dl], [dlopen],
465[
466 have_libdl=yes
467],
468[
469 #libdl not found, check for dlopen in libc.
470 AC_CHECK_LIB([c], [dlopen],
471 [
472 have_libc_dl=yes
473 ],
474 [
475 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
476 ])
477])
478AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
479AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
480
481# Check for fmemopen
482AC_CHECK_LIB([c], [fmemopen],
483[
484 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
485]
486)
487
488# Check for open_memstream
489AC_CHECK_LIB([c], [open_memstream],
490[
491 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
492]
493)
494
495# check for libpfm
496AC_CHECK_LIB([pfm], [pfm_initialize],
497 [
498 have_libpfm=yes
499 ])
500AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
501
502AC_ARG_ENABLE([git-version],
503 [AC_HELP_STRING([--disable-git-version],
504 [Do not use the git version for the build])],
505 [have_git_version=$enableval], [have_git_version=yes]
506)
507
508AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
509 [test "x${have_git_version}" = "xyes"])
510
511# For Python
512# SWIG version needed or newer:
513swig_version=2.0.0
514
515AC_ARG_ENABLE([python-bindings],
516 [AC_HELP_STRING([--enable-python-bindings],
517 [compile Python bindings])],
518 [enable_python_binding=$enableval], [enable_python_binding=no])
519
520AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
521
522if test "x$enable_python_binding" = xyes; then
523 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
524 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
525 AM_PATH_PYTHON([3.0])
526
527 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
528 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
529 AS_IF([test -z "$PYTHON_INCLUDE"], [
530 AS_IF([test -z "$PYTHON_CONFIG"], [
531 AC_PATH_PROGS([PYTHON_CONFIG],
532 [python$PYTHON_VERSION-config python-config],
533 [no],
534 [`dirname $PYTHON`])
535 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
536 ])
537 AC_MSG_CHECKING([python include flags])
538 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
539 AC_MSG_RESULT([$PYTHON_INCLUDE])
540 ])
541
542else
543 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
544[if you want Python bindings.])
545
546fi
547
548# Epoll check. If not present, the build will fallback on poll() API
549AX_HAVE_EPOLL(
550 [AX_CONFIG_FEATURE_ENABLE(epoll)],
551 [AX_CONFIG_FEATURE_DISABLE(epoll)]
552)
553AX_CONFIG_FEATURE(
554 [epoll], [This platform supports epoll(7)],
555 [HAVE_EPOLL], [This platform supports epoll(7).],
556 [enable_epoll="yes"], [enable_epoll="no"]
557)
558AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
559
560AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
561AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
562
563if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
564 AX_JAVA_OPTIONS
565 AX_PROG_JAVAC
566 AX_PROG_JAVA
567 AX_PROG_JAR
568
569 AX_CHECK_CLASSPATH
570
571 # Check for Java UST agent common class first
572 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
573 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
574 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
575 fi
576
577 if test "x$test_java_agent_jul" = "xyes"; then
578 # Check for JUL agent class
579 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
580 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
581 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
582 fi
583 fi
584
585 if test "x$test_java_agent_log4j" = "xyes"; then
586 # Check for Log4j agent class
587 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
588 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
589 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
590 fi
591
592 # Check for Log4j class
593 AX_CHECK_CLASS(org.apache.log4j.Logger)
594 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
595 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
596 fi
597 fi
598fi
599
600# set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
601# is not distributed in tarballs
602AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
603AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
604
605# enable building man pages (user's intention)
606AC_ARG_ENABLE(
607 man-pages,
608 AS_HELP_STRING(
609 [--disable-man-pages],
610 [Do not build and install man pages (already built in a distributed tarball)]
611 ),
612 [man_pages_opt=$enableval],
613 [man_pages_opt=yes]
614)
615
616# check for asciidoc and xmlto if we enabled building the man pages
617have_asciidoc_xmlto=no
618warn_prebuilt_man_pages=no
619
620AS_IF([test "x$man_pages_opt" = "xyes"], [
621 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
622 AC_PATH_PROG([XMLTO], [xmlto], [no])
623
624 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
625 AS_IF([test "x$in_git_repo" = "xyes"], [
626 # this is an error because we're in the Git repo, which
627 # means the man pages are not already generated for us,
628 # thus asciidoc/xmlto are required because we were asked
629 # to build the man pages
630 AC_MSG_ERROR([
631You need asciidoc and xmlto to build the LTTng-tools man pages. Use
632--disable-man-pages to disable building the man pages, in which case
633they will not be installed.
634 ])
635 ], [
636 # only warn here: since we're in the tarball, the man
637 # pages should already be generated at this point, thus
638 # asciidoc/xmlto are not strictly required
639 warn_prebuilt_man_pages=yes
640 ])
641 ], [
642 have_asciidoc_xmlto=yes
643 ])
644])
645
646# export man page build condition: build the man pages if the user
647# asked for it, and if the tools are available
648AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
649AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
650
651AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
652
653# embedded --help message
654AC_ARG_ENABLE(
655 [embedded-help],
656 AS_HELP_STRING(
657 [--enable-embedded-help],
658 [Embed the --help messages in the executable files]
659 ),
660 [embedded_help=$enableval],
661 [embedded_help=no]
662)
663AS_IF([test "x$embedded_help" = "xyes"], [
664 AS_IF([test "x$man_pages_opt" = "xno"], [
665 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
666 ])
667 AC_PATH_PROG([man_prog_path], [man], [no])
668 AS_IF([test "x$man_prog_path" = "xno"], [
669 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
670 ])
671 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
672 AC_SUBST([MANPROG], [$man_prog_path])
673])
674AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
675
676# Python agent test
677UST_PYTHON_AGENT="lttngust"
678
679AC_ARG_ENABLE(test-python2-agent,
680 AS_HELP_STRING([--enable-test-python2-agent],
681 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
682 ),[:],[test_python2_agent_autodetect=yes]
683)
684
685AC_ARG_ENABLE(test-python3-agent,
686 AS_HELP_STRING([--enable-test-python3-agent],
687 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
688 ),[:],[test_python3_agent_autodetect=yes]
689)
690
691AC_ARG_ENABLE(test-python-agent-all,
692 AS_HELP_STRING([--enable-test-python-agent-all],
693 [enable test for all python{2/3} agent.]
694 ),
695)
696
697AS_IF([test ! -z "$enable_test_python_agent_all"], [
698 unset test_python2_agent_autodetect
699 unset test_python3_agent_autodetect
700])
701
702AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
703 enable_test_python2_agent=yes
704 enable_test_python3_agent=yes
705])
706
707AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
708 enable_test_python2_agent=no
709 enable_test_python3_agent=no
710])
711
712
713AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
714 AS_IF([test -z "$PYTHON2"], [
715 PYTHON2=python2
716 ], [
717 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
718 ])
719
720 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
721 AS_IF([test -z "$PYTHON2_BIN"], [
722 AS_IF([test -z "$test_python2_agent_autodetect"],[
723 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
724 ])
725 ], [
726 AC_MSG_CHECKING([for python2 lttng-ust agent])
727 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
728 PYTHON2_AGENT=$PYTHON2_BIN
729 AC_MSG_RESULT([yes])
730 RUN_PYTHON_AGENT_TEST=yes
731 ], [
732 AC_MSG_RESULT([no])
733 AS_IF([test -z "$test_python2_agent_autodetect"],[
734 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
735 ])
736 ])
737
738 ])
739
740])
741
742AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
743 AS_IF([test -z "$PYTHON3"], [
744 PYTHON3=python3
745 ], [
746 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
747 ])
748
749 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
750 AS_IF([test -z "$PYTHON3_BIN"], [
751 AS_IF([test -z "$test_python3_agent_autodetect"],[
752 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
753 ])
754 ], [
755 AC_MSG_CHECKING([for python3 lttng-ust agent])
756 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
757 PYTHON3_AGENT=$PYTHON3_BIN
758 AC_MSG_RESULT([yes])
759 RUN_PYTHON_AGENT_TEST=yes
760 ], [
761 AC_MSG_RESULT([no])
762 AS_IF([test -z "$test_python3_agent_autodetect"],[
763 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
764 ])
765 ])
766
767 ])
768])
769AC_SUBST([RUN_PYTHON_AGENT_TEST])
770AC_SUBST([PYTHON2_AGENT])
771AC_SUBST([PYTHON3_AGENT])
772
773# Arguments for binaries build exclusion
774AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
775AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
776 [Disable the build of lttng-consumerd binaries]))
777AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
778AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
779 [Disable the build of lttng-relayd binaries]))
780AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
781 [Disable the build of lttng-sessiond binaries]))
782AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
783 [Disable the build of the extra components]))
784
785
786# Always build libconfig since it a dependency of libcommon
787build_lib_config=yes
788
789build_lib_compat=no
790build_lib_consumer=no
791build_lib_hashtable=no
792build_lib_health=no
793build_lib_index=no
794build_lib_kernel_consumer=no
795build_lib_kernel_ctl=no
796build_lib_lttng_ctl=no
797build_lib_relayd=no
798build_lib_sessiond_comm=no
799build_lib_testpoint=no
800build_lib_ust_consumer=no
801
802# There is an overlap for enabled dependencies, but this makes everything
803# simpler. libcommon and libconfig are always compiled so they are not repeated
804# here.
805
806# Enable binary dependencies.
807AS_IF([test x$enable_bin_lttng != xno],
808 [
809 build_lib_lttng_ctl=yes
810 ]
811)
812
813AS_IF([test x$enable_bin_lttng_consumerd != xno],
814 [
815 build_lib_consumer=yes
816 build_lib_sessiond_comm=yes
817 build_lib_index=yes
818 build_lib_health=yes
819 build_lib_testpoint=yes
820 ]
821)
822
823AS_IF([test x$enable_bin_lttng_crash != xno],
824 # Do nothing since libconfig and libcommon are built by default.
825 []
826)
827
828AS_IF([test x$enable_bin_lttng_relayd != xno],
829 [
830 build_lib_lttng_ctl=yes
831 build_lib_sessiond_comm=yes
832 build_lib_hashtable=yes
833 build_lib_compat=yes
834 build_lib_index=yes
835 build_lib_health=yes
836 build_lib_testpoint=yes
837 ]
838)
839AS_IF([test x$enable_bin_lttng_sessiond != xno],
840 [
841 build_lib_lttng_ctl=yes
842 build_lib_sessiond_comm=yes
843 build_lib_kernel_ctl=yes
844 build_lib_hashtable=yes
845 build_lib_compat=yes
846 build_lib_relayd=yes
847 build_lib_testpoint=yes
848 build_lib_health=yes
849 build_lib_health=yes
850 ]
851)
852
853# Libraries dependencies enabling
854AS_IF([test x$build_lib_lttng_ctl = xyes],
855 [
856 build_lib_sessiond_comm=yes
857 build_lib_hashtable=yes
858 ]
859)
860
861AS_IF([test x$build_lib_consumer = xyes],
862 [
863 build_lib_sessiond_comm=yes
864 build_lib_kernel_consumer=yes
865 build_lib_hashtable=yes
866 build_lib_compat=yes
867 build_lib_relayd=yes
868 AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
869 ]
870)
871
872AS_IF([test x$build_lib_kernel_consumer = xyes],
873 [
874 build_lib_kernel_ctl=yes
875 build_lib_relayd=yes
876 ]
877)
878
879AS_IF([test x$build_lib_relayd = xyes],
880 [
881 build_lib_sessiond_comm=yes
882 ]
883)
884
885
886# Export binaries build conditions.
887AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
888AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
889AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
890AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
891AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
892
893# Export the tests and extras build conditions.
894AS_IF([\
895test "x$enable_bin_lttng" != "xno" && \
896test "x$enable_bin_lttng_consumerd" != "xno" && \
897test "x$enable_bin_lttng_crash" != "xno" && \
898test "x$enable_bin_lttng_relayd" != "xno" && \
899test "x$enable_bin_lttng_sessiond" != "xno"],
900[build_tests=yes],
901[build_tests=no]
902)
903
904AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
905AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
906
907# Export libraries build conditions.
908AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
909AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
910AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
911AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
912AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
913AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
914AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
915AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
916AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
917AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
918AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
919AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
920AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
921
922# check for pgrep
923AC_PATH_PROG([PGREP], [pgrep], [no])
924AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
925
926# check for bison
927have_bison=yes
928
929AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
930AC_PATH_PROG([BISON], [bison])
931AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
932
933AS_IF([test "x$have_bison" = "xno"], [
934 AS_IF([test "x$in_git_repo" = "xyes"], [
935 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
936 ], [
937 AC_MSG_WARN([
938Missing Bison >= 2.4. Note that the parser files are already built in
939this distribution tarball, so Bison is only needed if you intend to
940modify their sources.
941 ])
942 ])
943])
944
945# export bison condition
946AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
947
948# check for flex
949have_flex=yes
950
951AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
952AC_PATH_PROG([FLEX], [flex])
953AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
954
955AS_IF([test "x$have_flex" = "xno"], [
956 AS_IF([test "x$in_git_repo" = "xyes"], [
957 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
958 ], [
959 AC_MSG_WARN([
960Missing Flex >= 2.5.35. Note that the lexer files are already built in
961this distribution tarball, so Flex is only needed if you intend to
962modify their sources.
963 ])
964 ])
965])
966
967# export flex condition
968AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
969
970AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
971AC_SUBST(AM_CFLAGS)
972
973AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
974AC_SUBST(AM_CPPFLAGS)
975
976lttngincludedir="${includedir}/lttng"
977AC_SUBST(lttngincludedir)
978
979lttngactionincludedir="${includedir}/lttng/action"
980AC_SUBST(lttngactionincludedir)
981
982lttngconditionincludedir="${includedir}/lttng/condition"
983AC_SUBST(lttngconditionincludedir)
984
985lttngnotificationincludedir="${includedir}/lttng/notification"
986AC_SUBST(lttngnotificationincludedir)
987
988lttngtriggerincludedir="${includedir}/lttng/trigger"
989AC_SUBST(lttngtriggerincludedir)
990
991lttnglibexecdir="${libdir}/lttng/libexec"
992AC_SUBST(lttnglibexecdir)
993
994AC_CONFIG_FILES([
995 Makefile
996 doc/Makefile
997 doc/man/Makefile
998 doc/man/asciidoc-attrs.conf
999 include/Makefile
1000 extras/Makefile
1001 extras/bindings/Makefile
1002 extras/bindings/swig/Makefile
1003 extras/bindings/swig/python/Makefile
1004 extras/core-handler/Makefile
1005 src/Makefile
1006 src/common/Makefile
1007 src/common/kernel-ctl/Makefile
1008 src/common/kernel-consumer/Makefile
1009 src/common/consumer/Makefile
1010 src/common/ust-consumer/Makefile
1011 src/common/hashtable/Makefile
1012 src/common/sessiond-comm/Makefile
1013 src/common/compat/Makefile
1014 src/common/relayd/Makefile
1015 src/common/testpoint/Makefile
1016 src/common/index/Makefile
1017 src/common/health/Makefile
1018 src/common/config/Makefile
1019 src/common/string-utils/Makefile
1020 src/lib/Makefile
1021 src/lib/lttng-ctl/Makefile
1022 src/lib/lttng-ctl/filter/Makefile
1023 src/lib/lttng-ctl/lttng-ctl.pc
1024 src/bin/Makefile
1025 src/bin/lttng-consumerd/Makefile
1026 src/bin/lttng-sessiond/Makefile
1027 src/bin/lttng-relayd/Makefile
1028 src/bin/lttng/Makefile
1029 src/bin/lttng-crash/Makefile
1030 tests/Makefile
1031 tests/destructive/Makefile
1032 tests/regression/Makefile
1033 tests/regression/kernel/Makefile
1034 tests/regression/tools/Makefile
1035 tests/regression/tools/streaming/Makefile
1036 tests/regression/tools/filtering/Makefile
1037 tests/regression/tools/health/Makefile
1038 tests/regression/tools/tracefile-limits/Makefile
1039 tests/regression/tools/snapshots/Makefile
1040 tests/regression/tools/live/Makefile
1041 tests/regression/tools/exclusion/Makefile
1042 tests/regression/tools/save-load/Makefile
1043 tests/regression/tools/save-load/configuration/Makefile
1044 tests/regression/tools/mi/Makefile
1045 tests/regression/tools/wildcard/Makefile
1046 tests/regression/tools/crash/Makefile
1047 tests/regression/tools/regen-metadata/Makefile
1048 tests/regression/tools/regen-statedump/Makefile
1049 tests/regression/tools/notification/Makefile
1050 tests/regression/ust/Makefile
1051 tests/regression/ust/nprocesses/Makefile
1052 tests/regression/ust/high-throughput/Makefile
1053 tests/regression/ust/low-throughput/Makefile
1054 tests/regression/ust/before-after/Makefile
1055 tests/regression/ust/buffers-pid/Makefile
1056 tests/regression/ust/periodical-metadata-flush/Makefile
1057 tests/regression/ust/multi-session/Makefile
1058 tests/regression/ust/overlap/Makefile
1059 tests/regression/ust/overlap/demo/Makefile
1060 tests/regression/ust/linking/Makefile
1061 tests/regression/ust/daemon/Makefile
1062 tests/regression/ust/exit-fast/Makefile
1063 tests/regression/ust/fork/Makefile
1064 tests/regression/ust/libc-wrapper/Makefile
1065 tests/regression/ust/baddr-statedump/Makefile
1066 tests/regression/ust/ust-dl/Makefile
1067 tests/regression/ust/java-jul/Makefile
1068 tests/regression/ust/java-log4j/Makefile
1069 tests/regression/ust/python-logging/Makefile
1070 tests/regression/ust/getcpu-override/Makefile
1071 tests/regression/ust/clock-override/Makefile
1072 tests/regression/ust/type-declarations/Makefile
1073 tests/regression/ust/rotation-destroy-flush/Makefile
1074 tests/regression/ust/blocking/Makefile
1075 tests/stress/Makefile
1076 tests/unit/Makefile
1077 tests/unit/ini_config/Makefile
1078 tests/perf/Makefile
1079 tests/utils/Makefile
1080 tests/utils/tap/Makefile
1081 tests/utils/testapp/Makefile
1082 tests/utils/testapp/gen-ust-events/Makefile
1083 tests/utils/testapp/gen-ust-nevents/Makefile
1084 tests/utils/testapp/gen-ust-nevents-str/Makefile
1085 tests/utils/testapp/gen-ust-tracef/Makefile
1086])
1087
1088# Inject variable into python test script.
1089AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1090# Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1091AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1092
1093AC_OUTPUT
1094
1095#
1096# Mini-report on what will be built.
1097#
1098
1099PPRINT_INIT
1100PPRINT_SET_INDENT(1)
1101PPRINT_SET_TS(38)
1102
1103AS_ECHO
1104AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1105AS_ECHO
1106
1107AS_IF([test -n "$report_fold"], [
1108 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1109], [
1110 AS_ECHO("$version_description")
1111])
1112
1113AS_ECHO
1114PPRINT_SUBTITLE([Features])
1115
1116# Target architecture we're building for.
1117target_arch=$host_cpu
1118[
1119for f in $CFLAGS; do
1120 if test $f = "-m32"; then
1121 target_arch="32-bit"
1122 elif test $f = "-m64"; then
1123 target_arch="64-bit"
1124 fi
1125done
1126]
1127PPRINT_PROP_STRING([Target architecture], $target_arch)
1128
1129# kmod enabled/disabled
1130test "x$kmod_found" = "xyes" && value=1 || value=0
1131PPRINT_PROP_BOOL([libkmod support], $value)
1132
1133# LTTng-UST enabled/disabled
1134test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1135PPRINT_PROP_BOOL([LTTng-UST support], $value)
1136
1137AS_ECHO
1138PPRINT_SUBTITLE([Binaries])
1139
1140# List binaries to be built
1141test x$enable_bin_lttng != xno && value=1 || value=0
1142PPRINT_PROP_BOOL([lttng], $value)
1143
1144test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1145PPRINT_PROP_BOOL([lttng-consumerd], $value)
1146
1147test x$enable_bin_lttng_crash != xno && value=1 || value=0
1148PPRINT_PROP_BOOL([lttng-crash], $value)
1149
1150test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1151PPRINT_PROP_BOOL([lttng-relayd], $value)
1152
1153test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1154PPRINT_PROP_BOOL([lttng-sessiond], $value)
1155
1156# Extras
1157test x$enable_extras != xno && value=1 || value=0
1158AS_ECHO
1159PPRINT_SET_INDENT(0)
1160PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1161PPRINT_SET_INDENT(1)
1162
1163AS_ECHO
1164PPRINT_SUBTITLE([Tests])
1165
1166# Print clear message that tests won't be built
1167AS_IF([test "x$build_tests" = "xno"],[
1168 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1169])
1170
1171# LTTng UST Java agent JUL tests enabled/disabled
1172test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1173PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1174
1175# LTTng UST Java agent Log4j tests enabled/disabled
1176test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1177PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1178
1179test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1180PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1181
1182test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1183PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1184
1185#Python binding enabled/disabled
1186test "x$enable_python_binding" = xyes && value=1 || value=0
1187AS_ECHO
1188PPRINT_SET_INDENT(0)
1189PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1190
1191# man pages build enabled/disabled
1192m4_pushdef([build_man_pages_msg], [Build and install man pages])
1193
1194AS_IF([test "x$man_pages_opt" != "xno"], [
1195 AS_IF([test "x$in_git_repo" = "xyes"], [
1196 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1197 ], [
1198 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1199 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1200 ], [
1201 PPRINT_PROP_STRING([build_man_pages_msg],
1202 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1203 $PPRINT_COLOR_SUBTITLE)
1204 ])
1205 ])
1206], [
1207 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1208])
1209
1210m4_popdef([build_man_pages_msg])
1211
1212test "x$embedded_help" = xyes && value=1 || value=0
1213PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1214
1215PPRINT_SET_INDENT(1)
1216
1217report_bindir="`eval eval echo $bindir`"
1218report_libdir="`eval eval echo $libdir`"
1219
1220# Print the bindir and libdir this `make install' will install into.
1221AS_ECHO
1222PPRINT_SUBTITLE([Install directories])
1223PPRINT_PROP_STRING([Binaries], [$report_bindir])
1224PPRINT_PROP_STRING([Libraries], [$report_libdir])
1225
1226AS_ECHO
1227PPRINT_SUBTITLE([Search directories])
1228
1229# If we build the sessiond, print the paths it will use
1230AS_IF([test "$SESSIOND_BIN" = ""],[
1231 path="$report_bindir/lttng-sessiond"
1232],[
1233 path="$SESSIOND_BIN"
1234])
1235PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1236
1237AS_IF([test "$CONSUMERD32_BIN" = ""],[
1238 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1239],[
1240 path="$CONSUMERD32_BIN"
1241])
1242PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1243
1244AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1245 path="`eval eval echo $libdir`"
1246],[
1247 path="$CONSUMERD32_LIBDIR"
1248])
1249PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1250
1251AS_IF([test "$CONSUMERD64_BIN" = ""],[
1252 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1253],[
1254 path="$CONSUMERD64_BIN"
1255])
1256PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1257
1258AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1259 path="`eval eval echo $libdir`"
1260],[
1261 path="$CONSUMERD64_LIBDIR"
1262])
1263PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1264PPRINT_SET_INDENT(0)
1265
1266AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1267 AS_ECHO
1268 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1269
1270Note that the man pages are already built in this distribution tarball,
1271therefore asciidoc and xmlto are only needed if you intend to modify
1272their sources.
1273
1274Also note that the installed man pages will contain the project's
1275default command-line option and environment variable values.
1276
1277Use --disable-man-pages to completely disable building and installing
1278the man pages.])
1279])
LTTng tools - Deliverables
This page took 0.028087 seconds and 5 git commands to generate.