projects / lttng-tools.git / blame_incremental
? search:
summary | shortlog | log | commit | commitdiff | tree
blob | blame (non-incremental) | history | HEAD
Fix: lttng list of channels should return errors
[lttng-tools.git] / configure.ac
... / ...
CommitLineData
1AC_PREREQ([2.64])
2AC_INIT([lttng-tools],[2.10.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4AC_CONFIG_HEADERS([include/config.h])
5AC_CONFIG_AUX_DIR([config])
6AC_CONFIG_MACRO_DIR([m4])
7
8AC_CANONICAL_TARGET
9AC_CANONICAL_HOST
10
11AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
12AM_MAINTAINER_MODE([enable])
13
14# Enable silent rules if available (Introduced in AM 1.11)
15m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19# Checks for C compiler
20AC_USE_SYSTEM_EXTENSIONS
21AC_SYS_LARGEFILE
22AC_PROG_CC
23AC_PROG_CC_STDC
24
25# Checks for programs.
26AC_PROG_GREP
27AC_PROG_MAKE_SET
28AC_PROG_SED
29AC_PATH_PROG([report_fold], [fold])
30LT_INIT
31
32# Check for objcopy, required by the base address statedump and dynamic linker tests
33AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
34AS_IF([test "x$OBJCOPY" = "xno"],
35 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
36)
37AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
38
39# check for pgrep
40AC_PATH_PROG([PGREP], [pgrep], [no])
41AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
42
43# check for bison
44AC_PROG_YACC
45BISON=$YACC
46AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
47
48AS_IF([test "x$have_bison" != "xyes"], [
49 AS_IF([test "x$in_git_repo" = "xyes"], [
50 AC_MSG_FAILURE([
51Bison >= 2.4 is required when building from the Git repository. You can
52set the YACC variable to override automatic detection.
53 ])
54 ], [
55 AC_MSG_WARN([
56Missing Bison >= 2.4. Note that the parser files are already built in
57this distribution tarball, so Bison is only needed if you intend to
58modify their sources. You can set the YACC variable to override automatic
59detection.
60 ])
61 ])
62])
63AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
64
65# check for flex
66AC_PROG_LEX
67FLEX=$LEX
68AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
69
70AS_IF([test "x$have_flex" != "xyes"], [
71 AS_IF([test "x$in_git_repo" = "xyes"], [
72 AC_MSG_FAILURE([
73Flex >= 2.5.35 is required when building from the Git repository. You can
74set the LEX variable to override automatic detection.
75 ])
76 ], [
77 AC_MSG_WARN([
78Missing Flex >= 2.5.35. Note that the lexer files are already built in
79this distribution tarball, so Flex is only needed if you intend to
80modify their sources. You can set the LEX variable to override automatic
81detection.
82 ])
83 ])
84])
85AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
86
87
88# Checks for typedefs, structures, and compiler characteristics.
89AC_C_INLINE
90AC_TYPE_INT32_T
91AC_TYPE_INT64_T
92AC_TYPE_MODE_T
93AC_TYPE_OFF_T
94AC_TYPE_PID_T
95AC_TYPE_SIZE_T
96AC_TYPE_SSIZE_T
97AC_TYPE_UID_T
98AC_TYPE_UINT16_T
99AC_TYPE_UINT32_T
100AC_TYPE_UINT64_T
101AC_TYPE_UINT8_T
102
103AX_C___ATTRIBUTE__
104AS_IF([test "x$ax_cv___attribute__" = "xyes"],
105 [:],
106 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
107
108AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
109
110AX_LIB_SOCKET_NSL
111
112LT_NO_UNDEFINED=""
113AS_CASE([$host_os],
114 [cygwin*],
115 [
116 LT_NO_UNDEFINED="-no-undefined"
117 ],
118 [cygwin*|darwin*|mingw*|solaris*],
119 [
120 # On platforms where we only support the relayd, disable the other binaries by default
121 AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
122 AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
123 AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
124 AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
125 AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
126 AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
127 ]
128)
129
130AC_SUBST(LT_NO_UNDEFINED)
131
132# Compute minor/major/patchlevel version numbers
133major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
134minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
135patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
136
137AC_SUBST([MAJOR_VERSION], [$major_version])
138AC_SUBST([MINOR_VERSION], [$minor_version])
139AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
140AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
141AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
142AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
143
144version_name="KeKriek"
145version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
146version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
147
148AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
149AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
150
151# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
152AC_ARG_ENABLE(libtool-linkdep-fixup,
153 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
154 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
155 libtool_fixup=$enableval,
156 libtool_fixup=yes)
157
158AS_IF([test "x$libtool_fixup" = "xyes"],
159 [
160 libtool_m4="$srcdir/m4/libtool.m4"
161 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
162 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
163 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
164 AS_IF([test $libtool_flag_pattern_count -ne 0],
165 [
166 AC_MSG_RESULT([$libtool_flag_pattern_count])
167 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
168 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
169 ],
170 [
171 AC_MSG_RESULT([none])
172 ])
173 ])
174
175AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
176
177AC_CHECK_HEADERS([ \
178 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
179 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
180 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
181 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
182 sys/mount.h sys/param.h sys/time.h
183])
184
185# Basic functions check
186AC_CHECK_FUNCS([ \
187 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
188 gethostbyname gethostname getpagesize localtime_r memchr memset \
189 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
190 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
191 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
192 sched_getcpu sysconf sync_file_range
193])
194
195# Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
196# add -lrt to LIBS
197AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
198
199# Babeltrace viewer check
200AC_ARG_WITH([babeltrace-bin],
201 AS_HELP_STRING([--with-babeltrace-bin],
202 [Location of the babeltrace viewer executable (including the filename)]),
203 [BABELTRACE_BIN="$withval"],
204 [BABELTRACE_BIN=''])
205AC_SUBST([BABELTRACE_BIN])
206
207# lttv-gui
208AC_ARG_WITH([lttv-gui-bin],
209 AS_HELP_STRING([--with-lttv-gui-bin],
210 [Location of the lttv GUI viewer executable (including the filename)]),
211 [LTTV_GUI_BIN="$withval"],
212 [LTTV_GUI_BIN=''])
213AC_SUBST([LTTV_GUI_BIN])
214
215AC_ARG_WITH([consumerd32-bin],
216 AS_HELP_STRING([--with-consumerd32-bin],
217 [Location of the 32-bit consumerd executable (including the filename)]),
218 [CONSUMERD32_BIN="$withval"],
219 [CONSUMERD32_BIN=''])
220AC_SUBST([CONSUMERD32_BIN])
221
222AC_ARG_WITH([consumerd64-bin],
223 AS_HELP_STRING([--with-consumerd64-bin],
224 [Location of the 64-bit consumerd executable (including the filename)]),
225 [CONSUMERD64_BIN="$withval"],
226 [CONSUMERD64_BIN=''])
227AC_SUBST([CONSUMERD64_BIN])
228
229AC_ARG_WITH([consumerd32-libdir],
230 AS_HELP_STRING([--with-consumerd32-libdir],
231 [Directory containing the 32-bit consumerd libraries]),
232 [CONSUMERD32_LIBDIR="$withval"],
233 [CONSUMERD32_LIBDIR=''])
234AC_SUBST([CONSUMERD32_LIBDIR])
235
236AC_ARG_WITH([consumerd64-libdir],
237 AS_HELP_STRING([--with-consumerd64-libdir],
238 [Directory containing the 64-bit consumerd libraries]),
239 [CONSUMERD64_LIBDIR="$withval"],
240 [CONSUMERD64_LIBDIR=''])
241AC_SUBST([CONSUMERD64_LIBDIR])
242
243AC_ARG_WITH([sessiond-bin],
244 AS_HELP_STRING([--with-sessiond-bin],
245 [Location of the sessiond executable (including the filename)]),
246 [SESSIOND_BIN="$withval"],
247 [SESSIOND_BIN=''])
248AC_SUBST([SESSIOND_BIN])
249
250AC_ARG_WITH([lttng-system-rundir],
251 AS_HELP_STRING([--with-lttng-system-rundir],
252 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
253 [LTTNG_SYSTEM_RUNDIR="$withval"],
254 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
255AC_SUBST([LTTNG_SYSTEM_RUNDIR])
256
257AC_ARG_ENABLE([test-java-agent-jul],
258 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
259 [test_java_agent_jul=$enableval],
260 [test_java_agent_jul=no]
261)
262
263AC_ARG_ENABLE([test-java-agent-log4j],
264 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
265 [test_java_agent_log4j=$enableval],
266 [test_java_agent_log4j=no]
267)
268
269AC_ARG_ENABLE([test-java-agent-all],
270 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
271 [test_java_agent_jul=$enableval
272 test_java_agent_log4j=$enableval],
273 [:]
274)
275
276AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
277AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
278AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
279AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
280AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
281AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
282AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
283AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
284
285AC_DEFUN([_AC_DEFINE_AND_SUBST], [
286 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
287 $1="$2"
288 AC_SUBST([$1])
289])
290
291AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
292 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
293 $1="$2"
294 AC_SUBST([$1])
295])
296
297# Default values
298m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
299m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
300m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
301m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
302m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
303m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
304_AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
305_AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
306_AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
307_AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
308_AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
309_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
310_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
311_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
312_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
313_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
314_AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
315_AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
316_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
317_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
318_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
319_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
320_AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
321_AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
322_AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
323_AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
324_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
325_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
326_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
327_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
328_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
329_AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
330_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
331_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
332_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
333_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
334_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
335_AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
336_AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
337_AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
338_AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
339_AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
340
341# Command short descriptions
342_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
343_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
344_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
345_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
346_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
347_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
348_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
349_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
350_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
351_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
352_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
353_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
354_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
355_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
356_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
357_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
358_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
359_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
360_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
361_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
362_AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
363
364if test "x$prefix" = "xNONE"; then
365 prefix=$ac_default_prefix
366fi
367CONFDIR=`eval echo $sysconfdir`
368AC_SUBST(CONFDIR)
369AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
370
371AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
372
373# Check libpopt
374PKG_CHECK_MODULES([POPT], [popt],
375 [
376 dnl PKG_CHECK_MODULES defines POPT_LIBS
377 ],
378 [
379 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
380 AC_MSG_WARN([Finding libpopt without pkg-config.])
381 AC_CHECK_LIB([popt],
382 [poptGetContext],
383 [POPT_LIBS="-lpopt"],
384 [
385 AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
386 ]
387 )
388 ]
389)
390AC_SUBST(POPT_LIBS)
391
392PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
393
394# First, check for uuid in system libs
395AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
396AC_CHECK_FUNCS([uuid_generate],
397 [
398 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
399 UUID_LIBS=""
400 ],
401 [
402 # Then, check if the pkg-config module is available, otherwise explicitly check
403 # for libuuid, or uuid support in the C-library.
404 PKG_CHECK_MODULES([UUID], [uuid],
405 [
406 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
407 dnl PKG_CHECK_MODULES defines UUID_LIBS
408 ],
409 [
410 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
411 AC_MSG_WARN([Finding libuuid without pkg-config.])
412 AC_CHECK_LIB([uuid], [uuid_generate],
413 [
414 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
415 UUID_LIBS="-luuid"
416 ],
417 [
418 # libuuid not found, check for uuid_create in libc.
419 AC_CHECK_LIB([c], [uuid_create],
420 [
421 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
422 UUID_LIBS="-lc"
423 ],
424 [
425 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
426 ]
427 )
428 ]
429 )
430 ]
431 )
432 ]
433)
434AC_SUBST(UUID_LIBS)
435
436AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
437
438# URCU library version needed or newer
439m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
440
441# Check liburcu needed function calls
442AC_CHECK_DECL([cds_list_add], [],
443 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
444AC_CHECK_DECL([cds_wfcq_init], [],
445 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
446AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
447 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
448AC_CHECK_DECL([futex_async], [],
449 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
450AC_CHECK_DECL([rcu_thread_offline], [],
451 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
452AC_CHECK_DECL([rcu_thread_online], [],
453 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
454AC_CHECK_DECL([caa_likely], [],
455 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
456AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
457 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
458
459#Function added in urcu 0.7.0
460AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
461 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
462)
463
464# Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
465# it can be explicitly disabled with --without-kmod
466AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
467AC_ARG_WITH([kmod],
468 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
469 [],
470 [with_kmod=check]
471)
472
473AS_IF([test "x$with_kmod" != "xno"],
474 [
475 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
476 [
477 AC_DEFINE([HAVE_KMOD], [1])
478 KMOD_LIBS="-lkmod"
479 ],
480 [
481 if test "x$with_kmod" != xcheck; then
482 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
483 else
484 with_kmod=no
485 fi
486 ]
487 )
488 ]
489)
490AC_SUBST(KMOD_LIBS)
491
492# Check for liblttng-ust-ctl, fail if it's not found,
493# it can be explicitly disabled with --without-lttng-ust
494AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
495AC_ARG_WITH([lttng-ust],
496 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
497 [],
498 [with_lttng_ust=yes]
499)
500
501AS_IF([test "x$with_lttng_ust" = "xyes"],
502 [
503 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
504 [
505 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
506 ],
507 [
508 AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
509 ],
510 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
511 )
512 ]
513)
514AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
515
516
517
518# check for dlopen
519AC_CHECK_LIB([dl], [dlopen],
520 [DL_LIBS="-ldl"],
521 [
522 #libdl not found, check for dlopen in libc.
523 AC_CHECK_LIB([c], [dlopen],
524 [DL_LIBS="-lc"],
525 [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
526 )
527 ]
528)
529AC_SUBST(DL_LIBS)
530
531# Check for fmemopen
532AC_CHECK_LIB([c], [fmemopen],
533[
534 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
535]
536)
537
538# Check for open_memstream
539AC_CHECK_LIB([c], [open_memstream],
540[
541 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
542]
543)
544
545# check for libpfm
546AC_CHECK_LIB([pfm], [pfm_initialize],
547 [
548 have_libpfm=yes
549 ])
550AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
551
552AC_ARG_ENABLE([git-version],
553 [AC_HELP_STRING([--disable-git-version],
554 [Do not use the git version for the build])],
555 [have_git_version=$enableval], [have_git_version=yes]
556)
557
558AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
559 [test "x${have_git_version}" = "xyes"])
560
561# For Python
562# SWIG version needed or newer:
563swig_version=2.0.0
564
565AC_ARG_ENABLE([python-bindings],
566 [AC_HELP_STRING([--enable-python-bindings],
567 [compile Python bindings])],
568 [enable_python_binding=$enableval], [enable_python_binding=no])
569
570AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
571
572if test "x$enable_python_binding" = xyes; then
573 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
574 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
575 AM_PATH_PYTHON([3.0])
576
577 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
578 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
579 AS_IF([test -z "$PYTHON_INCLUDE"], [
580 AS_IF([test -z "$PYTHON_CONFIG"], [
581 AC_PATH_PROGS([PYTHON_CONFIG],
582 [python$PYTHON_VERSION-config python-config],
583 [no],
584 [`dirname $PYTHON`])
585 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
586 ])
587 AC_MSG_CHECKING([python include flags])
588 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
589 AC_MSG_RESULT([$PYTHON_INCLUDE])
590 ])
591
592else
593 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
594[if you want Python bindings.])
595
596fi
597
598# Epoll check. If not present, the build will fallback on poll() API
599AX_HAVE_EPOLL(
600 [AX_CONFIG_FEATURE_ENABLE(epoll)],
601 [AX_CONFIG_FEATURE_DISABLE(epoll)]
602)
603AX_CONFIG_FEATURE(
604 [epoll], [This platform supports epoll(7)],
605 [HAVE_EPOLL], [This platform supports epoll(7).],
606 [enable_epoll="yes"], [enable_epoll="no"]
607)
608AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
609
610AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
611AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
612
613if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
614 AX_JAVA_OPTIONS
615 AX_PROG_JAVAC
616 AX_PROG_JAVA
617 AX_PROG_JAR
618
619 AX_CHECK_CLASSPATH
620
621 # Check for Java UST agent common class first
622 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
623 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
624 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
625 fi
626
627 if test "x$test_java_agent_jul" = "xyes"; then
628 # Check for JUL agent class
629 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
630 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
631 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
632 fi
633 fi
634
635 if test "x$test_java_agent_log4j" = "xyes"; then
636 # Check for Log4j agent class
637 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
638 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
639 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
640 fi
641
642 # Check for Log4j class
643 AX_CHECK_CLASS(org.apache.log4j.Logger)
644 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
645 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
646 fi
647 fi
648fi
649
650# set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
651# is not distributed in tarballs
652AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
653AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
654
655# enable building man pages (user's intention)
656AC_ARG_ENABLE(
657 man-pages,
658 AS_HELP_STRING(
659 [--disable-man-pages],
660 [Do not build and install man pages (already built in a distributed tarball)]
661 ),
662 [man_pages_opt=$enableval],
663 [man_pages_opt=yes]
664)
665
666# check for asciidoc and xmlto if we enabled building the man pages
667have_asciidoc_xmlto=no
668warn_prebuilt_man_pages=no
669
670AS_IF([test "x$man_pages_opt" = "xyes"], [
671 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
672 AC_PATH_PROG([XMLTO], [xmlto], [no])
673
674 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
675 AS_IF([test "x$in_git_repo" = "xyes"], [
676 # this is an error because we're in the Git repo, which
677 # means the man pages are not already generated for us,
678 # thus asciidoc/xmlto are required because we were asked
679 # to build the man pages
680 AC_MSG_ERROR([
681You need asciidoc and xmlto to build the LTTng-tools man pages. Use
682--disable-man-pages to disable building the man pages, in which case
683they will not be installed.
684 ])
685 ], [
686 # only warn here: since we're in the tarball, the man
687 # pages should already be generated at this point, thus
688 # asciidoc/xmlto are not strictly required
689 warn_prebuilt_man_pages=yes
690 ])
691 ], [
692 have_asciidoc_xmlto=yes
693 ])
694])
695
696# export man page build condition: build the man pages if the user
697# asked for it, and if the tools are available
698AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
699AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
700
701AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
702
703# embedded --help message
704AC_ARG_ENABLE(
705 [embedded-help],
706 AS_HELP_STRING(
707 [--enable-embedded-help],
708 [Embed the --help messages in the executable files]
709 ),
710 [embedded_help=$enableval],
711 [embedded_help=no]
712)
713AS_IF([test "x$embedded_help" = "xyes"], [
714 AS_IF([test "x$man_pages_opt" = "xno"], [
715 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
716 ])
717 AC_PATH_PROG([man_prog_path], [man], [no])
718 AS_IF([test "x$man_prog_path" = "xno"], [
719 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
720 ])
721 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
722 AC_SUBST([MANPROG], [$man_prog_path])
723])
724AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
725
726# Python agent test
727UST_PYTHON_AGENT="lttngust"
728
729AC_ARG_ENABLE(test-python2-agent,
730 AS_HELP_STRING([--enable-test-python2-agent],
731 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
732 ),[:],[test_python2_agent_autodetect=yes]
733)
734
735AC_ARG_ENABLE(test-python3-agent,
736 AS_HELP_STRING([--enable-test-python3-agent],
737 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
738 ),[:],[test_python3_agent_autodetect=yes]
739)
740
741AC_ARG_ENABLE(test-python-agent-all,
742 AS_HELP_STRING([--enable-test-python-agent-all],
743 [enable test for all python{2/3} agent.]
744 ),
745)
746
747AS_IF([test ! -z "$enable_test_python_agent_all"], [
748 unset test_python2_agent_autodetect
749 unset test_python3_agent_autodetect
750])
751
752AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
753 enable_test_python2_agent=yes
754 enable_test_python3_agent=yes
755])
756
757AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
758 enable_test_python2_agent=no
759 enable_test_python3_agent=no
760])
761
762
763AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
764 AS_IF([test -z "$PYTHON2"], [
765 PYTHON2=python2
766 ], [
767 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
768 ])
769
770 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
771 AS_IF([test -z "$PYTHON2_BIN"], [
772 AS_IF([test -z "$test_python2_agent_autodetect"],[
773 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
774 ])
775 ], [
776 AC_MSG_CHECKING([for python2 lttng-ust agent])
777 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
778 PYTHON2_AGENT=$PYTHON2_BIN
779 AC_MSG_RESULT([yes])
780 RUN_PYTHON_AGENT_TEST=yes
781 ], [
782 AC_MSG_RESULT([no])
783 AS_IF([test -z "$test_python2_agent_autodetect"],[
784 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
785 ])
786 ])
787
788 ])
789
790])
791
792AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
793 AS_IF([test -z "$PYTHON3"], [
794 PYTHON3=python3
795 ], [
796 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
797 ])
798
799 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
800 AS_IF([test -z "$PYTHON3_BIN"], [
801 AS_IF([test -z "$test_python3_agent_autodetect"],[
802 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
803 ])
804 ], [
805 AC_MSG_CHECKING([for python3 lttng-ust agent])
806 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
807 PYTHON3_AGENT=$PYTHON3_BIN
808 AC_MSG_RESULT([yes])
809 RUN_PYTHON_AGENT_TEST=yes
810 ], [
811 AC_MSG_RESULT([no])
812 AS_IF([test -z "$test_python3_agent_autodetect"],[
813 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
814 ])
815 ])
816
817 ])
818])
819AC_SUBST([RUN_PYTHON_AGENT_TEST])
820AC_SUBST([PYTHON2_AGENT])
821AC_SUBST([PYTHON3_AGENT])
822
823# Arguments for binaries build exclusion
824AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
825AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
826 [Disable the build of lttng-consumerd binaries]))
827AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
828AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
829 [Disable the build of lttng-relayd binaries]))
830AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
831 [Disable the build of lttng-sessiond binaries]))
832AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
833 [Disable the build of the extra components]))
834
835
836# Always build libconfig since it a dependency of libcommon
837build_lib_config=yes
838
839build_lib_compat=no
840build_lib_consumer=no
841build_lib_hashtable=no
842build_lib_health=no
843build_lib_index=no
844build_lib_kernel_consumer=no
845build_lib_kernel_ctl=no
846build_lib_lttng_ctl=no
847build_lib_relayd=no
848build_lib_sessiond_comm=no
849build_lib_testpoint=no
850build_lib_ust_consumer=no
851
852# There is an overlap for enabled dependencies, but this makes everything
853# simpler. libcommon and libconfig are always compiled so they are not repeated
854# here.
855
856# Enable binary dependencies.
857AS_IF([test x$enable_bin_lttng != xno],
858 [
859 build_lib_lttng_ctl=yes
860 ]
861)
862
863AS_IF([test x$enable_bin_lttng_consumerd != xno],
864 [
865 build_lib_consumer=yes
866 build_lib_sessiond_comm=yes
867 build_lib_index=yes
868 build_lib_health=yes
869 build_lib_testpoint=yes
870 ]
871)
872
873AS_IF([test x$enable_bin_lttng_crash != xno],
874 # Do nothing since libconfig and libcommon are built by default.
875 []
876)
877
878AS_IF([test x$enable_bin_lttng_relayd != xno],
879 [
880 build_lib_lttng_ctl=yes
881 build_lib_sessiond_comm=yes
882 build_lib_hashtable=yes
883 build_lib_compat=yes
884 build_lib_index=yes
885 build_lib_health=yes
886 build_lib_testpoint=yes
887 ]
888)
889AS_IF([test x$enable_bin_lttng_sessiond != xno],
890 [
891 build_lib_lttng_ctl=yes
892 build_lib_sessiond_comm=yes
893 build_lib_kernel_ctl=yes
894 build_lib_hashtable=yes
895 build_lib_compat=yes
896 build_lib_relayd=yes
897 build_lib_testpoint=yes
898 build_lib_health=yes
899 build_lib_health=yes
900 ]
901)
902
903# Libraries dependencies enabling
904AS_IF([test x$build_lib_lttng_ctl = xyes],
905 [
906 build_lib_sessiond_comm=yes
907 build_lib_hashtable=yes
908 ]
909)
910
911AS_IF([test x$build_lib_consumer = xyes],
912 [
913 build_lib_sessiond_comm=yes
914 build_lib_kernel_consumer=yes
915 build_lib_hashtable=yes
916 build_lib_compat=yes
917 build_lib_relayd=yes
918 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
919 ]
920)
921
922AS_IF([test x$build_lib_kernel_consumer = xyes],
923 [
924 build_lib_kernel_ctl=yes
925 build_lib_relayd=yes
926 ]
927)
928
929AS_IF([test x$build_lib_relayd = xyes],
930 [
931 build_lib_sessiond_comm=yes
932 ]
933)
934
935
936# Export binaries build conditions.
937AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
938AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
939AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
940AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
941AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
942
943# Export the tests and extras build conditions.
944AS_IF([\
945test "x$enable_bin_lttng" != "xno" && \
946test "x$enable_bin_lttng_consumerd" != "xno" && \
947test "x$enable_bin_lttng_crash" != "xno" && \
948test "x$enable_bin_lttng_relayd" != "xno" && \
949test "x$enable_bin_lttng_sessiond" != "xno"],
950[build_tests=yes],
951[build_tests=no]
952)
953
954AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
955AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
956
957# Export libraries build conditions.
958AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
959AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
960AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
961AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
962AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
963AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
964AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
965AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
966AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
967AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
968AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
969AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
970AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
971
972AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
973AC_SUBST(AM_CFLAGS)
974
975AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
976AC_SUBST(AM_CPPFLAGS)
977
978lttngincludedir="${includedir}/lttng"
979AC_SUBST(lttngincludedir)
980
981lttngactionincludedir="${includedir}/lttng/action"
982AC_SUBST(lttngactionincludedir)
983
984lttngconditionincludedir="${includedir}/lttng/condition"
985AC_SUBST(lttngconditionincludedir)
986
987lttngnotificationincludedir="${includedir}/lttng/notification"
988AC_SUBST(lttngnotificationincludedir)
989
990lttngtriggerincludedir="${includedir}/lttng/trigger"
991AC_SUBST(lttngtriggerincludedir)
992
993lttnglibexecdir="${libdir}/lttng/libexec"
994AC_SUBST(lttnglibexecdir)
995
996AC_CONFIG_FILES([
997 Makefile
998 doc/Makefile
999 doc/man/Makefile
1000 doc/man/asciidoc-attrs.conf
1001 include/Makefile
1002 extras/Makefile
1003 extras/bindings/Makefile
1004 extras/bindings/swig/Makefile
1005 extras/bindings/swig/python/Makefile
1006 extras/core-handler/Makefile
1007 src/Makefile
1008 src/common/Makefile
1009 src/common/kernel-ctl/Makefile
1010 src/common/kernel-consumer/Makefile
1011 src/common/consumer/Makefile
1012 src/common/ust-consumer/Makefile
1013 src/common/hashtable/Makefile
1014 src/common/sessiond-comm/Makefile
1015 src/common/compat/Makefile
1016 src/common/relayd/Makefile
1017 src/common/testpoint/Makefile
1018 src/common/index/Makefile
1019 src/common/health/Makefile
1020 src/common/config/Makefile
1021 src/common/string-utils/Makefile
1022 src/lib/Makefile
1023 src/lib/lttng-ctl/Makefile
1024 src/lib/lttng-ctl/filter/Makefile
1025 src/lib/lttng-ctl/lttng-ctl.pc
1026 src/bin/Makefile
1027 src/bin/lttng-consumerd/Makefile
1028 src/bin/lttng-sessiond/Makefile
1029 src/bin/lttng-relayd/Makefile
1030 src/bin/lttng/Makefile
1031 src/bin/lttng-crash/Makefile
1032 tests/Makefile
1033 tests/destructive/Makefile
1034 tests/regression/Makefile
1035 tests/regression/kernel/Makefile
1036 tests/regression/tools/Makefile
1037 tests/regression/tools/streaming/Makefile
1038 tests/regression/tools/filtering/Makefile
1039 tests/regression/tools/health/Makefile
1040 tests/regression/tools/tracefile-limits/Makefile
1041 tests/regression/tools/snapshots/Makefile
1042 tests/regression/tools/live/Makefile
1043 tests/regression/tools/exclusion/Makefile
1044 tests/regression/tools/save-load/Makefile
1045 tests/regression/tools/save-load/configuration/Makefile
1046 tests/regression/tools/mi/Makefile
1047 tests/regression/tools/wildcard/Makefile
1048 tests/regression/tools/crash/Makefile
1049 tests/regression/tools/regen-metadata/Makefile
1050 tests/regression/tools/regen-statedump/Makefile
1051 tests/regression/tools/notification/Makefile
1052 tests/regression/ust/Makefile
1053 tests/regression/ust/nprocesses/Makefile
1054 tests/regression/ust/high-throughput/Makefile
1055 tests/regression/ust/low-throughput/Makefile
1056 tests/regression/ust/before-after/Makefile
1057 tests/regression/ust/buffers-pid/Makefile
1058 tests/regression/ust/periodical-metadata-flush/Makefile
1059 tests/regression/ust/multi-session/Makefile
1060 tests/regression/ust/overlap/Makefile
1061 tests/regression/ust/overlap/demo/Makefile
1062 tests/regression/ust/linking/Makefile
1063 tests/regression/ust/daemon/Makefile
1064 tests/regression/ust/exit-fast/Makefile
1065 tests/regression/ust/fork/Makefile
1066 tests/regression/ust/libc-wrapper/Makefile
1067 tests/regression/ust/baddr-statedump/Makefile
1068 tests/regression/ust/ust-dl/Makefile
1069 tests/regression/ust/java-jul/Makefile
1070 tests/regression/ust/java-log4j/Makefile
1071 tests/regression/ust/python-logging/Makefile
1072 tests/regression/ust/getcpu-override/Makefile
1073 tests/regression/ust/clock-override/Makefile
1074 tests/regression/ust/type-declarations/Makefile
1075 tests/regression/ust/rotation-destroy-flush/Makefile
1076 tests/regression/ust/blocking/Makefile
1077 tests/stress/Makefile
1078 tests/unit/Makefile
1079 tests/unit/ini_config/Makefile
1080 tests/perf/Makefile
1081 tests/utils/Makefile
1082 tests/utils/tap/Makefile
1083 tests/utils/testapp/Makefile
1084 tests/utils/testapp/gen-ust-events/Makefile
1085 tests/utils/testapp/gen-ust-nevents/Makefile
1086 tests/utils/testapp/gen-ust-nevents-str/Makefile
1087 tests/utils/testapp/gen-ust-tracef/Makefile
1088])
1089
1090# Inject variable into python test script.
1091AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1092# Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1093AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1094
1095AC_OUTPUT
1096
1097#
1098# Mini-report on what will be built.
1099#
1100
1101PPRINT_INIT
1102PPRINT_SET_INDENT(1)
1103PPRINT_SET_TS(38)
1104
1105AS_ECHO
1106AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1107AS_ECHO
1108
1109AS_IF([test -n "$report_fold"], [
1110 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1111], [
1112 AS_ECHO("$version_description")
1113])
1114
1115AS_ECHO
1116PPRINT_SUBTITLE([Features])
1117
1118# Target architecture we're building for.
1119target_arch=$host_cpu
1120[
1121for f in $CFLAGS; do
1122 if test $f = "-m32"; then
1123 target_arch="32-bit"
1124 elif test $f = "-m64"; then
1125 target_arch="64-bit"
1126 fi
1127done
1128]
1129PPRINT_PROP_STRING([Target architecture], $target_arch)
1130
1131# kmod enabled/disabled
1132test "x$with_kmod" != "xno" && value=1 || value=0
1133PPRINT_PROP_BOOL([libkmod support], $value)
1134
1135# LTTng-UST enabled/disabled
1136test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1137PPRINT_PROP_BOOL([LTTng-UST support], $value)
1138
1139AS_ECHO
1140PPRINT_SUBTITLE([Binaries])
1141
1142# List binaries to be built
1143test x$enable_bin_lttng != xno && value=1 || value=0
1144PPRINT_PROP_BOOL([lttng], $value)
1145
1146test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1147PPRINT_PROP_BOOL([lttng-consumerd], $value)
1148
1149test x$enable_bin_lttng_crash != xno && value=1 || value=0
1150PPRINT_PROP_BOOL([lttng-crash], $value)
1151
1152test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1153PPRINT_PROP_BOOL([lttng-relayd], $value)
1154
1155test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1156PPRINT_PROP_BOOL([lttng-sessiond], $value)
1157
1158# Extras
1159test x$enable_extras != xno && value=1 || value=0
1160AS_ECHO
1161PPRINT_SET_INDENT(0)
1162PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1163PPRINT_SET_INDENT(1)
1164
1165AS_ECHO
1166PPRINT_SUBTITLE([Tests])
1167
1168# Print clear message that tests won't be built
1169AS_IF([test "x$build_tests" = "xno"],[
1170 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1171])
1172
1173# LTTng UST Java agent JUL tests enabled/disabled
1174test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1175PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1176
1177# LTTng UST Java agent Log4j tests enabled/disabled
1178test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1179PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1180
1181test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1182PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1183
1184test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1185PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1186
1187#Python binding enabled/disabled
1188test "x$enable_python_binding" = xyes && value=1 || value=0
1189AS_ECHO
1190PPRINT_SET_INDENT(0)
1191PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1192
1193# man pages build enabled/disabled
1194m4_pushdef([build_man_pages_msg], [Build and install man pages])
1195
1196AS_IF([test "x$man_pages_opt" != "xno"], [
1197 AS_IF([test "x$in_git_repo" = "xyes"], [
1198 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1199 ], [
1200 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1201 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1202 ], [
1203 PPRINT_PROP_STRING([build_man_pages_msg],
1204 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1205 $PPRINT_COLOR_SUBTITLE)
1206 ])
1207 ])
1208], [
1209 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1210])
1211
1212m4_popdef([build_man_pages_msg])
1213
1214test "x$embedded_help" = xyes && value=1 || value=0
1215PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1216
1217PPRINT_SET_INDENT(1)
1218
1219report_bindir="`eval eval echo $bindir`"
1220report_libdir="`eval eval echo $libdir`"
1221
1222# Print the bindir and libdir this `make install' will install into.
1223AS_ECHO
1224PPRINT_SUBTITLE([Install directories])
1225PPRINT_PROP_STRING([Binaries], [$report_bindir])
1226PPRINT_PROP_STRING([Libraries], [$report_libdir])
1227
1228AS_ECHO
1229PPRINT_SUBTITLE([Search directories])
1230
1231# If we build the sessiond, print the paths it will use
1232AS_IF([test "$SESSIOND_BIN" = ""],[
1233 path="$report_bindir/lttng-sessiond"
1234],[
1235 path="$SESSIOND_BIN"
1236])
1237PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1238
1239AS_IF([test "$CONSUMERD32_BIN" = ""],[
1240 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1241],[
1242 path="$CONSUMERD32_BIN"
1243])
1244PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1245
1246AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1247 path="`eval eval echo $libdir`"
1248],[
1249 path="$CONSUMERD32_LIBDIR"
1250])
1251PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1252
1253AS_IF([test "$CONSUMERD64_BIN" = ""],[
1254 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1255],[
1256 path="$CONSUMERD64_BIN"
1257])
1258PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1259
1260AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1261 path="`eval eval echo $libdir`"
1262],[
1263 path="$CONSUMERD64_LIBDIR"
1264])
1265PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1266PPRINT_SET_INDENT(0)
1267
1268AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1269 AS_ECHO
1270 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1271
1272Note that the man pages are already built in this distribution tarball,
1273therefore asciidoc and xmlto are only needed if you intend to modify
1274their sources.
1275
1276Also note that the installed man pages will contain the project's
1277default command-line option and environment variable values.
1278
1279Use --disable-man-pages to completely disable building and installing
1280the man pages.])
1281])
LTTng tools - Deliverables
This page took 0.028791 seconds and 5 git commands to generate.