projects / lttng-tools.git / blame_incremental
? search:
summary | shortlog | log | commit | commitdiff | tree
blob | blame (non-incremental) | history | HEAD
configure: missing check for needed header
[lttng-tools.git] / configure.ac
... / ...
CommitLineData
1AC_INIT([lttng-tools],[2.6.0-rc1],[dgoulet@efficios.com],[],[http://lttng.org])
2AC_CONFIG_AUX_DIR([config])
3AC_CANONICAL_TARGET
4AC_CANONICAL_HOST
5AC_CONFIG_MACRO_DIR([config])
6AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
7AM_MAINTAINER_MODE([enable])
8m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
9
10# Compute minor/major/patchlevel version numbers
11AC_PROG_SED
12major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
13minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
14patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
15AC_SUBST([MAJOR_VERSION], [$major_version])
16AC_SUBST([MINOR_VERSION], [$minor_version])
17AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
18AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
19AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
20AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
21
22version_name="Gaia"
23version_description="From Benelux brewery in Montreal, the Gaia is a witbier with a cloudy light amber ale color. Aroma of coriander with floral hay notes is enchanting. Taste is also dominated by the very floral coriander note and some medium sweet malt notes."
24
25AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
26AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
27
28AC_CONFIG_HEADERS([include/config.h])
29
30AC_PROG_GREP
31# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
32AC_ARG_ENABLE(libtool-linkdep-fixup,
33 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
34 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
35 libtool_fixup=$enableval,
36 libtool_fixup=yes)
37
38AS_IF([test "x$libtool_fixup" = "xyes"],
39 [
40 libtool_m4="$srcdir/config/libtool.m4"
41 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
42 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
43 libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
44 AS_IF([test $libtool_flag_pattern_count -ne 0],
45 [
46 AC_MSG_RESULT([$libtool_flag_pattern_count])
47 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
48 sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
49 ],
50 [
51 AC_MSG_RESULT([none])
52 ])
53 ])
54
55AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
56
57AC_CHECK_HEADERS([ \
58 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
59 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
60 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
61 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
62 sys/mount.h sys/param.h sys/time.h
63])
64
65# Basic functions check
66AC_CHECK_FUNCS([ \
67 atexit bzero clock_gettime dup2 fdatasync ftruncate \
68 gethostbyname gethostname getpagesize localtime_r memchr memset \
69 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
70 strncasecmp strndup strpbrk strrchr strstr strtol strtoul \
71 strtoull \
72])
73# Babeltrace viewer check
74AC_ARG_WITH([babeltrace-bin],
75 AS_HELP_STRING([--with-babeltrace-bin],
76 [Location of the babeltrace viewer executable (including the filename)]),
77 [BABELTRACE_BIN="$withval"],
78 [BABELTRACE_BIN=''])
79AC_SUBST([BABELTRACE_BIN])
80
81# lttv-gui
82AC_ARG_WITH([lttv-gui-bin],
83 AS_HELP_STRING([--with-lttv-gui-bin],
84 [Location of the lttv GUI viewer executable (including the filename)]),
85 [LTTV_GUI_BIN="$withval"],
86 [LTTV_GUI_BIN=''])
87AC_SUBST([LTTV_GUI_BIN])
88
89AC_ARG_WITH([consumerd32-bin],
90 AS_HELP_STRING([--with-consumerd32-bin],
91 [Location of the 32-bit consumerd executable (including the filename)]),
92 [CONSUMERD32_BIN="$withval"],
93 [CONSUMERD32_BIN=''])
94AC_SUBST([CONSUMERD32_BIN])
95
96AC_ARG_WITH([consumerd64-bin],
97 AS_HELP_STRING([--with-consumerd64-bin],
98 [Location of the 64-bit consumerd executable (including the filename)]),
99 [CONSUMERD64_BIN="$withval"],
100 [CONSUMERD64_BIN=''])
101AC_SUBST([CONSUMERD64_BIN])
102
103AC_ARG_WITH([consumerd32-libdir],
104 AS_HELP_STRING([--with-consumerd32-libdir],
105 [Directory containing the 32-bit consumerd libraries]),
106 [CONSUMERD32_LIBDIR="$withval"],
107 [CONSUMERD32_LIBDIR=''])
108AC_SUBST([CONSUMERD32_LIBDIR])
109
110AC_ARG_WITH([consumerd64-libdir],
111 AS_HELP_STRING([--with-consumerd64-libdir],
112 [Directory containing the 64-bit consumerd libraries]),
113 [CONSUMERD64_LIBDIR="$withval"],
114 [CONSUMERD64_LIBDIR=''])
115AC_SUBST([CONSUMERD64_LIBDIR])
116
117AC_ARG_WITH([sessiond-bin],
118 AS_HELP_STRING([--with-sessiond-bin],
119 [Location of the sessiond executable (including the filename)]),
120 [SESSIOND_BIN="$withval"],
121 [SESSIOND_BIN=''])
122AC_SUBST([SESSIOND_BIN])
123
124AC_ARG_WITH([lttng-system-rundir],
125 AS_HELP_STRING([--with-lttng-system-rundir],
126 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
127 [LTTNG_SYSTEM_RUNDIR="$withval"],
128 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
129AC_SUBST([LTTNG_SYSTEM_RUNDIR])
130
131AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
132AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
133AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
134AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
135AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
136AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
137AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
138AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
139
140if test "x$prefix" = "xNONE"; then
141 prefix=$ac_default_prefix
142fi
143CONFDIR=`eval echo $sysconfdir`
144AC_SUBST(CONFDIR)
145AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
146
147AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
148
149#
150# Check for pthread
151AC_CHECK_LIB([pthread], [pthread_create], [],
152 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
153)
154
155# Check libpopt
156AC_CHECK_LIB([popt], [poptGetContext], [],
157 [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
158)
159
160AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
161
162# Check for libuuid
163AC_CHECK_LIB([uuid], [uuid_generate],
164[
165 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
166 have_libuuid=yes
167],
168[
169 # libuuid not found, check for uuid_create in libc.
170 AC_CHECK_LIB([c], [uuid_create],
171 [
172 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
173 have_libc_uuid=yes
174 ],
175 [
176 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
177 ])
178]
179)
180AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
181AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
182
183# URCU library version needed or newer
184liburcu_version=">= 0.8.0"
185
186# Check liburcu needed function calls
187AC_CHECK_DECL([cds_list_add], [],
188 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
189)
190AC_CHECK_DECL([cds_wfcq_init], [],
191 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
192)
193AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
194 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
195)
196AC_CHECK_DECL([futex_async], [],
197 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
198)
199AC_CHECK_DECL([rcu_thread_offline], [],
200 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
201)
202AC_CHECK_DECL([rcu_thread_online], [],
203 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
204)
205AC_CHECK_DECL([caa_likely], [],
206 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
207)
208#Function added in urcu 0.7.0
209AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
210 [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
211)
212
213# Check kmod library
214AC_ARG_WITH(kmod-prefix,
215 AS_HELP_STRING([--with-kmod-prefix=PATH],
216 [Specify the installation prefix of the kmod library.
217 Headers must be in PATH/include; libraries in PATH/lib.]),
218 [
219 CPPFLAGS="$CPPFLAGS -I${withval}/include"
220 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
221 ])
222
223AC_ARG_ENABLE(kmod,
224 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
225 kmod_support=zz$enableval, kmod_support=yes)
226
227AS_IF([test "x$kmod_support" = "xyes"], [
228 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
229 [
230 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
231 LIBS="$LIBS -lkmod"
232 kmod_found=yes
233 ],
234 kmod_found=no
235 )
236])
237AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
238
239AC_ARG_WITH(lttng-ust-prefix,
240 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
241 [Specify the installation prefix of the lttng-ust library.
242 Headers must be in PATH/include; libraries in PATH/lib.]),
243 [
244 CPPFLAGS="$CPPFLAGS -I${withval}/include"
245 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
246 ])
247
248# Check liblttng-ust-ctl library
249AC_ARG_ENABLE(lttng-ust,
250 AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
251 lttng_ust_support=$enableval, lttng_ust_support=yes)
252
253AS_IF([test "x$lttng_ust_support" = "xyes"], [
254 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
255 [
256 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
257 lttng_ust_ctl_found=yes
258 ],
259 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
260 [-lurcu-common -lurcu-bp -lurcu-cds -lrt]
261 )
262])
263AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
264AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
265
266# check for dlopen
267AC_CHECK_LIB([dl], [dlopen],
268[
269 have_libdl=yes
270],
271[
272 #libdl not found, check for dlopen in libc.
273 AC_CHECK_LIB([c], [dlopen],
274 [
275 have_libc_dl=yes
276 ],
277 [
278 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
279 ])
280])
281AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
282AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
283
284# Check for fmemopen
285AC_CHECK_LIB([c], [fmemopen],
286[
287 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
288]
289)
290
291# Check for open_memstream
292AC_CHECK_LIB([c], [open_memstream],
293[
294 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
295]
296)
297
298AC_ARG_ENABLE([git-version],
299 [AC_HELP_STRING([--disable-git-version],
300 [Do not use the git version for the build])],
301 [have_git_version=$enableval], [have_git_version=yes]
302)
303
304AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
305 [test "x${have_git_version}" = "xyes"])
306
307# For Python
308# SWIG version needed or newer:
309swig_version=2.0.0
310
311AC_ARG_ENABLE([python-bindings],
312 [AC_HELP_STRING([--enable-python-bindings],
313 [compile Python bindings])],
314 [enable_python=yes], [enable_python=no])
315
316AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
317
318if test "x${enable_python:-yes}" = xyes; then
319 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
320 AM_PATH_PYTHON
321
322 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
323 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
324 AS_IF([test -z "$PYTHON_INCLUDE"], [
325 AS_IF([test -z "$PYTHON_CONFIG"], [
326 AC_PATH_PROGS([PYTHON_CONFIG],
327 [python$PYTHON_VERSION-config python-config],
328 [no],
329 [`dirname $PYTHON`])
330 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
331 ])
332 AC_MSG_CHECKING([python include flags])
333 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
334 AC_MSG_RESULT([$PYTHON_INCLUDE])
335 ])
336
337else
338 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
339[if you want Python bindings.])
340
341fi
342
343# Epoll check. If not present, the build will fallback on poll() API
344AX_HAVE_EPOLL(
345 [AX_CONFIG_FEATURE_ENABLE(epoll)],
346 [AX_CONFIG_FEATURE_DISABLE(epoll)]
347)
348AX_CONFIG_FEATURE(
349 [epoll], [This platform supports epoll(7)],
350 [HAVE_EPOLL], [This platform supports epoll(7).],
351 [enable_epoll="yes"], [enable_epoll="no"]
352)
353AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
354
355# Set compile flags to java include files if given. This is only used to
356# compile java agent tests.
357AC_ARG_WITH([java-jdk],
358 [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
359 [JAVA_JDK=$withval],
360 [JAVA_JDK=""]
361)
362AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
363AC_SUBST([JAVA_JDK])
364
365AS_IF([test $JAVA_JDK],[
366 AS_IF([test -d $JAVA_JDK],
367 [
368 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
369 SUBDIRS=`find $JAVA_JDK/include -type d`
370 CPPFLAGS+=" "
371 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
372 CPPFLAGS+=" "
373 ],[AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)]
374 )
375])
376
377# Check for the UST agent jar file in the system. Hardcoded path is added here
378# since we have *no* idea where this could be installed. Note that this is only
379# used for agent testing.
380AC_MSG_CHECKING(Java UST agent jar file)
381java_agent_jar_path="${prefix}/share/java/liblttng-ust-agent.jar"
382if test -f $java_agent_jar_path; then
383 build_java_agent=yes
384 AC_MSG_RESULT(found)
385else
386 build_java_agent=no
387 AC_MSG_RESULT(not found)
388fi
389AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$build_java_agent" = "xyes"])
390AC_SUBST([java_agent_jar_path])
391
392# Check for log4j support on the system to know if we can build or not the
393# log4j tests.
394if test "x$build_java_agent" = "xyes"; then
395 AC_MSG_CHECKING(Java agent support for log4j)
396 AX_JAVA_OPTIONS
397 AX_PROG_JAR
398 AX_PROG_JAVA
399 AX_PROG_JAVAC
400
401 # By default, use a commonly used classpath on the system to ease things up
402 # for the Java testing in this directory.
403 LOG4J_CLASSPATH="$java_agent_jar_path:$CLASSPATH:.:/usr/share/java/*"
404 JAVAFLAGS="-cp $LOG4J_CLASSPATH"
405 JAVACFLAGS="$JAVAFLAGS"
406 AX_CHECK_CLASS(org.apache.log4j.Logger)
407
408 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
409 build_java_log4j_agent=no
410 else
411 build_java_log4j_agent=yes
412 fi
413fi
414AM_CONDITIONAL([BUILD_JAVA_LOG4J_AGENT], [test "x$build_java_log4j_agent" = "xyes"])
415
416AC_SYS_LARGEFILE
417AC_PROG_CC
418LT_INIT
419AC_PROG_YACC
420AC_PROG_LEX
421
422if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
423 if test x"$YACC" != "xbison -y"; then
424 AC_MSG_ERROR([[bison not found and is required when building from git.
425 Please install bison]])
426 fi
427fi
428
429if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
430 if test x"$LEX" != "xflex"; then
431 AC_MSG_ERROR([[flex not found and is required when building from git.
432 Please install flex]])
433 fi
434fi
435
436CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
437
438DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
439
440lttngincludedir="${includedir}/lttng"
441
442AC_SUBST(lttngincludedir)
443AC_SUBST(DEFAULT_INCLUDES)
444
445lttnglibexecdir="${libdir}/lttng/libexec"
446AC_SUBST(lttnglibexecdir)
447
448AC_CONFIG_FILES([
449 Makefile
450 doc/Makefile
451 doc/man/Makefile
452 include/Makefile
453 extras/Makefile
454 extras/bindings/Makefile
455 extras/bindings/swig/Makefile
456 extras/bindings/swig/python/Makefile
457 extras/core-handler/Makefile
458 src/Makefile
459 src/common/Makefile
460 src/common/kernel-ctl/Makefile
461 src/common/kernel-consumer/Makefile
462 src/common/ust-consumer/Makefile
463 src/common/hashtable/Makefile
464 src/common/sessiond-comm/Makefile
465 src/common/compat/Makefile
466 src/common/relayd/Makefile
467 src/common/testpoint/Makefile
468 src/common/index/Makefile
469 src/common/health/Makefile
470 src/common/config/Makefile
471 src/lib/Makefile
472 src/lib/lttng-ctl/Makefile
473 src/lib/lttng-ctl/filter/Makefile
474 src/lib/lttng-ctl/lttng-ctl.pc
475 src/bin/Makefile
476 src/bin/lttng-consumerd/Makefile
477 src/bin/lttng-sessiond/Makefile
478 src/bin/lttng-relayd/Makefile
479 src/bin/lttng/Makefile
480 tests/Makefile
481 tests/regression/Makefile
482 tests/regression/kernel/Makefile
483 tests/regression/tools/Makefile
484 tests/regression/tools/streaming/Makefile
485 tests/regression/tools/filtering/Makefile
486 tests/regression/tools/health/Makefile
487 tests/regression/tools/tracefile-limits/Makefile
488 tests/regression/tools/snapshots/Makefile
489 tests/regression/tools/live/Makefile
490 tests/regression/tools/exclusion/Makefile
491 tests/regression/tools/save-load/Makefile
492 tests/regression/tools/mi/Makefile
493 tests/regression/ust/Makefile
494 tests/regression/ust/nprocesses/Makefile
495 tests/regression/ust/high-throughput/Makefile
496 tests/regression/ust/low-throughput/Makefile
497 tests/regression/ust/before-after/Makefile
498 tests/regression/ust/buffers-pid/Makefile
499 tests/regression/ust/periodical-metadata-flush/Makefile
500 tests/regression/ust/multi-session/Makefile
501 tests/regression/ust/overlap/Makefile
502 tests/regression/ust/overlap/demo/Makefile
503 tests/regression/ust/linking/Makefile
504 tests/regression/ust/daemon/Makefile
505 tests/regression/ust/exit-fast/Makefile
506 tests/regression/ust/fork/Makefile
507 tests/regression/ust/libc-wrapper/Makefile
508 tests/regression/ust/java-jul/Makefile
509 tests/regression/ust/java-log4j/Makefile
510 tests/regression/ust/python-logging/Makefile
511 tests/stress/Makefile
512 tests/unit/Makefile
513 tests/unit/ini_config/Makefile
514 tests/utils/Makefile
515 tests/utils/tap/Makefile
516 tests/utils/testapp/Makefile
517 tests/utils/testapp/gen-ust-events/Makefile
518 tests/utils/testapp/gen-ust-nevents/Makefile
519 tests/utils/testapp/gen-ust-tracef/Makefile
520])
521
522AC_OUTPUT
523
524#
525# Mini-report on what will be built
526#
527AS_ECHO()
528
529AS_ECHO("Version name: $version_name")
530AS_ECHO("$version_description")
531
532AS_ECHO()
533
534# Target architecture we're building for
535target_arch=$host_cpu
536[
537for f in $CFLAGS; do
538 if test $f = "-m32"; then
539 target_arch="32-bit"
540 elif test $f = "-m64"; then
541 target_arch="64-bit"
542 fi
543done
544]
545AS_ECHO_N("Target architecture: ")
546AS_ECHO($target_arch)
547
548# kmod enabled/disabled
549AS_ECHO_N("libkmod support: ")
550AS_IF([test "x$kmod_found" = "xyes"],[
551 AS_ECHO("Enabled")
552],[
553 AS_ECHO("Disabled")
554])
555
556# LTTng-UST enabled/disabled
557AS_ECHO_N("Lttng-UST support: ")
558AS_IF([test "x$lttng_ust_support" = "xyes"],[
559 AS_ECHO("Enabled")
560],[
561 AS_ECHO("Disabled")
562])
563
564#Python binding enabled/disabled
565AS_ECHO_N("Python binding: ")
566AS_IF([test "x${enable_python:-yes}" = xyes], [
567 AS_ECHO("Enabled")
568],[
569 AS_ECHO("Disabled")
570])
571
572# Do we build only the consumerd, or everything
573AS_IF([test "x$consumerd_only" = "xyes"],[
574 AS_ECHO("Only the consumerd daemon will be built.")
575],[
576 AS_ECHO("All binaries will be built.")
577])
578
579# Print the bindir and libdir this `make install' will install into.
580AS_ECHO()
581AS_ECHO_N("Binaries will be installed in: ")
582AS_ECHO("`eval eval echo $bindir`")
583AS_ECHO_N("Libraries will be installed in: ")
584AS_ECHO("`eval eval echo $libdir`")
585
586# If we build the sessiond, print the paths it will use
587AS_IF([test "x$consumerd_only" = "xno"],[
588 AS_ECHO()
589 AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
590 AS_IF([test "$SESSIOND_BIN" = ""],[
591 AS_ECHO_N("`eval eval echo $bindir`")
592 AS_ECHO("/lttng-sessiond")
593 ],[
594 AS_ECHO("$SESSIOND_BIN")
595 ])
596
597 AS_ECHO()
598 AS_ECHO("The sessiond daemon will look in the following directories: ")
599 AS_ECHO_N("32-bit consumerd executable at: ")
600 AS_IF([test "$CONSUMERD32_BIN" = ""],[
601 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
602 AS_ECHO("/lttng-consumerd")
603 ],[
604 AS_ECHO("$CONSUMERD32_BIN")
605 ])
606
607 AS_ECHO_N("32-bit consumer libraries in: ")
608 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
609 AS_ECHO("`eval eval echo $libdir`")
610 ],[
611 AS_ECHO("$CONSUMERD32_LIBDIR")
612 ])
613
614 AS_ECHO_N("64-bit consumerd executable at: ")
615 AS_IF([test "$CONSUMERD64_BIN" = ""],[
616 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
617 AS_ECHO("/lttng-consumerd")
618 ],[
619 AS_ECHO("$CONSUMERD64_BIN")
620 ])
621
622 AS_ECHO_N("64-bit consumer libraries in: ")
623 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
624 AS_ECHO("`eval eval echo $libdir`")
625 ],[
626 AS_ECHO("$CONSUMERD64_LIBDIR")
627 ])
628])
629
630AS_ECHO()
631
LTTng tools - Deliverables
This page took 0.025448 seconds and 5 git commands to generate.