configure.ac: Remove duplicated CMD_DESCR_ROTATE definition
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.12.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24 AC_PROG_CXX
25 RW_PROG_CXX_WORKS
26 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
27
28 # Checks for programs.
29 AC_PROG_GREP
30 AC_PROG_MAKE_SET
31 AC_PROG_SED
32 AC_PATH_PROG([report_fold], [fold])
33 LT_INIT
34
35 # Check for objcopy, required by the base address statedump and dynamic linker tests
36 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
37 AS_IF([test "x$OBJCOPY" = "xno"],
38 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
39 )
40 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
41
42 # check for pgrep
43 AC_PATH_PROG([PGREP], [pgrep], [no])
44 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
45
46 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
47 # is not distributed in tarballs
48 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
49 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
50
51 # check for bison
52 AC_PROG_YACC
53 BISON=$YACC
54 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
55
56 AS_IF([test "x$have_bison" != "xyes"], [
57 AS_IF([test "x$in_git_repo" = "xyes"], [
58 AC_MSG_FAILURE([
59 Bison >= 2.4 is required when building from the Git repository. You can
60 set the YACC variable to override automatic detection.
61 ])
62 ], [
63 AC_MSG_WARN([
64 Missing Bison >= 2.4. Note that the parser files are already built in
65 this distribution tarball, so Bison is only needed if you intend to
66 modify their sources. You can set the YACC variable to override automatic
67 detection.
68 ])
69 ])
70 ])
71 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
72
73 # check for flex
74 AC_PROG_LEX
75 FLEX=$LEX
76 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
77
78 AS_IF([test "x$have_flex" != "xyes"], [
79 AS_IF([test "x$in_git_repo" = "xyes"], [
80 AC_MSG_FAILURE([
81 Flex >= 2.5.35 is required when building from the Git repository. You can
82 set the LEX variable to override automatic detection.
83 ])
84 ], [
85 AC_MSG_WARN([
86 Missing Flex >= 2.5.35. Note that the lexer files are already built in
87 this distribution tarball, so Flex is only needed if you intend to
88 modify their sources. You can set the LEX variable to override automatic
89 detection.
90 ])
91 ])
92 ])
93 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
94
95
96 # Checks for typedefs, structures, and compiler characteristics.
97 AC_C_INLINE
98 AC_TYPE_INT32_T
99 AC_TYPE_INT64_T
100 AC_TYPE_MODE_T
101 AC_TYPE_OFF_T
102 AC_TYPE_PID_T
103 AC_TYPE_SIZE_T
104 AC_TYPE_SSIZE_T
105 AC_TYPE_UID_T
106 AC_TYPE_UINT16_T
107 AC_TYPE_UINT32_T
108 AC_TYPE_UINT64_T
109 AC_TYPE_UINT8_T
110
111 AX_C___ATTRIBUTE__
112 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
113 [:],
114 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
115
116 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
117
118 # Check if linker has the -no-pie option.
119 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
120 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
121
122 AX_LIB_SOCKET_NSL
123
124 LT_NO_UNDEFINED=""
125 AS_CASE([$host_os],
126 [cygwin*],
127 [
128 LT_NO_UNDEFINED="-no-undefined"
129 ],
130 [cygwin*|darwin*|mingw*|solaris*],
131 [
132 # On platforms where we only support the relayd, disable the other binaries by default
133 AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
134 AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
135 AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
136 AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
137 AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
138 AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
139 ]
140 )
141
142 AC_SUBST(LT_NO_UNDEFINED)
143
144 # Compute minor/major/patchlevel version numbers
145 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
146 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
147 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
148
149 AC_SUBST([MAJOR_VERSION], [$major_version])
150 AC_SUBST([MINOR_VERSION], [$minor_version])
151 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
152 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
153 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
154 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
155
156 version_name="Codename TBD"
157 version_description="Description TBD"
158 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
159
160 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
161 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
162
163 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
164 AC_ARG_ENABLE(libtool-linkdep-fixup,
165 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
166 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
167 libtool_fixup=$enableval,
168 libtool_fixup=yes)
169
170 AS_IF([test "x$libtool_fixup" = "xyes"],
171 [
172 libtool_m4="$srcdir/m4/libtool.m4"
173 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
174 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
175 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
176 AS_IF([test $libtool_flag_pattern_count -ne 0],
177 [
178 AC_MSG_RESULT([$libtool_flag_pattern_count])
179 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
180 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
181 ],
182 [
183 AC_MSG_RESULT([none])
184 ])
185 ])
186
187 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
188
189 AC_CHECK_HEADERS([ \
190 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
191 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
192 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
193 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
194 sys/mount.h sys/param.h sys/time.h elf.h
195 ])
196
197 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
198
199 # Basic functions check
200 AC_CHECK_FUNCS([ \
201 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
202 gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
203 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
204 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
205 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
206 sched_getcpu sysconf sync_file_range
207 ])
208
209 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
210 # add -lrt to LIBS
211 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
212
213 # Checks for dl.
214 AC_CHECK_LIB([dl], [dlopen], [
215 have_libdl=yes
216 libdl_name=dl
217 DL_LIBS="-ldl"
218 ], [
219 # libdl not found, check for dlopen in libc.
220 AC_CHECK_LIB([c], [dlopen], [
221 have_libc_dl=yes
222 libdl_name=c
223 DL_LIBS="-lc"
224 ], [
225 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
226 ])
227 ])
228 AC_SUBST(DL_LIBS)
229
230 # Check if libdl has dlmopen support.
231 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
232 AC_CHECK_LIB([$libdl_name], [dlmopen], [
233 AC_DEFINE([HAVE_DLMOPEN], [1])
234 HAVE_DLMOPEN=1
235 ], [
236 HAVE_DLMOPEN=0
237 ])
238 AC_SUBST(HAVE_DLMOPEN)
239
240 # Babeltrace viewer check
241 AC_ARG_WITH([babeltrace-bin],
242 AS_HELP_STRING([--with-babeltrace-bin],
243 [Location of the babeltrace viewer executable (including the filename)]),
244 [BABELTRACE_BIN="$withval"],
245 [BABELTRACE_BIN=''])
246 AC_SUBST([BABELTRACE_BIN])
247
248 # lttv-gui
249 AC_ARG_WITH([lttv-gui-bin],
250 AS_HELP_STRING([--with-lttv-gui-bin],
251 [Location of the lttv GUI viewer executable (including the filename)]),
252 [LTTV_GUI_BIN="$withval"],
253 [LTTV_GUI_BIN=''])
254 AC_SUBST([LTTV_GUI_BIN])
255
256 AC_ARG_WITH([consumerd32-bin],
257 AS_HELP_STRING([--with-consumerd32-bin],
258 [Location of the 32-bit consumerd executable (including the filename)]),
259 [CONSUMERD32_BIN="$withval"],
260 [CONSUMERD32_BIN=''])
261 AC_SUBST([CONSUMERD32_BIN])
262
263 AC_ARG_WITH([consumerd64-bin],
264 AS_HELP_STRING([--with-consumerd64-bin],
265 [Location of the 64-bit consumerd executable (including the filename)]),
266 [CONSUMERD64_BIN="$withval"],
267 [CONSUMERD64_BIN=''])
268 AC_SUBST([CONSUMERD64_BIN])
269
270 AC_ARG_WITH([consumerd32-libdir],
271 AS_HELP_STRING([--with-consumerd32-libdir],
272 [Directory containing the 32-bit consumerd libraries]),
273 [CONSUMERD32_LIBDIR="$withval"],
274 [CONSUMERD32_LIBDIR=''])
275 AC_SUBST([CONSUMERD32_LIBDIR])
276
277 AC_ARG_WITH([consumerd64-libdir],
278 AS_HELP_STRING([--with-consumerd64-libdir],
279 [Directory containing the 64-bit consumerd libraries]),
280 [CONSUMERD64_LIBDIR="$withval"],
281 [CONSUMERD64_LIBDIR=''])
282 AC_SUBST([CONSUMERD64_LIBDIR])
283
284 AC_ARG_WITH([sessiond-bin],
285 AS_HELP_STRING([--with-sessiond-bin],
286 [Location of the sessiond executable (including the filename)]),
287 [SESSIOND_BIN="$withval"],
288 [SESSIOND_BIN=''])
289 AC_SUBST([SESSIOND_BIN])
290
291 AC_ARG_WITH([lttng-system-rundir],
292 AS_HELP_STRING([--with-lttng-system-rundir],
293 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
294 [LTTNG_SYSTEM_RUNDIR="$withval"],
295 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
296 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
297
298 AC_ARG_ENABLE([test-java-agent-jul],
299 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
300 [test_java_agent_jul=$enableval],
301 [test_java_agent_jul=no]
302 )
303
304 AC_ARG_ENABLE([test-java-agent-log4j],
305 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
306 [test_java_agent_log4j=$enableval],
307 [test_java_agent_log4j=no]
308 )
309
310 AC_ARG_ENABLE([test-java-agent-all],
311 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
312 [test_java_agent_jul=$enableval
313 test_java_agent_log4j=$enableval],
314 [:]
315 )
316
317 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
318 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
319 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
320 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
321 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
322 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
323 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
324 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
325
326 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
327 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
328 $1="$2"
329 AC_SUBST([$1])
330 ])
331
332 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
333 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
334 $1="$2"
335 AC_SUBST([$1])
336 ])
337
338 # Default values
339 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
340 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
341 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
342 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
343 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
344 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
345 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
346 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
347 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
348 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
349 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
350 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
351 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
352 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
353 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
354 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
355 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
356 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
357 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
358 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
359 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
360 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
361 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
362 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
363 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
364 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
365 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
366 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
367 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
368 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
369 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
370 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
371 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
372 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
373 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
374 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
375 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
376 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
377 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
378 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
379 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
380 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
381 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
382 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
383 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
384 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
385 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
386 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
387 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
388
389 # Command short descriptions
390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
391 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
392 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
402 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
403 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
404 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
405 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
406 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
407 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
408 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
409 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
410 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
411 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
412 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
413 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
414 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
416
417 if test "x$prefix" = "xNONE"; then
418 prefix=$ac_default_prefix
419 fi
420 CONFDIR=`eval echo $sysconfdir`
421 AC_SUBST(CONFDIR)
422 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
423
424 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
425
426 # Check libpopt
427 PKG_CHECK_MODULES([POPT], [popt],
428 [
429 dnl PKG_CHECK_MODULES defines POPT_LIBS
430 ],
431 [
432 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
433 AC_MSG_WARN([Finding libpopt without pkg-config.])
434 AC_CHECK_LIB([popt],
435 [poptGetContext],
436 [POPT_LIBS="-lpopt"],
437 [
438 AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
439 ]
440 )
441 ]
442 )
443 AC_SUBST(POPT_LIBS)
444
445 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
446
447 # First, check for uuid in system libs
448 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
449 AC_CHECK_FUNCS([uuid_generate],
450 [
451 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
452 UUID_LIBS=""
453 ],
454 [
455 # Then, check if the pkg-config module is available, otherwise explicitly check
456 # for libuuid, or uuid support in the C-library.
457 PKG_CHECK_MODULES([UUID], [uuid],
458 [
459 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
460 dnl PKG_CHECK_MODULES defines UUID_LIBS
461 ],
462 [
463 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
464 AC_MSG_WARN([Finding libuuid without pkg-config.])
465 AC_CHECK_LIB([uuid], [uuid_generate],
466 [
467 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
468 UUID_LIBS="-luuid"
469 ],
470 [
471 # libuuid not found, check for uuid_create in libc.
472 AC_CHECK_LIB([c], [uuid_create],
473 [
474 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
475 UUID_LIBS="-lc"
476 ],
477 [
478 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
479 ]
480 )
481 ]
482 )
483 ]
484 )
485 ]
486 )
487 AC_SUBST(UUID_LIBS)
488
489 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
490
491 # URCU library version needed or newer
492 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
493
494 # Check liburcu needed function calls
495 AC_CHECK_DECL([cds_list_add], [],
496 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
497 AC_CHECK_DECL([cds_wfcq_init], [],
498 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
499 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
500 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
501 AC_CHECK_DECL([futex_async], [],
502 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
503 AC_CHECK_DECL([rcu_thread_offline], [],
504 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
505 AC_CHECK_DECL([rcu_thread_online], [],
506 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
507 AC_CHECK_DECL([caa_likely], [],
508 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
509 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
510 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
511
512 #Function added in urcu 0.7.0
513 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
514 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
515 )
516
517 #Function added in urcu 0.9.0
518 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
519 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
520 )
521
522 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
523 # it can be explicitly disabled with --without-kmod
524 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
525 AC_ARG_WITH([kmod],
526 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
527 [],
528 [with_kmod=check]
529 )
530
531 AS_IF([test "x$with_kmod" != "xno"],
532 [
533 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
534 [
535 AC_DEFINE([HAVE_KMOD], [1])
536 KMOD_LIBS="-lkmod"
537 ],
538 [
539 if test "x$with_kmod" != xcheck; then
540 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
541 else
542 with_kmod=no
543 fi
544 ]
545 )
546 ]
547 )
548 AC_SUBST(KMOD_LIBS)
549
550 # Check for liblttng-ust-ctl, fail if it's not found,
551 # it can be explicitly disabled with --without-lttng-ust
552 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
553 AC_ARG_WITH([lttng-ust],
554 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
555 [],
556 [with_lttng_ust=yes]
557 )
558
559 AS_IF([test "x$with_lttng_ust" = "xyes"], [
560 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
561
562 # Check for liblttng-ust
563 PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
564
565 # Check for liblttng-ust-ctl
566 PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
567
568 AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
569 ])
570
571 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
572
573
574 # Check for fmemopen
575 AC_CHECK_LIB([c], [fmemopen],
576 [
577 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
578 ]
579 )
580
581 # check for libpfm
582 AC_CHECK_LIB([pfm], [pfm_initialize],
583 [
584 have_libpfm=yes
585 ])
586 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
587
588 # For Python
589 # SWIG version needed or newer:
590 swig_version=2.0.0
591
592 AC_ARG_ENABLE([python-bindings],
593 [AC_HELP_STRING([--enable-python-bindings],
594 [compile Python bindings])],
595 [enable_python_binding=$enableval], [enable_python_binding=no])
596
597 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
598
599 if test "x$enable_python_binding" = xyes; then
600 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
601 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
602 AM_PATH_PYTHON([3.0])
603
604 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
605 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
606 AS_IF([test -z "$PYTHON_INCLUDE"], [
607 AS_IF([test -z "$PYTHON_CONFIG"], [
608 AC_PATH_PROGS([PYTHON_CONFIG],
609 [python$PYTHON_VERSION-config python-config],
610 [no],
611 [`dirname $PYTHON`])
612 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
613 ])
614 AC_MSG_CHECKING([python include flags])
615 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
616 AC_MSG_RESULT([$PYTHON_INCLUDE])
617 ])
618
619 else
620 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
621 [if you want Python bindings.])
622
623 fi
624
625 # Epoll check. If not present, the build will fallback on poll() API
626 AX_HAVE_EPOLL(
627 [AX_CONFIG_FEATURE_ENABLE(epoll)],
628 [AX_CONFIG_FEATURE_DISABLE(epoll)]
629 )
630 AX_CONFIG_FEATURE(
631 [epoll], [This platform supports epoll(7)],
632 [HAVE_EPOLL], [This platform supports epoll(7).],
633 [enable_epoll="yes"], [enable_epoll="no"]
634 )
635 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
636
637 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
638 [AX_CONFIG_FEATURE_ENABLE(dirfd)],
639 [AX_CONFIG_FEATURE_DISABLE(dirfd)]
640 )
641 AX_CONFIG_FEATURE(
642 [dirfd], [Use directory file descriptors],
643 [COMPAT_DIRFD], [This platform supports directory file descriptors.],
644 [enable_dirfd="yes"], [enable_dirfd="no"]
645 )
646 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
647
648 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
649 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
650
651 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
652 AX_JAVA_OPTIONS
653 AX_PROG_JAVAC
654 AX_PROG_JAVA
655 AX_PROG_JAR
656
657 AX_CHECK_CLASSPATH
658
659 # Check for Java UST agent common class first
660 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
661 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
662 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
663 fi
664
665 if test "x$test_java_agent_jul" = "xyes"; then
666 # Check for JUL agent class
667 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
668 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
669 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
670 fi
671 fi
672
673 if test "x$test_java_agent_log4j" = "xyes"; then
674 # Check for Log4j agent class
675 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
676 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
677 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
678 fi
679
680 # Check for Log4j class
681 AX_CHECK_CLASS(org.apache.log4j.Logger)
682 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
683 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
684 fi
685 fi
686 fi
687
688 # enable building man pages (user's intention)
689 AC_ARG_ENABLE(
690 man-pages,
691 AS_HELP_STRING(
692 [--disable-man-pages],
693 [Do not build and install man pages (already built in a distributed tarball)]
694 ),
695 [man_pages_opt=$enableval],
696 [man_pages_opt=yes]
697 )
698
699 # check for asciidoc and xmlto if we enabled building the man pages
700 have_asciidoc_xmlto=no
701 warn_prebuilt_man_pages=no
702
703 AS_IF([test "x$man_pages_opt" = "xyes"], [
704 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
705 AC_PATH_PROG([XMLTO], [xmlto], [no])
706
707 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
708 AS_IF([test "x$in_git_repo" = "xyes"], [
709 # this is an error because we're in the Git repo, which
710 # means the man pages are not already generated for us,
711 # thus asciidoc/xmlto are required because we were asked
712 # to build the man pages
713 AC_MSG_ERROR([
714 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
715 --disable-man-pages to disable building the man pages, in which case
716 they will not be installed.
717 ])
718 ], [
719 # only warn here: since we're in the tarball, the man
720 # pages should already be generated at this point, thus
721 # asciidoc/xmlto are not strictly required
722 warn_prebuilt_man_pages=yes
723 ])
724 ], [
725 have_asciidoc_xmlto=yes
726 ])
727 ])
728
729 # export man page build condition: build the man pages if the user
730 # asked for it, and if the tools are available
731 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
732 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
733
734 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
735
736 # embedded --help message
737 AC_ARG_ENABLE(
738 [embedded-help],
739 AS_HELP_STRING(
740 [--enable-embedded-help],
741 [Embed the --help messages in the executable files]
742 ),
743 [embedded_help=$enableval],
744 [embedded_help=no]
745 )
746 AS_IF([test "x$embedded_help" = "xyes"], [
747 AS_IF([test "x$man_pages_opt" = "xno"], [
748 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
749 ])
750 AC_PATH_PROG([man_prog_path], [man], [no])
751 AS_IF([test "x$man_prog_path" = "xno"], [
752 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
753 ])
754 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
755 AC_SUBST([MANPROG], [$man_prog_path])
756 ])
757 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
758
759 # Python agent test
760 UST_PYTHON_AGENT="lttngust"
761
762 AC_ARG_ENABLE(test-python2-agent,
763 AS_HELP_STRING([--enable-test-python2-agent],
764 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
765 ),[:],[test_python2_agent_autodetect=yes]
766 )
767
768 AC_ARG_ENABLE(test-python3-agent,
769 AS_HELP_STRING([--enable-test-python3-agent],
770 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
771 ),[:],[test_python3_agent_autodetect=yes]
772 )
773
774 AC_ARG_ENABLE(test-python-agent-all,
775 AS_HELP_STRING([--enable-test-python-agent-all],
776 [enable test for all python{2/3} agent.]
777 ),
778 )
779
780 AS_IF([test ! -z "$enable_test_python_agent_all"], [
781 unset test_python2_agent_autodetect
782 unset test_python3_agent_autodetect
783 ])
784
785 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
786 enable_test_python2_agent=yes
787 enable_test_python3_agent=yes
788 ])
789
790 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
791 enable_test_python2_agent=no
792 enable_test_python3_agent=no
793 ])
794
795
796 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
797 AS_IF([test -z "$PYTHON2"], [
798 PYTHON2=python2
799 ], [
800 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
801 ])
802
803 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
804 AS_IF([test -z "$PYTHON2_BIN"], [
805 AS_IF([test -z "$test_python2_agent_autodetect"],[
806 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
807 ])
808 ], [
809 AC_MSG_CHECKING([for python2 lttng-ust agent])
810 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
811 PYTHON2_AGENT=$PYTHON2_BIN
812 AC_MSG_RESULT([yes])
813 RUN_PYTHON_AGENT_TEST=yes
814 ], [
815 AC_MSG_RESULT([no])
816 AS_IF([test -z "$test_python2_agent_autodetect"],[
817 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
818 ])
819 ])
820
821 ])
822
823 ])
824
825 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
826 AS_IF([test -z "$PYTHON3"], [
827 PYTHON3=python3
828 ], [
829 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
830 ])
831
832 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
833 AS_IF([test -z "$PYTHON3_BIN"], [
834 AS_IF([test -z "$test_python3_agent_autodetect"],[
835 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
836 ])
837 ], [
838 AC_MSG_CHECKING([for python3 lttng-ust agent])
839 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
840 PYTHON3_AGENT=$PYTHON3_BIN
841 AC_MSG_RESULT([yes])
842 RUN_PYTHON_AGENT_TEST=yes
843 ], [
844 AC_MSG_RESULT([no])
845 AS_IF([test -z "$test_python3_agent_autodetect"],[
846 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
847 ])
848 ])
849
850 ])
851 ])
852 AC_SUBST([RUN_PYTHON_AGENT_TEST])
853 AC_SUBST([PYTHON2_AGENT])
854 AC_SUBST([PYTHON3_AGENT])
855
856 AC_ARG_ENABLE([test-sdt-uprobe],
857 [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
858 [test_sdt_uprobe="$enableval"],
859 [test_sdt_uprobe=autodetect]
860 )
861
862 AS_IF([test "$test_sdt_uprobe" != "no"], [
863 LTTNG_CHECK_SDT_WORKS
864 AC_PATH_PROG([DTRACE], [dtrace])
865 ])
866
867 AS_IF([test "$test_sdt_uprobe" = "yes"], [
868 AS_IF([test "$lttng_cv_sdt_works" = "no"], [
869 AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
870 ])
871 AS_IF([test "x$DTRACE" = "x"], [
872 AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
873 ])
874 ])
875
876 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
877 AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
878 AS_IF([test "x$DTRACE" != "x"], [
879 test_sdt_uprobe=yes
880 ])
881 ])
882 ])
883
884 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
885
886 # Arguments for binaries build exclusion
887 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
888 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
889 [Disable the build of lttng-consumerd binaries]))
890 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
891 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
892 [Disable the build of lttng-relayd binaries]))
893 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
894 [Disable the build of lttng-sessiond binaries]))
895 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
896 [Disable the build of the extra components]))
897
898
899 # Always build libconfig since it a dependency of libcommon
900 build_lib_config=yes
901
902 build_lib_compat=no
903 build_lib_consumer=no
904 build_lib_hashtable=no
905 build_lib_health=no
906 build_lib_index=no
907 build_lib_kernel_consumer=no
908 build_lib_kernel_ctl=no
909 build_lib_lttng_ctl=no
910 build_lib_relayd=no
911 build_lib_sessiond_comm=no
912 build_lib_testpoint=no
913 build_lib_ust_consumer=no
914
915 # There is an overlap for enabled dependencies, but this makes everything
916 # simpler. libcommon and libconfig are always compiled so they are not repeated
917 # here.
918
919 # Enable binary dependencies.
920 AS_IF([test x$enable_bin_lttng != xno],
921 [
922 build_lib_lttng_ctl=yes
923 ]
924 )
925
926 AS_IF([test x$enable_bin_lttng_consumerd != xno],
927 [
928 build_lib_consumer=yes
929 build_lib_sessiond_comm=yes
930 build_lib_index=yes
931 build_lib_health=yes
932 build_lib_testpoint=yes
933 ]
934 )
935
936 AS_IF([test x$enable_bin_lttng_crash != xno],
937 # Do nothing since libconfig and libcommon are built by default.
938 []
939 )
940
941 AS_IF([test x$enable_bin_lttng_relayd != xno],
942 [
943 build_lib_lttng_ctl=yes
944 build_lib_sessiond_comm=yes
945 build_lib_hashtable=yes
946 build_lib_compat=yes
947 build_lib_index=yes
948 build_lib_health=yes
949 build_lib_testpoint=yes
950 ]
951 )
952 AS_IF([test x$enable_bin_lttng_sessiond != xno],
953 [
954 build_lib_lttng_ctl=yes
955 build_lib_sessiond_comm=yes
956 build_lib_kernel_ctl=yes
957 build_lib_hashtable=yes
958 build_lib_compat=yes
959 build_lib_relayd=yes
960 build_lib_testpoint=yes
961 build_lib_health=yes
962 ]
963 )
964
965 # Libraries dependencies enabling
966 AS_IF([test x$build_lib_lttng_ctl = xyes],
967 [
968 build_lib_sessiond_comm=yes
969 build_lib_hashtable=yes
970 ]
971 )
972
973 AS_IF([test x$build_lib_consumer = xyes],
974 [
975 build_lib_sessiond_comm=yes
976 build_lib_kernel_consumer=yes
977 build_lib_hashtable=yes
978 build_lib_compat=yes
979 build_lib_relayd=yes
980 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
981 ]
982 )
983
984 AS_IF([test x$build_lib_kernel_consumer = xyes],
985 [
986 build_lib_kernel_ctl=yes
987 build_lib_relayd=yes
988 ]
989 )
990
991 AS_IF([test x$build_lib_relayd = xyes],
992 [
993 build_lib_sessiond_comm=yes
994 ]
995 )
996
997 # Find arch type
998 AS_CASE([$host_cpu],
999 [k1om], [ARCHTYPE="x86"],
1000 [i386], [ARCHTYPE="x86"],
1001 [i486], [ARCHTYPE="x86"],
1002 [i586], [ARCHTYPE="x86"],
1003 [i686], [ARCHTYPE="x86"],
1004 [amd64], [ARCHTYPE="x86"],
1005 [x86_64], [ARCHTYPE="x86"],
1006 [powerpc], [ARCHTYPE="ppc"],
1007 [ppc64], [ARCHTYPE="ppc"],
1008 [powerpc64], [ARCHTYPE="ppc"],
1009 [powerpc64le], [ARCHTYPE="ppc"],
1010 [ppc], [ARCHTYPE="ppc"],
1011 [s390], [ARCHTYPE="s390"],
1012 [s390x], [ARCHTYPE="s390"],
1013 [sparc], [ARCHTYPE="sparc64"],
1014 [sparc64], [ARCHTYPE="sparc64"],
1015 [alpha*], [ARCHTYPE="alpha"],
1016 [ia64], [ARCHTYPE="ia64"],
1017 [arm*], [ARCHTYPE="arm"],
1018 [aarch64*], [ARCHTYPE="aarch64"],
1019 [mips*], [ARCHTYPE="mips"],
1020 [nios2*], [ARCHTYPE="nios2"],
1021 [tile*], [ARCHTYPE="tile"],
1022 [hppa*], [ARCHTYPE="hppa"],
1023 [m68k], [ARCHTYPE="m68k"],
1024 [riscv*], [ARCHTYPE="riscv"],
1025 [ARCHTYPE="unknown"]
1026 )
1027
1028 AC_SUBST(ARCHTYPE)
1029
1030 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1031 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1032 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1033 # Userspace callstack capture is only supported by the Linux kernel on x86.
1034 AC_MSG_RESULT([yes])
1035 have_modules_userspace_callstack_context=yes
1036 AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1037 ], [
1038 AC_MSG_RESULT([no])
1039 have_modules_userspace_callstack_context=no
1040 ])
1041 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1042
1043 # Export binaries build conditions.
1044 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1045 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1046 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1047 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1048 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1049
1050 # Export the tests and extras build conditions.
1051 AS_IF([\
1052 test "x$enable_bin_lttng" != "xno" && \
1053 test "x$enable_bin_lttng_consumerd" != "xno" && \
1054 test "x$enable_bin_lttng_crash" != "xno" && \
1055 test "x$enable_bin_lttng_relayd" != "xno" && \
1056 test "x$enable_bin_lttng_sessiond" != "xno"],
1057 [build_tests=yes],
1058 [build_tests=no]
1059 )
1060
1061 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1062 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1063
1064 # Export libraries build conditions.
1065 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1066 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1067 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1068 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1069 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1070 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1071 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1072 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1073 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1074 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1075 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1076 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1077 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1078
1079 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1080 AC_SUBST(AM_CFLAGS)
1081
1082 # The order in which the include folders are searched is important.
1083 # The top_builddir should always be searched first in the event that a build
1084 # time generated file is included. An example of this is the "version.i" file.
1085 # In a scenario where lttng-tools is built from a distribution tarball and in a
1086 # out-of-tree manner, the generated "version.i" has priority on the one from
1087 # the source (distribution tarball) and must be found first.
1088 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1089 AC_SUBST(AM_CPPFLAGS)
1090
1091 lttngincludedir="${includedir}/lttng"
1092 AC_SUBST(lttngincludedir)
1093
1094 lttngactionincludedir="${includedir}/lttng/action"
1095 AC_SUBST(lttngactionincludedir)
1096
1097 lttngconditionincludedir="${includedir}/lttng/condition"
1098 AC_SUBST(lttngconditionincludedir)
1099
1100 lttngnotificationincludedir="${includedir}/lttng/notification"
1101 AC_SUBST(lttngnotificationincludedir)
1102
1103 lttngtriggerincludedir="${includedir}/lttng/trigger"
1104 AC_SUBST(lttngtriggerincludedir)
1105
1106 lttnglibexecdir="${libdir}/lttng/libexec"
1107 AC_SUBST(lttnglibexecdir)
1108
1109 AC_CONFIG_FILES([
1110 Makefile
1111 doc/Makefile
1112 doc/man/Makefile
1113 doc/man/asciidoc-attrs.conf
1114 include/Makefile
1115 extras/Makefile
1116 extras/bindings/Makefile
1117 extras/bindings/swig/Makefile
1118 extras/bindings/swig/python/Makefile
1119 extras/core-handler/Makefile
1120 src/Makefile
1121 src/common/Makefile
1122 src/common/kernel-ctl/Makefile
1123 src/common/kernel-consumer/Makefile
1124 src/common/consumer/Makefile
1125 src/common/ust-consumer/Makefile
1126 src/common/hashtable/Makefile
1127 src/common/sessiond-comm/Makefile
1128 src/common/compat/Makefile
1129 src/common/relayd/Makefile
1130 src/common/testpoint/Makefile
1131 src/common/index/Makefile
1132 src/common/health/Makefile
1133 src/common/config/Makefile
1134 src/common/string-utils/Makefile
1135 src/common/fd-tracker/Makefile
1136 src/lib/Makefile
1137 src/lib/lttng-ctl/Makefile
1138 src/lib/lttng-ctl/filter/Makefile
1139 src/lib/lttng-ctl/lttng-ctl.pc
1140 src/bin/Makefile
1141 src/bin/lttng-consumerd/Makefile
1142 src/bin/lttng-sessiond/Makefile
1143 src/bin/lttng-relayd/Makefile
1144 src/bin/lttng/Makefile
1145 src/bin/lttng-crash/Makefile
1146 tests/Makefile
1147 tests/destructive/Makefile
1148 tests/regression/Makefile
1149 tests/regression/kernel/Makefile
1150 tests/regression/tools/Makefile
1151 tests/regression/tools/streaming/Makefile
1152 tests/regression/tools/filtering/Makefile
1153 tests/regression/tools/health/Makefile
1154 tests/regression/tools/tracefile-limits/Makefile
1155 tests/regression/tools/snapshots/Makefile
1156 tests/regression/tools/live/Makefile
1157 tests/regression/tools/exclusion/Makefile
1158 tests/regression/tools/save-load/Makefile
1159 tests/regression/tools/save-load/configuration/Makefile
1160 tests/regression/tools/mi/Makefile
1161 tests/regression/tools/wildcard/Makefile
1162 tests/regression/tools/crash/Makefile
1163 tests/regression/tools/regen-metadata/Makefile
1164 tests/regression/tools/regen-statedump/Makefile
1165 tests/regression/tools/notification/Makefile
1166 tests/regression/tools/rotation/Makefile
1167 tests/regression/tools/base-path/Makefile
1168 tests/regression/tools/metadata/Makefile
1169 tests/regression/tools/working-directory/Makefile
1170 tests/regression/tools/relayd-grouping/Makefile
1171 tests/regression/ust/Makefile
1172 tests/regression/ust/nprocesses/Makefile
1173 tests/regression/ust/high-throughput/Makefile
1174 tests/regression/ust/low-throughput/Makefile
1175 tests/regression/ust/before-after/Makefile
1176 tests/regression/ust/buffers-pid/Makefile
1177 tests/regression/ust/periodical-metadata-flush/Makefile
1178 tests/regression/ust/multi-session/Makefile
1179 tests/regression/ust/multi-lib/Makefile
1180 tests/regression/ust/overlap/Makefile
1181 tests/regression/ust/overlap/demo/Makefile
1182 tests/regression/ust/linking/Makefile
1183 tests/regression/ust/daemon/Makefile
1184 tests/regression/ust/exit-fast/Makefile
1185 tests/regression/ust/fork/Makefile
1186 tests/regression/ust/libc-wrapper/Makefile
1187 tests/regression/ust/baddr-statedump/Makefile
1188 tests/regression/ust/ust-dl/Makefile
1189 tests/regression/ust/java-jul/Makefile
1190 tests/regression/ust/java-log4j/Makefile
1191 tests/regression/ust/python-logging/Makefile
1192 tests/regression/ust/getcpu-override/Makefile
1193 tests/regression/ust/clock-override/Makefile
1194 tests/regression/ust/type-declarations/Makefile
1195 tests/regression/ust/rotation-destroy-flush/Makefile
1196 tests/regression/ust/blocking/Makefile
1197 tests/regression/ust/namespaces/Makefile
1198 tests/stress/Makefile
1199 tests/unit/Makefile
1200 tests/unit/ini_config/Makefile
1201 tests/perf/Makefile
1202 tests/utils/Makefile
1203 tests/utils/tap/Makefile
1204 tests/utils/testapp/Makefile
1205 tests/utils/testapp/gen-ns-events/Makefile
1206 tests/utils/testapp/gen-ust-events/Makefile
1207 tests/utils/testapp/gen-ust-events-ns/Makefile
1208 tests/utils/testapp/gen-syscall-events-callstack/Makefile
1209 tests/utils/testapp/gen-ust-nevents/Makefile
1210 tests/utils/testapp/gen-ust-nevents-str/Makefile
1211 tests/utils/testapp/gen-syscall-events/Makefile
1212 tests/utils/testapp/gen-ust-tracef/Makefile
1213 tests/utils/testapp/userspace-probe-elf-binary/Makefile
1214 tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1215 tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1216 ])
1217
1218 # Inject variable into python test script.
1219 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1220 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1221 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1222 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1223
1224 AC_OUTPUT
1225
1226 #
1227 # Mini-report on what will be built.
1228 #
1229
1230 PPRINT_INIT
1231 PPRINT_SET_INDENT(1)
1232 PPRINT_SET_TS(38)
1233
1234 AS_ECHO
1235 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1236 AS_ECHO
1237
1238 AS_IF([test -n "$report_fold"], [
1239 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1240 ], [
1241 AS_ECHO("$version_description")
1242 ])
1243
1244 AS_ECHO
1245 PPRINT_SUBTITLE([Features])
1246
1247 # Target architecture we're building for.
1248 target_arch=$host_cpu
1249 [
1250 for f in $CFLAGS; do
1251 if test $f = "-m32"; then
1252 target_arch="32-bit"
1253 elif test $f = "-m64"; then
1254 target_arch="64-bit"
1255 fi
1256 done
1257 ]
1258 PPRINT_PROP_STRING([Target architecture], $target_arch)
1259
1260 # kmod enabled/disabled
1261 test "x$with_kmod" != "xno" && value=1 || value=0
1262 PPRINT_PROP_BOOL([libkmod support], $value)
1263
1264 # LTTng-UST enabled/disabled
1265 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1266 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1267
1268 AS_ECHO
1269 PPRINT_SUBTITLE([Binaries])
1270
1271 # List binaries to be built
1272 test x$enable_bin_lttng != xno && value=1 || value=0
1273 PPRINT_PROP_BOOL([lttng], $value)
1274
1275 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1276 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1277
1278 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1279 PPRINT_PROP_BOOL([lttng-crash], $value)
1280
1281 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1282 PPRINT_PROP_BOOL([lttng-relayd], $value)
1283
1284 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1285 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1286
1287 # Extras
1288 test x$enable_extras != xno && value=1 || value=0
1289 AS_ECHO
1290 PPRINT_SET_INDENT(0)
1291 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1292 PPRINT_SET_INDENT(1)
1293
1294 AS_ECHO
1295 PPRINT_SUBTITLE([Tests])
1296
1297 # Print clear message that tests won't be built
1298 AS_IF([test "x$build_tests" = "xno"],[
1299 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1300 ])
1301
1302 # LTTng UST Java agent JUL tests enabled/disabled
1303 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1304 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1305
1306 # LTTng UST Java agent Log4j tests enabled/disabled
1307 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1308 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1309
1310 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1311 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1312
1313 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1314 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1315
1316 # LTTng UST Java agent Log4j tests enabled/disabled
1317 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1318 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1319
1320 #Python binding enabled/disabled
1321 test "x$enable_python_binding" = xyes && value=1 || value=0
1322 AS_ECHO
1323 PPRINT_SET_INDENT(0)
1324 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1325
1326 # man pages build enabled/disabled
1327 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1328
1329 AS_IF([test "x$man_pages_opt" != "xno"], [
1330 AS_IF([test "x$in_git_repo" = "xyes"], [
1331 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1332 ], [
1333 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1334 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1335 ], [
1336 PPRINT_PROP_STRING([build_man_pages_msg],
1337 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1338 $PPRINT_COLOR_SUBTITLE)
1339 ])
1340 ])
1341 ], [
1342 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1343 ])
1344
1345 m4_popdef([build_man_pages_msg])
1346
1347 test "x$embedded_help" = xyes && value=1 || value=0
1348 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1349
1350 PPRINT_SET_INDENT(1)
1351
1352 report_bindir="`eval eval echo $bindir`"
1353 report_libdir="`eval eval echo $libdir`"
1354
1355 # Print the bindir and libdir this `make install' will install into.
1356 AS_ECHO
1357 PPRINT_SUBTITLE([Install directories])
1358 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1359 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1360
1361 AS_ECHO
1362 PPRINT_SUBTITLE([Search directories])
1363
1364 # If we build the sessiond, print the paths it will use
1365 AS_IF([test "$SESSIOND_BIN" = ""],[
1366 path="$report_bindir/lttng-sessiond"
1367 ],[
1368 path="$SESSIOND_BIN"
1369 ])
1370 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1371
1372 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1373 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1374 ],[
1375 path="$CONSUMERD32_BIN"
1376 ])
1377 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1378
1379 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1380 path="`eval eval echo $libdir`"
1381 ],[
1382 path="$CONSUMERD32_LIBDIR"
1383 ])
1384 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1385
1386 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1387 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1388 ],[
1389 path="$CONSUMERD64_BIN"
1390 ])
1391 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1392
1393 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1394 path="`eval eval echo $libdir`"
1395 ],[
1396 path="$CONSUMERD64_LIBDIR"
1397 ])
1398 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1399 PPRINT_SET_INDENT(0)
1400
1401 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1402 AS_ECHO
1403 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1404
1405 Note that the man pages are already built in this distribution tarball,
1406 therefore asciidoc and xmlto are only needed if you intend to modify
1407 their sources.
1408
1409 Also note that the installed man pages will contain the project's
1410 default command-line option and environment variable values.
1411
1412 Use --disable-man-pages to completely disable building and installing
1413 the man pages.])
1414 ])
This page took 0.099259 seconds and 5 git commands to generate.