c60e96715b156882a78fd2176bad6a86322e0a07
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.12.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24 AC_PROG_CXX
25 RW_PROG_CXX_WORKS
26 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
27
28 # Checks for programs.
29 AC_PROG_GREP
30 AC_PROG_MAKE_SET
31 AC_PROG_SED
32 AC_PATH_PROG([report_fold], [fold])
33 LT_INIT
34
35 # Check for objcopy, required by the base address statedump and dynamic linker tests
36 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
37 AS_IF([test "x$OBJCOPY" = "xno"],
38 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
39 )
40 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
41
42 # check for pgrep
43 AC_PATH_PROG([PGREP], [pgrep], [no])
44 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
45
46 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
47 # is not distributed in tarballs
48 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
49 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
50
51 # check for bison
52 AC_PROG_YACC
53 BISON=$YACC
54 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
55
56 AS_IF([test "x$have_bison" != "xyes"], [
57 AS_IF([test "x$in_git_repo" = "xyes"], [
58 AC_MSG_FAILURE([
59 Bison >= 2.4 is required when building from the Git repository. You can
60 set the YACC variable to override automatic detection.
61 ])
62 ], [
63 AC_MSG_WARN([
64 Missing Bison >= 2.4. Note that the parser files are already built in
65 this distribution tarball, so Bison is only needed if you intend to
66 modify their sources. You can set the YACC variable to override automatic
67 detection.
68 ])
69 ])
70 ])
71 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
72
73 # check for flex
74 AC_PROG_LEX
75 FLEX=$LEX
76 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
77
78 AS_IF([test "x$have_flex" != "xyes"], [
79 AS_IF([test "x$in_git_repo" = "xyes"], [
80 AC_MSG_FAILURE([
81 Flex >= 2.5.35 is required when building from the Git repository. You can
82 set the LEX variable to override automatic detection.
83 ])
84 ], [
85 AC_MSG_WARN([
86 Missing Flex >= 2.5.35. Note that the lexer files are already built in
87 this distribution tarball, so Flex is only needed if you intend to
88 modify their sources. You can set the LEX variable to override automatic
89 detection.
90 ])
91 ])
92 ])
93 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
94
95
96 # Checks for typedefs, structures, and compiler characteristics.
97 AC_C_INLINE
98 AC_TYPE_INT32_T
99 AC_TYPE_INT64_T
100 AC_TYPE_MODE_T
101 AC_TYPE_OFF_T
102 AC_TYPE_PID_T
103 AC_TYPE_SIZE_T
104 AC_TYPE_SSIZE_T
105 AC_TYPE_UID_T
106 AC_TYPE_UINT16_T
107 AC_TYPE_UINT32_T
108 AC_TYPE_UINT64_T
109 AC_TYPE_UINT8_T
110
111 AX_C___ATTRIBUTE__
112 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
113 [:],
114 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
115
116 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
117
118 # Check if linker has the -no-pie option.
119 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
120 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
121
122 AX_LIB_SOCKET_NSL
123
124 LT_NO_UNDEFINED=""
125 AS_CASE([$host_os],
126 [cygwin*],
127 [
128 LT_NO_UNDEFINED="-no-undefined"
129 ],
130 [cygwin*|darwin*|mingw*|solaris*],
131 [
132 # On platforms where we only support the relayd, disable the other binaries by default
133 AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
134 AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
135 AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
136 AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
137 AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
138 AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
139 ]
140 )
141
142 AC_SUBST(LT_NO_UNDEFINED)
143
144 # Compute minor/major/patchlevel version numbers
145 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
146 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
147 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
148
149 AC_SUBST([MAJOR_VERSION], [$major_version])
150 AC_SUBST([MINOR_VERSION], [$minor_version])
151 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
152 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
153 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
154 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
155
156 version_name="Codename TBD"
157 version_description="Description TBD"
158 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
159
160 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
161 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
162
163 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
164 AC_ARG_ENABLE(libtool-linkdep-fixup,
165 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
166 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
167 libtool_fixup=$enableval,
168 libtool_fixup=yes)
169
170 AS_IF([test "x$libtool_fixup" = "xyes"],
171 [
172 libtool_m4="$srcdir/m4/libtool.m4"
173 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
174 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
175 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
176 AS_IF([test $libtool_flag_pattern_count -ne 0],
177 [
178 AC_MSG_RESULT([$libtool_flag_pattern_count])
179 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
180 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
181 ],
182 [
183 AC_MSG_RESULT([none])
184 ])
185 ])
186
187 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
188
189 AC_CHECK_HEADERS([ \
190 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
191 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
192 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
193 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
194 sys/mount.h sys/param.h sys/time.h elf.h
195 ])
196
197 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
198
199 # Basic functions check
200 AC_CHECK_FUNCS([ \
201 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
202 gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
203 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
204 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
205 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
206 sched_getcpu sysconf sync_file_range
207 ])
208
209 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
210 # add -lrt to LIBS
211 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
212
213 # Checks for dl.
214 AC_CHECK_LIB([dl], [dlopen], [
215 have_libdl=yes
216 libdl_name=dl
217 DL_LIBS="-ldl"
218 ], [
219 # libdl not found, check for dlopen in libc.
220 AC_CHECK_LIB([c], [dlopen], [
221 have_libc_dl=yes
222 libdl_name=c
223 DL_LIBS="-lc"
224 ], [
225 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
226 ])
227 ])
228 AC_SUBST(DL_LIBS)
229
230 # Check if libdl has dlmopen support.
231 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
232 AC_CHECK_LIB([$libdl_name], [dlmopen], [
233 AC_DEFINE([HAVE_DLMOPEN], [1])
234 HAVE_DLMOPEN=1
235 ], [
236 HAVE_DLMOPEN=0
237 ])
238 AC_SUBST(HAVE_DLMOPEN)
239
240 # Babeltrace viewer check
241 AC_ARG_WITH([babeltrace-bin],
242 AS_HELP_STRING([--with-babeltrace-bin],
243 [Location of the babeltrace viewer executable (including the filename)]),
244 [BABELTRACE_BIN="$withval"],
245 [BABELTRACE_BIN=''])
246 AC_SUBST([BABELTRACE_BIN])
247
248 # lttv-gui
249 AC_ARG_WITH([lttv-gui-bin],
250 AS_HELP_STRING([--with-lttv-gui-bin],
251 [Location of the lttv GUI viewer executable (including the filename)]),
252 [LTTV_GUI_BIN="$withval"],
253 [LTTV_GUI_BIN=''])
254 AC_SUBST([LTTV_GUI_BIN])
255
256 AC_ARG_WITH([consumerd32-bin],
257 AS_HELP_STRING([--with-consumerd32-bin],
258 [Location of the 32-bit consumerd executable (including the filename)]),
259 [CONSUMERD32_BIN="$withval"],
260 [CONSUMERD32_BIN=''])
261 AC_SUBST([CONSUMERD32_BIN])
262
263 AC_ARG_WITH([consumerd64-bin],
264 AS_HELP_STRING([--with-consumerd64-bin],
265 [Location of the 64-bit consumerd executable (including the filename)]),
266 [CONSUMERD64_BIN="$withval"],
267 [CONSUMERD64_BIN=''])
268 AC_SUBST([CONSUMERD64_BIN])
269
270 AC_ARG_WITH([consumerd32-libdir],
271 AS_HELP_STRING([--with-consumerd32-libdir],
272 [Directory containing the 32-bit consumerd libraries]),
273 [CONSUMERD32_LIBDIR="$withval"],
274 [CONSUMERD32_LIBDIR=''])
275 AC_SUBST([CONSUMERD32_LIBDIR])
276
277 AC_ARG_WITH([consumerd64-libdir],
278 AS_HELP_STRING([--with-consumerd64-libdir],
279 [Directory containing the 64-bit consumerd libraries]),
280 [CONSUMERD64_LIBDIR="$withval"],
281 [CONSUMERD64_LIBDIR=''])
282 AC_SUBST([CONSUMERD64_LIBDIR])
283
284 AC_ARG_WITH([sessiond-bin],
285 AS_HELP_STRING([--with-sessiond-bin],
286 [Location of the sessiond executable (including the filename)]),
287 [SESSIOND_BIN="$withval"],
288 [SESSIOND_BIN=''])
289 AC_SUBST([SESSIOND_BIN])
290
291 AC_ARG_WITH([lttng-system-rundir],
292 AS_HELP_STRING([--with-lttng-system-rundir],
293 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
294 [LTTNG_SYSTEM_RUNDIR="$withval"],
295 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
296 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
297
298 AC_ARG_ENABLE([test-java-agent-jul],
299 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
300 [test_java_agent_jul=$enableval],
301 [test_java_agent_jul=no]
302 )
303
304 AC_ARG_ENABLE([test-java-agent-log4j],
305 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
306 [test_java_agent_log4j=$enableval],
307 [test_java_agent_log4j=no]
308 )
309
310 AC_ARG_ENABLE([test-java-agent-all],
311 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
312 [test_java_agent_jul=$enableval
313 test_java_agent_log4j=$enableval],
314 [:]
315 )
316
317 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
318 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
319 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
320 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
321 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
322 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
323 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
324 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
325
326 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
327 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
328 $1="$2"
329 AC_SUBST([$1])
330 ])
331
332 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
333 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
334 $1="$2"
335 AC_SUBST([$1])
336 ])
337
338 # Default values
339 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
340 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
341 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
342 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
343 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
344 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
345 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
346 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
347 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
348 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
349 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
350 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
351 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
352 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
353 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
354 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
355 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
356 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
357 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
358 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
359 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
360 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
361 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
362 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
363 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
364 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
365 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
366 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
367 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
368 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
369 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
370 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
371 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
372 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
373 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
374 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
375 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
376 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
377 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
378 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
379 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
380 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
381 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
382 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
383 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
384 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
385 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
386 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
387 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
388
389 # Command short descriptions
390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
391 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
392 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
402 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
403 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
404 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
405 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
406 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
407 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
408 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
409 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
410 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
411 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
412 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
413 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
414 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
416
417 if test "x$prefix" = "xNONE"; then
418 prefix=$ac_default_prefix
419 fi
420 CONFDIR=`eval echo $sysconfdir`
421 AC_SUBST(CONFDIR)
422 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
423
424 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
425
426 # Check libpopt
427 PKG_CHECK_MODULES([POPT], [popt],
428 [
429 dnl PKG_CHECK_MODULES defines POPT_LIBS
430 ],
431 [
432 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
433 AC_MSG_WARN([Finding libpopt without pkg-config.])
434 AC_CHECK_LIB([popt],
435 [poptGetContext],
436 [POPT_LIBS="-lpopt"],
437 [
438 AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
439 ]
440 )
441 ]
442 )
443 AC_SUBST(POPT_LIBS)
444
445 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
446
447 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
448
449 # URCU library version needed or newer
450 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
451
452 # Check liburcu needed function calls
453 AC_CHECK_DECL([cds_list_add], [],
454 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
455 AC_CHECK_DECL([cds_wfcq_init], [],
456 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
457 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
458 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
459 AC_CHECK_DECL([futex_async], [],
460 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
461 AC_CHECK_DECL([rcu_thread_offline], [],
462 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
463 AC_CHECK_DECL([rcu_thread_online], [],
464 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
465 AC_CHECK_DECL([caa_likely], [],
466 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
467 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
468 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
469
470 #Function added in urcu 0.7.0
471 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
472 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
473 )
474
475 #Function added in urcu 0.9.0
476 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
477 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
478 )
479
480 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
481 # it can be explicitly disabled with --without-kmod
482 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
483 AC_ARG_WITH([kmod],
484 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
485 [],
486 [with_kmod=check]
487 )
488
489 AS_IF([test "x$with_kmod" != "xno"],
490 [
491 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
492 [
493 AC_DEFINE([HAVE_KMOD], [1])
494 KMOD_LIBS="-lkmod"
495 ],
496 [
497 if test "x$with_kmod" != xcheck; then
498 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
499 else
500 with_kmod=no
501 fi
502 ]
503 )
504 ]
505 )
506 AC_SUBST(KMOD_LIBS)
507
508 # Check for liblttng-ust-ctl, fail if it's not found,
509 # it can be explicitly disabled with --without-lttng-ust
510 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
511 AC_ARG_WITH([lttng-ust],
512 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
513 [],
514 [with_lttng_ust=yes]
515 )
516
517 AS_IF([test "x$with_lttng_ust" = "xyes"], [
518 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
519
520 # Check for liblttng-ust
521 PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
522
523 # Check for liblttng-ust-ctl
524 PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
525
526 AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
527 ])
528
529 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
530
531
532 # Check for fmemopen
533 AC_CHECK_LIB([c], [fmemopen],
534 [
535 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
536 ]
537 )
538
539 # check for libpfm
540 AC_CHECK_LIB([pfm], [pfm_initialize],
541 [
542 have_libpfm=yes
543 ])
544 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
545
546 # For Python
547 # SWIG version needed or newer:
548 swig_version=2.0.0
549
550 AC_ARG_ENABLE([python-bindings],
551 [AC_HELP_STRING([--enable-python-bindings],
552 [compile Python bindings])],
553 [enable_python_binding=$enableval], [enable_python_binding=no])
554
555 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
556
557 if test "x$enable_python_binding" = xyes; then
558 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
559 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
560 AM_PATH_PYTHON([3.0])
561
562 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
563 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
564 AS_IF([test -z "$PYTHON_INCLUDE"], [
565 AS_IF([test -z "$PYTHON_CONFIG"], [
566 AC_PATH_PROGS([PYTHON_CONFIG],
567 [python$PYTHON_VERSION-config python-config],
568 [no],
569 [`dirname $PYTHON`])
570 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
571 ])
572 AC_MSG_CHECKING([python include flags])
573 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
574 AC_MSG_RESULT([$PYTHON_INCLUDE])
575 ])
576
577 else
578 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
579 [if you want Python bindings.])
580
581 fi
582
583 # Epoll check. If not present, the build will fallback on poll() API
584 AX_HAVE_EPOLL(
585 [AX_CONFIG_FEATURE_ENABLE(epoll)],
586 [AX_CONFIG_FEATURE_DISABLE(epoll)]
587 )
588 AX_CONFIG_FEATURE(
589 [epoll], [This platform supports epoll(7)],
590 [HAVE_EPOLL], [This platform supports epoll(7).],
591 [enable_epoll="yes"], [enable_epoll="no"]
592 )
593 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
594
595 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
596 [AX_CONFIG_FEATURE_ENABLE(dirfd)],
597 [AX_CONFIG_FEATURE_DISABLE(dirfd)]
598 )
599 AX_CONFIG_FEATURE(
600 [dirfd], [Use directory file descriptors],
601 [COMPAT_DIRFD], [This platform supports directory file descriptors.],
602 [enable_dirfd="yes"], [enable_dirfd="no"]
603 )
604 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
605
606 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
607 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
608
609 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
610 AX_JAVA_OPTIONS
611 AX_PROG_JAVAC
612 AX_PROG_JAVA
613 AX_PROG_JAR
614
615 AX_CHECK_CLASSPATH
616
617 # Check for Java UST agent common class first
618 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
619 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
620 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
621 fi
622
623 if test "x$test_java_agent_jul" = "xyes"; then
624 # Check for JUL agent class
625 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
626 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
627 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
628 fi
629 fi
630
631 if test "x$test_java_agent_log4j" = "xyes"; then
632 # Check for Log4j agent class
633 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
634 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
635 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
636 fi
637
638 # Check for Log4j class
639 AX_CHECK_CLASS(org.apache.log4j.Logger)
640 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
641 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
642 fi
643 fi
644 fi
645
646 # enable building man pages (user's intention)
647 AC_ARG_ENABLE(
648 man-pages,
649 AS_HELP_STRING(
650 [--disable-man-pages],
651 [Do not build and install man pages (already built in a distributed tarball)]
652 ),
653 [man_pages_opt=$enableval],
654 [man_pages_opt=yes]
655 )
656
657 # check for asciidoc and xmlto if we enabled building the man pages
658 have_asciidoc_xmlto=no
659 warn_prebuilt_man_pages=no
660
661 AS_IF([test "x$man_pages_opt" = "xyes"], [
662 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
663 AC_PATH_PROG([XMLTO], [xmlto], [no])
664
665 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
666 AS_IF([test "x$in_git_repo" = "xyes"], [
667 # this is an error because we're in the Git repo, which
668 # means the man pages are not already generated for us,
669 # thus asciidoc/xmlto are required because we were asked
670 # to build the man pages
671 AC_MSG_ERROR([
672 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
673 --disable-man-pages to disable building the man pages, in which case
674 they will not be installed.
675 ])
676 ], [
677 # only warn here: since we're in the tarball, the man
678 # pages should already be generated at this point, thus
679 # asciidoc/xmlto are not strictly required
680 warn_prebuilt_man_pages=yes
681 ])
682 ], [
683 have_asciidoc_xmlto=yes
684 ])
685 ])
686
687 # export man page build condition: build the man pages if the user
688 # asked for it, and if the tools are available
689 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
690 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
691
692 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
693
694 # embedded --help message
695 AC_ARG_ENABLE(
696 [embedded-help],
697 AS_HELP_STRING(
698 [--enable-embedded-help],
699 [Embed the --help messages in the executable files]
700 ),
701 [embedded_help=$enableval],
702 [embedded_help=no]
703 )
704 AS_IF([test "x$embedded_help" = "xyes"], [
705 AS_IF([test "x$man_pages_opt" = "xno"], [
706 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
707 ])
708 AC_PATH_PROG([man_prog_path], [man], [no])
709 AS_IF([test "x$man_prog_path" = "xno"], [
710 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
711 ])
712 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
713 AC_SUBST([MANPROG], [$man_prog_path])
714 ])
715 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
716
717 # Python agent test
718 UST_PYTHON_AGENT="lttngust"
719
720 AC_ARG_ENABLE(test-python2-agent,
721 AS_HELP_STRING([--enable-test-python2-agent],
722 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
723 ),[:],[test_python2_agent_autodetect=yes]
724 )
725
726 AC_ARG_ENABLE(test-python3-agent,
727 AS_HELP_STRING([--enable-test-python3-agent],
728 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
729 ),[:],[test_python3_agent_autodetect=yes]
730 )
731
732 AC_ARG_ENABLE(test-python-agent-all,
733 AS_HELP_STRING([--enable-test-python-agent-all],
734 [enable test for all python{2/3} agent.]
735 ),
736 )
737
738 AS_IF([test ! -z "$enable_test_python_agent_all"], [
739 unset test_python2_agent_autodetect
740 unset test_python3_agent_autodetect
741 ])
742
743 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
744 enable_test_python2_agent=yes
745 enable_test_python3_agent=yes
746 ])
747
748 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
749 enable_test_python2_agent=no
750 enable_test_python3_agent=no
751 ])
752
753
754 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
755 AS_IF([test -z "$PYTHON2"], [
756 PYTHON2=python2
757 ], [
758 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
759 ])
760
761 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
762 AS_IF([test -z "$PYTHON2_BIN"], [
763 AS_IF([test -z "$test_python2_agent_autodetect"],[
764 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
765 ])
766 ], [
767 AC_MSG_CHECKING([for python2 lttng-ust agent])
768 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
769 PYTHON2_AGENT=$PYTHON2_BIN
770 AC_MSG_RESULT([yes])
771 RUN_PYTHON_AGENT_TEST=yes
772 ], [
773 AC_MSG_RESULT([no])
774 AS_IF([test -z "$test_python2_agent_autodetect"],[
775 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
776 ])
777 ])
778
779 ])
780
781 ])
782
783 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
784 AS_IF([test -z "$PYTHON3"], [
785 PYTHON3=python3
786 ], [
787 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
788 ])
789
790 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
791 AS_IF([test -z "$PYTHON3_BIN"], [
792 AS_IF([test -z "$test_python3_agent_autodetect"],[
793 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
794 ])
795 ], [
796 AC_MSG_CHECKING([for python3 lttng-ust agent])
797 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
798 PYTHON3_AGENT=$PYTHON3_BIN
799 AC_MSG_RESULT([yes])
800 RUN_PYTHON_AGENT_TEST=yes
801 ], [
802 AC_MSG_RESULT([no])
803 AS_IF([test -z "$test_python3_agent_autodetect"],[
804 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
805 ])
806 ])
807
808 ])
809 ])
810 AC_SUBST([RUN_PYTHON_AGENT_TEST])
811 AC_SUBST([PYTHON2_AGENT])
812 AC_SUBST([PYTHON3_AGENT])
813
814 AC_ARG_ENABLE([test-sdt-uprobe],
815 [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
816 [test_sdt_uprobe="$enableval"],
817 [test_sdt_uprobe=autodetect]
818 )
819
820 AS_IF([test "$test_sdt_uprobe" != "no"], [
821 LTTNG_CHECK_SDT_WORKS
822 AC_PATH_PROG([DTRACE], [dtrace])
823 ])
824
825 AS_IF([test "$test_sdt_uprobe" = "yes"], [
826 AS_IF([test "$lttng_cv_sdt_works" = "no"], [
827 AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
828 ])
829 AS_IF([test "x$DTRACE" = "x"], [
830 AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
831 ])
832 ])
833
834 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
835 AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
836 AS_IF([test "x$DTRACE" != "x"], [
837 test_sdt_uprobe=yes
838 ])
839 ])
840 ])
841
842 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
843
844 # Arguments for binaries build exclusion
845 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
846 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
847 [Disable the build of lttng-consumerd binaries]))
848 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
849 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
850 [Disable the build of lttng-relayd binaries]))
851 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
852 [Disable the build of lttng-sessiond binaries]))
853 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
854 [Disable the build of the extra components]))
855
856
857 # Always build libconfig since it a dependency of libcommon
858 build_lib_config=yes
859
860 build_lib_compat=no
861 build_lib_consumer=no
862 build_lib_hashtable=no
863 build_lib_health=no
864 build_lib_index=no
865 build_lib_kernel_consumer=no
866 build_lib_kernel_ctl=no
867 build_lib_lttng_ctl=no
868 build_lib_relayd=no
869 build_lib_fd_tracker=no
870 build_lib_sessiond_comm=no
871 build_lib_testpoint=no
872 build_lib_ust_consumer=no
873
874 # There is an overlap for enabled dependencies, but this makes everything
875 # simpler. libcommon and libconfig are always compiled so they are not repeated
876 # here.
877
878 # Enable binary dependencies.
879 AS_IF([test x$enable_bin_lttng != xno],
880 [
881 build_lib_lttng_ctl=yes
882 ]
883 )
884
885 AS_IF([test x$enable_bin_lttng_consumerd != xno],
886 [
887 build_lib_consumer=yes
888 build_lib_sessiond_comm=yes
889 build_lib_index=yes
890 build_lib_health=yes
891 build_lib_testpoint=yes
892 ]
893 )
894
895 AS_IF([test x$enable_bin_lttng_crash != xno],
896 # Do nothing since libconfig and libcommon are built by default.
897 []
898 )
899
900 AS_IF([test x$enable_bin_lttng_relayd != xno],
901 [
902 build_lib_lttng_ctl=yes
903 build_lib_sessiond_comm=yes
904 build_lib_hashtable=yes
905 build_lib_compat=yes
906 build_lib_index=yes
907 build_lib_health=yes
908 build_lib_testpoint=yes
909 build_lib_fd_tracker=yes
910 ]
911 )
912 AS_IF([test x$enable_bin_lttng_sessiond != xno],
913 [
914 build_lib_lttng_ctl=yes
915 build_lib_sessiond_comm=yes
916 build_lib_kernel_ctl=yes
917 build_lib_hashtable=yes
918 build_lib_compat=yes
919 build_lib_relayd=yes
920 build_lib_testpoint=yes
921 build_lib_health=yes
922 ]
923 )
924
925 # Libraries dependencies enabling
926 AS_IF([test x$build_lib_lttng_ctl = xyes],
927 [
928 build_lib_sessiond_comm=yes
929 build_lib_hashtable=yes
930 ]
931 )
932
933 AS_IF([test x$build_lib_consumer = xyes],
934 [
935 build_lib_sessiond_comm=yes
936 build_lib_kernel_consumer=yes
937 build_lib_hashtable=yes
938 build_lib_compat=yes
939 build_lib_relayd=yes
940 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
941 ]
942 )
943
944 AS_IF([test x$build_lib_kernel_consumer = xyes],
945 [
946 build_lib_kernel_ctl=yes
947 build_lib_relayd=yes
948 ]
949 )
950
951 AS_IF([test x$build_lib_relayd = xyes],
952 [
953 build_lib_sessiond_comm=yes
954 ]
955 )
956
957 # Find arch type
958 AS_CASE([$host_cpu],
959 [k1om], [ARCHTYPE="x86"],
960 [i386], [ARCHTYPE="x86"],
961 [i486], [ARCHTYPE="x86"],
962 [i586], [ARCHTYPE="x86"],
963 [i686], [ARCHTYPE="x86"],
964 [amd64], [ARCHTYPE="x86"],
965 [x86_64], [ARCHTYPE="x86"],
966 [powerpc], [ARCHTYPE="ppc"],
967 [ppc64], [ARCHTYPE="ppc"],
968 [powerpc64], [ARCHTYPE="ppc"],
969 [powerpc64le], [ARCHTYPE="ppc"],
970 [ppc], [ARCHTYPE="ppc"],
971 [s390], [ARCHTYPE="s390"],
972 [s390x], [ARCHTYPE="s390"],
973 [sparc], [ARCHTYPE="sparc64"],
974 [sparc64], [ARCHTYPE="sparc64"],
975 [alpha*], [ARCHTYPE="alpha"],
976 [ia64], [ARCHTYPE="ia64"],
977 [arm*], [ARCHTYPE="arm"],
978 [aarch64*], [ARCHTYPE="aarch64"],
979 [mips*], [ARCHTYPE="mips"],
980 [nios2*], [ARCHTYPE="nios2"],
981 [tile*], [ARCHTYPE="tile"],
982 [hppa*], [ARCHTYPE="hppa"],
983 [m68k], [ARCHTYPE="m68k"],
984 [riscv*], [ARCHTYPE="riscv"],
985 [ARCHTYPE="unknown"]
986 )
987
988 AC_SUBST(ARCHTYPE)
989
990 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
991 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
992 AS_IF([test "x$ARCHTYPE" = "xx86"],[
993 # Userspace callstack capture is only supported by the Linux kernel on x86.
994 AC_MSG_RESULT([yes])
995 have_modules_userspace_callstack_context=yes
996 AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
997 ], [
998 AC_MSG_RESULT([no])
999 have_modules_userspace_callstack_context=no
1000 ])
1001 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1002
1003 # Export binaries build conditions.
1004 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1005 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1006 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1007 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1008 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1009
1010 # Export the tests and extras build conditions.
1011 AS_IF([\
1012 test "x$enable_bin_lttng" != "xno" && \
1013 test "x$enable_bin_lttng_consumerd" != "xno" && \
1014 test "x$enable_bin_lttng_crash" != "xno" && \
1015 test "x$enable_bin_lttng_relayd" != "xno" && \
1016 test "x$enable_bin_lttng_sessiond" != "xno"],
1017 [build_tests=yes],
1018 [build_tests=no]
1019 )
1020
1021 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1022 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1023
1024 # Export libraries build conditions.
1025 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1026 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1027 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1028 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1029 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1030 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1031 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1032 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1033 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1034 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1035 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1036 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1037 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1038 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1039
1040 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1041 AC_SUBST(AM_CFLAGS)
1042
1043 # The order in which the include folders are searched is important.
1044 # The top_builddir should always be searched first in the event that a build
1045 # time generated file is included. An example of this is the "version.i" file.
1046 # In a scenario where lttng-tools is built from a distribution tarball and in a
1047 # out-of-tree manner, the generated "version.i" has priority on the one from
1048 # the source (distribution tarball) and must be found first.
1049 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1050 AC_SUBST(AM_CPPFLAGS)
1051
1052 lttngincludedir="${includedir}/lttng"
1053 AC_SUBST(lttngincludedir)
1054
1055 lttngactionincludedir="${includedir}/lttng/action"
1056 AC_SUBST(lttngactionincludedir)
1057
1058 lttngconditionincludedir="${includedir}/lttng/condition"
1059 AC_SUBST(lttngconditionincludedir)
1060
1061 lttngnotificationincludedir="${includedir}/lttng/notification"
1062 AC_SUBST(lttngnotificationincludedir)
1063
1064 lttngtriggerincludedir="${includedir}/lttng/trigger"
1065 AC_SUBST(lttngtriggerincludedir)
1066
1067 lttnglibexecdir="${libdir}/lttng/libexec"
1068 AC_SUBST(lttnglibexecdir)
1069
1070 AC_CONFIG_FILES([
1071 Makefile
1072 doc/Makefile
1073 doc/man/Makefile
1074 doc/man/asciidoc-attrs.conf
1075 include/Makefile
1076 extras/Makefile
1077 extras/bindings/Makefile
1078 extras/bindings/swig/Makefile
1079 extras/bindings/swig/python/Makefile
1080 extras/core-handler/Makefile
1081 src/Makefile
1082 src/common/Makefile
1083 src/common/kernel-ctl/Makefile
1084 src/common/kernel-consumer/Makefile
1085 src/common/consumer/Makefile
1086 src/common/ust-consumer/Makefile
1087 src/common/hashtable/Makefile
1088 src/common/sessiond-comm/Makefile
1089 src/common/compat/Makefile
1090 src/common/relayd/Makefile
1091 src/common/testpoint/Makefile
1092 src/common/index/Makefile
1093 src/common/health/Makefile
1094 src/common/config/Makefile
1095 src/common/string-utils/Makefile
1096 src/common/fd-tracker/Makefile
1097 src/lib/Makefile
1098 src/lib/lttng-ctl/Makefile
1099 src/lib/lttng-ctl/filter/Makefile
1100 src/lib/lttng-ctl/lttng-ctl.pc
1101 src/bin/Makefile
1102 src/bin/lttng-consumerd/Makefile
1103 src/bin/lttng-sessiond/Makefile
1104 src/bin/lttng-relayd/Makefile
1105 src/bin/lttng/Makefile
1106 src/bin/lttng-crash/Makefile
1107 tests/Makefile
1108 tests/destructive/Makefile
1109 tests/regression/Makefile
1110 tests/regression/kernel/Makefile
1111 tests/regression/tools/Makefile
1112 tests/regression/tools/streaming/Makefile
1113 tests/regression/tools/filtering/Makefile
1114 tests/regression/tools/health/Makefile
1115 tests/regression/tools/tracefile-limits/Makefile
1116 tests/regression/tools/snapshots/Makefile
1117 tests/regression/tools/live/Makefile
1118 tests/regression/tools/exclusion/Makefile
1119 tests/regression/tools/save-load/Makefile
1120 tests/regression/tools/save-load/configuration/Makefile
1121 tests/regression/tools/mi/Makefile
1122 tests/regression/tools/wildcard/Makefile
1123 tests/regression/tools/crash/Makefile
1124 tests/regression/tools/regen-metadata/Makefile
1125 tests/regression/tools/regen-statedump/Makefile
1126 tests/regression/tools/notification/Makefile
1127 tests/regression/tools/rotation/Makefile
1128 tests/regression/tools/base-path/Makefile
1129 tests/regression/tools/metadata/Makefile
1130 tests/regression/tools/working-directory/Makefile
1131 tests/regression/tools/relayd-grouping/Makefile
1132 tests/regression/ust/Makefile
1133 tests/regression/ust/nprocesses/Makefile
1134 tests/regression/ust/high-throughput/Makefile
1135 tests/regression/ust/low-throughput/Makefile
1136 tests/regression/ust/before-after/Makefile
1137 tests/regression/ust/buffers-pid/Makefile
1138 tests/regression/ust/periodical-metadata-flush/Makefile
1139 tests/regression/ust/multi-session/Makefile
1140 tests/regression/ust/multi-lib/Makefile
1141 tests/regression/ust/overlap/Makefile
1142 tests/regression/ust/overlap/demo/Makefile
1143 tests/regression/ust/linking/Makefile
1144 tests/regression/ust/daemon/Makefile
1145 tests/regression/ust/exit-fast/Makefile
1146 tests/regression/ust/fork/Makefile
1147 tests/regression/ust/libc-wrapper/Makefile
1148 tests/regression/ust/baddr-statedump/Makefile
1149 tests/regression/ust/ust-dl/Makefile
1150 tests/regression/ust/java-jul/Makefile
1151 tests/regression/ust/java-log4j/Makefile
1152 tests/regression/ust/python-logging/Makefile
1153 tests/regression/ust/getcpu-override/Makefile
1154 tests/regression/ust/clock-override/Makefile
1155 tests/regression/ust/type-declarations/Makefile
1156 tests/regression/ust/rotation-destroy-flush/Makefile
1157 tests/regression/ust/blocking/Makefile
1158 tests/regression/ust/namespaces/Makefile
1159 tests/stress/Makefile
1160 tests/unit/Makefile
1161 tests/unit/ini_config/Makefile
1162 tests/perf/Makefile
1163 tests/utils/Makefile
1164 tests/utils/tap/Makefile
1165 tests/utils/testapp/Makefile
1166 tests/utils/testapp/gen-ns-events/Makefile
1167 tests/utils/testapp/gen-ust-events/Makefile
1168 tests/utils/testapp/gen-ust-events-ns/Makefile
1169 tests/utils/testapp/gen-syscall-events-callstack/Makefile
1170 tests/utils/testapp/gen-ust-nevents/Makefile
1171 tests/utils/testapp/gen-ust-nevents-str/Makefile
1172 tests/utils/testapp/gen-syscall-events/Makefile
1173 tests/utils/testapp/gen-ust-tracef/Makefile
1174 tests/utils/testapp/userspace-probe-elf-binary/Makefile
1175 tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1176 tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1177 ])
1178
1179 # Inject variable into python test script.
1180 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1181 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1182 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1183 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1184
1185 AC_OUTPUT
1186
1187 #
1188 # Mini-report on what will be built.
1189 #
1190
1191 PPRINT_INIT
1192 PPRINT_SET_INDENT(1)
1193 PPRINT_SET_TS(38)
1194
1195 AS_ECHO
1196 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1197 AS_ECHO
1198
1199 AS_IF([test -n "$report_fold"], [
1200 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1201 ], [
1202 AS_ECHO("$version_description")
1203 ])
1204
1205 AS_ECHO
1206 PPRINT_SUBTITLE([Features])
1207
1208 # Target architecture we're building for.
1209 target_arch=$host_cpu
1210 [
1211 for f in $CFLAGS; do
1212 if test $f = "-m32"; then
1213 target_arch="32-bit"
1214 elif test $f = "-m64"; then
1215 target_arch="64-bit"
1216 fi
1217 done
1218 ]
1219 PPRINT_PROP_STRING([Target architecture], $target_arch)
1220
1221 # kmod enabled/disabled
1222 test "x$with_kmod" != "xno" && value=1 || value=0
1223 PPRINT_PROP_BOOL([libkmod support], $value)
1224
1225 # LTTng-UST enabled/disabled
1226 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1227 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1228
1229 AS_ECHO
1230 PPRINT_SUBTITLE([Binaries])
1231
1232 # List binaries to be built
1233 test x$enable_bin_lttng != xno && value=1 || value=0
1234 PPRINT_PROP_BOOL([lttng], $value)
1235
1236 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1237 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1238
1239 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1240 PPRINT_PROP_BOOL([lttng-crash], $value)
1241
1242 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1243 PPRINT_PROP_BOOL([lttng-relayd], $value)
1244
1245 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1246 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1247
1248 # Extras
1249 test x$enable_extras != xno && value=1 || value=0
1250 AS_ECHO
1251 PPRINT_SET_INDENT(0)
1252 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1253 PPRINT_SET_INDENT(1)
1254
1255 AS_ECHO
1256 PPRINT_SUBTITLE([Tests])
1257
1258 # Print clear message that tests won't be built
1259 AS_IF([test "x$build_tests" = "xno"],[
1260 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1261 ])
1262
1263 # LTTng UST Java agent JUL tests enabled/disabled
1264 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1265 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1266
1267 # LTTng UST Java agent Log4j tests enabled/disabled
1268 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1269 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1270
1271 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1272 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1273
1274 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1275 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1276
1277 # LTTng UST Java agent Log4j tests enabled/disabled
1278 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1279 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1280
1281 #Python binding enabled/disabled
1282 test "x$enable_python_binding" = xyes && value=1 || value=0
1283 AS_ECHO
1284 PPRINT_SET_INDENT(0)
1285 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1286
1287 # man pages build enabled/disabled
1288 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1289
1290 AS_IF([test "x$man_pages_opt" != "xno"], [
1291 AS_IF([test "x$in_git_repo" = "xyes"], [
1292 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1293 ], [
1294 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1295 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1296 ], [
1297 PPRINT_PROP_STRING([build_man_pages_msg],
1298 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1299 $PPRINT_COLOR_SUBTITLE)
1300 ])
1301 ])
1302 ], [
1303 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1304 ])
1305
1306 m4_popdef([build_man_pages_msg])
1307
1308 test "x$embedded_help" = xyes && value=1 || value=0
1309 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1310
1311 PPRINT_SET_INDENT(1)
1312
1313 report_bindir="`eval eval echo $bindir`"
1314 report_libdir="`eval eval echo $libdir`"
1315
1316 # Print the bindir and libdir this `make install' will install into.
1317 AS_ECHO
1318 PPRINT_SUBTITLE([Install directories])
1319 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1320 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1321
1322 AS_ECHO
1323 PPRINT_SUBTITLE([Search directories])
1324
1325 # If we build the sessiond, print the paths it will use
1326 AS_IF([test "$SESSIOND_BIN" = ""],[
1327 path="$report_bindir/lttng-sessiond"
1328 ],[
1329 path="$SESSIOND_BIN"
1330 ])
1331 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1332
1333 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1334 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1335 ],[
1336 path="$CONSUMERD32_BIN"
1337 ])
1338 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1339
1340 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1341 path="`eval eval echo $libdir`"
1342 ],[
1343 path="$CONSUMERD32_LIBDIR"
1344 ])
1345 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1346
1347 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1348 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1349 ],[
1350 path="$CONSUMERD64_BIN"
1351 ])
1352 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1353
1354 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1355 path="`eval eval echo $libdir`"
1356 ],[
1357 path="$CONSUMERD64_LIBDIR"
1358 ])
1359 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1360 PPRINT_SET_INDENT(0)
1361
1362 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1363 AS_ECHO
1364 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1365
1366 Note that the man pages are already built in this distribution tarball,
1367 therefore asciidoc and xmlto are only needed if you intend to modify
1368 their sources.
1369
1370 Also note that the installed man pages will contain the project's
1371 default command-line option and environment variable values.
1372
1373 Use --disable-man-pages to completely disable building and installing
1374 the man pages.])
1375 ])
This page took 0.094628 seconds and 4 git commands to generate.