configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.8.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 # Checks for C compiler
  18 AC_USE_SYSTEM_EXTENSIONS
  19 AC_SYS_LARGEFILE
  20 AC_PROG_CC
  21 AC_PROG_CC_STDC
  22
  23 # Checks for programs.
  24 AC_PROG_GREP
  25 AC_PROG_LEX
  26 AC_PROG_MAKE_SET
  27 AC_PROG_SED
  28 AC_PROG_YACC
  29 LT_INIT
  30
  31 # Checks for typedefs, structures, and compiler characteristics.
  32 AC_C_INLINE
  33 AC_TYPE_INT32_T
  34 AC_TYPE_INT64_T
  35 AC_TYPE_MODE_T
  36 AC_TYPE_OFF_T
  37 AC_TYPE_PID_T
  38 AC_TYPE_SIZE_T
  39 AC_TYPE_SSIZE_T
  40 AC_TYPE_UID_T
  41 AC_TYPE_UINT16_T
  42 AC_TYPE_UINT32_T
  43 AC_TYPE_UINT64_T
  44 AC_TYPE_UINT8_T
  45
  46 AX_C___ATTRIBUTE__
  47 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  48         [:],
  49         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  50
  51 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  52 LIBS="$PTHREAD_LIBS $LIBS"
  53 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  54 CC="$PTHREAD_CC"
  55
  56 AX_LIB_SOCKET_NSL
  57
  58 # Compute minor/major/patchlevel version numbers
  59 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  60 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  61 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  62 AC_SUBST([MAJOR_VERSION], [$major_version])
  63 AC_SUBST([MINOR_VERSION], [$minor_version])
  64 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  65 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  66 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  67 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  68
  69 version_name="Herbe à Détourne"
  70 version_description='Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.'
  71 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  72
  73 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  74 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  75
  76 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  77 AC_ARG_ENABLE(libtool-linkdep-fixup,
  78         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  79                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  80         libtool_fixup=$enableval,
  81         libtool_fixup=yes)
  82
  83 AS_IF([test "x$libtool_fixup" = "xyes"],
  84             [
  85             libtool_m4="$srcdir/m4/libtool.m4"
  86             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  87             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  88             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  89             AS_IF([test $libtool_flag_pattern_count -ne 0],
  90             [
  91                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  92                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  93                   SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  94                   ],
  95                   [
  96                   AC_MSG_RESULT([none])
  97                   ])
  98             ])
  99
 100 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 101
 102 AC_CHECK_HEADERS([ \
 103         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 104         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 105         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 106         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 107         sys/mount.h sys/param.h sys/time.h
 108 ])
 109
 110 # Basic functions check
 111 AC_CHECK_FUNCS([ \
 112         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 113         gethostbyname gethostname getpagesize localtime_r memchr memset \
 114         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 115         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 116         strtoull dirfd gethostbyname2 getipnodebyname \
 117 ])
 118
 119 # Babeltrace viewer check
 120 AC_ARG_WITH([babeltrace-bin],
 121         AS_HELP_STRING([--with-babeltrace-bin],
 122         [Location of the babeltrace viewer executable (including the filename)]),
 123         [BABELTRACE_BIN="$withval"],
 124         [BABELTRACE_BIN=''])
 125 AC_SUBST([BABELTRACE_BIN])
 126
 127 # lttv-gui
 128 AC_ARG_WITH([lttv-gui-bin],
 129         AS_HELP_STRING([--with-lttv-gui-bin],
 130    [Location of the lttv GUI viewer executable (including the filename)]),
 131    [LTTV_GUI_BIN="$withval"],
 132    [LTTV_GUI_BIN=''])
 133 AC_SUBST([LTTV_GUI_BIN])
 134
 135 AC_ARG_WITH([consumerd32-bin],
 136         AS_HELP_STRING([--with-consumerd32-bin],
 137         [Location of the 32-bit consumerd executable (including the filename)]),
 138         [CONSUMERD32_BIN="$withval"],
 139         [CONSUMERD32_BIN=''])
 140 AC_SUBST([CONSUMERD32_BIN])
 141
 142 AC_ARG_WITH([consumerd64-bin],
 143         AS_HELP_STRING([--with-consumerd64-bin],
 144         [Location of the 64-bit consumerd executable (including the filename)]),
 145         [CONSUMERD64_BIN="$withval"],
 146         [CONSUMERD64_BIN=''])
 147 AC_SUBST([CONSUMERD64_BIN])
 148
 149 AC_ARG_WITH([consumerd32-libdir],
 150         AS_HELP_STRING([--with-consumerd32-libdir],
 151         [Directory containing the 32-bit consumerd libraries]),
 152         [CONSUMERD32_LIBDIR="$withval"],
 153         [CONSUMERD32_LIBDIR=''])
 154 AC_SUBST([CONSUMERD32_LIBDIR])
 155
 156 AC_ARG_WITH([consumerd64-libdir],
 157         AS_HELP_STRING([--with-consumerd64-libdir],
 158         [Directory containing the 64-bit consumerd libraries]),
 159         [CONSUMERD64_LIBDIR="$withval"],
 160         [CONSUMERD64_LIBDIR=''])
 161 AC_SUBST([CONSUMERD64_LIBDIR])
 162
 163 AC_ARG_WITH([sessiond-bin],
 164         AS_HELP_STRING([--with-sessiond-bin],
 165         [Location of the sessiond executable (including the filename)]),
 166         [SESSIOND_BIN="$withval"],
 167         [SESSIOND_BIN=''])
 168 AC_SUBST([SESSIOND_BIN])
 169
 170 AC_ARG_WITH([lttng-system-rundir],
 171         AS_HELP_STRING([--with-lttng-system-rundir],
 172         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 173         [LTTNG_SYSTEM_RUNDIR="$withval"],
 174         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 175 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 176
 177 AC_ARG_ENABLE([test-java-agent-jul],
 178         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 179         [test_java_agent_jul=$enableval],
 180         [test_java_agent_jul=no]
 181 )
 182
 183 AC_ARG_ENABLE([test-java-agent-log4j],
 184         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 185         [test_java_agent_log4j=$enableval],
 186         [test_java_agent_log4j=no]
 187 )
 188
 189 AC_ARG_ENABLE([test-java-agent-all],
 190         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 191         [test_java_agent_jul=$enableval
 192          test_java_agent_log4j=$enableval],
 193         [:]
 194 )
 195
 196 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 197 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 198 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 199 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 200 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 201 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 202 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 203 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 204
 205 if test "x$prefix" = "xNONE"; then
 206         prefix=$ac_default_prefix
 207 fi
 208 CONFDIR=`eval echo $sysconfdir`
 209 AC_SUBST(CONFDIR)
 210 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 211
 212 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 213
 214 #
 215 # Check for pthread
 216 AC_CHECK_LIB([pthread], [pthread_create], [],
 217         [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 218 )
 219
 220 # Check libpopt
 221 AC_CHECK_LIB([popt], [poptGetContext], [],
 222         [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
 223 )
 224
 225 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 226
 227 # Check for libuuid
 228 AC_CHECK_LIB([uuid], [uuid_generate],
 229 [
 230         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 231         have_libuuid=yes
 232 ],
 233 [
 234         # libuuid not found, check for uuid_create in libc.
 235         AC_CHECK_LIB([c], [uuid_create],
 236         [
 237                 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 238                 have_libc_uuid=yes
 239         ],
 240         [
 241                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 242         ])
 243 ]
 244 )
 245 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 246 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 247
 248 # URCU library version needed or newer
 249 liburcu_version=">= 0.8.0"
 250
 251 # Check liburcu needed function calls
 252 AC_CHECK_DECL([cds_list_add], [],
 253         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 254 )
 255 AC_CHECK_DECL([cds_wfcq_init], [],
 256         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 257 )
 258 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 259     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 260 )
 261 AC_CHECK_DECL([futex_async], [],
 262         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 263 )
 264 AC_CHECK_DECL([rcu_thread_offline], [],
 265         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 266 )
 267 AC_CHECK_DECL([rcu_thread_online], [],
 268         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 269 )
 270 AC_CHECK_DECL([caa_likely], [],
 271         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 272 )
 273 #Function added in urcu 0.7.0
 274 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 275         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 276 )
 277
 278 # Check kmod library
 279 AC_ARG_WITH(kmod-prefix,
 280   AS_HELP_STRING([--with-kmod-prefix=PATH],
 281                 [Specify the installation prefix of the kmod library.
 282                 Headers must be in PATH/include; libraries in PATH/lib.]),
 283                 [
 284                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 285                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 286                 ])
 287
 288 AC_ARG_ENABLE(kmod,
 289         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 290         kmod_support=zz$enableval, kmod_support=yes)
 291
 292 AS_IF([test "x$kmod_support" = "xyes"], [
 293         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 294                 [
 295                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 296                         LIBS="$LIBS -lkmod"
 297                         kmod_found=yes
 298                 ],
 299                 kmod_found=no
 300         )
 301 ])
 302 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 303
 304 AC_ARG_WITH(lttng-ust-prefix,
 305   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 306                  [Specify the installation prefix of the lttng-ust library.
 307                   Headers must be in PATH/include; libraries in PATH/lib.]),
 308                   [
 309                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 310                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 311                   ])
 312
 313 # Check liblttng-ust-ctl library
 314 AC_ARG_ENABLE(lttng-ust,
 315         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 316         lttng_ust_support=$enableval, lttng_ust_support=yes)
 317
 318 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 319         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 320                 [
 321                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 322                         lttng_ust_ctl_found=yes
 323                 ],
 324                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 325                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 326         )
 327 ])
 328 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 329 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 330
 331 # check for dlopen
 332 AC_CHECK_LIB([dl], [dlopen],
 333 [
 334         have_libdl=yes
 335 ],
 336 [
 337         #libdl not found, check for dlopen in libc.
 338         AC_CHECK_LIB([c], [dlopen],
 339         [
 340                 have_libc_dl=yes
 341         ],
 342         [
 343                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 344         ])
 345 ])
 346 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 347 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 348
 349 # Check for fmemopen
 350 AC_CHECK_LIB([c], [fmemopen],
 351 [
 352         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 353 ]
 354 )
 355
 356 # Check for open_memstream
 357 AC_CHECK_LIB([c], [open_memstream],
 358 [
 359         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 360 ]
 361 )
 362
 363 AC_ARG_ENABLE([git-version],
 364               [AC_HELP_STRING([--disable-git-version],
 365                               [Do not use the git version for the build])],
 366               [have_git_version=$enableval], [have_git_version=yes]
 367 )
 368
 369 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 370         [test "x${have_git_version}" = "xyes"])
 371
 372 # For Python
 373 # SWIG version needed or newer:
 374 swig_version=2.0.0
 375
 376 AC_ARG_ENABLE([python-bindings],
 377               [AC_HELP_STRING([--enable-python-bindings],
 378                               [compile Python bindings])],
 379               [enable_python_binding=yes], [enable_python_binding=no])
 380
 381 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
 382
 383 if test "x${enable_python_binding:-yes}" = xyes; then
 384   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 385   AM_PATH_PYTHON([3.0])
 386
 387   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 388   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 389   AS_IF([test -z "$PYTHON_INCLUDE"], [
 390     AS_IF([test -z "$PYTHON_CONFIG"], [
 391       AC_PATH_PROGS([PYTHON_CONFIG],
 392                     [python$PYTHON_VERSION-config python-config],
 393                     [no],
 394                     [`dirname $PYTHON`])
 395       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 396     ])
 397     AC_MSG_CHECKING([python include flags])
 398     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 399     AC_MSG_RESULT([$PYTHON_INCLUDE])
 400   ])
 401
 402 else
 403     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 404 [if you want Python bindings.])
 405
 406 fi
 407
 408 # Epoll check. If not present, the build will fallback on poll() API
 409 AX_HAVE_EPOLL(
 410         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 411         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 412 )
 413 AX_CONFIG_FEATURE(
 414         [epoll], [This platform supports epoll(7)],
 415         [HAVE_EPOLL], [This platform supports epoll(7).],
 416         [enable_epoll="yes"], [enable_epoll="no"]
 417 )
 418 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 419
 420 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 421 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 422
 423 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 424         AX_JAVA_OPTIONS
 425         AX_PROG_JAVAC
 426         AX_PROG_JAVA
 427         AX_PROG_JAR
 428
 429         AX_CHECK_CLASSPATH
 430
 431         # Check for Java UST agent common class first
 432         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 433         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 434                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 435         fi
 436
 437         if test "x$test_java_agent_jul" = "xyes"; then
 438                 # Check for JUL agent class
 439                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 440                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 441                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 442                 fi
 443         fi
 444
 445         if test "x$test_java_agent_log4j" = "xyes"; then
 446                 # Check for Log4j agent class
 447                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 448                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 449                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 450                 fi
 451
 452                 # Check for Log4j class
 453                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 454                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 455                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 456                 fi
 457         fi
 458 fi
 459
 460 # Python agent test
 461 UST_PYTHON_AGENT="lttngust"
 462
 463 AC_ARG_ENABLE(test-python2-agent,
 464         AS_HELP_STRING([--enable-test-python2-agent],
 465                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 466         ),[:],[test_python2_agent_autodetect=yes]
 467 )
 468
 469 AC_ARG_ENABLE(test-python3-agent,
 470         AS_HELP_STRING([--enable-test-python3-agent],
 471                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 472         ),[:],[test_python3_agent_autodetect=yes]
 473 )
 474
 475 AC_ARG_ENABLE(test-python-agent-all,
 476         AS_HELP_STRING([--enable-test-python-agent-all],
 477                 [enable test for all python{2/3} agent.]
 478         ),
 479 )
 480
 481 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 482        unset test_python2_agent_autodetect
 483        unset test_python3_agent_autodetect
 484 ])
 485
 486 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 487        enable_test_python2_agent=yes
 488        enable_test_python3_agent=yes
 489 ])
 490
 491 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 492        enable_test_python2_agent=no
 493        enable_test_python3_agent=no
 494 ])
 495
 496
 497 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 498         AS_IF([test -z "$PYTHON2"], [
 499                         PYTHON2=python2
 500                 ], [
 501                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 502         ])
 503
 504         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 505         AS_IF([test -z "$PYTHON2_BIN"], [
 506                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 507                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 508                 ])
 509         ], [
 510                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 511                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 512                         PYTHON2_AGENT=$PYTHON2_BIN
 513                         AC_MSG_RESULT([yes])
 514                         RUN_PYTHON_AGENT_TEST=yes
 515                 ], [
 516                         AC_MSG_RESULT([no])
 517                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 518                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 519                         ])
 520                 ])
 521
 522         ])
 523
 524 ])
 525
 526 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 527         AS_IF([test -z "$PYTHON3"], [
 528                 PYTHON3=python3
 529         ], [
 530                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 531         ])
 532
 533         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 534         AS_IF([test -z "$PYTHON3_BIN"], [
 535                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 536                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 537                 ])
 538         ], [
 539                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 540                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 541                         PYTHON3_AGENT=$PYTHON3_BIN
 542                         AC_MSG_RESULT([yes])
 543                         RUN_PYTHON_AGENT_TEST=yes
 544                 ], [
 545                         AC_MSG_RESULT([no])
 546                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 547                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 548                         ])
 549                 ])
 550
 551         ])
 552 ])
 553
 554 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 555 AC_SUBST([PYTHON2_AGENT])
 556 AC_SUBST([PYTHON3_AGENT])
 557
 558
 559 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 560         if test x"$YACC" != "xbison -y"; then
 561                 AC_MSG_ERROR([[bison not found and is required when building from git.
 562                 Please install bison]])
 563         fi
 564         AC_PATH_PROG([BISON],[bison])
 565         AX_PROG_BISON_VERSION([2.4], [],[
 566                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 567         ])
 568 fi
 569
 570 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 571         if test x"$LEX" != "xflex"; then
 572                 AC_MSG_ERROR([[flex not found and is required when building from git.
 573                 Please install flex]])
 574         fi
 575         AC_PATH_PROG([FLEX],[flex])
 576         AX_PROG_FLEX_VERSION([2.5.35], [],[
 577                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 578         ])
 579 fi
 580
 581 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 582
 583 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 584
 585 lttngincludedir="${includedir}/lttng"
 586
 587 AC_SUBST(lttngincludedir)
 588 AC_SUBST(DEFAULT_INCLUDES)
 589
 590 lttnglibexecdir="${libdir}/lttng/libexec"
 591 AC_SUBST(lttnglibexecdir)
 592
 593 AC_CONFIG_FILES([
 594         Makefile
 595         doc/Makefile
 596         doc/man/Makefile
 597         include/Makefile
 598         extras/Makefile
 599         extras/bindings/Makefile
 600         extras/bindings/swig/Makefile
 601         extras/bindings/swig/python/Makefile
 602         extras/core-handler/Makefile
 603         src/Makefile
 604         src/common/Makefile
 605         src/common/kernel-ctl/Makefile
 606         src/common/kernel-consumer/Makefile
 607         src/common/consumer/Makefile
 608         src/common/ust-consumer/Makefile
 609         src/common/hashtable/Makefile
 610         src/common/sessiond-comm/Makefile
 611         src/common/compat/Makefile
 612         src/common/relayd/Makefile
 613         src/common/testpoint/Makefile
 614         src/common/index/Makefile
 615         src/common/health/Makefile
 616         src/common/config/Makefile
 617         src/lib/Makefile
 618         src/lib/lttng-ctl/Makefile
 619         src/lib/lttng-ctl/filter/Makefile
 620         src/lib/lttng-ctl/lttng-ctl.pc
 621         src/bin/Makefile
 622         src/bin/lttng-consumerd/Makefile
 623         src/bin/lttng-sessiond/Makefile
 624         src/bin/lttng-relayd/Makefile
 625         src/bin/lttng/Makefile
 626         src/bin/lttng-crash/Makefile
 627         tests/Makefile
 628         tests/regression/Makefile
 629         tests/regression/kernel/Makefile
 630         tests/regression/tools/Makefile
 631         tests/regression/tools/streaming/Makefile
 632         tests/regression/tools/filtering/Makefile
 633         tests/regression/tools/health/Makefile
 634         tests/regression/tools/tracefile-limits/Makefile
 635         tests/regression/tools/snapshots/Makefile
 636         tests/regression/tools/live/Makefile
 637         tests/regression/tools/exclusion/Makefile
 638         tests/regression/tools/save-load/Makefile
 639         tests/regression/tools/mi/Makefile
 640         tests/regression/tools/wildcard/Makefile
 641         tests/regression/tools/crash/Makefile
 642         tests/regression/ust/Makefile
 643         tests/regression/ust/nprocesses/Makefile
 644         tests/regression/ust/high-throughput/Makefile
 645         tests/regression/ust/low-throughput/Makefile
 646         tests/regression/ust/before-after/Makefile
 647         tests/regression/ust/buffers-pid/Makefile
 648         tests/regression/ust/periodical-metadata-flush/Makefile
 649         tests/regression/ust/multi-session/Makefile
 650         tests/regression/ust/overlap/Makefile
 651         tests/regression/ust/overlap/demo/Makefile
 652         tests/regression/ust/linking/Makefile
 653         tests/regression/ust/daemon/Makefile
 654         tests/regression/ust/exit-fast/Makefile
 655         tests/regression/ust/fork/Makefile
 656         tests/regression/ust/libc-wrapper/Makefile
 657         tests/regression/ust/java-jul/Makefile
 658         tests/regression/ust/java-log4j/Makefile
 659         tests/regression/ust/python-logging/Makefile
 660         tests/regression/ust/getcpu-override/Makefile
 661         tests/regression/ust/clock-override/Makefile
 662         tests/stress/Makefile
 663         tests/unit/Makefile
 664         tests/unit/ini_config/Makefile
 665         tests/utils/Makefile
 666         tests/utils/tap/Makefile
 667         tests/utils/testapp/Makefile
 668         tests/utils/testapp/gen-ust-events/Makefile
 669         tests/utils/testapp/gen-ust-nevents/Makefile
 670         tests/utils/testapp/gen-ust-tracef/Makefile
 671 ])
 672
 673 # Inject variable into python test script
 674 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
 675
 676 AC_OUTPUT
 677
 678 #
 679 # Mini-report on what will be built
 680 #
 681 AS_ECHO()
 682
 683 AS_ECHO("Version name: $version_name")
 684 AS_ECHO("$version_description")
 685
 686 AS_ECHO()
 687
 688 # Target architecture we're building for
 689 target_arch=$host_cpu
 690 [
 691 for f in $CFLAGS; do
 692         if test $f = "-m32"; then
 693                         target_arch="32-bit"
 694         elif test $f = "-m64"; then
 695                         target_arch="64-bit"
 696         fi
 697 done
 698 ]
 699 AS_ECHO_N("Target architecture: ")
 700 AS_ECHO($target_arch)
 701
 702 # kmod enabled/disabled
 703 AS_ECHO_N("libkmod support: ")
 704 AS_IF([test "x$kmod_found" = "xyes"],[
 705         AS_ECHO("Enabled")
 706 ],[
 707         AS_ECHO("Disabled")
 708 ])
 709
 710 # LTTng-UST enabled/disabled
 711 AS_ECHO_N("Lttng-UST support: ")
 712 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 713         AS_ECHO("Enabled")
 714 ],[
 715         AS_ECHO("Disabled")
 716 ])
 717
 718 # LTTng UST Java agent JUL tests enabled/disabled
 719 AS_ECHO_N("LTTng-UST Java agent JUL tests: ")
 720 AS_IF([test "x$test_java_agent_jul" = "xyes"],[
 721         AS_ECHO("Enabled")
 722 ],[
 723         AS_ECHO("Disabled")
 724 ])
 725
 726 # LTTng UST Java agent Log4j tests enabled/disabled
 727 AS_ECHO_N("LTTng-UST Java agent Log4j tests: ")
 728 AS_IF([test "x$test_java_agent_log4j" = "xyes"],[
 729         AS_ECHO("Enabled")
 730 ],[
 731         AS_ECHO("Disabled")
 732 ])
 733
 734 AS_ECHO_N("LTTng-UST Python2 agent tests: ")
 735 AS_IF([test ! -z "$PYTHON2_AGENT"],[
 736         AS_ECHO("Enabled")
 737 ],[
 738         AS_ECHO("Disabled")
 739 ])
 740
 741 AS_ECHO_N("LTTng-UST Python3 agent tests: ")
 742 AS_IF([test ! -z "$PYTHON3_AGENT"],[
 743         AS_ECHO("Enabled")
 744 ],[
 745         AS_ECHO("Disabled")
 746 ])
 747
 748 #Python binding enabled/disabled
 749 AS_ECHO_N("Python binding: ")
 750 AS_IF([test "x${enable_python_binding:-yes}" = xyes], [
 751         AS_ECHO("Enabled")
 752 ],[
 753         AS_ECHO("Disabled")
 754 ])
 755
 756 # Print the bindir and libdir this `make install' will install into.
 757 AS_ECHO()
 758 AS_ECHO_N("Binaries will be installed in:  ")
 759 AS_ECHO("`eval eval echo $bindir`")
 760 AS_ECHO_N("Libraries will be installed in: ")
 761 AS_ECHO("`eval eval echo $libdir`")
 762
 763 # If we build the sessiond, print the paths it will use
 764 AS_ECHO()
 765 AS_ECHO_N("The lttng command will search for the lttng-sessiond executable at: ")
 766 AS_IF([test "$SESSIOND_BIN" = ""],[
 767         AS_ECHO_N("`eval eval echo $bindir`")
 768         AS_ECHO("/lttng-sessiond")
 769 ],[
 770         AS_ECHO("$SESSIOND_BIN")
 771 ])
 772
 773 AS_ECHO()
 774 AS_ECHO("The sessiond daemon will search the following directories: ")
 775 AS_ECHO_N("32-bit consumerd executable: ")
 776 AS_IF([test "$CONSUMERD32_BIN" = ""],[
 777         AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 778         AS_ECHO("/lttng-consumerd")
 779 ],[
 780         AS_ECHO("$CONSUMERD32_BIN")
 781 ])
 782
 783 AS_ECHO_N("32-bit consumer libraries:   ")
 784 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 785         AS_ECHO("`eval eval echo $libdir`")
 786 ],[
 787         AS_ECHO("$CONSUMERD32_LIBDIR")
 788 ])
 789
 790 AS_ECHO_N("64-bit consumerd executable: ")
 791 AS_IF([test "$CONSUMERD64_BIN" = ""],[
 792         AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 793         AS_ECHO("/lttng-consumerd")
 794 ],[
 795         AS_ECHO("$CONSUMERD64_BIN")
 796 ])
 797
 798 AS_ECHO_N("64-bit consumer libraries:   ")
 799 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 800         AS_ECHO("`eval eval echo $libdir`")
 801 ],[
 802         AS_ECHO("$CONSUMERD64_LIBDIR")
 803 ])
 804
 805 AS_ECHO()
 806