Fix: standardize man pages building/installing
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.9.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_LEX
28 AC_PROG_MAKE_SET
29 AC_PROG_SED
30 AC_PROG_YACC
31 AC_PATH_PROG(report_fold, fold)
32 LT_INIT
33
34 # Check for objcopy, required by the base address statedump and dynamic linker tests
35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
36 AS_IF([test "x$OBJCOPY" = xno],
37 [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
38 )
39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
40
41 # Checks for typedefs, structures, and compiler characteristics.
42 AC_C_INLINE
43 AC_TYPE_INT32_T
44 AC_TYPE_INT64_T
45 AC_TYPE_MODE_T
46 AC_TYPE_OFF_T
47 AC_TYPE_PID_T
48 AC_TYPE_SIZE_T
49 AC_TYPE_SSIZE_T
50 AC_TYPE_UID_T
51 AC_TYPE_UINT16_T
52 AC_TYPE_UINT32_T
53 AC_TYPE_UINT64_T
54 AC_TYPE_UINT8_T
55
56 AX_C___ATTRIBUTE__
57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
58 [:],
59 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
60
61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
62 LIBS="$PTHREAD_LIBS $LIBS"
63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
64 CC="$PTHREAD_CC"
65
66 AX_LIB_SOCKET_NSL
67
68 # Compute minor/major/patchlevel version numbers
69 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
70 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
71 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
72
73 AC_SUBST([MAJOR_VERSION], [$major_version])
74 AC_SUBST([MINOR_VERSION], [$minor_version])
75 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
76 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
77 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
78 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
79
80 version_name="Codename TBD"
81 version_description='Description TBD'
82 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
83
84 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
85 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
86
87 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
88 AC_ARG_ENABLE(libtool-linkdep-fixup,
89 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
90 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
91 libtool_fixup=$enableval,
92 libtool_fixup=yes)
93
94 AS_IF([test "x$libtool_fixup" = "xyes"],
95 [
96 libtool_m4="$srcdir/m4/libtool.m4"
97 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
98 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
99 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
100 AS_IF([test $libtool_flag_pattern_count -ne 0],
101 [
102 AC_MSG_RESULT([$libtool_flag_pattern_count])
103 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
104 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
105 ],
106 [
107 AC_MSG_RESULT([none])
108 ])
109 ])
110
111 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
112
113 AC_CHECK_HEADERS([ \
114 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
115 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
116 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
117 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
118 sys/mount.h sys/param.h sys/time.h
119 ])
120
121 # Basic functions check
122 AC_CHECK_FUNCS([ \
123 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
124 gethostbyname gethostname getpagesize localtime_r memchr memset \
125 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
126 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
127 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
128 ])
129
130 # Babeltrace viewer check
131 AC_ARG_WITH([babeltrace-bin],
132 AS_HELP_STRING([--with-babeltrace-bin],
133 [Location of the babeltrace viewer executable (including the filename)]),
134 [BABELTRACE_BIN="$withval"],
135 [BABELTRACE_BIN=''])
136 AC_SUBST([BABELTRACE_BIN])
137
138 # lttv-gui
139 AC_ARG_WITH([lttv-gui-bin],
140 AS_HELP_STRING([--with-lttv-gui-bin],
141 [Location of the lttv GUI viewer executable (including the filename)]),
142 [LTTV_GUI_BIN="$withval"],
143 [LTTV_GUI_BIN=''])
144 AC_SUBST([LTTV_GUI_BIN])
145
146 AC_ARG_WITH([consumerd32-bin],
147 AS_HELP_STRING([--with-consumerd32-bin],
148 [Location of the 32-bit consumerd executable (including the filename)]),
149 [CONSUMERD32_BIN="$withval"],
150 [CONSUMERD32_BIN=''])
151 AC_SUBST([CONSUMERD32_BIN])
152
153 AC_ARG_WITH([consumerd64-bin],
154 AS_HELP_STRING([--with-consumerd64-bin],
155 [Location of the 64-bit consumerd executable (including the filename)]),
156 [CONSUMERD64_BIN="$withval"],
157 [CONSUMERD64_BIN=''])
158 AC_SUBST([CONSUMERD64_BIN])
159
160 AC_ARG_WITH([consumerd32-libdir],
161 AS_HELP_STRING([--with-consumerd32-libdir],
162 [Directory containing the 32-bit consumerd libraries]),
163 [CONSUMERD32_LIBDIR="$withval"],
164 [CONSUMERD32_LIBDIR=''])
165 AC_SUBST([CONSUMERD32_LIBDIR])
166
167 AC_ARG_WITH([consumerd64-libdir],
168 AS_HELP_STRING([--with-consumerd64-libdir],
169 [Directory containing the 64-bit consumerd libraries]),
170 [CONSUMERD64_LIBDIR="$withval"],
171 [CONSUMERD64_LIBDIR=''])
172 AC_SUBST([CONSUMERD64_LIBDIR])
173
174 AC_ARG_WITH([sessiond-bin],
175 AS_HELP_STRING([--with-sessiond-bin],
176 [Location of the sessiond executable (including the filename)]),
177 [SESSIOND_BIN="$withval"],
178 [SESSIOND_BIN=''])
179 AC_SUBST([SESSIOND_BIN])
180
181 AC_ARG_WITH([lttng-system-rundir],
182 AS_HELP_STRING([--with-lttng-system-rundir],
183 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
184 [LTTNG_SYSTEM_RUNDIR="$withval"],
185 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
186 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
187
188 AC_ARG_ENABLE([test-java-agent-jul],
189 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
190 [test_java_agent_jul=$enableval],
191 [test_java_agent_jul=no]
192 )
193
194 AC_ARG_ENABLE([test-java-agent-log4j],
195 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
196 [test_java_agent_log4j=$enableval],
197 [test_java_agent_log4j=no]
198 )
199
200 AC_ARG_ENABLE([test-java-agent-all],
201 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
202 [test_java_agent_jul=$enableval
203 test_java_agent_log4j=$enableval],
204 [:]
205 )
206
207 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
208 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
209 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
210 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
211 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
212 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
213 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
214 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
215
216 if test "x$prefix" = "xNONE"; then
217 prefix=$ac_default_prefix
218 fi
219 CONFDIR=`eval echo $sysconfdir`
220 AC_SUBST(CONFDIR)
221 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
222
223 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
224
225 #
226 # Check for pthread
227 AC_CHECK_LIB([pthread], [pthread_create], [],
228 [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
229 )
230
231 # Check libpopt
232 PKG_CHECK_MODULES([POPT], [popt],
233 [LIBS="$LIBS $POPT_LIBS"],
234 [
235 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
236 AC_MSG_WARN([Finding libpopt without pkg-config.])
237 AC_CHECK_LIB([popt],
238 [poptGetContext],
239 [],
240 [
241 AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
242 ]
243 )
244 ]
245 )
246
247 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
248
249 # Check for libuuid
250 PKG_CHECK_MODULES([UUID], [uuid],
251 [
252 LIBS="$LIBS $UUID_LIBS"
253 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
254 have_libuuid=yes
255 ],
256 [
257 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
258 AC_MSG_WARN([Finding libuuid without pkg-config.])
259 AC_CHECK_LIB([uuid],
260 [uuid_generate],
261 [
262 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
263 have_libuuid=yes
264 ],
265 [
266 # libuuid not found, check for uuid_create in libc.
267 AC_CHECK_LIB([c],
268 [uuid_create],
269 [
270 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
271 have_libc_uuid=yes
272 ],
273 [
274 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
275 ]
276 )
277 ]
278 )
279 ])
280 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
281 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
282
283 # URCU library version needed or newer
284 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
285
286 # Check liburcu needed function calls
287 AC_CHECK_DECL([cds_list_add], [],
288 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
289 AC_CHECK_DECL([cds_wfcq_init], [],
290 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
291 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
292 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
293 AC_CHECK_DECL([futex_async], [],
294 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
295 AC_CHECK_DECL([rcu_thread_offline], [],
296 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
297 AC_CHECK_DECL([rcu_thread_online], [],
298 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
299 AC_CHECK_DECL([caa_likely], [],
300 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
301 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
302 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
303
304 #Function added in urcu 0.7.0
305 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
306 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
307 )
308
309 # Check kmod library
310 AC_ARG_WITH(kmod-prefix,
311 AS_HELP_STRING([--with-kmod-prefix=PATH],
312 [Specify the installation prefix of the kmod library.
313 Headers must be in PATH/include; libraries in PATH/lib.]),
314 [
315 CPPFLAGS="$CPPFLAGS -I${withval}/include"
316 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
317 ])
318
319 AC_ARG_ENABLE(kmod,
320 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
321 kmod_support=zz$enableval, kmod_support=yes)
322
323 AS_IF([test "x$kmod_support" = "xyes"], [
324 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
325 [
326 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
327 LIBS="$LIBS -lkmod"
328 kmod_found=yes
329 ],
330 kmod_found=no
331 )
332 ])
333 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
334
335 AC_ARG_WITH(lttng-ust-prefix,
336 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
337 [Specify the installation prefix of the lttng-ust library.
338 Headers must be in PATH/include; libraries in PATH/lib.]),
339 [
340 CPPFLAGS="$CPPFLAGS -I${withval}/include"
341 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
342 ])
343
344 # Check liblttng-ust-ctl library
345 AC_ARG_WITH(lttng-ust,
346 AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
347 lttng_ust_support=$withval, lttng_ust_support=yes)
348
349 AS_IF([test "x$lttng_ust_support" = "xyes"], [
350 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
351 [
352 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
353 lttng_ust_ctl_found=yes
354 ],
355 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
356 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
357 )
358 ])
359 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
360 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
361
362 # check for dlopen
363 AC_CHECK_LIB([dl], [dlopen],
364 [
365 have_libdl=yes
366 ],
367 [
368 #libdl not found, check for dlopen in libc.
369 AC_CHECK_LIB([c], [dlopen],
370 [
371 have_libc_dl=yes
372 ],
373 [
374 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
375 ])
376 ])
377 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
378 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
379
380 # Check for fmemopen
381 AC_CHECK_LIB([c], [fmemopen],
382 [
383 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
384 ]
385 )
386
387 # Check for open_memstream
388 AC_CHECK_LIB([c], [open_memstream],
389 [
390 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
391 ]
392 )
393
394 AC_ARG_ENABLE([git-version],
395 [AC_HELP_STRING([--disable-git-version],
396 [Do not use the git version for the build])],
397 [have_git_version=$enableval], [have_git_version=yes]
398 )
399
400 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
401 [test "x${have_git_version}" = "xyes"])
402
403 # For Python
404 # SWIG version needed or newer:
405 swig_version=2.0.0
406
407 AC_ARG_ENABLE([python-bindings],
408 [AC_HELP_STRING([--enable-python-bindings],
409 [compile Python bindings])],
410 [enable_python_binding=yes], [enable_python_binding=no])
411
412 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
413
414 if test "x${enable_python_binding:-yes}" = xyes; then
415 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
416 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
417 AM_PATH_PYTHON([3.0])
418
419 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
420 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
421 AS_IF([test -z "$PYTHON_INCLUDE"], [
422 AS_IF([test -z "$PYTHON_CONFIG"], [
423 AC_PATH_PROGS([PYTHON_CONFIG],
424 [python$PYTHON_VERSION-config python-config],
425 [no],
426 [`dirname $PYTHON`])
427 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
428 ])
429 AC_MSG_CHECKING([python include flags])
430 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
431 AC_MSG_RESULT([$PYTHON_INCLUDE])
432 ])
433
434 else
435 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
436 [if you want Python bindings.])
437
438 fi
439
440 # Epoll check. If not present, the build will fallback on poll() API
441 AX_HAVE_EPOLL(
442 [AX_CONFIG_FEATURE_ENABLE(epoll)],
443 [AX_CONFIG_FEATURE_DISABLE(epoll)]
444 )
445 AX_CONFIG_FEATURE(
446 [epoll], [This platform supports epoll(7)],
447 [HAVE_EPOLL], [This platform supports epoll(7).],
448 [enable_epoll="yes"], [enable_epoll="no"]
449 )
450 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
451
452 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
453 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
454
455 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
456 AX_JAVA_OPTIONS
457 AX_PROG_JAVAC
458 AX_PROG_JAVA
459 AX_PROG_JAR
460
461 AX_CHECK_CLASSPATH
462
463 # Check for Java UST agent common class first
464 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
465 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
466 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
467 fi
468
469 if test "x$test_java_agent_jul" = "xyes"; then
470 # Check for JUL agent class
471 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
472 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
473 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
474 fi
475 fi
476
477 if test "x$test_java_agent_log4j" = "xyes"; then
478 # Check for Log4j agent class
479 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
480 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
481 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
482 fi
483
484 # Check for Log4j class
485 AX_CHECK_CLASS(org.apache.log4j.Logger)
486 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
487 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
488 fi
489 fi
490 fi
491
492 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
493 # is not distributed in tarballs
494 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
495 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
496
497 # enable building man pages (user's intention)
498 AC_ARG_ENABLE(
499 man-pages,
500 AS_HELP_STRING(
501 [--disable-man-pages],
502 [Build and install man pages (already built in a distributed tarball)]
503 ),
504 [man_pages_opt=$enableval],
505 [man_pages_opt=yes]
506 )
507
508 # check for asciidoc and xmlto if we enabled building the man pages
509 have_asciidoc_xmlto=no
510
511 AS_IF([test "x$man_pages_opt" = "xyes"], [
512 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
513 AC_PATH_PROG([XMLTO], [xmlto], [no])
514
515 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
516 AS_IF([test "x$in_git_repo" = "xyes"], [
517 # this is an error because we're in the Git repo, which
518 # means the man pages are not already generated for us,
519 # thus asciidoc/xmlto are required because we were asked
520 # to build the man pages
521 AC_MSG_ERROR([
522 Both asciidoc and xmlto are needed to build the LTTng man pages. Use
523 --disable-man-pages to disable building the man pages, in which case
524 they will not be installed.
525 ])
526 ], [
527 # only warn here: since we're in the tarball, the man
528 # pages should already be generated at this point, thus
529 # asciidoc/xmlto are not strictly required
530 AC_MSG_WARN([
531 Both asciidoc and xmlto are needed to build the LTTng man pages. Note
532 that the man pages are already built in this distribution tarball, so
533 asciidoc and xmlto are only needed if you intend to modify their
534 sources. Use --disable-man-pages to completely disable building
535 and installing the man pages.
536 ])
537 ])
538 ], [
539 have_asciidoc_xmlto=yes
540 ])
541 ])
542
543 # export man page build condition: build the man pages if the user
544 # asked for it, and if the tools are available
545 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
546 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
547
548 # Python agent test
549 UST_PYTHON_AGENT="lttngust"
550
551 AC_ARG_ENABLE(test-python2-agent,
552 AS_HELP_STRING([--enable-test-python2-agent],
553 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
554 ),[:],[test_python2_agent_autodetect=yes]
555 )
556
557 AC_ARG_ENABLE(test-python3-agent,
558 AS_HELP_STRING([--enable-test-python3-agent],
559 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
560 ),[:],[test_python3_agent_autodetect=yes]
561 )
562
563 AC_ARG_ENABLE(test-python-agent-all,
564 AS_HELP_STRING([--enable-test-python-agent-all],
565 [enable test for all python{2/3} agent.]
566 ),
567 )
568
569 AS_IF([test ! -z "$enable_test_python_agent_all"], [
570 unset test_python2_agent_autodetect
571 unset test_python3_agent_autodetect
572 ])
573
574 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
575 enable_test_python2_agent=yes
576 enable_test_python3_agent=yes
577 ])
578
579 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
580 enable_test_python2_agent=no
581 enable_test_python3_agent=no
582 ])
583
584
585 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
586 AS_IF([test -z "$PYTHON2"], [
587 PYTHON2=python2
588 ], [
589 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
590 ])
591
592 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
593 AS_IF([test -z "$PYTHON2_BIN"], [
594 AS_IF([test -z "$test_python2_agent_autodetect"],[
595 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
596 ])
597 ], [
598 AC_MSG_CHECKING([for python2 lttng-ust agent])
599 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
600 PYTHON2_AGENT=$PYTHON2_BIN
601 AC_MSG_RESULT([yes])
602 RUN_PYTHON_AGENT_TEST=yes
603 ], [
604 AC_MSG_RESULT([no])
605 AS_IF([test -z "$test_python2_agent_autodetect"],[
606 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
607 ])
608 ])
609
610 ])
611
612 ])
613
614 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
615 AS_IF([test -z "$PYTHON3"], [
616 PYTHON3=python3
617 ], [
618 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
619 ])
620
621 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
622 AS_IF([test -z "$PYTHON3_BIN"], [
623 AS_IF([test -z "$test_python3_agent_autodetect"],[
624 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
625 ])
626 ], [
627 AC_MSG_CHECKING([for python3 lttng-ust agent])
628 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
629 PYTHON3_AGENT=$PYTHON3_BIN
630 AC_MSG_RESULT([yes])
631 RUN_PYTHON_AGENT_TEST=yes
632 ], [
633 AC_MSG_RESULT([no])
634 AS_IF([test -z "$test_python3_agent_autodetect"],[
635 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
636 ])
637 ])
638
639 ])
640 ])
641 AC_SUBST([RUN_PYTHON_AGENT_TEST])
642 AC_SUBST([PYTHON2_AGENT])
643 AC_SUBST([PYTHON3_AGENT])
644
645 # Arguments for binaries build exclusion
646 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
647 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
648 [Disable the build of lttng-consumerd binaries]))
649 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
650 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
651 [Disable the build of lttng-relayd binaries]))
652 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
653 [Disable the build of lttng-sessiond binaries]))
654 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
655 [Disable the build of the extra components]))
656
657
658 # Always build libconfig since it a dependency of libcommon
659 build_lib_config=yes
660
661 build_lib_compat=no
662 build_lib_consumer=no
663 build_lib_hashtable=no
664 build_lib_health=no
665 build_lib_index=no
666 build_lib_kernel_consumer=no
667 build_lib_kernel_ctl=no
668 build_lib_lttng_ctl=no
669 build_lib_relayd=no
670 build_lib_sessiond_comm=no
671 build_lib_testpoint=no
672 build_lib_ust_consumer=no
673
674 # There is an overlap for enabled dependencies, but this makes everything
675 # simpler. libcommon and libconfig are always compiled so they are not repeated
676 # here.
677
678 # Enable binary dependencies.
679 AS_IF([test x$enable_bin_lttng != xno],
680 [
681 build_lib_lttng_ctl=yes
682 ]
683 )
684
685 AS_IF([test x$enable_bin_lttng_consumerd != xno],
686 [
687 build_lib_consumer=yes
688 build_lib_sessiond_comm=yes
689 build_lib_index=yes
690 build_lib_health=yes
691 build_lib_testpoint=yes
692 ]
693 )
694
695 AS_IF([test x$enable_bin_lttng_crash != xno],
696 # Do nothing since libconfig and libcommon are built by default.
697 []
698 )
699
700 AS_IF([test x$enable_bin_lttng_relayd != xno],
701 [
702 build_lib_lttng_ctl=yes
703 build_lib_sessiond_comm=yes
704 build_lib_hashtable=yes
705 build_lib_compat=yes
706 build_lib_index=yes
707 build_lib_health=yes
708 build_lib_testpoint=yes
709 ]
710 )
711 AS_IF([test x$enable_bin_lttng_sessiond != xno],
712 [
713 build_lib_lttng_ctl=yes
714 build_lib_sessiond_comm=yes
715 build_lib_kernel_ctl=yes
716 build_lib_hashtable=yes
717 build_lib_compat=yes
718 build_lib_relayd=yes
719 build_lib_testpoint=yes
720 build_lib_health=yes
721 build_lib_health=yes
722 ]
723 )
724
725 # Libraries dependencies enabling
726 AS_IF([test x$build_lib_lttng_ctl = xyes],
727 [
728 build_lib_sessiond_comm=yes
729 build_lib_hashtable=yes
730 ]
731 )
732
733 AS_IF([test x$build_lib_consumer = xyes],
734 [
735 build_lib_sessiond_comm=yes
736 build_lib_kernel_consumer=yes
737 build_lib_hashtable=yes
738 build_lib_compat=yes
739 build_lib_relayd=yes
740 AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
741 ]
742 )
743
744 AS_IF([test x$build_lib_kernel_consumer = xyes],
745 [
746 build_lib_kernel_ctl=yes
747 build_lib_relayd=yes
748 ]
749 )
750
751 AS_IF([test x$build_lib_relayd = xyes],
752 [
753 build_lib_sessiond_comm=yes
754 ]
755 )
756
757
758 # Export binaries build conditions.
759 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
760 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
761 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
762 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
763 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
764
765 # Export the tests and extras build conditions.
766 AS_IF([\
767 test "x$enable_bin_lttng" != "xno" && \
768 test "x$enable_bin_lttng_consumerd" != "xno" && \
769 test "x$enable_bin_lttng_crash" != "xno" && \
770 test "x$enable_bin_lttng_relayd" != "xno" && \
771 test "x$enable_bin_lttng_sessiond" != "xno"],
772 [build_tests=yes],
773 [build_tests=no]
774 )
775
776 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
777 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
778
779 # Export libraries build conditions.
780 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
781 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
782 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
783 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
784 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
785 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
786 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
787 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
788 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
789 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
790 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
791 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
792 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
793
794 # check for pgrep
795 AC_PATH_PROG([PGREP], [pgrep], [no])
796 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
797
798 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
799 if test x"$(basename "$YACC")" != "xbison -y"; then
800 AC_MSG_ERROR([[bison not found and is required when building from git.
801 Please install bison]])
802 fi
803 AC_PATH_PROG([BISON],[bison])
804 AX_PROG_BISON_VERSION([2.4], [],[
805 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
806 ])
807 fi
808
809 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
810 if test x"$LEX" != "xflex"; then
811 AC_MSG_ERROR([[flex not found and is required when building from git.
812 Please install flex]])
813 fi
814 AC_PATH_PROG([FLEX],[flex])
815 AX_PROG_FLEX_VERSION([2.5.35], [],[
816 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
817 ])
818 fi
819
820 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
821
822 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
823
824 lttngincludedir="${includedir}/lttng"
825
826 AC_SUBST(lttngincludedir)
827 AC_SUBST(DEFAULT_INCLUDES)
828
829 lttnglibexecdir="${libdir}/lttng/libexec"
830 AC_SUBST(lttnglibexecdir)
831
832 AC_CONFIG_FILES([
833 Makefile
834 doc/Makefile
835 doc/man/Makefile
836 include/Makefile
837 extras/Makefile
838 extras/bindings/Makefile
839 extras/bindings/swig/Makefile
840 extras/bindings/swig/python/Makefile
841 extras/core-handler/Makefile
842 src/Makefile
843 src/common/Makefile
844 src/common/kernel-ctl/Makefile
845 src/common/kernel-consumer/Makefile
846 src/common/consumer/Makefile
847 src/common/ust-consumer/Makefile
848 src/common/hashtable/Makefile
849 src/common/sessiond-comm/Makefile
850 src/common/compat/Makefile
851 src/common/relayd/Makefile
852 src/common/testpoint/Makefile
853 src/common/index/Makefile
854 src/common/health/Makefile
855 src/common/config/Makefile
856 src/lib/Makefile
857 src/lib/lttng-ctl/Makefile
858 src/lib/lttng-ctl/filter/Makefile
859 src/lib/lttng-ctl/lttng-ctl.pc
860 src/bin/Makefile
861 src/bin/lttng-consumerd/Makefile
862 src/bin/lttng-sessiond/Makefile
863 src/bin/lttng-relayd/Makefile
864 src/bin/lttng/Makefile
865 src/bin/lttng-crash/Makefile
866 tests/Makefile
867 tests/destructive/Makefile
868 tests/regression/Makefile
869 tests/regression/kernel/Makefile
870 tests/regression/tools/Makefile
871 tests/regression/tools/streaming/Makefile
872 tests/regression/tools/filtering/Makefile
873 tests/regression/tools/health/Makefile
874 tests/regression/tools/tracefile-limits/Makefile
875 tests/regression/tools/snapshots/Makefile
876 tests/regression/tools/live/Makefile
877 tests/regression/tools/exclusion/Makefile
878 tests/regression/tools/save-load/Makefile
879 tests/regression/tools/mi/Makefile
880 tests/regression/tools/wildcard/Makefile
881 tests/regression/tools/crash/Makefile
882 tests/regression/tools/metadata-regen/Makefile
883 tests/regression/ust/Makefile
884 tests/regression/ust/nprocesses/Makefile
885 tests/regression/ust/high-throughput/Makefile
886 tests/regression/ust/low-throughput/Makefile
887 tests/regression/ust/before-after/Makefile
888 tests/regression/ust/buffers-pid/Makefile
889 tests/regression/ust/periodical-metadata-flush/Makefile
890 tests/regression/ust/multi-session/Makefile
891 tests/regression/ust/overlap/Makefile
892 tests/regression/ust/overlap/demo/Makefile
893 tests/regression/ust/linking/Makefile
894 tests/regression/ust/daemon/Makefile
895 tests/regression/ust/exit-fast/Makefile
896 tests/regression/ust/fork/Makefile
897 tests/regression/ust/libc-wrapper/Makefile
898 tests/regression/ust/baddr-statedump/Makefile
899 tests/regression/ust/ust-dl/Makefile
900 tests/regression/ust/java-jul/Makefile
901 tests/regression/ust/java-log4j/Makefile
902 tests/regression/ust/python-logging/Makefile
903 tests/regression/ust/getcpu-override/Makefile
904 tests/regression/ust/clock-override/Makefile
905 tests/regression/ust/type-declarations/Makefile
906 tests/stress/Makefile
907 tests/unit/Makefile
908 tests/unit/ini_config/Makefile
909 tests/utils/Makefile
910 tests/utils/tap/Makefile
911 tests/utils/testapp/Makefile
912 tests/utils/testapp/gen-ust-events/Makefile
913 tests/utils/testapp/gen-ust-nevents/Makefile
914 tests/utils/testapp/gen-ust-tracef/Makefile
915 ])
916
917 # Inject variable into python test script.
918 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
919
920 AC_OUTPUT
921
922 #
923 # Mini-report on what will be built.
924 #
925
926 PPRINT_INIT
927 PPRINT_SET_INDENT(1)
928 PPRINT_SET_TS(38)
929
930 AS_ECHO
931 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
932 AS_ECHO
933
934 AS_IF([test -n "$report_fold"], [
935 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
936 ], [
937 AS_ECHO("$version_description")
938 ])
939
940 AS_ECHO
941 PPRINT_SUBTITLE([Features])
942
943 # Target architecture we're building for.
944 target_arch=$host_cpu
945 [
946 for f in $CFLAGS; do
947 if test $f = "-m32"; then
948 target_arch="32-bit"
949 elif test $f = "-m64"; then
950 target_arch="64-bit"
951 fi
952 done
953 ]
954 PPRINT_PROP_STRING([Target architecture], $target_arch)
955
956 # kmod enabled/disabled
957 test "x$kmod_found" = "xyes" && value=1 || value=0
958 PPRINT_PROP_BOOL([libkmod support], $value)
959
960 # LTTng-UST enabled/disabled
961 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
962 PPRINT_PROP_BOOL([LTTng-UST support], $value)
963
964 AS_ECHO
965 PPRINT_SUBTITLE([Binaries])
966
967 # List binaries to be built
968 test x$enable_bin_lttng != xno && value=1 || value=0
969 PPRINT_PROP_BOOL([lttng], $value)
970
971 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
972 PPRINT_PROP_BOOL([lttng-consumerd], $value)
973
974 test x$enable_bin_lttng_crash != xno && value=1 || value=0
975 PPRINT_PROP_BOOL([lttng-crash], $value)
976
977 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
978 PPRINT_PROP_BOOL([lttng-relayd], $value)
979
980 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
981 PPRINT_PROP_BOOL([lttng-sessiond], $value)
982
983 # Extras
984 test x$enable_extras != xno && value=1 || value=0
985 AS_ECHO
986 PPRINT_SET_INDENT(0)
987 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
988 PPRINT_SET_INDENT(1)
989
990 AS_ECHO
991 PPRINT_SUBTITLE([Tests])
992
993 # Print clear message that tests won't be built
994 AS_IF([test "x$build_tests" = "xno"],[
995 PPRINT_WARN([Tests won't be built since some binaries were disabled])
996 ])
997
998 # LTTng UST Java agent JUL tests enabled/disabled
999 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1000 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1001
1002 # LTTng UST Java agent Log4j tests enabled/disabled
1003 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1004 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1005
1006 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1007 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1008
1009 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1010 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1011
1012 #Python binding enabled/disabled
1013 test "x${enable_python_binding:-yes}" = xyes && value=1 || value=0
1014 AS_ECHO
1015 PPRINT_SET_INDENT(0)
1016 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1017
1018 # man pages build enabled/disabled
1019 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1020
1021 AS_IF([test "x$man_pages_opt" != "xno"], [
1022 AS_IF([test "x$in_git_repo" = "xyes"], [
1023 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1024 ], [
1025 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1026 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1027 ], [
1028 PPRINT_PROP_STRING([build_man_pages_msg],
1029 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1030 $PPRINT_COLOR_SUBTITLE)
1031 ])
1032 ])
1033 ], [
1034 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1035 ])
1036
1037 m4_popdef([build_man_pages_msg])
1038
1039 PPRINT_SET_INDENT(1)
1040
1041 report_bindir="`eval eval echo $bindir`"
1042 report_libdir="`eval eval echo $libdir`"
1043
1044 # Print the bindir and libdir this `make install' will install into.
1045 AS_ECHO
1046 PPRINT_SUBTITLE([Install directories])
1047 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1048 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1049
1050 AS_ECHO
1051 PPRINT_SUBTITLE([Search directories])
1052
1053 # If we build the sessiond, print the paths it will use
1054 AS_IF([test "$SESSIOND_BIN" = ""],[
1055 path="$report_bindir/lttng-sessiond"
1056 ],[
1057 path="$SESSIOND_BIN"
1058 ])
1059 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1060
1061 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1062 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1063 ],[
1064 path="$CONSUMERD32_BIN"
1065 ])
1066 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1067
1068 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1069 path="`eval eval echo $libdir`"
1070 ],[
1071 path="$CONSUMERD32_LIBDIR"
1072 ])
1073 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1074
1075 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1076 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1077 ],[
1078 path="$CONSUMERD64_BIN"
1079 ])
1080 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1081
1082 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1083 path="`eval eval echo $libdir`"
1084 ],[
1085 path="$CONSUMERD64_LIBDIR"
1086 ])
1087 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
This page took 0.051579 seconds and 5 git commands to generate.