configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62
  63 AX_LIB_SOCKET_NSL
  64
  65 LT_NO_UNDEFINED=""
  66 AS_CASE([$host_os],
  67   [cygwin*],
  68     [
  69       LT_NO_UNDEFINED="-no-undefined"
  70     ]
  71 )
  72
  73 AC_SUBST(LT_NO_UNDEFINED)
  74
  75 # Compute minor/major/patchlevel version numbers
  76 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  77 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  78 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  79
  80 AC_SUBST([MAJOR_VERSION], [$major_version])
  81 AC_SUBST([MINOR_VERSION], [$minor_version])
  82 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  83 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  84 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  85 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  86
  87 version_name="KeKriek"
  88 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
  89 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  90
  91 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  92 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  93
  94 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  95 AC_ARG_ENABLE(libtool-linkdep-fixup,
  96         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  97                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  98         libtool_fixup=$enableval,
  99         libtool_fixup=yes)
 100
 101 AS_IF([test "x$libtool_fixup" = "xyes"],
 102             [
 103             libtool_m4="$srcdir/m4/libtool.m4"
 104             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 105             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 106             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 107             AS_IF([test $libtool_flag_pattern_count -ne 0],
 108             [
 109                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 110                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 111                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 112                   ],
 113                   [
 114                   AC_MSG_RESULT([none])
 115                   ])
 116             ])
 117
 118 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 119
 120 AC_CHECK_HEADERS([ \
 121         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 122         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 123         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 124         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 125         sys/mount.h sys/param.h sys/time.h
 126 ])
 127
 128 # Basic functions check
 129 AC_CHECK_FUNCS([ \
 130         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 131         gethostbyname gethostname getpagesize localtime_r memchr memset \
 132         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 133         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 134         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 135 ])
 136
 137 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 138 # add -lrt to LIBS
 139 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 140
 141 # Babeltrace viewer check
 142 AC_ARG_WITH([babeltrace-bin],
 143         AS_HELP_STRING([--with-babeltrace-bin],
 144         [Location of the babeltrace viewer executable (including the filename)]),
 145         [BABELTRACE_BIN="$withval"],
 146         [BABELTRACE_BIN=''])
 147 AC_SUBST([BABELTRACE_BIN])
 148
 149 # lttv-gui
 150 AC_ARG_WITH([lttv-gui-bin],
 151         AS_HELP_STRING([--with-lttv-gui-bin],
 152    [Location of the lttv GUI viewer executable (including the filename)]),
 153    [LTTV_GUI_BIN="$withval"],
 154    [LTTV_GUI_BIN=''])
 155 AC_SUBST([LTTV_GUI_BIN])
 156
 157 AC_ARG_WITH([consumerd32-bin],
 158         AS_HELP_STRING([--with-consumerd32-bin],
 159         [Location of the 32-bit consumerd executable (including the filename)]),
 160         [CONSUMERD32_BIN="$withval"],
 161         [CONSUMERD32_BIN=''])
 162 AC_SUBST([CONSUMERD32_BIN])
 163
 164 AC_ARG_WITH([consumerd64-bin],
 165         AS_HELP_STRING([--with-consumerd64-bin],
 166         [Location of the 64-bit consumerd executable (including the filename)]),
 167         [CONSUMERD64_BIN="$withval"],
 168         [CONSUMERD64_BIN=''])
 169 AC_SUBST([CONSUMERD64_BIN])
 170
 171 AC_ARG_WITH([consumerd32-libdir],
 172         AS_HELP_STRING([--with-consumerd32-libdir],
 173         [Directory containing the 32-bit consumerd libraries]),
 174         [CONSUMERD32_LIBDIR="$withval"],
 175         [CONSUMERD32_LIBDIR=''])
 176 AC_SUBST([CONSUMERD32_LIBDIR])
 177
 178 AC_ARG_WITH([consumerd64-libdir],
 179         AS_HELP_STRING([--with-consumerd64-libdir],
 180         [Directory containing the 64-bit consumerd libraries]),
 181         [CONSUMERD64_LIBDIR="$withval"],
 182         [CONSUMERD64_LIBDIR=''])
 183 AC_SUBST([CONSUMERD64_LIBDIR])
 184
 185 AC_ARG_WITH([sessiond-bin],
 186         AS_HELP_STRING([--with-sessiond-bin],
 187         [Location of the sessiond executable (including the filename)]),
 188         [SESSIOND_BIN="$withval"],
 189         [SESSIOND_BIN=''])
 190 AC_SUBST([SESSIOND_BIN])
 191
 192 AC_ARG_WITH([lttng-system-rundir],
 193         AS_HELP_STRING([--with-lttng-system-rundir],
 194         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 195         [LTTNG_SYSTEM_RUNDIR="$withval"],
 196         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 197 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 198
 199 AC_ARG_ENABLE([test-java-agent-jul],
 200         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 201         [test_java_agent_jul=$enableval],
 202         [test_java_agent_jul=no]
 203 )
 204
 205 AC_ARG_ENABLE([test-java-agent-log4j],
 206         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 207         [test_java_agent_log4j=$enableval],
 208         [test_java_agent_log4j=no]
 209 )
 210
 211 AC_ARG_ENABLE([test-java-agent-all],
 212         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 213         [test_java_agent_jul=$enableval
 214          test_java_agent_log4j=$enableval],
 215         [:]
 216 )
 217
 218 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 219 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 220 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 221 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 222 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 223 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 224 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 225 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 226
 227 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 228         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 229         $1="$2"
 230         AC_SUBST([$1])
 231 ])
 232
 233 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 234         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 235         $1="$2"
 236         AC_SUBST([$1])
 237 ])
 238
 239 # Default values
 240 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 241 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 242 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 243 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 244 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 245 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 246 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 247 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 248 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 249 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 250 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 251 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 252 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 253 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 254 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 255 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 256 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 257 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 258 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 259 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 260 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 261 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 262 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 263 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 264 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 265 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 266 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 267 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 268 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 269 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 270 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 271 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 272 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 273 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 274 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 275 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 276 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 277 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 278 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 279 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 280 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 281 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 282
 283 # Command short descriptions
 284 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 285 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 286 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 294 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 295 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 296 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 297 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 298 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 299 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 300 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 301 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 302 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 303 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 304 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 305
 306 if test "x$prefix" = "xNONE"; then
 307         prefix=$ac_default_prefix
 308 fi
 309 CONFDIR=`eval echo $sysconfdir`
 310 AC_SUBST(CONFDIR)
 311 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 312
 313 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 314
 315 #
 316 # Check for pthread
 317 AC_CHECK_LIB([pthread], [pthread_create], [],
 318         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 319 )
 320
 321 # Check libpopt
 322 PKG_CHECK_MODULES([POPT], [popt],
 323         [LIBS="$LIBS $POPT_LIBS"],
 324         [
 325                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 326                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 327                 AC_CHECK_LIB([popt],
 328                         [poptGetContext],
 329                         [],
 330                         [
 331                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 332                         ]
 333                 )
 334         ]
 335 )
 336
 337 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 338
 339 # First, check for uuid in system libs
 340 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 341 AC_CHECK_FUNCS([uuid_generate],
 342   [
 343     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 344     UUID_LIBS=""
 345   ],
 346   [
 347     # Then, check if the pkg-config module is available, otherwise explicitly check
 348     # for libuuid, or uuid support in the C-library.
 349     PKG_CHECK_MODULES([UUID], [uuid],
 350       [
 351         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 352         dnl PKG_CHECK_MODULES defines UUID_LIBS
 353       ],
 354       [
 355         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 356         AC_MSG_WARN([Finding libuuid without pkg-config.])
 357         AC_CHECK_LIB([uuid], [uuid_generate],
 358           [
 359             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 360             UUID_LIBS="-luuid"
 361           ],
 362           [
 363             # libuuid not found, check for uuid_create in libc.
 364             AC_CHECK_LIB([c], [uuid_create],
 365               [
 366                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 367                 UUID_LIBS="-lc"
 368               ],
 369               [
 370                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 371               ]
 372             )
 373           ]
 374         )
 375       ]
 376     )
 377   ]
 378 )
 379 AC_SUBST(UUID_LIBS)
 380
 381 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 382
 383 # URCU library version needed or newer
 384 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 385
 386 # Check liburcu needed function calls
 387 AC_CHECK_DECL([cds_list_add], [],
 388         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 389 AC_CHECK_DECL([cds_wfcq_init], [],
 390         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 391 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 392         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 393 AC_CHECK_DECL([futex_async], [],
 394         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 395 AC_CHECK_DECL([rcu_thread_offline], [],
 396         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 397 AC_CHECK_DECL([rcu_thread_online], [],
 398         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 399 AC_CHECK_DECL([caa_likely], [],
 400         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 401 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 402         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 403
 404 #Function added in urcu 0.7.0
 405 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 406         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 407 )
 408
 409 #Function added in urcu 0.9.0
 410 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 411         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 412 )
 413
 414 # Check kmod library
 415 AC_ARG_WITH(kmod-prefix,
 416   AS_HELP_STRING([--with-kmod-prefix=PATH],
 417                 [Specify the installation prefix of the kmod library.
 418                 Headers must be in PATH/include; libraries in PATH/lib.]),
 419                 [
 420                         AM_CPPFLAGS="$AM_CPPFLAGS -I${withval}/include"
 421                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 422                 ])
 423
 424 AC_ARG_ENABLE(kmod,
 425         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 426         kmod_support=$enableval, kmod_support=yes)
 427
 428 AS_IF([test "x$kmod_support" = "xyes"], [
 429         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 430                 [
 431                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 432                         LIBS="$LIBS -lkmod"
 433                         kmod_found=yes
 434                 ],
 435                 kmod_found=no
 436         )
 437 ])
 438 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 439
 440 AC_ARG_WITH(lttng-ust-prefix,
 441   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 442                  [Specify the installation prefix of the lttng-ust library.
 443                   Headers must be in PATH/include; libraries in PATH/lib.]),
 444                   [
 445                     AM_CPPFLAGS="$AM_CPPFLAGS -I${withval}/include"
 446                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 447                   ])
 448
 449 # Check liblttng-ust-ctl library
 450 AC_ARG_WITH(lttng-ust,
 451         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 452         lttng_ust_support=$withval, lttng_ust_support=yes)
 453
 454 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 455         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 456                 [
 457                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 458                         lttng_ust_ctl_found=yes
 459                 ],
 460                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 461                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 462         )
 463 ])
 464 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 465 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 466
 467 # check for dlopen
 468 AC_CHECK_LIB([dl], [dlopen],
 469   [DL_LIBS="-ldl"],
 470   [
 471     #libdl not found, check for dlopen in libc.
 472     AC_CHECK_LIB([c], [dlopen],
 473       [DL_LIBS="-lc"],
 474       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 475     )
 476   ]
 477 )
 478 AC_SUBST(DL_LIBS)
 479
 480 # Check for fmemopen
 481 AC_CHECK_LIB([c], [fmemopen],
 482 [
 483         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 484 ]
 485 )
 486
 487 # Check for open_memstream
 488 AC_CHECK_LIB([c], [open_memstream],
 489 [
 490         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 491 ]
 492 )
 493
 494 # check for libpfm
 495 AC_CHECK_LIB([pfm], [pfm_initialize],
 496              [
 497               have_libpfm=yes
 498               ])
 499 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 500
 501 AC_ARG_ENABLE([git-version],
 502               [AC_HELP_STRING([--disable-git-version],
 503                               [Do not use the git version for the build])],
 504               [have_git_version=$enableval], [have_git_version=yes]
 505 )
 506
 507 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 508         [test "x${have_git_version}" = "xyes"])
 509
 510 # For Python
 511 # SWIG version needed or newer:
 512 swig_version=2.0.0
 513
 514 AC_ARG_ENABLE([python-bindings],
 515               [AC_HELP_STRING([--enable-python-bindings],
 516                               [compile Python bindings])],
 517               [enable_python_binding=$enableval], [enable_python_binding=no])
 518
 519 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 520
 521 if test "x$enable_python_binding" = xyes; then
 522   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 523   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 524   AM_PATH_PYTHON([3.0])
 525
 526   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 527   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 528   AS_IF([test -z "$PYTHON_INCLUDE"], [
 529     AS_IF([test -z "$PYTHON_CONFIG"], [
 530       AC_PATH_PROGS([PYTHON_CONFIG],
 531                     [python$PYTHON_VERSION-config python-config],
 532                     [no],
 533                     [`dirname $PYTHON`])
 534       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 535     ])
 536     AC_MSG_CHECKING([python include flags])
 537     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 538     AC_MSG_RESULT([$PYTHON_INCLUDE])
 539   ])
 540
 541 else
 542     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 543 [if you want Python bindings.])
 544
 545 fi
 546
 547 # Epoll check. If not present, the build will fallback on poll() API
 548 AX_HAVE_EPOLL(
 549         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 550         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 551 )
 552 AX_CONFIG_FEATURE(
 553         [epoll], [This platform supports epoll(7)],
 554         [HAVE_EPOLL], [This platform supports epoll(7).],
 555         [enable_epoll="yes"], [enable_epoll="no"]
 556 )
 557 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 558
 559 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 560 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 561
 562 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 563         AX_JAVA_OPTIONS
 564         AX_PROG_JAVAC
 565         AX_PROG_JAVA
 566         AX_PROG_JAR
 567
 568         AX_CHECK_CLASSPATH
 569
 570         # Check for Java UST agent common class first
 571         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 572         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 573                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 574         fi
 575
 576         if test "x$test_java_agent_jul" = "xyes"; then
 577                 # Check for JUL agent class
 578                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 579                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 580                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 581                 fi
 582         fi
 583
 584         if test "x$test_java_agent_log4j" = "xyes"; then
 585                 # Check for Log4j agent class
 586                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 587                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 588                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 589                 fi
 590
 591                 # Check for Log4j class
 592                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 593                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 594                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 595                 fi
 596         fi
 597 fi
 598
 599 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 600 # is not distributed in tarballs
 601 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 602 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 603
 604 # enable building man pages (user's intention)
 605 AC_ARG_ENABLE(
 606         man-pages,
 607         AS_HELP_STRING(
 608                 [--disable-man-pages],
 609                 [Do not build and install man pages (already built in a distributed tarball)]
 610         ),
 611         [man_pages_opt=$enableval],
 612         [man_pages_opt=yes]
 613 )
 614
 615 # check for asciidoc and xmlto if we enabled building the man pages
 616 have_asciidoc_xmlto=no
 617 warn_prebuilt_man_pages=no
 618
 619 AS_IF([test "x$man_pages_opt" = "xyes"], [
 620         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 621         AC_PATH_PROG([XMLTO], [xmlto], [no])
 622
 623         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 624                 AS_IF([test "x$in_git_repo" = "xyes"], [
 625                         # this is an error because we're in the Git repo, which
 626                         # means the man pages are not already generated for us,
 627                         # thus asciidoc/xmlto are required because we were asked
 628                         # to build the man pages
 629                         AC_MSG_ERROR([
 630 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 631 --disable-man-pages to disable building the man pages, in which case
 632 they will not be installed.
 633                         ])
 634                 ], [
 635                         # only warn here: since we're in the tarball, the man
 636                         # pages should already be generated at this point, thus
 637                         # asciidoc/xmlto are not strictly required
 638                         warn_prebuilt_man_pages=yes
 639                 ])
 640         ], [
 641                 have_asciidoc_xmlto=yes
 642         ])
 643 ])
 644
 645 # export man page build condition: build the man pages if the user
 646 # asked for it, and if the tools are available
 647 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 648 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 649
 650 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 651
 652 # embedded --help message
 653 AC_ARG_ENABLE(
 654         [embedded-help],
 655         AS_HELP_STRING(
 656                 [--enable-embedded-help],
 657                 [Embed the --help messages in the executable files]
 658         ),
 659         [embedded_help=$enableval],
 660         [embedded_help=no]
 661 )
 662 AS_IF([test "x$embedded_help" = "xyes"], [
 663         AS_IF([test "x$man_pages_opt" = "xno"], [
 664                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 665         ])
 666         AC_PATH_PROG([man_prog_path], [man], [no])
 667         AS_IF([test "x$man_prog_path" = "xno"], [
 668                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 669         ])
 670         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 671         AC_SUBST([MANPROG], [$man_prog_path])
 672 ])
 673 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 674
 675 # Python agent test
 676 UST_PYTHON_AGENT="lttngust"
 677
 678 AC_ARG_ENABLE(test-python2-agent,
 679         AS_HELP_STRING([--enable-test-python2-agent],
 680                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 681         ),[:],[test_python2_agent_autodetect=yes]
 682 )
 683
 684 AC_ARG_ENABLE(test-python3-agent,
 685         AS_HELP_STRING([--enable-test-python3-agent],
 686                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 687         ),[:],[test_python3_agent_autodetect=yes]
 688 )
 689
 690 AC_ARG_ENABLE(test-python-agent-all,
 691         AS_HELP_STRING([--enable-test-python-agent-all],
 692                 [enable test for all python{2/3} agent.]
 693         ),
 694 )
 695
 696 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 697        unset test_python2_agent_autodetect
 698        unset test_python3_agent_autodetect
 699 ])
 700
 701 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 702        enable_test_python2_agent=yes
 703        enable_test_python3_agent=yes
 704 ])
 705
 706 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 707        enable_test_python2_agent=no
 708        enable_test_python3_agent=no
 709 ])
 710
 711
 712 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 713         AS_IF([test -z "$PYTHON2"], [
 714                         PYTHON2=python2
 715                 ], [
 716                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 717         ])
 718
 719         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 720         AS_IF([test -z "$PYTHON2_BIN"], [
 721                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 722                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 723                 ])
 724         ], [
 725                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 726                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 727                         PYTHON2_AGENT=$PYTHON2_BIN
 728                         AC_MSG_RESULT([yes])
 729                         RUN_PYTHON_AGENT_TEST=yes
 730                 ], [
 731                         AC_MSG_RESULT([no])
 732                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 733                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 734                         ])
 735                 ])
 736
 737         ])
 738
 739 ])
 740
 741 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 742         AS_IF([test -z "$PYTHON3"], [
 743                 PYTHON3=python3
 744         ], [
 745                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 746         ])
 747
 748         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 749         AS_IF([test -z "$PYTHON3_BIN"], [
 750                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 751                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 752                 ])
 753         ], [
 754                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 755                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 756                         PYTHON3_AGENT=$PYTHON3_BIN
 757                         AC_MSG_RESULT([yes])
 758                         RUN_PYTHON_AGENT_TEST=yes
 759                 ], [
 760                         AC_MSG_RESULT([no])
 761                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 762                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 763                         ])
 764                 ])
 765
 766         ])
 767 ])
 768 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 769 AC_SUBST([PYTHON2_AGENT])
 770 AC_SUBST([PYTHON3_AGENT])
 771
 772 # Arguments for binaries build exclusion
 773 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 774 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 775               [Disable the build of lttng-consumerd binaries]))
 776 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 777 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 778               [Disable the build of lttng-relayd binaries]))
 779 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 780               [Disable the build of lttng-sessiond binaries]))
 781 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 782               [Disable the build of the extra components]))
 783
 784
 785 # Always build libconfig since it a dependency of libcommon
 786 build_lib_config=yes
 787
 788 build_lib_compat=no
 789 build_lib_consumer=no
 790 build_lib_hashtable=no
 791 build_lib_health=no
 792 build_lib_index=no
 793 build_lib_kernel_consumer=no
 794 build_lib_kernel_ctl=no
 795 build_lib_lttng_ctl=no
 796 build_lib_relayd=no
 797 build_lib_sessiond_comm=no
 798 build_lib_testpoint=no
 799 build_lib_ust_consumer=no
 800
 801 # There is an overlap for enabled dependencies, but this makes everything
 802 # simpler. libcommon and libconfig are always compiled so they are not repeated
 803 # here.
 804
 805 # Enable binary dependencies.
 806 AS_IF([test x$enable_bin_lttng != xno],
 807       [
 808        build_lib_lttng_ctl=yes
 809       ]
 810 )
 811
 812 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 813       [
 814        build_lib_consumer=yes
 815        build_lib_sessiond_comm=yes
 816        build_lib_index=yes
 817        build_lib_health=yes
 818        build_lib_testpoint=yes
 819       ]
 820 )
 821
 822 AS_IF([test x$enable_bin_lttng_crash != xno],
 823       # Do nothing since libconfig and libcommon are built by default.
 824       []
 825 )
 826
 827 AS_IF([test x$enable_bin_lttng_relayd != xno],
 828       [
 829        build_lib_lttng_ctl=yes
 830        build_lib_sessiond_comm=yes
 831        build_lib_hashtable=yes
 832        build_lib_compat=yes
 833        build_lib_index=yes
 834        build_lib_health=yes
 835        build_lib_testpoint=yes
 836       ]
 837 )
 838 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 839       [
 840        build_lib_lttng_ctl=yes
 841        build_lib_sessiond_comm=yes
 842        build_lib_kernel_ctl=yes
 843        build_lib_hashtable=yes
 844        build_lib_compat=yes
 845        build_lib_relayd=yes
 846        build_lib_testpoint=yes
 847        build_lib_health=yes
 848        build_lib_health=yes
 849       ]
 850 )
 851
 852 # Libraries dependencies enabling
 853 AS_IF([test x$build_lib_lttng_ctl = xyes],
 854       [
 855        build_lib_sessiond_comm=yes
 856        build_lib_hashtable=yes
 857       ]
 858 )
 859
 860 AS_IF([test x$build_lib_consumer = xyes],
 861       [
 862        build_lib_sessiond_comm=yes
 863        build_lib_kernel_consumer=yes
 864        build_lib_hashtable=yes
 865        build_lib_compat=yes
 866        build_lib_relayd=yes
 867        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 868       ]
 869 )
 870
 871 AS_IF([test x$build_lib_kernel_consumer = xyes],
 872       [
 873        build_lib_kernel_ctl=yes
 874        build_lib_relayd=yes
 875       ]
 876 )
 877
 878 AS_IF([test x$build_lib_relayd = xyes],
 879       [
 880        build_lib_sessiond_comm=yes
 881       ]
 882 )
 883
 884
 885 # Export binaries build conditions.
 886 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 887 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 888 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 889 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 890 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 891
 892 # Export the tests and extras build conditions.
 893 AS_IF([\
 894 test "x$enable_bin_lttng" != "xno" && \
 895 test "x$enable_bin_lttng_consumerd" != "xno" && \
 896 test "x$enable_bin_lttng_crash" != "xno" && \
 897 test "x$enable_bin_lttng_relayd" != "xno" && \
 898 test "x$enable_bin_lttng_sessiond" != "xno"],
 899 [build_tests=yes],
 900 [build_tests=no]
 901 )
 902
 903 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 904 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 905
 906 # Export libraries build conditions.
 907 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 908 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 909 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 910 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 911 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 912 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 913 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 914 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 915 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 916 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 917 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 918 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 919 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 920
 921 # check for pgrep
 922 AC_PATH_PROG([PGREP], [pgrep], [no])
 923 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 924
 925 # check for bison
 926 have_bison=yes
 927
 928 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 929 AC_PATH_PROG([BISON], [bison])
 930 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 931
 932 AS_IF([test "x$have_bison" = "xno"], [
 933         AS_IF([test "x$in_git_repo" = "xyes"], [
 934                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 935         ], [
 936                 AC_MSG_WARN([
 937 Missing Bison >= 2.4. Note that the parser files are already built in
 938 this distribution tarball, so Bison is only needed if you intend to
 939 modify their sources.
 940                 ])
 941         ])
 942 ])
 943
 944 # export bison condition
 945 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 946
 947 # check for flex
 948 have_flex=yes
 949
 950 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 951 AC_PATH_PROG([FLEX], [flex])
 952 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 953
 954 AS_IF([test "x$have_flex" = "xno"], [
 955         AS_IF([test "x$in_git_repo" = "xyes"], [
 956                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 957         ], [
 958                 AC_MSG_WARN([
 959 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 960 this distribution tarball, so Flex is only needed if you intend to
 961 modify their sources.
 962                 ])
 963         ])
 964 ])
 965
 966 # export flex condition
 967 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 968
 969 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
 970 AC_SUBST(AM_CFLAGS)
 971
 972 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
 973 AC_SUBST(AM_CPPFLAGS)
 974
 975 lttngincludedir="${includedir}/lttng"
 976 AC_SUBST(lttngincludedir)
 977
 978 lttngactionincludedir="${includedir}/lttng/action"
 979 AC_SUBST(lttngactionincludedir)
 980
 981 lttngconditionincludedir="${includedir}/lttng/condition"
 982 AC_SUBST(lttngconditionincludedir)
 983
 984 lttngnotificationincludedir="${includedir}/lttng/notification"
 985 AC_SUBST(lttngnotificationincludedir)
 986
 987 lttngtriggerincludedir="${includedir}/lttng/trigger"
 988 AC_SUBST(lttngtriggerincludedir)
 989
 990 lttnglibexecdir="${libdir}/lttng/libexec"
 991 AC_SUBST(lttnglibexecdir)
 992
 993 AC_CONFIG_FILES([
 994         Makefile
 995         doc/Makefile
 996         doc/man/Makefile
 997         doc/man/asciidoc-attrs.conf
 998         include/Makefile
 999         extras/Makefile
1000         extras/bindings/Makefile
1001         extras/bindings/swig/Makefile
1002         extras/bindings/swig/python/Makefile
1003         extras/core-handler/Makefile
1004         src/Makefile
1005         src/common/Makefile
1006         src/common/kernel-ctl/Makefile
1007         src/common/kernel-consumer/Makefile
1008         src/common/consumer/Makefile
1009         src/common/ust-consumer/Makefile
1010         src/common/hashtable/Makefile
1011         src/common/sessiond-comm/Makefile
1012         src/common/compat/Makefile
1013         src/common/relayd/Makefile
1014         src/common/testpoint/Makefile
1015         src/common/index/Makefile
1016         src/common/health/Makefile
1017         src/common/config/Makefile
1018         src/common/string-utils/Makefile
1019         src/lib/Makefile
1020         src/lib/lttng-ctl/Makefile
1021         src/lib/lttng-ctl/filter/Makefile
1022         src/lib/lttng-ctl/lttng-ctl.pc
1023         src/bin/Makefile
1024         src/bin/lttng-consumerd/Makefile
1025         src/bin/lttng-sessiond/Makefile
1026         src/bin/lttng-relayd/Makefile
1027         src/bin/lttng/Makefile
1028         src/bin/lttng-crash/Makefile
1029         tests/Makefile
1030         tests/destructive/Makefile
1031         tests/regression/Makefile
1032         tests/regression/kernel/Makefile
1033         tests/regression/tools/Makefile
1034         tests/regression/tools/streaming/Makefile
1035         tests/regression/tools/filtering/Makefile
1036         tests/regression/tools/health/Makefile
1037         tests/regression/tools/tracefile-limits/Makefile
1038         tests/regression/tools/snapshots/Makefile
1039         tests/regression/tools/live/Makefile
1040         tests/regression/tools/exclusion/Makefile
1041         tests/regression/tools/save-load/Makefile
1042         tests/regression/tools/save-load/configuration/Makefile
1043         tests/regression/tools/mi/Makefile
1044         tests/regression/tools/wildcard/Makefile
1045         tests/regression/tools/crash/Makefile
1046         tests/regression/tools/regen-metadata/Makefile
1047         tests/regression/tools/regen-statedump/Makefile
1048         tests/regression/tools/notification/Makefile
1049         tests/regression/ust/Makefile
1050         tests/regression/ust/nprocesses/Makefile
1051         tests/regression/ust/high-throughput/Makefile
1052         tests/regression/ust/low-throughput/Makefile
1053         tests/regression/ust/before-after/Makefile
1054         tests/regression/ust/buffers-pid/Makefile
1055         tests/regression/ust/periodical-metadata-flush/Makefile
1056         tests/regression/ust/multi-session/Makefile
1057         tests/regression/ust/overlap/Makefile
1058         tests/regression/ust/overlap/demo/Makefile
1059         tests/regression/ust/linking/Makefile
1060         tests/regression/ust/daemon/Makefile
1061         tests/regression/ust/exit-fast/Makefile
1062         tests/regression/ust/fork/Makefile
1063         tests/regression/ust/libc-wrapper/Makefile
1064         tests/regression/ust/baddr-statedump/Makefile
1065         tests/regression/ust/ust-dl/Makefile
1066         tests/regression/ust/java-jul/Makefile
1067         tests/regression/ust/java-log4j/Makefile
1068         tests/regression/ust/python-logging/Makefile
1069         tests/regression/ust/getcpu-override/Makefile
1070         tests/regression/ust/clock-override/Makefile
1071         tests/regression/ust/type-declarations/Makefile
1072         tests/regression/ust/rotation-destroy-flush/Makefile
1073         tests/regression/ust/blocking/Makefile
1074         tests/stress/Makefile
1075         tests/unit/Makefile
1076         tests/unit/ini_config/Makefile
1077         tests/perf/Makefile
1078         tests/utils/Makefile
1079         tests/utils/tap/Makefile
1080         tests/utils/testapp/Makefile
1081         tests/utils/testapp/gen-ust-events/Makefile
1082         tests/utils/testapp/gen-ust-nevents/Makefile
1083         tests/utils/testapp/gen-ust-nevents-str/Makefile
1084         tests/utils/testapp/gen-ust-tracef/Makefile
1085 ])
1086
1087 # Inject variable into python test script.
1088 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1089 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1090 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1091
1092 AC_OUTPUT
1093
1094 #
1095 # Mini-report on what will be built.
1096 #
1097
1098 PPRINT_INIT
1099 PPRINT_SET_INDENT(1)
1100 PPRINT_SET_TS(38)
1101
1102 AS_ECHO
1103 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1104 AS_ECHO
1105
1106 AS_IF([test -n "$report_fold"], [
1107         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1108 ], [
1109         AS_ECHO("$version_description")
1110 ])
1111
1112 AS_ECHO
1113 PPRINT_SUBTITLE([Features])
1114
1115 # Target architecture we're building for.
1116 target_arch=$host_cpu
1117 [
1118 for f in $CFLAGS; do
1119         if test $f = "-m32"; then
1120                         target_arch="32-bit"
1121         elif test $f = "-m64"; then
1122                         target_arch="64-bit"
1123         fi
1124 done
1125 ]
1126 PPRINT_PROP_STRING([Target architecture], $target_arch)
1127
1128 # kmod enabled/disabled
1129 test "x$kmod_found" = "xyes" && value=1 || value=0
1130 PPRINT_PROP_BOOL([libkmod support], $value)
1131
1132 # LTTng-UST enabled/disabled
1133 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1134 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1135
1136 AS_ECHO
1137 PPRINT_SUBTITLE([Binaries])
1138
1139 # List binaries to be built
1140 test x$enable_bin_lttng != xno && value=1 || value=0
1141 PPRINT_PROP_BOOL([lttng], $value)
1142
1143 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1144 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1145
1146 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1147 PPRINT_PROP_BOOL([lttng-crash], $value)
1148
1149 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1150 PPRINT_PROP_BOOL([lttng-relayd], $value)
1151
1152 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1153 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1154
1155 # Extras
1156 test x$enable_extras != xno && value=1 || value=0
1157 AS_ECHO
1158 PPRINT_SET_INDENT(0)
1159 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1160 PPRINT_SET_INDENT(1)
1161
1162 AS_ECHO
1163 PPRINT_SUBTITLE([Tests])
1164
1165 # Print clear message that tests won't be built
1166 AS_IF([test "x$build_tests" = "xno"],[
1167         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1168 ])
1169
1170 # LTTng UST Java agent JUL tests enabled/disabled
1171 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1172 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1173
1174 # LTTng UST Java agent Log4j tests enabled/disabled
1175 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1176 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1177
1178 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1179 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1180
1181 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1182 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1183
1184 #Python binding enabled/disabled
1185 test "x$enable_python_binding" = xyes && value=1 || value=0
1186 AS_ECHO
1187 PPRINT_SET_INDENT(0)
1188 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1189
1190 # man pages build enabled/disabled
1191 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1192
1193 AS_IF([test "x$man_pages_opt" != "xno"], [
1194         AS_IF([test "x$in_git_repo" = "xyes"], [
1195                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1196         ], [
1197                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1198                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1199                 ], [
1200                         PPRINT_PROP_STRING([build_man_pages_msg],
1201                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1202                                 $PPRINT_COLOR_SUBTITLE)
1203                 ])
1204         ])
1205 ], [
1206         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1207 ])
1208
1209 m4_popdef([build_man_pages_msg])
1210
1211 test "x$embedded_help" = xyes && value=1 || value=0
1212 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1213
1214 PPRINT_SET_INDENT(1)
1215
1216 report_bindir="`eval eval echo $bindir`"
1217 report_libdir="`eval eval echo $libdir`"
1218
1219 # Print the bindir and libdir this `make install' will install into.
1220 AS_ECHO
1221 PPRINT_SUBTITLE([Install directories])
1222 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1223 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1224
1225 AS_ECHO
1226 PPRINT_SUBTITLE([Search directories])
1227
1228 # If we build the sessiond, print the paths it will use
1229 AS_IF([test "$SESSIOND_BIN" = ""],[
1230         path="$report_bindir/lttng-sessiond"
1231 ],[
1232         path="$SESSIOND_BIN"
1233 ])
1234 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1235
1236 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1237         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1238 ],[
1239         path="$CONSUMERD32_BIN"
1240 ])
1241 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1242
1243 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1244         path="`eval eval echo $libdir`"
1245 ],[
1246         path="$CONSUMERD32_LIBDIR"
1247 ])
1248 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1249
1250 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1251         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1252 ],[
1253         path="$CONSUMERD64_BIN"
1254 ])
1255 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1256
1257 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1258         path="`eval eval echo $libdir`"
1259 ],[
1260         path="$CONSUMERD64_LIBDIR"
1261 ])
1262 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1263 PPRINT_SET_INDENT(0)
1264
1265 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1266         AS_ECHO
1267         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1268
1269 Note that the man pages are already built in this distribution tarball,
1270 therefore asciidoc and xmlto are only needed if you intend to modify
1271 their sources.
1272
1273 Also note that the installed man pages will contain the project's
1274 default command-line option and environment variable values.
1275
1276 Use --disable-man-pages to completely disable building and installing
1277 the man pages.])
1278 ])